configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.3.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 # Checks for C compiler
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_PROG_CC
  25 AC_PROG_CC_STDC
  26
  27 # Checks for programs.
  28 AC_PROG_MAKE_SET
  29 LT_INIT
  30 AC_PROG_YACC
  31 AC_PROG_LEX
  32 AC_PROG_MKDIR_P
  33 AC_PROG_LN_S
  34
  35 AX_C___ATTRIBUTE__
  36 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  37         [:],
  38         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Check linker option
  41 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  42 AC_SUBST([LD_NO_AS_NEEDED])
  43
  44 AC_CHECK_HEADERS([fcntl.h limits.h netdb.h netinet/in.h stddef.h sys/socket.h])
  45
  46 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  47         if test x"$YACC" != "xbison -y"; then
  48                 AC_MSG_ERROR([[bison not found and is required when building from git.
  49                 Please install bison]])
  50         fi
  51         AC_PATH_PROG([BISON],[bison])
  52         AX_PROG_BISON_VERSION([2.4], [],[
  53                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  54         ])
  55 fi
  56
  57 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  58         if test x"$LEX" != "xflex"; then
  59                 AC_MSG_ERROR([[flex not found and is required when building from git.
  60                 Please install flex]])
  61         fi
  62         AC_PATH_PROG([FLEX],[flex])
  63         AX_PROG_FLEX_VERSION([2.5.35], [],[
  64                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  65         ])
  66 fi
  67
  68
  69 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  70
  71 # Checks for typedefs, structures, and compiler characteristics.
  72 AC_C_INLINE
  73 AC_TYPE_PID_T
  74 AC_TYPE_SIZE_T
  75 AC_TYPE_INT16_T
  76 AC_TYPE_INT32_T
  77 AC_TYPE_INT64_T
  78 AC_TYPE_INT8_T
  79 AC_TYPE_OFF_T
  80 AC_TYPE_SSIZE_T
  81 AC_TYPE_UINT16_T
  82 AC_TYPE_UINT32_T
  83 AC_TYPE_UINT64_T
  84 AC_TYPE_UINT8_T
  85
  86 # Checks for library functions.
  87 AC_FUNC_MALLOC
  88 AC_FUNC_MMAP
  89 AC_CHECK_FUNCS([ \
  90         gettimeofday munmap strtoul ftruncate gethostbyname \
  91         localtime_r memset mkdir rmdir setenv socket \
  92         strchr strdup strerror strndup strrchr strtoull tzset \
  93 ])
  94
  95 # Check for MinGW32.
  96 MINGW32=no
  97 case $host in
  98   *-*-mingw*)
  99         MINGW32=yes;;
 100 esac
 101
 102 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 103
 104 # Check what libraries are required on this platform to link sockets programs.
 105 AX_LIB_SOCKET_NSL
 106
 107 # Check for libuuid
 108 AC_CHECK_LIB([uuid], [uuid_generate],
 109 [
 110         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 111         have_libuuid=yes
 112 ],
 113 [
 114         # libuuid not found, check for uuid_create in libc.
 115         AC_CHECK_LIB([c], [uuid_create],
 116         [
 117                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 118                 have_libc_uuid=yes
 119         ],
 120         [
 121                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 122                 if test "x$MINGW32" = xno; then
 123                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 124                 fi
 125         ])
 126 ]
 127 )
 128 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 129 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 130
 131 # Check for fmemopen
 132 AC_CHECK_LIB([c], [fmemopen],
 133 [
 134         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 135 ]
 136 )
 137
 138 # Check for open_memstream
 139 AC_CHECK_LIB([c], [open_memstream],
 140 [
 141         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 142 ]
 143 )
 144
 145 AC_CHECK_LIB([popt], [poptGetContext], [],
 146         [AC_MSG_ERROR([Cannot find popt.])]
 147 )
 148
 149
 150 # For Python
 151 # SWIG version needed or newer:
 152 swig_version=2.0.0
 153
 154 AC_ARG_ENABLE([python-bindings],
 155               [AC_HELP_STRING([--enable-python-bindings],
 156                               [generate Python bindings])],
 157               [enable_python=yes], [enable_python=no])
 158
 159 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 160
 161 AC_ARG_ENABLE([python-bindings-doc],
 162               [AC_HELP_STRING([--enable-python-bindings-doc],
 163                               [generate Python bindings documentation])],
 164               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 165
 166 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 167   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 168 fi
 169
 170 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 171
 172 if test "x${enable_python:-yes}" = xyes; then
 173   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 174   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 175
 176   AM_PATH_PYTHON_MODULES([PYTHON])
 177   # pythondir is the path where extra modules are to be installed
 178   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 179   # pyexecdir is the path that contains shared objects used by the extra modules
 180   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 181   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 182   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 183   AS_IF([test -z "$PYTHON_INCLUDE"], [
 184     AS_IF([test -z "$PYTHON_CONFIG"], [
 185       AC_PATH_PROGS([PYTHON_CONFIG],
 186                     [python$PYTHON_VERSION-config python-config],
 187                     [no],
 188                     [`dirname $PYTHON`])
 189       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 190     ])
 191     AC_MSG_CHECKING([python include flags])
 192     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 193     AC_MSG_RESULT([$PYTHON_INCLUDE])
 194   ])
 195 else
 196     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 197 [if you want Python bindings.])
 198
 199 fi
 200
 201 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 202     AM_CHECK_PYTHON_SPHINX([PYTHON])
 203     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 204       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 205     )
 206 fi
 207
 208 pkg_modules="gmodule-2.0 >= 2.0.0"
 209 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 210 AC_SUBST(PACKAGE_LIBS)
 211
 212 LIBS="$LIBS $GMODULE_LIBS"
 213 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat -include config.h"
 214 AC_SUBST(PACKAGE_CFLAGS)
 215
 216 babeltraceincludedir="${includedir}/babeltrace"
 217 AC_SUBST(babeltraceincludedir)
 218
 219 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 220 AC_SUBST(babeltracectfincludedir)
 221
 222 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 223 AC_SUBST(babeltracectfwriterincludedir)
 224
 225 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 226 AC_SUBST(babeltracectfirincludedir)
 227
 228 AC_CONFIG_FILES([
 229         Makefile
 230         types/Makefile
 231         compat/Makefile
 232         formats/Makefile
 233         formats/ctf/Makefile
 234         formats/ctf/types/Makefile
 235         formats/ctf-text/Makefile
 236         formats/ctf-text/types/Makefile
 237         formats/ctf-metadata/Makefile
 238         formats/bt-dummy/Makefile
 239         formats/lttng-live/Makefile
 240         formats/ctf/metadata/Makefile
 241         formats/ctf/writer/Makefile
 242         formats/ctf/ir/Makefile
 243         converter/Makefile
 244         doc/Makefile
 245         doc/bindings/Makefile
 246         doc/bindings/python/Makefile
 247         lib/Makefile
 248         lib/prio_heap/Makefile
 249         include/Makefile
 250         bindings/Makefile
 251         bindings/python/Makefile
 252         tests/Makefile
 253         tests/bin/Makefile
 254         tests/lib/Makefile
 255         tests/utils/Makefile
 256         tests/utils/tap/Makefile
 257         extras/Makefile
 258         extras/valgrind/Makefile
 259         babeltrace.pc
 260         babeltrace-ctf.pc
 261 ])
 262 AC_OUTPUT