src/plugins/ctf/common/metadata/lexer.l

   1 %{
   2 /*
   3  * lexer.l
   4  *
   5  * Common Trace Formal Lexer
   6  *
   7  * Copyright 2010 - Mathieu Desnoyers <mathieu.desnoyers@efficios.com>
   8  *
   9  * Permission is hereby granted, free of charge, to any person obtaining a copy
  10  * of this software and associated documentation files (the "Software"), to deal
  11  * in the Software without restriction, including without limitation the rights
  12  * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  13  * copies of the Software, and to permit persons to whom the Software is
  14  * furnished to do so, subject to the following conditions:
  15  *
  16  * The above copyright notice and this permission notice shall be included in
  17  * all copies or substantial portions of the Software.
  18  *
  19  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  20  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  22  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  23  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  24  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  25  * SOFTWARE.
  26  */
  27
  28 #define BT_LOG_OUTPUT_LEVEL ctf_plugin_metadata_log_level
  29 #define BT_LOG_TAG "PLUGIN-CTF-METADATA-LEXER"
  30 #include "logging.h"
  31
  32 #include <stdio.h>
  33 #include <ctype.h>
  34 #include "scanner.h"
  35 #include "parser.h"
  36 #include "ast.h"
  37
  38 #define YY_FATAL_ERROR(_msg)    BT_LOGF_STR(_msg)
  39
  40 #define PARSE_INTEGER_LITERAL(base)                                     \
  41         do {                                                            \
  42                 errno = 0;                                              \
  43                 yylval->ull = strtoull(yytext, NULL, base);             \
  44                 if (errno) {                                            \
  45                         _BT_LOGE_LINENO(yylineno,                       \
  46                                 "Cannot parser constant integer: "      \
  47                                 "base=%d, text=\"%s\"", base, yytext);  \
  48                         return CTF_ERROR;                               \
  49                 }                                                       \
  50         } while (0)
  51
  52 BT_HIDDEN
  53 void setstring(struct ctf_scanner *scanner, YYSTYPE *lvalp, const char *src);
  54
  55 static void yyunput (int c, register char * yy_bp , yyscan_t yyscanner)
  56         __attribute__((unused));
  57 static int input (yyscan_t yyscanner) __attribute__((unused));
  58
  59 BT_HIDDEN
  60 int import_string(struct ctf_scanner *scanner, YYSTYPE *lvalp, const char *src, char delim);
  61
  62 %}
  63
  64 %x comment_ml comment_sl string_lit char_const
  65 %option reentrant yylineno noyywrap bison-bridge
  66 %option extra-type="struct ctf_scanner *"
  67         /* bison-locations */
  68 INTEGER_SUFFIX                  (U|UL|ULL|LU|LLU|Ul|Ull|lU|llU|u|uL|uLL|Lu|LLu|ul|ull|lu|llu)
  69 DIGIT                           [0-9]
  70 NONDIGIT                        [a-zA-Z_]
  71 HEXDIGIT                        [0-9A-Fa-f]
  72 OCTALDIGIT                      [0-7]
  73 UCHARLOWERCASE                  \\u{HEXDIGIT}{4}
  74 UCHARUPPERCASE                  \\U{HEXDIGIT}{8}
  75 ID_NONDIGIT                     {NONDIGIT}|{UCHARLOWERCASE}|{UCHARUPPERCASE}
  76 IDENTIFIER                      {ID_NONDIGIT}({ID_NONDIGIT}|{DIGIT})*
  77 %%
  78
  79                                 /*
  80                                  * Using start conditions to deal with comments
  81                                  * and strings.
  82                                  */
  83
  84 "/*"                            BEGIN(comment_ml);
  85 <comment_ml>[^*\n]*             /* eat anything that's not a '*' */
  86 <comment_ml>"*"+[^*/\n]*        /* eat up '*'s not followed by '/'s */
  87 <comment_ml>\n
  88 <comment_ml>"*"+"/"             BEGIN(INITIAL);
  89
  90 "//"[^\n]*\n                    /* skip comment */
  91
  92 L?\"(\\.|[^\\"])*\"             { if (import_string(yyextra, yylval, yytext, '\"') < 0) return CTF_ERROR; else return CTF_STRING_LITERAL; }
  93 L?\'(\\.|[^\\'])*\'             { if (import_string(yyextra, yylval, yytext, '\'') < 0) return CTF_ERROR; else return CTF_CHARACTER_LITERAL; }
  94
  95 "["                             return CTF_LSBRAC;
  96 "]"                             return CTF_RSBRAC;
  97 "("                             return CTF_LPAREN;
  98 ")"                             return CTF_RPAREN;
  99 "{"                             return CTF_LBRAC;
 100 "}"                             return CTF_RBRAC;
 101 "->"                            return CTF_RARROW;
 102 "*"                             return CTF_STAR;
 103 "+"                             return CTF_PLUS;
 104 "-"                             return CTF_MINUS;
 105 "<"                             return CTF_LT;
 106 ">"                             return CTF_GT;
 107 :=                              return CTF_TYPEASSIGN;
 108 :                               return CTF_COLON;
 109 ;                               return CTF_SEMICOLON;
 110 "..."                           return CTF_DOTDOTDOT;
 111 "."                             return CTF_DOT;
 112 =                               return CTF_EQUAL;
 113 ","                             return CTF_COMMA;
 114 align                           setstring(yyextra, yylval, yytext); return CTF_TOK_ALIGN;
 115 const                           setstring(yyextra, yylval, yytext); return CTF_CONST;
 116 char                            setstring(yyextra, yylval, yytext); return CTF_CHAR;
 117 clock                           setstring(yyextra, yylval, yytext); return CTF_CLOCK;
 118 double                          setstring(yyextra, yylval, yytext); return CTF_DOUBLE;
 119 enum                            setstring(yyextra, yylval, yytext); return CTF_ENUM;
 120 env                             setstring(yyextra, yylval, yytext); return CTF_ENV;
 121 event                           setstring(yyextra, yylval, yytext); return CTF_EVENT;
 122 floating_point                  setstring(yyextra, yylval, yytext); return CTF_FLOATING_POINT;
 123 float                           setstring(yyextra, yylval, yytext); return CTF_FLOAT;
 124 integer                         setstring(yyextra, yylval, yytext); return CTF_INTEGER;
 125 int                             setstring(yyextra, yylval, yytext); return CTF_INT;
 126 long                            setstring(yyextra, yylval, yytext); return CTF_LONG;
 127 short                           setstring(yyextra, yylval, yytext); return CTF_SHORT;
 128 signed                          setstring(yyextra, yylval, yytext); return CTF_SIGNED;
 129 stream                          setstring(yyextra, yylval, yytext); return CTF_STREAM;
 130 string                          setstring(yyextra, yylval, yytext); return CTF_STRING;
 131 struct                          setstring(yyextra, yylval, yytext); return CTF_STRUCT;
 132 trace                           setstring(yyextra, yylval, yytext); return CTF_TRACE;
 133 callsite                        setstring(yyextra, yylval, yytext); return CTF_CALLSITE;
 134 typealias                       setstring(yyextra, yylval, yytext); return CTF_TYPEALIAS;
 135 typedef                         setstring(yyextra, yylval, yytext); return CTF_TYPEDEF;
 136 unsigned                        setstring(yyextra, yylval, yytext); return CTF_UNSIGNED;
 137 variant                         setstring(yyextra, yylval, yytext); return CTF_VARIANT;
 138 void                            setstring(yyextra, yylval, yytext); return CTF_VOID;
 139 _Bool                           setstring(yyextra, yylval, yytext); return CTF_BOOL;
 140 _Complex                        setstring(yyextra, yylval, yytext); return CTF_COMPLEX;
 141 _Imaginary                      setstring(yyextra, yylval, yytext); return CTF_IMAGINARY;
 142 [1-9]{DIGIT}*{INTEGER_SUFFIX}?  PARSE_INTEGER_LITERAL(10); return CTF_INTEGER_LITERAL;
 143 0{OCTALDIGIT}*{INTEGER_SUFFIX}? PARSE_INTEGER_LITERAL(8); return CTF_INTEGER_LITERAL;
 144 0[xX]{HEXDIGIT}+{INTEGER_SUFFIX}?       PARSE_INTEGER_LITERAL(16); return CTF_INTEGER_LITERAL;
 145
 146 {IDENTIFIER}                    BT_LOGT("Got identifier: id=\"%s\"", yytext); setstring(yyextra, yylval, yytext); if (is_type(yyextra, yytext)) return ID_TYPE; else return IDENTIFIER;
 147 [ \t\r\n]                       ; /* ignore */
 148 .                               _BT_LOGE_LINENO(yylineno, "Invalid character: char=\"%c\", val=0x%02x", isprint(yytext[0]) ? yytext[0] : '\0', yytext[0]); return CTF_ERROR;
 149 %%