binutils/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2020 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([binutils], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ar.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_ISC_POSIX
  26
  27 AM_INIT_AUTOMAKE
  28
  29 AC_PROG_CC
  30 AC_GNU_SOURCE
  31 AC_USE_SYSTEM_EXTENSIONS
  32
  33 LT_INIT
  34 ACX_LARGEFILE
  35
  36 AC_ARG_ENABLE(targets,
  37 [  --enable-targets        alternative target configurations],
  38 [case "${enableval}" in
  39   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  40             ;;
  41   no)       enable_targets= ;;
  42   *)        enable_targets=$enableval ;;
  43 esac])dnl
  44
  45 AC_ARG_ENABLE(deterministic-archives,
  46 [AS_HELP_STRING([--enable-deterministic-archives],
  47                 [ar and ranlib default to -D behavior])], [
  48 if test "${enableval}" = no; then
  49   default_ar_deterministic=0
  50 else
  51   default_ar_deterministic=1
  52 fi], [default_ar_deterministic=0])
  53
  54 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  55                    [Should ar and ranlib use -D behavior by default?])
  56
  57 AC_ARG_ENABLE(default-strings-all,
  58 [AS_HELP_STRING([--disable-default-strings-all],
  59                 [strings defaults to --data behavior])], [
  60 if test "${enableval}" = no; then
  61   default_strings_all=0
  62 else
  63   default_strings_all=1
  64 fi], [default_strings_all=1])
  65
  66 AC_DEFINE_UNQUOTED(DEFAULT_STRINGS_ALL, $default_strings_all,
  67                    [Should strings use -a behavior by default?])
  68
  69 AM_BINUTILS_WARNINGS
  70
  71 AC_CONFIG_HEADERS(config.h:config.in)
  72
  73 AH_VERBATIM([00_CONFIG_H_CHECK],
  74 [/* Check that config.h is #included before system headers
  75    (this works only for glibc, but that should be enough).  */
  76 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  77 #  error config.h must be #included before system headers
  78 #endif
  79 #define __CONFIG_H__ 1])
  80
  81 if test -z "$target" ; then
  82     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  83 fi
  84 if test -z "$host" ; then
  85     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  86 fi
  87
  88 AC_PROG_YACC
  89 AM_PROG_LEX
  90
  91 ALL_LINGUAS="bg ca da es fi fr hr id it ja pt ro ru rw sk sr sv tr uk vi zh_CN zh_TW"
  92 ZW_GNU_GETTEXT_SISTER_DIR
  93 AM_PO_SUBDIRS
  94
  95 AM_MAINTAINER_MODE
  96 AM_CONDITIONAL(GENINSRC_NEVER, false)
  97 AC_EXEEXT
  98 if test -n "$EXEEXT"; then
  99   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
 100             [Does the platform use an executable suffix?])
 101 fi
 102 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
 103                    [Suffix used for executables, if any.])
 104
 105 # host-specific stuff:
 106
 107 HDEFINES=
 108
 109 . ${srcdir}/../bfd/configure.host
 110
 111 AC_SUBST(HDEFINES)
 112 AR=${AR-ar}
 113 AC_SUBST(AR)
 114 AC_PROG_RANLIB
 115 AC_PROG_INSTALL
 116
 117 BFD_CC_FOR_BUILD
 118
 119 DEMANGLER_NAME=c++filt
 120 case "${host}" in
 121   *-*-go32* | *-*-msdos*)
 122     DEMANGLER_NAME=cxxfilt
 123 esac
 124 AC_SUBST(DEMANGLER_NAME)
 125
 126 AC_CHECK_SIZEOF([long])
 127 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 128
 129 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h locale.h sys/param.h wchar.h)
 130 AC_HEADER_SYS_WAIT
 131 ACX_HEADER_STRING
 132 AC_FUNC_ALLOCA
 133 AC_FUNC_MMAP
 134 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll setlocale)
 135 AC_CHECK_FUNC([mkstemp],
 136               AC_DEFINE([HAVE_MKSTEMP], 1,
 137               [Define to 1 if you have the `mkstemp' function.]))
 138 AC_CHECK_FUNC([mkdtemp],
 139               AC_DEFINE([HAVE_MKDTEMP], 1,
 140               [Define to 1 if you have the `mkdtemp' function.]))
 141   AC_MSG_CHECKING([for mbstate_t])
 142   AC_TRY_COMPILE([#include <wchar.h>],
 143   [mbstate_t teststate;],
 144   have_mbstate_t=yes, have_mbstate_t=no)
 145   AC_MSG_RESULT($have_mbstate_t)
 146   if test x"$have_mbstate_t" = xyes; then
 147     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 148   fi
 149
 150 # Some systems have frexp only in -lm, not in -lc.
 151 AC_SEARCH_LIBS(frexp, m)
 152
 153 AM_LC_MESSAGES
 154
 155 AC_MSG_CHECKING(for time_t in time.h)
 156 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 157 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 158 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 159 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 160 if test $bu_cv_decl_time_t_time_h = yes; then
 161   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 162             [Is the type time_t defined in <time.h>?])
 163 fi
 164
 165 AC_MSG_CHECKING(for time_t in sys/types.h)
 166 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 167 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 168 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 169 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 170 if test $bu_cv_decl_time_t_types_h = yes; then
 171   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 172             [Is the type time_t defined in <sys/types.h>?])
 173 fi
 174
 175 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 176 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 177 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 178 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 179 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 180 if test $bu_cv_decl_getopt_unistd_h = yes; then
 181   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 182             [Is the prototype for getopt in <unistd.h> in the expected format?])
 183 fi
 184
 185 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 186 # by default.
 187 AC_MSG_CHECKING([for utime.h])
 188 AC_CACHE_VAL(bu_cv_header_utime_h,
 189 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 190 #ifdef HAVE_TIME_H
 191 #include <time.h>
 192 #endif
 193 #include <utime.h>],
 194 [struct utimbuf s;])],
 195 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 196 AC_MSG_RESULT($bu_cv_header_utime_h)
 197 if test $bu_cv_header_utime_h = yes; then
 198   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 199 fi
 200
 201 AC_CHECK_DECLS([asprintf, environ, fprintf, getc_unlocked, getenv,
 202                 sbrk, snprintf, stpcpy, strnlen, strstr, vsnprintf])
 203
 204 # Link in zlib if we can.  This allows us to read compressed debug
 205 # sections.  This is used only by readelf.c (objdump uses bfd for
 206 # reading compressed sections).
 207 AM_ZLIB
 208
 209 BFD_BINARY_FOPEN
 210
 211 # target-specific stuff:
 212
 213 # Canonicalize the secondary target names.
 214 if test -n "$enable_targets"; then
 215     for targ in `echo $enable_targets | sed 's/,/ /g'`
 216     do
 217         result=`$ac_config_sub $targ 2>/dev/null`
 218         if test -n "$result"; then
 219             canon_targets="$canon_targets $result"
 220         else
 221             # Allow targets that config.sub doesn't recognize, like "all".
 222             canon_targets="$canon_targets $targ"
 223         fi
 224     done
 225 fi
 226
 227 AC_CHECK_HEADER(iconv.h)
 228 AM_ICONV
 229
 230 all_targets=false
 231 BUILD_SRCONV=
 232 BUILD_DLLTOOL=
 233 DLLTOOL_DEFS=
 234 DLLTOOL_DEFAULT=
 235 BUILD_WINDRES=
 236 BUILD_WINDMC=
 237 BUILD_DLLWRAP=
 238 BUILD_MISC=
 239 BUILD_INSTALL_MISC=
 240 OBJDUMP_DEFS=
 241 OBJDUMP_PRIVATE_VECTORS=
 242 OBJDUMP_PRIVATE_OFILES=
 243 od_vectors=
 244
 245 for targ in $target $canon_targets
 246 do
 247     if test "x$targ" = "xall"; then
 248         all_targets=true
 249         BUILD_SRCONV='$(SRCONV_PROG)'
 250         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 251         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 252         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 253         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 254         if test -z "$DLLTOOL_DEFAULT"; then
 255           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 256         fi
 257         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 258         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 259         od_vectors="$od_vectors objdump_private_desc_xcoff"
 260     else
 261         case $targ in
 262         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 263         esac
 264
 265         case $targ in
 266         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 267           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 268           if test -z "$DLLTOOL_DEFAULT"; then
 269             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 270           fi
 271           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 272           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 273           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 274           ;;
 275         arm-*-pe*)
 276           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 277           if test -z "$DLLTOOL_DEFAULT"; then
 278             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 279           fi
 280           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 281           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 282           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 283           ;;
 284         x86_64-*-mingw* | x86_64-*-cygwin*)
 285           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 286           if test -z "$DLLTOOL_DEFAULT"; then
 287             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 288           fi
 289           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 290           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 291           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 292           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 293           ;;
 294 changequote(,)dnl
 295         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 296 changequote([,])dnl
 297           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 298           if test -z "$DLLTOOL_DEFAULT"; then
 299             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 300           fi
 301           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 302           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 303           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 304           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 305           ;;
 306 changequote(,)dnl
 307         i[3-7]86-*-interix)
 308 changequote([,])dnl
 309           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 310           if test -z "$DLLTOOL_DEFAULT"; then
 311             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 312           fi
 313           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 314           ;;
 315 changequote(,)dnl
 316         powerpc*-aix5.[01])
 317 changequote([,])dnl
 318           ;;
 319 changequote(,)dnl
 320         powerpc*-aix[5-9].*)
 321 changequote([,])dnl
 322           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 323           ;;
 324         powerpc*-*-pe* | powerpc*-*-cygwin*)
 325           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 326           if test -z "$DLLTOOL_DEFAULT"; then
 327             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 328           fi
 329           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 330           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 331           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 332           ;;
 333         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 334           case "$BUILD_INSTALL_MISC" in
 335             *embedspu*) ;;
 336             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 337           esac
 338           ;;
 339         sh*-*-pe)
 340           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 341           if test -z "$DLLTOOL_DEFAULT"; then
 342             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 343           fi
 344           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 345           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 346           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 347           ;;
 348         spu-*-*)
 349           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 350           ;;
 351         mips*-*-pe)
 352           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 353           if test -z "$DLLTOOL_DEFAULT"; then
 354             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 355           fi
 356           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 357           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 358           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 359           ;;
 360         mcore-*-pe)
 361           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 362           if test -z "$DLLTOOL_DEFAULT"; then
 363             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 364           fi
 365           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 366           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 367           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 368           ;;
 369         mcore-*-elf)
 370           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 371           if test -z "$DLLTOOL_DEFAULT"; then
 372             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 373           fi
 374           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 375           ;;
 376         mep-*)
 377           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 378           ;;
 379         esac
 380
 381         # Add objdump private vectors.
 382         case $targ in
 383         avr-*-*)
 384           od_vectors="$od_vectors objdump_private_desc_elf32_avr"
 385           ;;
 386         powerpc*-*-aix* | rs6000-*-aix*)
 387           od_vectors="$od_vectors objdump_private_desc_xcoff"
 388           ;;
 389         *-*-darwin*)
 390           od_vectors="$od_vectors objdump_private_desc_mach_o"
 391           ;;
 392         esac
 393     fi
 394 done
 395
 396 # Uniq objdump private vector, build objdump target ofiles.
 397 od_files=
 398 f=""
 399 for i in $od_vectors ; do
 400     case " $f " in
 401     *" $i "*) ;;
 402     *)
 403         f="$f $i"
 404         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 405         case $i in
 406         objdump_private_desc_elf32_avr)
 407             od_files="$od_files od-elf32_avr" ;;
 408         objdump_private_desc_xcoff)
 409             od_files="$od_files od-xcoff" ;;
 410         objdump_private_desc_mach_o)
 411             od_files="$od_files od-macho" ;;
 412         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 413         esac
 414         ;;
 415     esac
 416 done
 417
 418 # Uniq objdump target ofiles
 419 f=""
 420 for i in $od_files ; do
 421     case " $f " in
 422     *" $i "*) ;;
 423     *)
 424         f="$f $i"
 425         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 426         ;;
 427     esac
 428 done
 429
 430 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 431
 432 if test "${with_windres+set}" = set; then
 433           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 434 fi
 435
 436 if test "${with_windmc+set}" = set; then
 437           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 438 fi
 439
 440 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 441
 442 AC_SUBST(BUILD_SRCONV)
 443 AC_SUBST(BUILD_DLLTOOL)
 444 AC_SUBST(DLLTOOL_DEFS)
 445 AC_SUBST(BUILD_WINDRES)
 446 AC_SUBST(BUILD_WINDMC)
 447 AC_SUBST(BUILD_DLLWRAP)
 448 AC_SUBST(BUILD_MISC)
 449 AC_SUBST(BUILD_INSTALL_MISC)
 450 AC_SUBST(OBJDUMP_DEFS)
 451 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 452
 453 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 454
 455 targ=$target
 456 . $srcdir/../bfd/config.bfd
 457 if test "x$targ_underscore" = "xyes"; then
 458     UNDERSCORE=1
 459 else
 460     UNDERSCORE=0
 461 fi
 462 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 463  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 464
 465 # Emulation
 466 targ=$target
 467 . ${srcdir}/configure.tgt
 468 EMULATION=$targ_emul
 469 EMULATION_VECTOR=$targ_emul_vector
 470
 471 AC_SUBST(EMULATION)
 472 AC_SUBST(EMULATION_VECTOR)
 473
 474 # Required for html and install-html
 475 AC_SUBST(datarootdir)
 476 AC_SUBST(docdir)
 477 AC_SUBST(htmldir)
 478 AC_SUBST(pdfdir)
 479
 480 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 481 AC_OUTPUT