src/plugins/ctf/common/metadata/lexer.l

   1 %{
   2 /*
   3  * lexer.l
   4  *
   5  * Common Trace Formal Lexer
   6  *
   7  * Copyright 2010 - Mathieu Desnoyers <mathieu.desnoyers@efficios.com>
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a copy
  10  * of this software and associated documentation files (the "Software"), to deal
  11  * in the Software without restriction, including without limitation the rights
  12  * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  13  * copies of the Software, and to permit persons to whom the Software is
  14  * furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included in
  17  * all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  20  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  22  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  23  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  24  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  25  * SOFTWARE.
  26  */
  27
  28 #define BT_LOG_OUTPUT_LEVEL ctf_plugin_metadata_log_level
  29 #define BT_LOG_TAG "PLUGIN-CTF-METADATA-LEXER"
  30 #include "logging.h"
  31
  32 #include <stdio.h>
  33 #include <ctype.h>
  34 #include "scanner.h"
  35 #include "parser-wrap.h"
  36 #include "ast.h"
  37
  38 #define YY_FATAL_ERROR(_msg)    BT_LOGF_STR(_msg)
  39
  40 #define PARSE_INTEGER_LITERAL(base)                                     \
  41         do {                                                            \
  42                 errno = 0;                                              \
  43                 yylval->ull = strtoull(yytext, NULL, base);             \
  44                 if (errno) {                                            \
  45                         _BT_LOGE_LINENO(yylineno,                       \
  46                                 "Cannot parser constant integer: "      \
  47                                 "base=%d, text=\"%s\"", base, yytext);  \
  48                         return CTF_ERROR;                               \
  49                 }                                                       \
  50         } while (0)
  51
  52 BT_HIDDEN
  53 void setstring(struct ctf_scanner *scanner, YYSTYPE *lvalp, const char *src);
  54
  55 BT_HIDDEN
  56 int import_string(struct ctf_scanner *scanner, YYSTYPE *lvalp, const char *src, char delim);
  57
  58 %}
  59
  60 %x comment_ml comment_sl string_lit char_const
  61 %option reentrant yylineno noyywrap bison-bridge
  62 %option extra-type="struct ctf_scanner *"
  63         /* bison-locations */
  64 INTEGER_SUFFIX                  (U|UL|ULL|LU|LLU|Ul|Ull|lU|llU|u|uL|uLL|Lu|LLu|ul|ull|lu|llu)
  65 DIGIT                           [0-9]
  66 NONDIGIT                        [a-zA-Z_]
  67 HEXDIGIT                        [0-9A-Fa-f]
  68 OCTALDIGIT                      [0-7]
  69 UCHARLOWERCASE                  \\u{HEXDIGIT}{4}
  70 UCHARUPPERCASE                  \\U{HEXDIGIT}{8}
  71 ID_NONDIGIT                     {NONDIGIT}|{UCHARLOWERCASE}|{UCHARUPPERCASE}
  72 IDENTIFIER                      {ID_NONDIGIT}({ID_NONDIGIT}|{DIGIT})*
  73 %%
  74
  75                                 /*
  76                                  * Using start conditions to deal with comments
  77                                  * and strings.
  78                                  */
  79
  80 "/*"                            BEGIN(comment_ml);
  81 <comment_ml>[^*\n]*             /* eat anything that's not a '*' */
  82 <comment_ml>"*"+[^*/\n]*        /* eat up '*'s not followed by '/'s */
  83 <comment_ml>\n
  84 <comment_ml>"*"+"/"             BEGIN(INITIAL);
  85
  86 "//"[^\n]*\n                    /* skip comment */
  87
  88 L?\"(\\.|[^\\"])*\"             { if (import_string(yyextra, yylval, yytext, '\"') < 0) return CTF_ERROR; else return CTF_STRING_LITERAL; }
  89 L?\'(\\.|[^\\'])*\'             { if (import_string(yyextra, yylval, yytext, '\'') < 0) return CTF_ERROR; else return CTF_CHARACTER_LITERAL; }
  90
  91 "["                             return CTF_LSBRAC;
  92 "]"                             return CTF_RSBRAC;
  93 "("                             return CTF_LPAREN;
  94 ")"                             return CTF_RPAREN;
  95 "{"                             return CTF_LBRAC;
  96 "}"                             return CTF_RBRAC;
  97 "->"                            return CTF_RARROW;
  98 "*"                             return CTF_STAR;
  99 "+"                             return CTF_PLUS;
 100 "-"                             return CTF_MINUS;
 101 "<"                             return CTF_LT;
 102 ">"                             return CTF_GT;
 103 :=                              return CTF_TYPEASSIGN;
 104 :                               return CTF_COLON;
 105 ;                               return CTF_SEMICOLON;
 106 "..."                           return CTF_DOTDOTDOT;
 107 "."                             return CTF_DOT;
 108 =                               return CTF_EQUAL;
 109 ","                             return CTF_COMMA;
 110 align                           setstring(yyextra, yylval, yytext); return CTF_TOK_ALIGN;
 111 const                           setstring(yyextra, yylval, yytext); return CTF_CONST;
 112 char                            setstring(yyextra, yylval, yytext); return CTF_CHAR;
 113 clock                           setstring(yyextra, yylval, yytext); return CTF_CLOCK;
 114 double                          setstring(yyextra, yylval, yytext); return CTF_DOUBLE;
 115 enum                            setstring(yyextra, yylval, yytext); return CTF_ENUM;
 116 env                             setstring(yyextra, yylval, yytext); return CTF_ENV;
 117 event                           setstring(yyextra, yylval, yytext); return CTF_EVENT;
 118 floating_point                  setstring(yyextra, yylval, yytext); return CTF_FLOATING_POINT;
 119 float                           setstring(yyextra, yylval, yytext); return CTF_FLOAT;
 120 integer                         setstring(yyextra, yylval, yytext); return CTF_INTEGER;
 121 int                             setstring(yyextra, yylval, yytext); return CTF_INT;
 122 long                            setstring(yyextra, yylval, yytext); return CTF_LONG;
 123 short                           setstring(yyextra, yylval, yytext); return CTF_SHORT;
 124 signed                          setstring(yyextra, yylval, yytext); return CTF_SIGNED;
 125 stream                          setstring(yyextra, yylval, yytext); return CTF_STREAM;
 126 string                          setstring(yyextra, yylval, yytext); return CTF_STRING;
 127 struct                          setstring(yyextra, yylval, yytext); return CTF_STRUCT;
 128 trace                           setstring(yyextra, yylval, yytext); return CTF_TRACE;
 129 callsite                        setstring(yyextra, yylval, yytext); return CTF_CALLSITE;
 130 typealias                       setstring(yyextra, yylval, yytext); return CTF_TYPEALIAS;
 131 typedef                         setstring(yyextra, yylval, yytext); return CTF_TYPEDEF;
 132 unsigned                        setstring(yyextra, yylval, yytext); return CTF_UNSIGNED;
 133 variant                         setstring(yyextra, yylval, yytext); return CTF_VARIANT;
 134 void                            setstring(yyextra, yylval, yytext); return CTF_VOID;
 135 _Bool                           setstring(yyextra, yylval, yytext); return CTF_BOOL;
 136 _Complex                        setstring(yyextra, yylval, yytext); return CTF_COMPLEX;
 137 _Imaginary                      setstring(yyextra, yylval, yytext); return CTF_IMAGINARY;
 138 [1-9]{DIGIT}*{INTEGER_SUFFIX}?  PARSE_INTEGER_LITERAL(10); return CTF_INTEGER_LITERAL;
 139 0{OCTALDIGIT}*{INTEGER_SUFFIX}? PARSE_INTEGER_LITERAL(8); return CTF_INTEGER_LITERAL;
 140 0[xX]{HEXDIGIT}+{INTEGER_SUFFIX}?       PARSE_INTEGER_LITERAL(16); return CTF_INTEGER_LITERAL;
 141
 142 {IDENTIFIER}                    BT_LOGT("Got identifier: id=\"%s\"", yytext); setstring(yyextra, yylval, yytext); if (is_type(yyextra, yytext)) return ID_TYPE; else return IDENTIFIER;
 143 [ \t\r\n]                       ; /* ignore */
 144 .                               _BT_LOGE_LINENO(yylineno, "Invalid character: char=\"%c\", val=0x%02x", isprint(yytext[0]) ? yytext[0] : '\0', yytext[0]); return CTF_ERROR;
 145 %%