configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/debuginfod.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo"
 167
 168 # these tools are built using the target libraries, and are intended to
 169 # run only in the target environment
 170 #
 171 # note: any program that *uses* libraries that are in the "target_libraries"
 172 # list belongs in this list.
 173 #
 174 target_tools="target-rda"
 175
 176 ################################################################################
 177
 178 ## All tools belong in one of the four categories, and are assigned above
 179 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 180 ## is important because configure will choke if they ever get through.
 181 ## ${configdirs} is directories we build using the host tools.
 182 ## ${target_configdirs} is directories we build using the target tools.
 183 configdirs=`echo ${host_libs} ${host_tools}`
 184 target_configdirs=`echo ${target_libraries} ${target_tools}`
 185 build_configdirs=`echo ${build_libs} ${build_tools}`
 186
 187 m4_divert_text([PARSE_ARGS],
 188 [case $srcdir in
 189   *" "*)
 190 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 191     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 192 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 193     ;;
 194 esac
 195 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 196 ])
 197
 198 ################################################################################
 199
 200 srcname="gnu development package"
 201
 202 # This gets set non-empty for some net releases of packages.
 203 appdirs=""
 204
 205 # Define is_cross_compiler to save on calls to 'test'.
 206 is_cross_compiler=
 207 if test x"${host}" = x"${target}" ; then
 208   is_cross_compiler=no
 209 else
 210   is_cross_compiler=yes
 211 fi
 212
 213 # Find the build and target subdir names.
 214 GCC_TOPLEV_SUBDIRS
 215 # Be sure to cover against remnants of an in-tree build.
 216 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 217   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 218 Use a pristine source tree when building in a separate tree])
 219 fi
 220
 221 # Skipdirs are removed silently.
 222 skipdirs=
 223 # Noconfigdirs are removed loudly.
 224 noconfigdirs=""
 225
 226 use_gnu_ld=
 227 # Make sure we don't let GNU ld be added if we didn't want it.
 228 if test x$with_gnu_ld = xno ; then
 229   use_gnu_ld=no
 230   noconfigdirs="$noconfigdirs ld gold"
 231 fi
 232
 233 use_gnu_as=
 234 # Make sure we don't let GNU as be added if we didn't want it.
 235 if test x$with_gnu_as = xno ; then
 236   use_gnu_as=no
 237   noconfigdirs="$noconfigdirs gas"
 238 fi
 239
 240 use_included_zlib=
 241 AC_ARG_WITH(system-zlib,
 242 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 243 # Make sure we don't let ZLIB be added if we didn't want it.
 244 if test x$with_system_zlib = xyes ; then
 245   use_included_zlib=no
 246   noconfigdirs="$noconfigdirs zlib"
 247 fi
 248
 249 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 250 # is provided.
 251 if test x$with_system_readline = xyes ; then
 252   noconfigdirs="$noconfigdirs readline"
 253 fi
 254
 255 # some tools are so dependent upon X11 that if we're not building with X,
 256 # it's not even worth trying to configure, much less build, that tool.
 257
 258 case ${with_x} in
 259   yes | "") ;; # the default value for this tree is that X11 is available
 260   no)
 261     skipdirs="${skipdirs} tk itcl libgui"
 262     # We won't be able to build gdbtk without X.
 263     enable_gdbtk=no
 264     ;;
 265   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 266 esac
 267
 268 # Some are only suitable for cross toolchains.
 269 # Remove these if host=target.
 270 cross_only="target-libgloss target-newlib target-opcodes"
 271
 272 case $is_cross_compiler in
 273   no) skipdirs="${skipdirs} ${cross_only}" ;;
 274 esac
 275
 276 # If both --with-headers and --with-libs are specified, default to
 277 # --without-newlib.
 278 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 279    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 280   if test x"${with_newlib}" = x ; then
 281     with_newlib=no
 282   fi
 283 fi
 284
 285 # Recognize --with-newlib/--without-newlib.
 286 case ${with_newlib} in
 287   no) skipdirs="${skipdirs} target-newlib" ;;
 288   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 289 esac
 290
 291 AC_ARG_ENABLE(as-accelerator-for,
 292 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 293                 [build as offload target compiler.
 294                 Specify offload host triple by ARG])])
 295
 296 AC_ARG_ENABLE(offload-targets,
 297 [AS_HELP_STRING([--enable-offload-targets=LIST],
 298                 [enable offloading to devices from comma-separated LIST of
 299                 TARGET[=DIR]. Use optional path to find offload target compiler
 300                 during the build])],
 301 [
 302   if test x"$enable_offload_targets" = x; then
 303     AC_MSG_ERROR([no offload targets specified])
 304   fi
 305 ], [enable_offload_targets=])
 306
 307 # Handle --enable-gold, --enable-ld.
 308 # --disable-gold [--enable-ld]
 309 #     Build only ld.  Default option.
 310 # --enable-gold [--enable-ld]
 311 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 312 #     as "ld.bfd" and "ld".
 313 # --enable-gold=default [--enable-ld]
 314 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 315 #     install ld as "ld.bfd".
 316 # --enable-gold[=default] --disable-ld
 317 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 318 # --enable-gold --enable-ld=default
 319 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 320 #     and ld.bfd).
 321 #     In other words, ld is default
 322 # --enable-gold=default --enable-ld=default
 323 #     Error.
 324
 325 default_ld=
 326 AC_ARG_ENABLE(gold,
 327 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 328                 [build gold @<:@ARG={default,yes,no}@:>@])],
 329 ENABLE_GOLD=$enableval,
 330 ENABLE_GOLD=no)
 331 case "${ENABLE_GOLD}" in
 332   yes|default)
 333     # Check for ELF target.
 334     is_elf=no
 335     case "${target}" in
 336       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 337       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 338       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 339       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 340         case "${target}" in
 341           *-*-linux*aout* | *-*-linux*oldld*)
 342             ;;
 343           *)
 344             is_elf=yes
 345             ;;
 346         esac
 347     esac
 348
 349     if test "$is_elf" = "yes"; then
 350       # Check for target supported by gold.
 351       case "${target}" in
 352         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 353         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 354           configdirs="$configdirs gold"
 355           if test x${ENABLE_GOLD} = xdefault; then
 356             default_ld=gold
 357           fi
 358           ENABLE_GOLD=yes
 359           ;;
 360       esac
 361     fi
 362     ;;
 363   no)
 364     ;;
 365   *)
 366     AC_MSG_ERROR([invalid --enable-gold argument])
 367     ;;
 368 esac
 369
 370 AC_ARG_ENABLE(ld,
 371 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 372                 [build ld @<:@ARG={default,yes,no}@:>@])],
 373 ENABLE_LD=$enableval,
 374 ENABLE_LD=yes)
 375
 376 case "${ENABLE_LD}" in
 377   default)
 378     if test x${default_ld} != x; then
 379       AC_MSG_ERROR([either gold or ld can be the default ld])
 380     fi
 381     ;;
 382   yes)
 383     ;;
 384   no)
 385     if test x${ENABLE_GOLD} != xyes; then
 386       AC_MSG_WARN([neither ld nor gold are enabled])
 387     fi
 388     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 389     ;;
 390   *)
 391     AC_MSG_ERROR([invalid --enable-ld argument])
 392     ;;
 393 esac
 394
 395 # PR gas/19109
 396 # Decide the default method for compressing debug sections.
 397 # Provide a configure time option to override our default.
 398 AC_ARG_ENABLE(compressed_debug_sections,
 399 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 400                 [Enable compressed debug sections for gas, gold or ld by
 401                  default])],
 402 [
 403   if test x"$enable_compressed_debug_sections" = xyes; then
 404     AC_MSG_ERROR([no program with compressed debug sections specified])
 405   fi
 406 ], [enable_compressed_debug_sections=])
 407
 408 # Configure extra directories which are host specific
 409
 410 case "${host}" in
 411   *-cygwin*)
 412     configdirs="$configdirs libtermcap" ;;
 413 esac
 414
 415 # A target can indicate whether a language isn't supported for some reason.
 416 # Only spaces may be used in this macro; not newlines or tabs.
 417 unsupported_languages=
 418
 419 # Remove more programs from consideration, based on the host or
 420 # target this usually means that a port of the program doesn't
 421 # exist yet.
 422
 423 case "${host}" in
 424   i[[3456789]]86-*-msdosdjgpp*)
 425     noconfigdirs="$noconfigdirs tcl tk itcl"
 426     ;;
 427 esac
 428
 429
 430 AC_ARG_ENABLE(libquadmath,
 431 AS_HELP_STRING([--disable-libquadmath],
 432   [do not build libquadmath directory]),
 433 ENABLE_LIBQUADMATH=$enableval,
 434 ENABLE_LIBQUADMATH=yes)
 435 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 436   noconfigdirs="$noconfigdirs target-libquadmath"
 437 fi
 438
 439
 440 AC_ARG_ENABLE(libquadmath-support,
 441 AS_HELP_STRING([--disable-libquadmath-support],
 442   [disable libquadmath support for Fortran]),
 443 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 444 ENABLE_LIBQUADMATH_SUPPORT=yes)
 445 enable_libquadmath_support=
 446 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 447   enable_libquadmath_support=no
 448 fi
 449
 450
 451 AC_ARG_ENABLE(libada,
 452 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 453 ENABLE_LIBADA=$enableval,
 454 ENABLE_LIBADA=yes)
 455 if test "${ENABLE_LIBADA}" != "yes" ; then
 456   noconfigdirs="$noconfigdirs gnattools"
 457 fi
 458
 459 AC_ARG_ENABLE(libssp,
 460 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 461 ENABLE_LIBSSP=$enableval,
 462 ENABLE_LIBSSP=yes)
 463
 464 AC_ARG_ENABLE(libstdcxx,
 465 AS_HELP_STRING([--disable-libstdcxx],
 466   [do not build libstdc++-v3 directory]),
 467 ENABLE_LIBSTDCXX=$enableval,
 468 ENABLE_LIBSTDCXX=default)
 469 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 470   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 471 fi]
 472
 473 # If this is accelerator compiler and its target is intelmic we enable
 474 # target liboffloadmic by default.  If this is compiler with offloading
 475 # for intelmic we enable host liboffloadmic by default.  Otherwise
 476 # liboffloadmic is disabled by default.
 477 AC_ARG_ENABLE([liboffloadmic],
 478 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 479                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 480 [case "$enableval" in
 481   no | host | target)
 482     enable_liboffloadmic=$enableval ;;
 483   *)
 484     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 485 esac],
 486 [if test x"$enable_as_accelerator_for" != x; then
 487   case "${target}" in
 488     *-intelmic-* | *-intelmicemul-*)
 489       enable_liboffloadmic=target
 490       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 491       ;;
 492     *)
 493       enable_liboffloadmic=no
 494       ;;
 495   esac
 496 else
 497   case "${enable_offload_targets}" in
 498     *-intelmic-* | *-intelmicemul-*)
 499       enable_liboffloadmic=host
 500       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 501       ;;
 502     *)
 503       enable_liboffloadmic=no
 504       ;;
 505     esac
 506 fi])
 507 AC_SUBST(extra_liboffloadmic_configure_flags)
 508
 509 # Enable libgomp by default on hosted POSIX systems, and a few others.
 510 if test x$enable_libgomp = x ; then
 511     case "${target}" in
 512     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 513         ;;
 514     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 515         ;;
 516     *-*-solaris2* | *-*-hpux11*)
 517         ;;
 518     *-*-darwin* | *-*-aix*)
 519         ;;
 520     nvptx*-*-*)
 521         ;;
 522     *)
 523         noconfigdirs="$noconfigdirs target-libgomp"
 524         ;;
 525     esac
 526 fi
 527
 528 # Disable libatomic on unsupported systems.
 529 if test -d ${srcdir}/libatomic; then
 530     if test x$enable_libatomic = x; then
 531         AC_MSG_CHECKING([for libatomic support])
 532         if (srcdir=${srcdir}/libatomic; \
 533                 . ${srcdir}/configure.tgt; \
 534                 test -n "$UNSUPPORTED")
 535         then
 536             AC_MSG_RESULT([no])
 537             noconfigdirs="$noconfigdirs target-libatomic"
 538         else
 539             AC_MSG_RESULT([yes])
 540         fi
 541     fi
 542 fi
 543
 544 # Disable liboffloadmic on unsupported systems.
 545 if test -d ${srcdir}/liboffloadmic; then
 546     if test x$enable_liboffloadmic != xno; then
 547         AC_MSG_CHECKING([for liboffloadmic support])
 548         if (srcdir=${srcdir}/liboffloadmic; \
 549                 . ${srcdir}/configure.tgt; \
 550                 test -n "$UNSUPPORTED")
 551         then
 552             AC_MSG_RESULT([no])
 553             noconfigdirs="$noconfigdirs target-liboffloadmic"
 554         else
 555             AC_MSG_RESULT([yes])
 556         fi
 557     fi
 558 fi
 559
 560 # Disable libitm on unsupported systems.
 561 if test -d ${srcdir}/libitm; then
 562     if test x$enable_libitm = x; then
 563         AC_MSG_CHECKING([for libitm support])
 564         if (srcdir=${srcdir}/libitm; \
 565                 . ${srcdir}/configure.tgt; \
 566                 test -n "$UNSUPPORTED")
 567         then
 568             AC_MSG_RESULT([no])
 569             noconfigdirs="$noconfigdirs target-libitm"
 570         else
 571             AC_MSG_RESULT([yes])
 572         fi
 573     fi
 574 fi
 575
 576 # Disable libsanitizer on unsupported systems.
 577 if test -d ${srcdir}/libsanitizer; then
 578     if test x$enable_libsanitizer = x; then
 579         AC_MSG_CHECKING([for libsanitizer support])
 580         if (srcdir=${srcdir}/libsanitizer; \
 581                 . ${srcdir}/configure.tgt; \
 582                 test -n "$UNSUPPORTED")
 583         then
 584             AC_MSG_RESULT([no])
 585             noconfigdirs="$noconfigdirs target-libsanitizer"
 586         else
 587             AC_MSG_RESULT([yes])
 588         fi
 589     fi
 590 fi
 591
 592 # Disable libvtv on unsupported systems.
 593 if test -d ${srcdir}/libvtv; then
 594     if test x$enable_libvtv = x; then
 595         AC_MSG_CHECKING([for libvtv support])
 596         if (srcdir=${srcdir}/libvtv; \
 597                 . ${srcdir}/configure.tgt; \
 598                 test "$VTV_SUPPORTED" != "yes")
 599         then
 600             AC_MSG_RESULT([no])
 601             noconfigdirs="$noconfigdirs target-libvtv"
 602         else
 603             AC_MSG_RESULT([yes])
 604         fi
 605     fi
 606 fi
 607
 608
 609 # Disable libhsail-rt on unsupported systems.
 610 if test -d ${srcdir}/libhsail-rt; then
 611     if test x$enable_libhsail_rt = x; then
 612         AC_MSG_CHECKING([for libhsail-rt support])
 613         if (srcdir=${srcdir}/libhsail-rt; \
 614                 . ${srcdir}/configure.tgt; \
 615                 test -n "$UNSUPPORTED")
 616         then
 617             AC_MSG_RESULT([no])
 618             unsupported_languages="$unsupported_languages brig"
 619             # This implicitly disables also target-libhsail-rt as it won't
 620             # get added to the build without BRIG FE.
 621         else
 622             AC_MSG_RESULT([yes])
 623         fi
 624     fi
 625 fi
 626
 627
 628 # Disable libquadmath for some systems.
 629 case "${target}" in
 630   avr-*-*)
 631     noconfigdirs="$noconfigdirs target-libquadmath"
 632     ;;
 633   # libquadmath is unused on AIX and libquadmath build process use of
 634   # LD_LIBRARY_PATH can break AIX bootstrap.
 635   powerpc-*-aix* | rs6000-*-aix*)
 636     noconfigdirs="$noconfigdirs target-libquadmath"
 637     ;;
 638 esac
 639
 640 # Disable libssp for some systems.
 641 case "${target}" in
 642   avr-*-*)
 643     # No hosted I/O support.
 644     noconfigdirs="$noconfigdirs target-libssp"
 645     ;;
 646   powerpc-*-aix* | rs6000-*-aix*)
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649   rl78-*-*)
 650     # libssp uses a misaligned load to trigger a fault, but the RL78
 651     # doesn't fault for those - instead, it gives a build-time error
 652     # for explicit misaligned loads.
 653     noconfigdirs="$noconfigdirs target-libssp"
 654     ;;
 655   visium-*-*)
 656     # No hosted I/O support.
 657     noconfigdirs="$noconfigdirs target-libssp"
 658     ;;
 659 esac
 660
 661 # Disable libstdc++-v3 for some systems.
 662 # Allow user to override this if they pass --enable-libstdc++-v3
 663 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 664   case "${target}" in
 665     *-*-vxworks*)
 666       # VxWorks uses the Dinkumware C++ library.
 667       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 668       ;;
 669     arm*-wince-pe*)
 670       # the C++ libraries don't build on top of CE's C libraries
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     avr-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676     ft32-*-*)
 677       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 678       ;;
 679   esac
 680 fi
 681
 682 # Disable Fortran for some systems.
 683 case "${target}" in
 684   mmix-*-*)
 685     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 686     unsupported_languages="$unsupported_languages fortran"
 687     ;;
 688 esac
 689
 690 # Disable libffi for some systems.
 691 case "${target}" in
 692   powerpc-*-darwin*)
 693     ;;
 694   i[[3456789]]86-*-darwin*)
 695     ;;
 696   x86_64-*-darwin[[912]]*)
 697     ;;
 698   *-*-darwin*)
 699     noconfigdirs="$noconfigdirs target-libffi"
 700     ;;
 701   *-*-netware*)
 702     noconfigdirs="$noconfigdirs target-libffi"
 703     ;;
 704   *-*-phoenix*)
 705     noconfigdirs="$noconfigdirs target-libffi"
 706     ;;
 707   *-*-rtems*)
 708     noconfigdirs="$noconfigdirs target-libffi"
 709     ;;
 710   *-*-tpf*)
 711     noconfigdirs="$noconfigdirs target-libffi"
 712     ;;
 713   *-*-uclinux*)
 714     noconfigdirs="$noconfigdirs target-libffi"
 715     ;;
 716   *-*-vxworks*)
 717     noconfigdirs="$noconfigdirs target-libffi"
 718     ;;
 719   aarch64*-*-freebsd*)
 720     noconfigdirs="$noconfigdirs target-libffi"
 721     ;;
 722   alpha*-*-*vms*)
 723     noconfigdirs="$noconfigdirs target-libffi"
 724     ;;
 725   arm*-*-freebsd*)
 726     noconfigdirs="$noconfigdirs target-libffi"
 727     ;;
 728   arm-wince-pe)
 729     noconfigdirs="$noconfigdirs target-libffi"
 730     ;;
 731   arm*-*-symbianelf*)
 732     noconfigdirs="$noconfigdirs target-libffi"
 733     ;;
 734   cris-*-* | crisv32-*-*)
 735     case "${target}" in
 736       *-*-linux*)
 737         ;;
 738       *) # See PR46792 regarding target-libffi.
 739         noconfigdirs="$noconfigdirs target-libffi";;
 740     esac
 741     ;;
 742   hppa*64*-*-hpux*)
 743     noconfigdirs="$noconfigdirs target-libffi"
 744     ;;
 745   hppa*-hp-hpux11*)
 746     ;;
 747   hppa*-*-hpux*)
 748     noconfigdirs="$noconfigdirs target-libffi"
 749     ;;
 750   ia64*-*-*vms*)
 751     noconfigdirs="$noconfigdirs target-libffi"
 752     ;;
 753   i[[3456789]]86-w64-mingw*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   i[[3456789]]86-*-mingw*)
 757     noconfigdirs="$noconfigdirs target-libffi"
 758     ;;
 759   x86_64-*-mingw*)
 760     noconfigdirs="$noconfigdirs target-libffi"
 761     ;;
 762   mmix-*-*)
 763     noconfigdirs="$noconfigdirs target-libffi"
 764     ;;
 765   powerpc-*-aix*)
 766     ;;
 767   rs6000-*-aix*)
 768     ;;
 769   ft32-*-*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   *-*-lynxos*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775 esac
 776
 777 # Disable the go frontend on systems where it is known to not work. Please keep
 778 # this in sync with contrib/config-list.mk.
 779 case "${target}" in
 780 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 781     unsupported_languages="$unsupported_languages go"
 782     ;;
 783 esac
 784
 785 # Disable libgo for some systems where it is known to not work.
 786 # For testing, you can easily override this with --enable-libgo.
 787 if test x$enable_libgo = x; then
 788     case "${target}" in
 789     *-*-darwin*)
 790         # PR 46986
 791         noconfigdirs="$noconfigdirs target-libgo"
 792         ;;
 793     *-*-cygwin* | *-*-mingw*)
 794         noconfigdirs="$noconfigdirs target-libgo"
 795         ;;
 796     esac
 797 fi
 798
 799 # Default libgloss CPU subdirectory.
 800 libgloss_dir="$target_cpu"
 801
 802 case "${target}" in
 803   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 804     libgloss_dir=wince
 805     ;;
 806   aarch64*-*-* )
 807     libgloss_dir=aarch64
 808     ;;
 809   arm*-*-*)
 810     libgloss_dir=arm
 811     ;;
 812   cris-*-* | crisv32-*-*)
 813     libgloss_dir=cris
 814     ;;
 815   hppa*-*-*)
 816     libgloss_dir=pa
 817     ;;
 818   i[[3456789]]86-*-*)
 819     libgloss_dir=i386
 820     ;;
 821   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 822     libgloss_dir=m68hc11
 823     ;;
 824   m68*-*-* | fido-*-*)
 825     libgloss_dir=m68k
 826     ;;
 827   mips*-*-*)
 828     libgloss_dir=mips
 829     ;;
 830   powerpc*-*-*)
 831     libgloss_dir=rs6000
 832     ;;
 833   sparc*-*-*)
 834     libgloss_dir=sparc
 835     ;;
 836 esac
 837
 838 # Disable newlib and libgloss for various target OSes.
 839 case "${target}" in
 840   alpha*-dec-osf*)
 841     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 842     ;;
 843   i[[3456789]]86-*-linux*)
 844     # This section makes it possible to build newlib natively on linux.
 845     # If we are using a cross compiler then don't configure newlib.
 846     if test x${is_cross_compiler} != xno ; then
 847       noconfigdirs="$noconfigdirs target-newlib"
 848     fi
 849     noconfigdirs="$noconfigdirs target-libgloss"
 850     # If we are not using a cross compiler, do configure newlib.
 851     # Note however, that newlib will only be configured in this situation
 852     # if the --with-newlib option has been given, because otherwise
 853     # 'target-newlib' will appear in skipdirs.
 854     ;;
 855   i[[3456789]]86-*-rdos*)
 856     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 857     ;;
 858   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 859     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 860     ;;
 861   sparc-*-sunos4*)
 862     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 863     ;;
 864   *-*-aix*)
 865     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 866     ;;
 867   *-*-beos*)
 868     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 869     ;;
 870   *-*-chorusos)
 871     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 872     ;;
 873   *-*-dragonfly*)
 874     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 875     ;;
 876   *-*-freebsd*)
 877     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 878     ;;
 879   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 880     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 881     ;;
 882   *-*-lynxos*)
 883     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 884     ;;
 885   *-*-mingw*)
 886     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 887     ;;
 888   *-*-netbsd*)
 889     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 890     ;;
 891   *-*-netware*)
 892     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 893     ;;
 894   *-*-tpf*)
 895     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 896     ;;
 897   *-*-uclinux*)
 898     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 899     ;;
 900   *-*-vxworks*)
 901     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 902     ;;
 903 esac
 904
 905 case "${target}" in
 906   *-*-chorusos)
 907     ;;
 908   aarch64-*-darwin*)
 909     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 910     noconfigdirs="$noconfigdirs sim target-rda"
 911     ;;
 912   arm-*-darwin*)
 913     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 914     noconfigdirs="$noconfigdirs sim target-rda"
 915     ;;
 916   powerpc-*-darwin*)
 917     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 918     noconfigdirs="$noconfigdirs sim target-rda"
 919     ;;
 920   i[[3456789]]86-*-darwin*)
 921     noconfigdirs="$noconfigdirs ld gprof"
 922     noconfigdirs="$noconfigdirs sim target-rda"
 923     ;;
 924   x86_64-*-darwin[[912]]*)
 925     noconfigdirs="$noconfigdirs ld gas gprof"
 926     noconfigdirs="$noconfigdirs sim target-rda"
 927     ;;
 928   *-*-darwin*)
 929     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 930     noconfigdirs="$noconfigdirs sim target-rda"
 931     ;;
 932   *-*-dragonfly*)
 933     ;;
 934   *-*-freebsd*)
 935     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 936         && test -f /usr/local/include/gmp.h; then
 937       with_gmp=/usr/local
 938     fi
 939     ;;
 940   *-*-kaos*)
 941     # Remove unsupported stuff on all kaOS configurations.
 942     noconfigdirs="$noconfigdirs target-libgloss"
 943     ;;
 944   *-*-netbsd*)
 945     ;;
 946   *-*-netware*)
 947     ;;
 948   *-*-phoenix*)
 949     noconfigdirs="$noconfigdirs target-libgloss"
 950     ;;
 951   *-*-rtems*)
 952     noconfigdirs="$noconfigdirs target-libgloss"
 953     ;;
 954     # The tpf target doesn't support gdb yet.
 955   *-*-tpf*)
 956     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 957     ;;
 958   *-*-uclinux*)
 959     noconfigdirs="$noconfigdirs target-rda"
 960     ;;
 961   *-*-vxworks*)
 962     ;;
 963   alpha*-dec-osf*)
 964     # ld works, but does not support shared libraries.
 965     # gas doesn't generate exception information.
 966     noconfigdirs="$noconfigdirs gas ld"
 967     ;;
 968   alpha*-*-*vms*)
 969     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 970     ;;
 971   alpha*-*-*)
 972     # newlib is not 64 bit ready
 973     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 974     ;;
 975   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 976     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 977     ;;
 978   arc*-*-*)
 979     noconfigdirs="$noconfigdirs sim"
 980     ;;
 981   arm-*-pe*)
 982     noconfigdirs="$noconfigdirs target-libgloss"
 983     ;;
 984   arm-*-riscix*)
 985     noconfigdirs="$noconfigdirs ld target-libgloss"
 986     ;;
 987   avr-*-*)
 988     if test x${with_avrlibc} != xno; then
 989       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     fi
 991     ;;
 992   c4x-*-* | tic4x-*-*)
 993     noconfigdirs="$noconfigdirs target-libgloss"
 994     ;;
 995   tic54x-*-*)
 996     noconfigdirs="$noconfigdirs target-libgloss gdb"
 997     ;;
 998   d10v-*-*)
 999     noconfigdirs="$noconfigdirs target-libgloss"
1000     ;;
1001   d30v-*-*)
1002     noconfigdirs="$noconfigdirs gdb"
1003     ;;
1004   fr30-*-elf*)
1005     noconfigdirs="$noconfigdirs gdb"
1006     ;;
1007   ft32-*-*)
1008     noconfigdirs="$noconfigdirs target-rda gprof"
1009     ;;
1010   moxie-*-*)
1011     noconfigdirs="$noconfigdirs"
1012     ;;
1013   h8300*-*-*)
1014     noconfigdirs="$noconfigdirs target-libgloss"
1015     ;;
1016   h8500-*-*)
1017     noconfigdirs="$noconfigdirs target-libgloss"
1018     ;;
1019   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1020     ;;
1021   hppa*64*-*-hpux*)
1022     noconfigdirs="$noconfigdirs gdb"
1023     ;;
1024   hppa*-*-hpux11*)
1025     noconfigdirs="$noconfigdirs gdb ld"
1026     ;;
1027   hppa*64*-*-linux*)
1028     ;;
1029   hppa*-*-linux*)
1030     ;;
1031   hppa*-*-*elf* | \
1032   hppa*-*-lites* | \
1033   hppa*-*-openbsd* | \
1034   hppa*64*-*-*)
1035     ;;
1036   hppa*-*-pro*)
1037     ;;
1038   hppa*-*-*)
1039     noconfigdirs="$noconfigdirs ld"
1040     ;;
1041   i960-*-*)
1042     noconfigdirs="$noconfigdirs gdb"
1043     ;;
1044   ia64*-*-elf*)
1045     # No gdb support yet.
1046     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1047     ;;
1048   ia64*-**-hpux*)
1049     # No ld support yet.
1050     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1051     ;;
1052   ia64*-*-*vms*)
1053     # No ld support yet.
1054     noconfigdirs="$noconfigdirs libgui itcl ld"
1055     ;;
1056   i[[3456789]]86-w64-mingw*)
1057     ;;
1058   i[[3456789]]86-*-mingw*)
1059     target_configdirs="$target_configdirs target-winsup"
1060     ;;
1061   *-*-cygwin*)
1062     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1063     noconfigdirs="$noconfigdirs target-libgloss"
1064     # always build newlib if winsup directory is present.
1065     if test -d "$srcdir/winsup/cygwin"; then
1066       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1067     elif test -d "$srcdir/newlib"; then
1068       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1069     fi
1070     ;;
1071   i[[3456789]]86-*-pe)
1072     noconfigdirs="$noconfigdirs target-libgloss"
1073     ;;
1074   i[[3456789]]86-*-sco3.2v5*)
1075     # The linker does not yet know about weak symbols in COFF,
1076     # and is not configured to handle mixed ELF and COFF.
1077     noconfigdirs="$noconfigdirs ld target-libgloss"
1078     ;;
1079   i[[3456789]]86-*-sco*)
1080     noconfigdirs="$noconfigdirs gprof target-libgloss"
1081     ;;
1082   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1083     noconfigdirs="$noconfigdirs target-libgloss"
1084     ;;
1085   i[[3456789]]86-*-sysv4*)
1086     noconfigdirs="$noconfigdirs target-libgloss"
1087     ;;
1088   i[[3456789]]86-*-beos*)
1089     noconfigdirs="$noconfigdirs gdb"
1090     ;;
1091   i[[3456789]]86-*-rdos*)
1092     noconfigdirs="$noconfigdirs gdb"
1093     ;;
1094   mmix-*-*)
1095     noconfigdirs="$noconfigdirs gdb"
1096     ;;
1097   mt-*-*)
1098     noconfigdirs="$noconfigdirs sim"
1099     ;;
1100   nfp-*-*)
1101     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1102     noconfigdirs="$noconfigdirs $target_libraries"
1103     ;;
1104   powerpc-*-aix*)
1105     # copied from rs6000-*-* entry
1106     noconfigdirs="$noconfigdirs gprof"
1107     ;;
1108   powerpc*-*-winnt* | powerpc*-*-pe*)
1109     target_configdirs="$target_configdirs target-winsup"
1110     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1111     # always build newlib.
1112     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1113     ;;
1114     # This is temporary until we can link against shared libraries
1115   powerpcle-*-solaris*)
1116     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1117     ;;
1118   powerpc-*-beos*)
1119     noconfigdirs="$noconfigdirs gdb"
1120     ;;
1121   rs6000-*-lynxos*)
1122     noconfigdirs="$noconfigdirs gprof"
1123     ;;
1124   rs6000-*-aix*)
1125     noconfigdirs="$noconfigdirs gprof"
1126     ;;
1127   rs6000-*-*)
1128     noconfigdirs="$noconfigdirs gprof"
1129     ;;
1130   m68k-apollo-*)
1131     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1132     ;;
1133   microblaze*)
1134     noconfigdirs="$noconfigdirs gprof"
1135     ;;
1136   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1137     if test x$with_newlib = xyes; then
1138       noconfigdirs="$noconfigdirs gprof"
1139     fi
1140     ;;
1141   mips*-*-irix5*)
1142     noconfigdirs="$noconfigdirs gprof target-libgloss"
1143     ;;
1144   mips*-*-irix6*)
1145     noconfigdirs="$noconfigdirs gprof target-libgloss"
1146     ;;
1147   mips*-*-bsd*)
1148     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1149     ;;
1150   mips*-*-linux*)
1151     ;;
1152   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1153   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1154     noconfigdirs="$noconfigdirs ld gas gprof"
1155     ;;
1156   mips*-*-*)
1157     noconfigdirs="$noconfigdirs gprof"
1158     ;;
1159   nvptx*-*-*)
1160     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1161     ;;
1162   sh-*-*)
1163     case "${target}" in
1164       sh*-*-elf)
1165          ;;
1166       *)
1167          noconfigdirs="$noconfigdirs target-libgloss" ;;
1168     esac
1169     ;;
1170   sparc-*-sunos4*)
1171     if test x${is_cross_compiler} = xno ; then
1172            use_gnu_ld=no
1173     fi
1174     ;;
1175   tic6x-*-*)
1176     noconfigdirs="$noconfigdirs sim"
1177     ;;
1178   tilepro*-*-* | tilegx*-*-*)
1179     noconfigdirs="$noconfigdirs sim"
1180     ;;
1181   v810-*-*)
1182     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1183     ;;
1184   vax-*-*)
1185     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1186     ;;
1187   wasm32-*-*)
1188     noconfigdirs="$noconfigdirs ld"
1189     ;;
1190 esac
1191
1192 # If we aren't building newlib, then don't build libgloss, since libgloss
1193 # depends upon some newlib header files.
1194 case "${noconfigdirs}" in
1195   *target-libgloss*) ;;
1196   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1197 esac
1198
1199 # Work in distributions that contain no compiler tools, like Autoconf.
1200 host_makefile_frag=/dev/null
1201 if test -d ${srcdir}/config ; then
1202 case "${host}" in
1203   i[[3456789]]86-*-msdosdjgpp*)
1204     host_makefile_frag="config/mh-djgpp"
1205     ;;
1206   *-cygwin*)
1207     ACX_CHECK_CYGWIN_CAT_WORKS
1208     host_makefile_frag="config/mh-cygwin"
1209     ;;
1210   *-mingw*)
1211     host_makefile_frag="config/mh-mingw"
1212     ;;
1213   alpha*-linux*)
1214     host_makefile_frag="config/mh-alpha-linux"
1215     ;;
1216   hppa*-hp-hpux10*)
1217     host_makefile_frag="config/mh-pa-hpux10"
1218     ;;
1219   hppa*-hp-hpux*)
1220     host_makefile_frag="config/mh-pa"
1221     ;;
1222   hppa*-*)
1223     host_makefile_frag="config/mh-pa"
1224     ;;
1225   *-*-darwin*)
1226     host_makefile_frag="config/mh-darwin"
1227     ;;
1228   powerpc-*-aix*)
1229     host_makefile_frag="config/mh-ppc-aix"
1230     ;;
1231   rs6000-*-aix*)
1232     host_makefile_frag="config/mh-ppc-aix"
1233     ;;
1234 esac
1235 fi
1236
1237 if test "${build}" != "${host}" ; then
1238   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1239   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1240   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1241   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1242   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1243   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1244   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1245   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1246   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1247   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1248   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1249   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1250 else
1251   AR_FOR_BUILD="\$(AR)"
1252   AS_FOR_BUILD="\$(AS)"
1253   CC_FOR_BUILD="\$(CC)"
1254   CXX_FOR_BUILD="\$(CXX)"
1255   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1256   GOC_FOR_BUILD="\$(GOC)"
1257   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1258   LD_FOR_BUILD="\$(LD)"
1259   NM_FOR_BUILD="\$(NM)"
1260   RANLIB_FOR_BUILD="\$(RANLIB)"
1261   WINDRES_FOR_BUILD="\$(WINDRES)"
1262   WINDMC_FOR_BUILD="\$(WINDMC)"
1263 fi
1264
1265 AC_PROG_CC
1266 AC_PROG_CXX
1267
1268 # We must set the default linker to the linker used by gcc for the correct
1269 # operation of libtool.  If LD is not defined and we are using gcc, try to
1270 # set the LD default to the ld used by gcc.
1271 if test -z "$LD"; then
1272   if test "$GCC" = yes; then
1273     case $build in
1274     *-*-mingw*)
1275       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1276     *)
1277       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1278     esac
1279     case $gcc_prog_ld in
1280     # Accept absolute paths.
1281     [[\\/]* | [A-Za-z]:[\\/]*)]
1282       LD="$gcc_prog_ld" ;;
1283     esac
1284   fi
1285 fi
1286
1287 # Check whether -static-libstdc++ -static-libgcc is supported.
1288 have_static_libs=no
1289 if test "$GCC" = yes; then
1290   saved_LDFLAGS="$LDFLAGS"
1291
1292   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1293   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1294   AC_LANG_PUSH(C++)
1295   AC_LINK_IFELSE([AC_LANG_SOURCE([
1296 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1297 #error -static-libstdc++ not implemented
1298 #endif
1299 int main() {}])],
1300     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1301     [AC_MSG_RESULT([no])])
1302   AC_LANG_POP(C++)
1303
1304   LDFLAGS="$saved_LDFLAGS"
1305 fi
1306
1307 ACX_PROG_GNAT
1308 ACX_PROG_CMP_IGNORE_INITIAL
1309
1310 AC_ARG_ENABLE([bootstrap],
1311 [AS_HELP_STRING([--enable-bootstrap],
1312                 [enable bootstrapping @<:@yes if native build@:>@])],,
1313 enable_bootstrap=default)
1314
1315 # Issue errors and warnings for invalid/strange bootstrap combinations.
1316 if test -r $srcdir/gcc/configure; then
1317   have_compiler=yes
1318 else
1319   have_compiler=no
1320 fi
1321
1322 case "$have_compiler:$host:$target:$enable_bootstrap" in
1323   *:*:*:no) ;;
1324
1325   # Default behavior.  Enable bootstrap if we have a compiler
1326   # and we are in a native configuration.
1327   yes:$build:$build:default)
1328     enable_bootstrap=yes ;;
1329
1330   *:*:*:default)
1331     enable_bootstrap=no ;;
1332
1333   # We have a compiler and we are in a native configuration, bootstrap is ok
1334   yes:$build:$build:yes)
1335     ;;
1336
1337   # Other configurations, but we have a compiler.  Assume the user knows
1338   # what he's doing.
1339   yes:*:*:yes)
1340     AC_MSG_WARN([trying to bootstrap a cross compiler])
1341     ;;
1342
1343   # No compiler: if they passed --enable-bootstrap explicitly, fail
1344   no:*:*:yes)
1345     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1346
1347   # Fail if wrong command line
1348   *)
1349     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1350     ;;
1351 esac
1352
1353 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1354 # C++98 compiler can still start the bootstrap.
1355 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1356   CXX="$CXX -std=gnu++98"
1357 fi
1358
1359 # Used for setting $lt_cv_objdir
1360 _LT_CHECK_OBJDIR
1361
1362 # Check for GMP, MPFR and MPC
1363 gmplibs="-lmpc -lmpfr -lgmp"
1364 gmpinc=
1365 have_gmp=no
1366
1367 # Check for debuginfod
1368 AC_DEBUGINFOD
1369
1370 # Specify a location for mpc
1371 # check for this first so it ends up on the link line before mpfr.
1372 AC_ARG_WITH(mpc,
1373 [AS_HELP_STRING([--with-mpc=PATH],
1374                 [specify prefix directory for installed MPC package.
1375                  Equivalent to --with-mpc-include=PATH/include
1376                  plus --with-mpc-lib=PATH/lib])])
1377 AC_ARG_WITH(mpc-include,
1378 [AS_HELP_STRING([--with-mpc-include=PATH],
1379                 [specify directory for installed MPC include files])])
1380 AC_ARG_WITH(mpc-lib,
1381 [AS_HELP_STRING([--with-mpc-lib=PATH],
1382                 [specify directory for the installed MPC library])])
1383
1384 if test "x$with_mpc" != x; then
1385   gmplibs="-L$with_mpc/lib $gmplibs"
1386   gmpinc="-I$with_mpc/include $gmpinc"
1387 fi
1388 if test "x$with_mpc_include" != x; then
1389   gmpinc="-I$with_mpc_include $gmpinc"
1390 fi
1391 if test "x$with_mpc_lib" != x; then
1392   gmplibs="-L$with_mpc_lib $gmplibs"
1393 fi
1394 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1395   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1396   gmpinc='-I$$s/mpc/src '"$gmpinc"
1397   # Do not test the mpc version.  Assume that it is sufficient, since
1398   # it is in the source tree, and the library has not been built yet
1399   # but it would be included on the link line in the version check below
1400   # hence making the test fail.
1401   have_gmp=yes
1402 fi
1403
1404 # Specify a location for mpfr
1405 # check for this first so it ends up on the link line before gmp.
1406 AC_ARG_WITH(mpfr-dir,
1407 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1408 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1409 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1410
1411 AC_ARG_WITH(mpfr,
1412 [AS_HELP_STRING([--with-mpfr=PATH],
1413                 [specify prefix directory for installed MPFR package.
1414                  Equivalent to --with-mpfr-include=PATH/include
1415                  plus --with-mpfr-lib=PATH/lib])])
1416 AC_ARG_WITH(mpfr-include,
1417 [AS_HELP_STRING([--with-mpfr-include=PATH],
1418                 [specify directory for installed MPFR include files])])
1419 AC_ARG_WITH(mpfr-lib,
1420 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1421                 [specify directory for the installed MPFR library])])
1422
1423 if test "x$with_mpfr" != x; then
1424   gmplibs="-L$with_mpfr/lib $gmplibs"
1425   gmpinc="-I$with_mpfr/include $gmpinc"
1426 fi
1427 if test "x$with_mpfr_include" != x; then
1428   gmpinc="-I$with_mpfr_include $gmpinc"
1429 fi
1430 if test "x$with_mpfr_lib" != x; then
1431   gmplibs="-L$with_mpfr_lib $gmplibs"
1432 fi
1433 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1434   # MPFR v3.1.0 moved the sources into a src sub-directory.
1435   if ! test -d ${srcdir}/mpfr/src; then
1436     AC_MSG_ERROR([dnl
1437 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1438   fi
1439   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1440   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1441   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1442   # Do not test the mpfr version.  Assume that it is sufficient, since
1443   # it is in the source tree, and the library has not been built yet
1444   # but it would be included on the link line in the version check below
1445   # hence making the test fail.
1446   have_gmp=yes
1447 fi
1448
1449 # Specify a location for gmp
1450 AC_ARG_WITH(gmp-dir,
1451 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1452 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1453 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1454
1455 AC_ARG_WITH(gmp,
1456 [AS_HELP_STRING([--with-gmp=PATH],
1457                 [specify prefix directory for the installed GMP package.
1458                  Equivalent to --with-gmp-include=PATH/include
1459                  plus --with-gmp-lib=PATH/lib])])
1460 AC_ARG_WITH(gmp-include,
1461 [AS_HELP_STRING([--with-gmp-include=PATH],
1462                 [specify directory for installed GMP include files])])
1463 AC_ARG_WITH(gmp-lib,
1464 [AS_HELP_STRING([--with-gmp-lib=PATH],
1465                 [specify directory for the installed GMP library])])
1466
1467
1468 if test "x$with_gmp" != x; then
1469   gmplibs="-L$with_gmp/lib $gmplibs"
1470   gmpinc="-I$with_gmp/include $gmpinc"
1471 fi
1472 if test "x$with_gmp_include" != x; then
1473   gmpinc="-I$with_gmp_include $gmpinc"
1474 fi
1475 if test "x$with_gmp_lib" != x; then
1476   gmplibs="-L$with_gmp_lib $gmplibs"
1477 fi
1478 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1479   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1480   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1481   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1482   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1483   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1484   # Do not test the gmp version.  Assume that it is sufficient, since
1485   # it is in the source tree, and the library has not been built yet
1486   # but it would be included on the link line in the version check below
1487   # hence making the test fail.
1488   have_gmp=yes
1489 fi
1490
1491 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1492   have_gmp=yes
1493   saved_CFLAGS="$CFLAGS"
1494   CFLAGS="$CFLAGS $gmpinc"
1495   # Check for the recommended and required versions of GMP.
1496   AC_MSG_CHECKING([for the correct version of gmp.h])
1497   AC_TRY_COMPILE([#include "gmp.h"],[
1498   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1499   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1500   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1501   choke me
1502   #endif
1503   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1504   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1505   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1506   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1507   choke me
1508   #endif
1509   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1510    [AC_MSG_RESULT([no]); have_gmp=no])
1511
1512   # If we have GMP, check the MPFR version.
1513   if test x"$have_gmp" = xyes; then
1514     # Check for the recommended and required versions of MPFR.
1515     AC_MSG_CHECKING([for the correct version of mpfr.h])
1516     AC_TRY_COMPILE([#include <gmp.h>
1517     #include <mpfr.h>],[
1518     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1519     choke me
1520     #endif
1521     ], [AC_TRY_COMPILE([#include <gmp.h>
1522     #include <mpfr.h>],[
1523     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1524     choke me
1525     #endif
1526     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1527      [AC_MSG_RESULT([no]); have_gmp=no])
1528   fi
1529
1530   # Check for the MPC header version.
1531   if test x"$have_gmp" = xyes ; then
1532     # Check for the recommended and required versions of MPC.
1533     AC_MSG_CHECKING([for the correct version of mpc.h])
1534     AC_TRY_COMPILE([#include <mpc.h>],[
1535     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1536     choke me
1537     #endif
1538     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1539     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1540     choke me
1541     #endif
1542     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1543      [AC_MSG_RESULT([no]); have_gmp=no])
1544   fi
1545
1546   # Now check the MPFR library.
1547   if test x"$have_gmp" = xyes; then
1548     saved_LIBS="$LIBS"
1549     LIBS="$LIBS $gmplibs"
1550     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1551     AC_TRY_LINK([#include <mpc.h>],[
1552     mpfr_t n;
1553     mpfr_t x;
1554     mpc_t c;
1555     int t;
1556     mpfr_init (n);
1557     mpfr_init (x);
1558     mpfr_atan2 (n, n, x, GMP_RNDN);
1559     mpfr_erfc (n, x, GMP_RNDN);
1560     mpfr_subnormalize (x, t, GMP_RNDN);
1561     mpfr_clear(n);
1562     mpfr_clear(x);
1563     mpc_init2 (c, 53);
1564     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1565     mpc_cosh (c, c, MPC_RNDNN);
1566     mpc_pow (c, c, c, MPC_RNDNN);
1567     mpc_acosh (c, c, MPC_RNDNN);
1568     mpc_clear (c);
1569     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1570     LIBS="$saved_LIBS"
1571   fi
1572
1573   CFLAGS="$saved_CFLAGS"
1574
1575 # The library versions listed in the error message below should match
1576 # the HARD-minimums enforced above.
1577   if test x$have_gmp != xyes; then
1578     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1579 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1580 their locations.  Source code for these libraries can be found at
1581 their respective hosting sites as well as at
1582 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1583 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1584 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1585 make sure that you have installed both the libraries and the header
1586 files.  They may be located in separate packages.])
1587   fi
1588 fi
1589
1590 # Flags needed for both GMP, MPFR and/or MPC.
1591 AC_SUBST(gmplibs)
1592 AC_SUBST(gmpinc)
1593 AC_SUBST(extra_mpfr_configure_flags)
1594 AC_SUBST(extra_mpc_gmp_configure_flags)
1595 AC_SUBST(extra_mpc_mpfr_configure_flags)
1596 AC_SUBST(extra_isl_gmp_configure_flags)
1597
1598 # Libraries to use for stage1 or when not bootstrapping.
1599 AC_ARG_WITH(stage1-libs,
1600 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1601 [if test "$withval" = "no" -o "$withval" = "yes"; then
1602    stage1_libs=
1603  else
1604    stage1_libs=$withval
1605  fi],
1606 [stage1_libs=])
1607 AC_SUBST(stage1_libs)
1608
1609 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1610 # default is yes if gcc is being built; no otherwise.  The reason for
1611 # this default is that gdb is sometimes linked against GNU Source
1612 # Highlight, which is a shared library that uses C++ exceptions.  In
1613 # this case, -static-libstdc++ will cause crashes.
1614 AC_ARG_WITH(static-standard-libraries,
1615 [AS_HELP_STRING([--with-static-standard-libraries],
1616                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1617 [], [with_static_standard_libraries=auto])
1618 if test "$with_static_standard_libraries" = auto; then
1619   with_static_standard_libraries=$have_compiler
1620 fi
1621
1622 # Linker flags to use for stage1 or when not bootstrapping.
1623 AC_ARG_WITH(stage1-ldflags,
1624 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1625 [if test "$withval" = "no" -o "$withval" = "yes"; then
1626    stage1_ldflags=
1627  else
1628    stage1_ldflags=$withval
1629  fi],
1630 [stage1_ldflags=
1631  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1632  # if supported.  But if the user explicitly specified the libraries to use,
1633  # trust that they are doing what they want.
1634  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1635      -a "$have_static_libs" = yes; then
1636    stage1_ldflags="-static-libstdc++ -static-libgcc"
1637  fi])
1638 AC_SUBST(stage1_ldflags)
1639
1640 # Libraries to use for stage2 and later builds.
1641 AC_ARG_WITH(boot-libs,
1642 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1643 [if test "$withval" = "no" -o "$withval" = "yes"; then
1644    poststage1_libs=
1645  else
1646    poststage1_libs=$withval
1647  fi],
1648 [poststage1_libs=])
1649 AC_SUBST(poststage1_libs)
1650
1651 # Linker flags to use for stage2 and later builds.
1652 AC_ARG_WITH(boot-ldflags,
1653 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1654                 [linker flags for stage2 and later])],
1655 [if test "$withval" = "no" -o "$withval" = "yes"; then
1656    poststage1_ldflags=
1657  else
1658    poststage1_ldflags=$withval
1659  fi],
1660 [poststage1_ldflags=
1661  # In stages 2 and 3, default to linking libstdc++ and libgcc
1662  # statically.  But if the user explicitly specified the libraries to
1663  # use, trust that they are doing what they want.
1664  if test "$poststage1_libs" = ""; then
1665    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1666  fi])
1667 AC_SUBST(poststage1_ldflags)
1668
1669 # GCC GRAPHITE dependency isl.
1670 # Basic setup is inlined here, actual checks are in config/isl.m4
1671
1672 AC_ARG_WITH(isl,
1673   [AS_HELP_STRING(
1674    [--with-isl=PATH],
1675    [Specify prefix directory for the installed isl package.
1676     Equivalent to --with-isl-include=PATH/include
1677     plus --with-isl-lib=PATH/lib])])
1678
1679 # Treat --without-isl as a request to disable
1680 # GRAPHITE support and skip all following checks.
1681 if test "x$with_isl" != "xno"; then
1682   # Check for isl
1683   dnl Provide configure switches and initialize islinc & isllibs
1684   dnl with user input.
1685   ISL_INIT_FLAGS
1686   dnl The versions of isl that work for Graphite
1687   ISL_CHECK_VERSION()
1688   dnl Only execute fail-action, if isl has been requested.
1689   ISL_IF_FAILED([
1690     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1691 fi
1692
1693 # If the isl check failed, disable builds of in-tree variant of isl
1694 if test "x$with_isl" = xno ||
1695    test "x$gcc_cv_isl" = xno; then
1696   noconfigdirs="$noconfigdirs isl"
1697   islinc=
1698 fi
1699
1700 AC_SUBST(isllibs)
1701 AC_SUBST(islinc)
1702
1703 # Check for LTO support.
1704 AC_ARG_ENABLE(lto,
1705 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1706 enable_lto=$enableval,
1707 enable_lto=yes; default_enable_lto=yes)
1708
1709 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1710   build_lto_plugin=yes
1711 ],[if test x"$default_enable_lto" = x"yes" ; then
1712     case $target in
1713       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1714       # On other non-ELF platforms, LTO has yet to be validated.
1715       *) enable_lto=no ;;
1716     esac
1717   else
1718   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1719   # It would also be nice to check the binutils support, but we don't
1720   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1721   # warn during gcc/ subconfigure; unless you're bootstrapping with
1722   # -flto it won't be needed until after installation anyway.
1723     case $target in
1724       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1725       *) if test x"$enable_lto" = x"yes"; then
1726         AC_MSG_ERROR([LTO support is not enabled for this target.])
1727         fi
1728       ;;
1729     esac
1730   fi
1731   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1732   # Build it unless LTO was explicitly disabled.
1733   case $target in
1734     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1735     *) ;;
1736   esac
1737 ])
1738
1739 AC_ARG_ENABLE(linker-plugin-configure-flags,
1740   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1741     [additional flags for configuring linker plugins @<:@none@:>@])],
1742   extra_linker_plugin_configure_flags=$enableval,
1743   extra_linker_plugin_configure_flags=)
1744 AC_SUBST(extra_linker_plugin_configure_flags)
1745 AC_ARG_ENABLE(linker-plugin-flags,
1746   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1747     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1748   extra_linker_plugin_flags=$enableval,
1749   extra_linker_plugin_flags=)
1750 AC_SUBST(extra_linker_plugin_flags)
1751
1752 # Enable --enable-host-shared.
1753 # Checked early to determine whether jit is an 'all' language
1754 AC_ARG_ENABLE(host-shared,
1755 [AS_HELP_STRING([--enable-host-shared],
1756                 [build host code as shared libraries])],
1757 [host_shared=$enableval], [host_shared=no])
1758 AC_SUBST(host_shared)
1759
1760 # By default, C and C++ are the only stage 1 languages.
1761 stage1_languages=,c,
1762
1763 # Target libraries that we bootstrap.
1764 bootstrap_target_libs=,target-libgcc,
1765
1766 # Figure out what language subdirectories are present.
1767 # Look if the user specified --enable-languages="..."; if not, use
1768 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1769 # go away some day.
1770 # NB:  embedded tabs in this IF block -- do not untabify
1771 if test -d ${srcdir}/gcc; then
1772   if test x"${enable_languages+set}" != xset; then
1773     if test x"${LANGUAGES+set}" = xset; then
1774       enable_languages="${LANGUAGES}"
1775         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1776     else
1777       enable_languages=default
1778     fi
1779   else
1780     if test x"${enable_languages}" = x ||
1781        test x"${enable_languages}" = xyes;
1782        then
1783       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1784       exit 1
1785     fi
1786   fi
1787   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1788
1789   # 'f95' is the old name for the 'fortran' language. We issue a warning
1790   # and make the substitution.
1791   case ,${enable_languages}, in
1792     *,f95,*)
1793       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1794       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1795       ;;
1796   esac
1797
1798   # If bootstrapping, C++ must be enabled.
1799   case ",$enable_languages,:$enable_bootstrap" in
1800     *,c++,*:*) ;;
1801     *:yes)
1802       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1803         enable_languages="${enable_languages},c++"
1804       else
1805         AC_MSG_ERROR([bootstrapping requires c++ sources])
1806       fi
1807       ;;
1808   esac
1809
1810   # First scan to see if an enabled language requires some other language.
1811   # We assume that a given config-lang.in will list all the language
1812   # front ends it requires, even if some are required indirectly.
1813   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1814     case ${lang_frag} in
1815       ..) ;;
1816       # The odd quoting in the next line works around
1817       # an apparent bug in bash 1.12 on linux.
1818       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1819       *)
1820         # From the config-lang.in, get $language, $lang_requires, and
1821         # $lang_requires_boot_languages.
1822         language=
1823         lang_requires=
1824         lang_requires_boot_languages=
1825         # set srcdir during sourcing lang_frag to the gcc dir.
1826         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1827         # polutes this shell
1828         saved_srcdir=${srcdir}
1829         srcdir=${srcdir}/gcc . ${lang_frag}
1830         srcdir=${saved_srcdir}
1831         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1832           case ,${enable_languages}, in
1833             *,$other,*) ;;
1834             *,default,*) ;;
1835             *,all,*) ;;
1836             *,$language,*)
1837               echo " \`$other' language required by \`$language'; enabling" 1>&2
1838               enable_languages="${enable_languages},${other}"
1839               ;;
1840           esac
1841         done
1842         for other in ${lang_requires_boot_languages} ; do
1843           if test "$other" != "c"; then
1844             case ,${enable_stage1_languages}, in
1845               *,$other,*) ;;
1846               *,default,*) ;;
1847               *,all,*) ;;
1848               *)
1849                 case ,${enable_languages}, in
1850                   *,$language,*)
1851                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1852                     enable_stage1_languages="$enable_stage1_languages,${other}"
1853                     ;;
1854                 esac
1855                 ;;
1856             esac
1857           fi
1858         done
1859         ;;
1860     esac
1861   done
1862
1863   new_enable_languages=,c,
1864
1865   # If LTO is enabled, add the LTO front end.
1866   if test "$enable_lto" = "yes" ; then
1867     case ,${enable_languages}, in
1868       *,lto,*) ;;
1869       *) enable_languages="${enable_languages},lto" ;;
1870     esac
1871     if test "${build_lto_plugin}" = "yes" ; then
1872       configdirs="$configdirs lto-plugin"
1873     fi
1874   fi
1875
1876   # If we're building an offloading compiler, add the LTO front end.
1877   if test x"$enable_as_accelerator_for" != x ; then
1878     case ,${enable_languages}, in
1879       *,lto,*) ;;
1880       *) enable_languages="${enable_languages},lto" ;;
1881     esac
1882   fi
1883
1884   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1885   potential_languages=,c,
1886
1887   enabled_target_libs=
1888   disabled_target_libs=
1889
1890   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1891     case ${lang_frag} in
1892       ..) ;;
1893       # The odd quoting in the next line works around
1894       # an apparent bug in bash 1.12 on linux.
1895       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1896       *)
1897         # From the config-lang.in, get $language, $target_libs,
1898         # $lang_dirs, $boot_language, and $build_by_default
1899         language=
1900         target_libs=
1901         lang_dirs=
1902         subdir_requires=
1903         boot_language=no
1904         build_by_default=yes
1905         # set srcdir during sourcing.  See above about save & restore
1906         saved_srcdir=${srcdir}
1907         srcdir=${srcdir}/gcc . ${lang_frag}
1908         srcdir=${saved_srcdir}
1909         if test x${language} = x; then
1910           echo "${lang_frag} doesn't set \$language." 1>&2
1911           exit 1
1912         fi
1913
1914         if test "$language" = "c++"; then
1915           boot_language=yes
1916         fi
1917
1918         add_this_lang=no
1919         # C is always enabled, so no need to add it again
1920         if test "$language" != "c"; then
1921           case ,${enable_languages}, in
1922             *,${language},*)
1923               # Language was explicitly selected; include it
1924               add_this_lang=yes
1925               ;;
1926             *,all,*)
1927               # All languages are enabled
1928               add_this_lang=all
1929               ;;
1930             *,default,*)
1931               # 'default' was selected, select it if it is a default language
1932               add_this_lang=${build_by_default}
1933               ;;
1934           esac
1935         fi
1936
1937         # Disable languages that need other directories if these aren't available.
1938         for i in $subdir_requires; do
1939           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1940           case ${add_this_lang} in
1941             yes)
1942               # Specifically requested language; tell them.
1943               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1944               ;;
1945             all)
1946               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1947               add_this_lang=unsupported
1948               ;;
1949             *)
1950               # Silently disable.
1951               add_this_lang=unsupported
1952               ;;
1953           esac
1954         done
1955
1956         # Disable Ada if no preexisting GNAT is available.
1957         case ${add_this_lang}:${language}:${have_gnat} in
1958           yes:ada:no)
1959             # Specifically requested language; tell them.
1960             AC_MSG_ERROR([GNAT is required to build $language])
1961             ;;
1962           all:ada:no)
1963             AC_MSG_WARN([GNAT is required to build $language])
1964             add_this_lang=unsupported
1965             ;;
1966           *:ada:no)
1967             # Silently disable.
1968             add_this_lang=unsupported
1969             ;;
1970         esac
1971
1972         # Disable jit if -enable-host-shared not specified
1973         case ${add_this_lang}:${language}:${host_shared} in
1974           yes:jit:no)
1975             # PR jit/64780: explicitly specify --enable-host-shared
1976             AC_MSG_ERROR([
1977 Enabling language "jit" requires --enable-host-shared.
1978
1979 --enable-host-shared typically slows the rest of the compiler down by
1980 a few %, so you must explicitly enable it.
1981
1982 If you want to build both the jit and the regular compiler, it is often
1983 best to do this via two separate configure/builds, in separate
1984 directories, to avoid imposing the performance cost of
1985 --enable-host-shared on the regular compiler.])
1986             ;;
1987           all:jit:no)
1988             AC_MSG_WARN([--enable-host-shared required to build $language])
1989             add_this_lang=unsupported
1990             ;;
1991           *:jit:no)
1992             # Silently disable.
1993             add_this_lang=unsupported
1994             ;;
1995         esac
1996
1997         # Disable a language that is unsupported by the target.
1998         case "${add_this_lang}: $unsupported_languages " in
1999           no:*) ;;
2000           unsupported:*) ;;
2001           *:*" $language "*)
2002             AC_MSG_WARN([${language} not supported for this target])
2003             add_this_lang=unsupported
2004             ;;
2005         esac
2006
2007         case $add_this_lang in
2008           unsupported)
2009             # Remove language-dependent dirs.
2010             disabled_target_libs="$disabled_target_libs $target_libs"
2011             noconfigdirs="$noconfigdirs $lang_dirs"
2012             ;;
2013           no)
2014             # Remove language-dependent dirs; still show language as supported.
2015             disabled_target_libs="$disabled_target_libs $target_libs"
2016             noconfigdirs="$noconfigdirs $lang_dirs"
2017             potential_languages="${potential_languages}${language},"
2018             ;;
2019           all|yes)
2020             new_enable_languages="${new_enable_languages}${language},"
2021             potential_languages="${potential_languages}${language},"
2022             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2023             enabled_target_libs="$enabled_target_libs $target_libs"
2024             case "${boot_language}:,$enable_stage1_languages," in
2025               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2026                 # Add to (comma-separated) list of stage 1 languages.
2027                 case ",$stage1_languages," in
2028                   *,$language,* | ,yes, | ,all,) ;;
2029                   *) stage1_languages="${stage1_languages}${language}," ;;
2030                 esac
2031                 # We need to bootstrap any supporting libraries.
2032                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2033                 ;;
2034             esac
2035             ;;
2036         esac
2037         ;;
2038     esac
2039   done
2040
2041   # Add target libraries which are only needed for disabled languages
2042   # to noconfigdirs.
2043   if test -n "$disabled_target_libs"; then
2044     for dir in $disabled_target_libs; do
2045       case " $enabled_target_libs " in
2046       *" ${dir} "*) ;;
2047       *) noconfigdirs="$noconfigdirs $dir" ;;
2048       esac
2049     done
2050   fi
2051
2052   AC_ARG_ENABLE(stage1-languages,
2053   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2054                   [choose additional languages to build during
2055                   stage1.  Mostly useful for compiler development])],
2056   [case ,${enable_stage1_languages}, in
2057     ,no,|,,)
2058       # Set it to something that will have no effect in the loop below
2059       enable_stage1_languages=c ;;
2060     ,yes,)
2061       enable_stage1_languages=`echo $new_enable_languages | \
2062         sed -e "s/^,//" -e "s/,$//" ` ;;
2063     *,all,*)
2064       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2065         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2066   esac
2067
2068   # Add "good" languages from enable_stage1_languages to stage1_languages,
2069   # while "bad" languages go in missing_languages.  Leave no duplicates.
2070   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2071     case $potential_languages in
2072       *,$i,*)
2073         case $stage1_languages in
2074           *,$i,*) ;;
2075           *) stage1_languages="$stage1_languages$i," ;;
2076         esac ;;
2077       *)
2078         case $missing_languages in
2079           *,$i,*) ;;
2080           *) missing_languages="$missing_languages$i," ;;
2081         esac ;;
2082      esac
2083   done])
2084
2085   # Remove leading/trailing commas that were added for simplicity
2086   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2087   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2088   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2089   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2090
2091   if test "x$missing_languages" != x; then
2092     AC_MSG_ERROR([
2093 The following requested languages could not be built: ${missing_languages}
2094 Supported languages are: ${potential_languages}])
2095   fi
2096   if test "x$new_enable_languages" != "x$enable_languages"; then
2097     echo The following languages will be built: ${new_enable_languages}
2098     enable_languages="$new_enable_languages"
2099   fi
2100
2101   AC_SUBST(stage1_languages)
2102   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2103 fi
2104
2105 # Handle --disable-<component> generically.
2106 for dir in $configdirs $build_configdirs $target_configdirs ; do
2107   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2108   varname=`echo $dirname | sed -e s/+/_/g`
2109   if eval test x\${enable_${varname}} "=" xno ; then
2110     noconfigdirs="$noconfigdirs $dir"
2111   fi
2112 done
2113
2114 # Check for Boehm's garbage collector
2115 AC_ARG_ENABLE(objc-gc,
2116 [AS_HELP_STRING([--enable-objc-gc],
2117                 [enable use of Boehm's garbage collector with the
2118                  GNU Objective-C runtime])])
2119 AC_ARG_WITH([target-bdw-gc],
2120 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2121                 [specify prefix directory for installed bdw-gc package.
2122                  Equivalent to --with-target-bdw-gc-include=PATH/include
2123                  plus --with-target-bdw-gc-lib=PATH/lib])])
2124 AC_ARG_WITH([target-bdw-gc-include],
2125 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2126                 [specify directories for installed bdw-gc include files])])
2127 AC_ARG_WITH([target-bdw-gc-lib],
2128 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2129                 [specify directories for installed bdw-gc library])])
2130
2131 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2132   AC_MSG_CHECKING([for bdw garbage collector])
2133   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2134     dnl no bdw-gw options, assume default locations
2135     AC_MSG_RESULT([using bdw-gc in default locations])
2136   else
2137     dnl bdw-gw options, first error checking, complete checking in libobjc
2138     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2139       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2140     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2141       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2142     else
2143       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2144     fi
2145   fi
2146 esac
2147
2148 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2149 case ,${enable_languages}, in
2150   *,c++,*)
2151     # Disable libitm, libsanitizer if we're not building libstdc++
2152     case "${noconfigdirs}" in
2153       *target-libstdc++-v3*)
2154         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2155         ;;
2156       *) ;;
2157     esac
2158     ;;
2159   *)
2160     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2161     ;;
2162 esac
2163
2164 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2165 # $build_configdirs and $target_configdirs.
2166 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2167
2168 notsupp=""
2169 for dir in . $skipdirs $noconfigdirs ; do
2170   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2171   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2172     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2173     if test -r $srcdir/$dirname/configure ; then
2174       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2175         true
2176       else
2177         notsupp="$notsupp $dir"
2178       fi
2179     fi
2180   fi
2181   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2182     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2183     if test -r $srcdir/$dirname/configure ; then
2184       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2185         true
2186       else
2187         notsupp="$notsupp $dir"
2188       fi
2189     fi
2190   fi
2191   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2192     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2193     if test -r $srcdir/$dirname/configure ; then
2194       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2195         true
2196       else
2197         notsupp="$notsupp $dir"
2198       fi
2199     fi
2200   fi
2201 done
2202
2203 # Quietly strip out all directories which aren't configurable in this tree.
2204 # This relies on all configurable subdirectories being autoconfiscated, which
2205 # is now the case.
2206 build_configdirs_all="$build_configdirs"
2207 build_configdirs=
2208 for i in ${build_configdirs_all} ; do
2209   j=`echo $i | sed -e s/build-//g`
2210   if test -f ${srcdir}/$j/configure ; then
2211     build_configdirs="${build_configdirs} $i"
2212   fi
2213 done
2214
2215 configdirs_all="$configdirs"
2216 configdirs=
2217 for i in ${configdirs_all} ; do
2218   if test -f ${srcdir}/$i/configure ; then
2219     configdirs="${configdirs} $i"
2220   fi
2221 done
2222
2223 target_configdirs_all="$target_configdirs"
2224 target_configdirs=
2225 for i in ${target_configdirs_all} ; do
2226   j=`echo $i | sed -e s/target-//g`
2227   if test -f ${srcdir}/$j/configure ; then
2228     target_configdirs="${target_configdirs} $i"
2229   fi
2230 done
2231
2232 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2233 # so we have to add it after the preceding checks.
2234 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2235 then
2236   case " $configdirs " in
2237     *" libiberty "*)
2238       # If we can build libiberty, we can also build libiberty-linker-plugin.
2239       configdirs="$configdirs libiberty-linker-plugin"
2240       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2241         --with-libiberty=../libiberty-linker-plugin";;
2242     *)
2243       AC_MSG_ERROR([libiberty missing]);;
2244   esac
2245 fi
2246
2247 # Sometimes we have special requirements for the host libiberty.
2248 extra_host_libiberty_configure_flags=
2249 extra_host_zlib_configure_flags=
2250 case " $configdirs " in
2251   *" lto-plugin "* | *" libcc1 "*)
2252     # When these are to be built as shared libraries, the same applies to
2253     # libiberty.
2254     extra_host_libiberty_configure_flags=--enable-shared
2255     ;;
2256   *" bfd "*)
2257     # When bfd is to be built as a shared library, the same applies to
2258     # zlib.
2259     if test "$enable_shared" = "yes"; then
2260       extra_host_zlib_configure_flags=--enable-host-shared
2261     fi
2262     ;;
2263 esac
2264 AC_SUBST(extra_host_libiberty_configure_flags)
2265 AC_SUBST(extra_host_zlib_configure_flags)
2266
2267 # Produce a warning message for the subdirs we can't configure.
2268 # This isn't especially interesting in the Cygnus tree, but in the individual
2269 # FSF releases, it's important to let people know when their machine isn't
2270 # supported by the one or two programs in a package.
2271
2272 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2273   # If $appdirs is non-empty, at least one of those directories must still
2274   # be configured, or we error out.  (E.g., if the gas release supports a
2275   # specified target in some subdirs but not the gas subdir, we shouldn't
2276   # pretend that all is well.)
2277   if test -n "$appdirs" ; then
2278     for dir in $appdirs ; do
2279       if test -r $dir/Makefile.in ; then
2280         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2281           appdirs=""
2282           break
2283         fi
2284         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2285           appdirs=""
2286           break
2287         fi
2288       fi
2289     done
2290     if test -n "$appdirs" ; then
2291       echo "*** This configuration is not supported by this package." 1>&2
2292       exit 1
2293     fi
2294   fi
2295   # Okay, some application will build, or we don't care to check.  Still
2296   # notify of subdirs not getting built.
2297   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2298   echo "    ${notsupp}" 1>&2
2299   echo "    (Any other directories should still work fine.)" 1>&2
2300 fi
2301
2302 case "$host" in
2303   *msdosdjgpp*)
2304     enable_gdbtk=no ;;
2305 esac
2306
2307 # To find our prefix, in gcc_cv_tool_prefix.
2308 ACX_TOOL_DIRS
2309
2310 copy_dirs=
2311
2312 AC_ARG_WITH([build-sysroot],
2313   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2314                   [use sysroot as the system root during the build])],
2315   [if test x"$withval" != x ; then
2316      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2317    fi],
2318   [SYSROOT_CFLAGS_FOR_TARGET=])
2319 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2320
2321 AC_ARG_WITH([debug-prefix-map],
2322   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2323                   [map A to B, C to D ... in debug information])],
2324   [if test x"$withval" != x; then
2325      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2326      for debug_map in $withval; do
2327        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2328      done
2329    fi],
2330   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2331 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2332
2333 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2334 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2335 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2336 # We want to ensure that TARGET libraries (which we know are built with
2337 # gcc) are built with "-O2 -g", so include those options when setting
2338 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2339 if test "x$CFLAGS_FOR_TARGET" = x; then
2340   if test "x${is_cross_compiler}" = xyes; then
2341     CFLAGS_FOR_TARGET="-g -O2"
2342   else
2343     CFLAGS_FOR_TARGET=$CFLAGS
2344     case " $CFLAGS " in
2345       *" -O2 "*) ;;
2346       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2347     esac
2348     case " $CFLAGS " in
2349       *" -g "* | *" -g3 "*) ;;
2350       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2351     esac
2352   fi
2353 fi
2354 AC_SUBST(CFLAGS_FOR_TARGET)
2355
2356 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2357   if test "x${is_cross_compiler}" = xyes; then
2358     CXXFLAGS_FOR_TARGET="-g -O2"
2359   else
2360     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2361     case " $CXXFLAGS " in
2362       *" -O2 "*) ;;
2363       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2364     esac
2365     case " $CXXFLAGS " in
2366       *" -g "* | *" -g3 "*) ;;
2367       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2368     esac
2369   fi
2370 fi
2371 AC_SUBST(CXXFLAGS_FOR_TARGET)
2372
2373 AC_SUBST(LDFLAGS_FOR_TARGET)
2374
2375 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2376 # the named directory are copied to $(tooldir)/sys-include.
2377 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2378   if test x${is_cross_compiler} = xno ; then
2379     echo 1>&2 '***' --with-headers is only supported when cross compiling
2380     exit 1
2381   fi
2382   if test x"${with_headers}" != xyes ; then
2383     x=${gcc_cv_tool_prefix}
2384     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2385   fi
2386 fi
2387
2388 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2389 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2390 # are permitted.
2391 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2392   if test x${is_cross_compiler} = xno ; then
2393     echo 1>&2 '***' --with-libs is only supported when cross compiling
2394     exit 1
2395   fi
2396   if test x"${with_libs}" != xyes ; then
2397     # Copy the libraries in reverse order, so that files in the first named
2398     # library override files in subsequent libraries.
2399     x=${gcc_cv_tool_prefix}
2400     for l in ${with_libs}; do
2401       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2402     done
2403   fi
2404 fi
2405
2406 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2407 #
2408 # This is done by determining whether or not the appropriate directory
2409 # is available, and by checking whether or not specific configurations
2410 # have requested that this magic not happen.
2411 #
2412 # The command line options always override the explicit settings in
2413 # configure.ac, and the settings in configure.ac override this magic.
2414 #
2415 # If the default for a toolchain is to use GNU as and ld, and you don't
2416 # want to do that, then you should use the --without-gnu-as and
2417 # --without-gnu-ld options for the configure script.  Similarly, if
2418 # the default is to use the included zlib and you don't want to do that,
2419 # you should use the --with-system-zlib option for the configure script.
2420
2421 if test x${use_gnu_as} = x &&
2422    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2423   with_gnu_as=yes
2424   extra_host_args="$extra_host_args --with-gnu-as"
2425 fi
2426
2427 if test x${use_gnu_ld} = x &&
2428    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2429   with_gnu_ld=yes
2430   extra_host_args="$extra_host_args --with-gnu-ld"
2431 fi
2432
2433 if test x${use_included_zlib} = x &&
2434    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2435   :
2436 else
2437   with_system_zlib=yes
2438   extra_host_args="$extra_host_args --with-system-zlib"
2439 fi
2440
2441 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2442 # can detect this case.
2443
2444 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2445   with_newlib=yes
2446   extra_host_args="$extra_host_args --with-newlib"
2447 fi
2448
2449 # Handle ${copy_dirs}
2450 set fnord ${copy_dirs}
2451 shift
2452 while test $# != 0 ; do
2453   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2454     :
2455   else
2456     echo Copying $1 to $2
2457
2458     # Use the install script to create the directory and all required
2459     # parent directories.
2460     if test -d $2 ; then
2461       :
2462     else
2463       echo >config.temp
2464       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2465     fi
2466
2467     # Copy the directory, assuming we have tar.
2468     # FIXME: Should we use B in the second tar?  Not all systems support it.
2469     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2470
2471     # It is the responsibility of the user to correctly adjust all
2472     # symlinks.  If somebody can figure out how to handle them correctly
2473     # here, feel free to add the code.
2474
2475     echo $1 > $2/COPIED
2476   fi
2477   shift; shift
2478 done
2479
2480 # Determine a target-dependent exec_prefix that the installed
2481 # gcc will search in.  Keep this list sorted by triplet, with
2482 # the *-*-osname triplets last.
2483 md_exec_prefix=
2484 case "${target}" in
2485   i[[34567]]86-pc-msdosdjgpp*)
2486     md_exec_prefix=/dev/env/DJDIR/bin
2487     ;;
2488   *-*-hpux* | \
2489   *-*-nto-qnx* | \
2490   *-*-solaris2*)
2491     md_exec_prefix=/usr/ccs/bin
2492     ;;
2493 esac
2494
2495 extra_arflags_for_target=
2496 extra_nmflags_for_target=
2497 extra_ranlibflags_for_target=
2498 target_makefile_frag=/dev/null
2499 case "${target}" in
2500   spu-*-*)
2501     target_makefile_frag="config/mt-spu"
2502     ;;
2503   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2504     target_makefile_frag="config/mt-sde"
2505     ;;
2506   mipsisa*-*-elfoabi*)
2507     target_makefile_frag="config/mt-mips-elfoabi"
2508     ;;
2509   mips*-*-*linux* | mips*-*-gnu*)
2510     target_makefile_frag="config/mt-mips-gnu"
2511     ;;
2512   nios2-*-elf*)
2513     target_makefile_frag="config/mt-nios2-elf"
2514     ;;
2515   *-*-linux-android*)
2516     target_makefile_frag="config/mt-android"
2517     ;;
2518   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2519     target_makefile_frag="config/mt-gnu"
2520     ;;
2521   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2522     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2523     # commands to handle both 32-bit and 64-bit objects.  These flags are
2524     # harmless if we're using GNU nm or ar.
2525     extra_arflags_for_target=" -X32_64"
2526     extra_nmflags_for_target=" -B -X32_64"
2527     ;;
2528 esac
2529
2530 alphaieee_frag=/dev/null
2531 case $target in
2532   alpha*-*-*)
2533     # This just makes sure to use the -mieee option to build target libs.
2534     # This should probably be set individually by each library.
2535     alphaieee_frag="config/mt-alphaieee"
2536     ;;
2537 esac
2538
2539 # If --enable-target-optspace always use -Os instead of -O2 to build
2540 # the target libraries, similarly if it is not specified, use -Os
2541 # on selected platforms.
2542 ospace_frag=/dev/null
2543 case "${enable_target_optspace}:${target}" in
2544   yes:*)
2545     ospace_frag="config/mt-ospace"
2546     ;;
2547   :d30v-*)
2548     ospace_frag="config/mt-d30v"
2549     ;;
2550   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2551     ospace_frag="config/mt-ospace"
2552     ;;
2553   no:* | :*)
2554     ;;
2555   *)
2556     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2557     ;;
2558 esac
2559
2560 # Some systems (e.g., one of the i386-aix systems the gas testers are
2561 # using) don't handle "\$" correctly, so don't use it here.
2562 tooldir='${exec_prefix}'/${target_noncanonical}
2563 build_tooldir=${tooldir}
2564
2565 # Create a .gdbinit file which runs the one in srcdir
2566 # and tells GDB to look there for source files.
2567
2568 if test -r ${srcdir}/.gdbinit ; then
2569   case ${srcdir} in
2570     .) ;;
2571     *) cat > ./.gdbinit <<EOF
2572 # ${NO_EDIT}
2573 dir ${srcdir}
2574 dir .
2575 source ${srcdir}/.gdbinit
2576 EOF
2577     ;;
2578   esac
2579 fi
2580
2581 # Make sure that the compiler is able to generate an executable.  If it
2582 # can't, we are probably in trouble.  We don't care whether we can run the
2583 # executable--we might be using a cross compiler--we only care whether it
2584 # can be created.  At this point the main configure script has set CC.
2585 we_are_ok=no
2586 echo "int main () { return 0; }" > conftest.c
2587 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2588 if test $? = 0 ; then
2589   if test -s conftest || test -s conftest.exe ; then
2590     we_are_ok=yes
2591   fi
2592 fi
2593 case $we_are_ok in
2594   no)
2595     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2596     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2597     rm -f conftest*
2598     exit 1
2599     ;;
2600 esac
2601 rm -f conftest*
2602
2603 # Decide which environment variable is used to find dynamic libraries.
2604 case "${host}" in
2605   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2606   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2607   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2608   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2609 esac
2610
2611 # On systems where the dynamic library environment variable is PATH,
2612 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2613 # built executables to PATH.
2614 if test "$RPATH_ENVVAR" = PATH; then
2615   GCC_SHLIB_SUBDIR=/shlib
2616 else
2617   GCC_SHLIB_SUBDIR=
2618 fi
2619
2620 # Adjust the toplevel makefile according to whether bootstrap was selected.
2621 case $enable_bootstrap in
2622   yes)
2623     bootstrap_suffix=bootstrap
2624     BUILD_CONFIG=bootstrap-debug
2625     ;;
2626   no)
2627     bootstrap_suffix=no-bootstrap
2628     BUILD_CONFIG=
2629     ;;
2630 esac
2631
2632 AC_MSG_CHECKING(for default BUILD_CONFIG)
2633
2634 AC_ARG_WITH([build-config],
2635   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2636                   [use config/NAME.mk build configuration])],
2637   [case $with_build_config in
2638    yes) with_build_config= ;;
2639    no) with_build_config= BUILD_CONFIG= ;;
2640    esac])
2641
2642 if test "x${with_build_config}" != x; then
2643   BUILD_CONFIG=$with_build_config
2644 else
2645   case $BUILD_CONFIG in
2646   bootstrap-debug)
2647     if echo "int f (void) { return 0; }" > conftest.c &&
2648        ${CC} -c conftest.c &&
2649        mv conftest.o conftest.o.g0 &&
2650        ${CC} -c -g conftest.c &&
2651        mv conftest.o conftest.o.g &&
2652        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2653       :
2654     else
2655       BUILD_CONFIG=
2656     fi
2657     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2658     ;;
2659   esac
2660 fi
2661 AC_MSG_RESULT($BUILD_CONFIG)
2662 AC_SUBST(BUILD_CONFIG)
2663
2664 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2665 AC_MSG_CHECKING([for --enable-vtable-verify])
2666 AC_ARG_ENABLE(vtable-verify,
2667 [AS_HELP_STRING([--enable-vtable-verify],
2668                 [Enable vtable verification feature])],
2669 [case "$enableval" in
2670  yes) enable_vtable_verify=yes ;;
2671  no)  enable_vtable_verify=no ;;
2672  *)   enable_vtable_verify=no;;
2673  esac],
2674 [enable_vtable_verify=no])
2675 AC_MSG_RESULT($enable_vtable_verify)
2676
2677 # Record target_configdirs and the configure arguments for target and
2678 # build configuration in Makefile.
2679 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2680 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2681 bootstrap_fixincludes=no
2682
2683 # If we are building libgomp, bootstrap it.
2684 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2685   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2686 fi
2687
2688 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2689 # or bootstrap-ubsan, bootstrap it.
2690 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2691   case "$BUILD_CONFIG" in
2692     *bootstrap-asan* | *bootstrap-ubsan* )
2693       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2694       bootstrap_fixincludes=yes
2695       ;;
2696   esac
2697 fi
2698
2699 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2700 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2701    test "$enable_vtable_verify" != no; then
2702   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2703 fi
2704
2705 # Determine whether gdb needs tk/tcl or not.
2706 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2707 # and in that case we want gdb to be built without tk.  Ugh!
2708 # In fact I believe gdb is the *only* package directly dependent on tk,
2709 # so we should be able to put the 'maybe's in unconditionally and
2710 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2711 # 100% sure that that's safe though.
2712
2713 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2714 case "$enable_gdbtk" in
2715   no)
2716     GDB_TK="" ;;
2717   yes)
2718     GDB_TK="${gdb_tk}" ;;
2719   *)
2720     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2721     # distro.  Eventually someone will fix this and move Insight, nee
2722     # gdbtk to a separate directory.
2723     if test -d ${srcdir}/gdb/gdbtk ; then
2724       GDB_TK="${gdb_tk}"
2725     else
2726       GDB_TK=""
2727     fi
2728     ;;
2729 esac
2730 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2731 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2732
2733 # gdb depends on gnulib, but as nothing else does, only include it if
2734 # gdb is built.
2735 if echo " ${configdirs} " | grep " gdb " > /dev/null 2>&1 ; then
2736   # The Makefile provides the ordering, so it's enough here to add
2737   # gnulib to the list.
2738   configdirs="${configdirs} gnulib"
2739 fi
2740
2741 # Strip out unwanted targets.
2742
2743 # While at that, we remove Makefiles if we were started for recursive
2744 # configuration, so that the top-level Makefile reconfigures them,
2745 # like we used to do when configure itself was recursive.
2746
2747 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2748 # but now we're fixing up the Makefile ourselves with the additional
2749 # commands passed to AC_CONFIG_FILES.  Use separate variables
2750 # extrasub-{build,host,target} not because there is any reason to split
2751 # the substitutions up that way, but only to remain below the limit of
2752 # 99 commands in a script, for HP-UX sed.
2753
2754 # Do not nest @if/@endif or @unless/@endunless pairs, because
2755 # configure will not warn you at all.
2756
2757 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2758   yes:yes:*\ gold\ *:*,c++,*) ;;
2759   yes:yes:*\ gold\ *:*)
2760     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2761     ;;
2762 esac
2763
2764 extrasub_build=
2765 for module in ${build_configdirs} ; do
2766   if test -z "${no_recursion}" \
2767      && test -f ${build_subdir}/${module}/Makefile; then
2768     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2769     rm -f ${build_subdir}/${module}/Makefile
2770   fi
2771   extrasub_build="$extrasub_build
2772 /^@if build-$module\$/d
2773 /^@endif build-$module\$/d
2774 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2775 /^@if build-$module-$bootstrap_suffix\$/d
2776 /^@endif build-$module-$bootstrap_suffix\$/d
2777 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2778 done
2779 extrasub_host=
2780 for module in ${configdirs} ; do
2781   if test -z "${no_recursion}"; then
2782     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2783       if test -f ${file}; then
2784         echo 1>&2 "*** removing ${file} to force reconfigure"
2785         rm -f ${file}
2786       fi
2787     done
2788   fi
2789   case ${module},${bootstrap_fixincludes} in
2790     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2791     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2792   esac
2793   extrasub_host="$extrasub_host
2794 /^@if $module\$/d
2795 /^@endif $module\$/d
2796 /^@unless $module\$/,/^@endunless $module\$/d
2797 /^@if $module-$host_bootstrap_suffix\$/d
2798 /^@endif $module-$host_bootstrap_suffix\$/d
2799 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2800 done
2801 extrasub_target=
2802 for module in ${target_configdirs} ; do
2803   if test -z "${no_recursion}" \
2804      && test -f ${target_subdir}/${module}/Makefile; then
2805     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2806     rm -f ${target_subdir}/${module}/Makefile
2807   fi
2808
2809   # We only bootstrap target libraries listed in bootstrap_target_libs.
2810   case $bootstrap_target_libs in
2811     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2812     *) target_bootstrap_suffix=no-bootstrap ;;
2813   esac
2814
2815   extrasub_target="$extrasub_target
2816 /^@if target-$module\$/d
2817 /^@endif target-$module\$/d
2818 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2819 /^@if target-$module-$target_bootstrap_suffix\$/d
2820 /^@endif target-$module-$target_bootstrap_suffix\$/d
2821 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2822 done
2823
2824 # Do the final fixup along with target modules.
2825 extrasub_target="$extrasub_target
2826 /^@if /,/^@endif /d
2827 /^@unless /d
2828 /^@endunless /d"
2829
2830 # Create the serialization dependencies.  This uses a temporary file.
2831
2832 AC_ARG_ENABLE([serial-configure],
2833 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2834                 [force sequential configuration of
2835                  sub-packages for the host, target or build
2836                  machine, or all sub-packages])])
2837
2838 case ${enable_serial_configure} in
2839   yes)
2840     enable_serial_build_configure=yes
2841     enable_serial_host_configure=yes
2842     enable_serial_target_configure=yes
2843     ;;
2844 esac
2845
2846 # These force 'configure's to be done one at a time, to avoid problems
2847 # with contention over a shared config.cache.
2848 rm -f serdep.tmp
2849 echo '# serdep.tmp' > serdep.tmp
2850 olditem=
2851 test "x${enable_serial_build_configure}" = xyes &&
2852 for item in ${build_configdirs} ; do
2853   case ${olditem} in
2854     "") ;;
2855     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2856   esac
2857   olditem=${item}
2858 done
2859 olditem=
2860 test "x${enable_serial_host_configure}" = xyes &&
2861 for item in ${configdirs} ; do
2862   case ${olditem} in
2863     "") ;;
2864     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2865   esac
2866   olditem=${item}
2867 done
2868 olditem=
2869 test "x${enable_serial_target_configure}" = xyes &&
2870 for item in ${target_configdirs} ; do
2871   case ${olditem} in
2872     "") ;;
2873     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2874   esac
2875   olditem=${item}
2876 done
2877 serialization_dependencies=serdep.tmp
2878 AC_SUBST_FILE(serialization_dependencies)
2879
2880 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2881 # target, nonopt, and variable assignments.  These are the ones we
2882 # might not want to pass down to subconfigures.  The exception being
2883 # --cache-file=/dev/null, which is used to turn off the use of cache
2884 # files altogether, and which should be passed on to subconfigures.
2885 # Also strip program-prefix, program-suffix, and program-transform-name,
2886 # so that we can pass down a consistent program-transform-name.
2887 baseargs=
2888 tbaseargs=
2889 keep_next=no
2890 skip_next=no
2891 eval "set -- $ac_configure_args"
2892 for ac_arg
2893 do
2894   if test X"$skip_next" = X"yes"; then
2895     skip_next=no
2896     continue
2897   fi
2898   if test X"$keep_next" = X"yes"; then
2899     case $ac_arg in
2900       *\'*)
2901         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2902     esac
2903     baseargs="$baseargs '$ac_arg'"
2904     tbaseargs="$tbaseargs '$ac_arg'"
2905     keep_next=no
2906     continue
2907   fi
2908
2909   # Handle separated arguments.  Based on the logic generated by
2910   # autoconf 2.59.
2911   case $ac_arg in
2912     *=* | --config-cache | -C | -disable-* | --disable-* \
2913       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2914       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2915       | -with-* | --with-* | -without-* | --without-* | --x)
2916       separate_arg=no
2917       ;;
2918     -*)
2919       separate_arg=yes
2920       ;;
2921     *)
2922       separate_arg=no
2923       ;;
2924   esac
2925
2926   skip_targ=no
2927   case $ac_arg in
2928 changequote(,)
2929   --with-* | --without-*)
2930     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2931
2932     case $libopt in
2933     *[-_]include)
2934       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2935       ;;
2936     *[-_]lib)
2937       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2938       ;;
2939     *)
2940       lib=$libopt
2941       ;;
2942     esac
2943 changequote([,])
2944
2945     case $lib in
2946     mpc | mpfr | gmp | isl)
2947       # If we're processing --with-$lib, --with-$lib-include or
2948       # --with-$lib-lib, for one of the libs above, and target is
2949       # different from host, don't pass the current argument to any
2950       # target library's configure.
2951       if test x$is_cross_compiler = xyes; then
2952         skip_targ=yes
2953       fi
2954       ;;
2955     esac
2956     ;;
2957   esac
2958
2959   case "$ac_arg" in
2960     --cache-file=/dev/null | \
2961     -cache-file=/dev/null )
2962       # Handled here to avoid the test to skip args below.
2963       baseargs="$baseargs '$ac_arg'"
2964       tbaseargs="$tbaseargs '$ac_arg'"
2965       # Assert: $separate_arg should always be no.
2966       keep_next=$separate_arg
2967       ;;
2968     --no*)
2969       continue
2970       ;;
2971     --c* | \
2972     --sr* | \
2973     --ho* | \
2974     --bu* | \
2975     --t* | \
2976     --program-* | \
2977     -cache_file* | \
2978     -srcdir* | \
2979     -host* | \
2980     -build* | \
2981     -target* | \
2982     -program-prefix* | \
2983     -program-suffix* | \
2984     -program-transform-name* )
2985       skip_next=$separate_arg
2986       continue
2987       ;;
2988     -*)
2989       # An option.  Add it.
2990       case $ac_arg in
2991         *\'*)
2992           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2993       esac
2994       baseargs="$baseargs '$ac_arg'"
2995       if test X"$skip_targ" = Xno; then
2996         tbaseargs="$tbaseargs '$ac_arg'"
2997       fi
2998       keep_next=$separate_arg
2999       ;;
3000     *)
3001       # Either a variable assignment, or a nonopt (triplet).  Don't
3002       # pass it down; let the Makefile handle this.
3003       continue
3004       ;;
3005   esac
3006 done
3007 # Remove the initial space we just introduced and, as these will be
3008 # expanded by make, quote '$'.
3009 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3010
3011 # Add in --program-transform-name, after --program-prefix and
3012 # --program-suffix have been applied to it.  Autoconf has already
3013 # doubled dollar signs and backslashes in program_transform_name; we want
3014 # the backslashes un-doubled, and then the entire thing wrapped in single
3015 # quotes, because this will be expanded first by make and then by the shell.
3016 # Also, because we want to override the logic in subdir configure scripts to
3017 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3018 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3019 ${program_transform_name}
3020 EOF_SED
3021 gcc_transform_name=`cat conftestsed.out`
3022 rm -f conftestsed.out
3023 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3024 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3025 if test "$silent" = yes; then
3026   baseargs="$baseargs --silent"
3027   tbaseargs="$tbaseargs --silent"
3028 fi
3029 baseargs="$baseargs --disable-option-checking"
3030 tbaseargs="$tbaseargs --disable-option-checking"
3031
3032 # Record and document user additions to sub configure arguments.
3033 AC_ARG_VAR([build_configargs],
3034            [additional configure arguments for build directories])
3035 AC_ARG_VAR([host_configargs],
3036            [additional configure arguments for host directories])
3037 AC_ARG_VAR([target_configargs],
3038            [additional configure arguments for target directories])
3039
3040 # For the build-side libraries, we just need to pretend we're native,
3041 # and not use the same cache file.  Multilibs are neither needed nor
3042 # desired.  We can't even use the same cache file for all build-side
3043 # libraries, as they're compiled differently; some with C, some with
3044 # C++ or with different feature-enabling options.
3045 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3046
3047 # For host modules, accept cache file option, or specification as blank.
3048 case "${cache_file}" in
3049 "") # empty
3050   cache_file_option="" ;;
3051 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3052   cache_file_option="--cache-file=${cache_file}" ;;
3053 *) # relative path
3054   cache_file_option="--cache-file=../${cache_file}" ;;
3055 esac
3056
3057 # Host dirs don't like to share a cache file either, horribly enough.
3058 # This seems to be due to autoconf 2.5x stupidity.
3059 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3060
3061 target_configargs="$target_configargs ${tbaseargs}"
3062
3063 # Passing a --with-cross-host argument lets the target libraries know
3064 # whether they are being built with a cross-compiler or being built
3065 # native.  However, it would be better to use other mechanisms to make the
3066 # sorts of decisions they want to make on this basis.  Please consider
3067 # this option to be deprecated.  FIXME.
3068 if test x${is_cross_compiler} = xyes ; then
3069   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3070 fi
3071
3072 # Special user-friendly check for native x86_64-linux build, if
3073 # multilib is not explicitly enabled.
3074 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3075   x86_64-*linux*:yes:$build:$build:)
3076     # Make sure we have a development environment that handles 32-bit
3077     dev64=no
3078     echo "int main () { return 0; }" > conftest.c
3079     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3080     if test $? = 0 ; then
3081       if test -s conftest || test -s conftest.exe ; then
3082         dev64=yes
3083       fi
3084     fi
3085     rm -f conftest*
3086     if test x${dev64} != xyes ; then
3087       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3088     fi
3089     ;;
3090 esac
3091
3092 # Default to --enable-multilib.
3093 if test x${enable_multilib} = x ; then
3094   target_configargs="--enable-multilib ${target_configargs}"
3095 fi
3096
3097 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3098 # changed from the earlier setting of with_newlib.
3099 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3100   target_configargs="--with-newlib ${target_configargs}"
3101 fi
3102
3103 # Different target subdirs use different values of certain variables
3104 # (notably CXX).  Worse, multilibs use *lots* of different values.
3105 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3106 # it doesn't automatically accept command-line overrides of them.
3107 # This means it's not safe for target subdirs to share a cache file,
3108 # which is disgusting, but there you have it.  Hopefully this can be
3109 # fixed in future.  It's still worthwhile to use a cache file for each
3110 # directory.  I think.
3111
3112 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3113 # We need to pass --target, as newer autoconf's requires consistency
3114 # for target_alias and gcc doesn't manage it consistently.
3115 target_configargs="--cache-file=./config.cache ${target_configargs}"
3116
3117 FLAGS_FOR_TARGET=
3118 case " $target_configdirs " in
3119  *" newlib "*)
3120   case " $target_configargs " in
3121   *" --with-newlib "*)
3122    case "$target" in
3123     *-cygwin*)
3124       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3125       ;;
3126    esac
3127
3128    # If we're not building GCC, don't discard standard headers.
3129    if test -d ${srcdir}/gcc; then
3130      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3131
3132      if test "${build}" != "${host}"; then
3133        # On Canadian crosses, CC_FOR_TARGET will have already been set
3134        # by `configure', so we won't have an opportunity to add -Bgcc/
3135        # to it.  This is right: we don't want to search that directory
3136        # for binaries, but we want the header files in there, so add
3137        # them explicitly.
3138        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3139
3140        # Someone might think of using the pre-installed headers on
3141        # Canadian crosses, in case the installed compiler is not fully
3142        # compatible with the compiler being built.  In this case, it
3143        # would be better to flag an error than risking having
3144        # incompatible object files being constructed.  We can't
3145        # guarantee that an error will be flagged, but let's hope the
3146        # compiler will do it, when presented with incompatible header
3147        # files.
3148      fi
3149    fi
3150
3151    case "${target}-${is_cross_compiler}" in
3152    i[[3456789]]86-*-linux*-no)
3153       # Here host == target, so we don't need to build gcc,
3154       # so we don't want to discard standard headers.
3155       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3156       ;;
3157    *)
3158       # If we're building newlib, use its generic headers last, but search
3159       # for any libc-related directories first (so make it the last -B
3160       # switch).
3161       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3162
3163       # If we're building libgloss, find the startup file, simulator library
3164       # and linker script.
3165       case " $target_configdirs " in
3166         *" libgloss "*)
3167         # Look for startup file, simulator library and maybe linker script.
3168         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3169         # Look for libnosys.a in case the target needs it.
3170         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3171         # Most targets have the linker script in the source directory.
3172         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3173         ;;
3174       esac
3175       ;;
3176    esac
3177    ;;
3178   esac
3179   ;;
3180 esac
3181
3182 case "$target" in
3183   x86_64-*mingw* | *-w64-mingw*)
3184   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3185   # however, use a symlink named 'mingw' in ${prefix} .
3186     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3187     ;;
3188   *-mingw*)
3189   # MinGW can't be handled as Cygwin above since it does not use newlib.
3190     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3191     ;;
3192 esac
3193
3194 # Allow the user to override the flags for
3195 # our build compiler if desired.
3196 if test x"${build}" = x"${host}" ; then
3197   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3198   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3199   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3200 fi
3201
3202 # On Canadian crosses, we'll be searching the right directories for
3203 # the previously-installed cross compiler, so don't bother to add
3204 # flags for directories within the install tree of the compiler
3205 # being built; programs in there won't even run.
3206 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3207   # Search for pre-installed headers if nothing else fits.
3208   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3209 fi
3210
3211 if test "x${use_gnu_ld}" = x &&
3212    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3213   # Arrange for us to find uninstalled linker scripts.
3214   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3215 fi
3216
3217 # Search for other target-specific linker scripts and such.
3218 case "${target}" in
3219   mep*)
3220     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3221     ;;
3222 esac
3223
3224 # Makefile fragments.
3225 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3226 do
3227   eval fragval=\$$frag
3228   if test $fragval != /dev/null; then
3229     eval $frag=${srcdir}/$fragval
3230   fi
3231 done
3232 AC_SUBST_FILE(host_makefile_frag)
3233 AC_SUBST_FILE(target_makefile_frag)
3234 AC_SUBST_FILE(alphaieee_frag)
3235 AC_SUBST_FILE(ospace_frag)
3236
3237 # Miscellanea: directories, flags, etc.
3238 AC_SUBST(RPATH_ENVVAR)
3239 AC_SUBST(GCC_SHLIB_SUBDIR)
3240 AC_SUBST(tooldir)
3241 AC_SUBST(build_tooldir)
3242 AC_SUBST(CONFIGURE_GDB_TK)
3243 AC_SUBST(GDB_TK)
3244 AC_SUBST(INSTALL_GDB_TK)
3245
3246 # Build module lists & subconfigure args.
3247 AC_SUBST(build_configargs)
3248 AC_SUBST(build_configdirs)
3249
3250 # Host module lists & subconfigure args.
3251 AC_SUBST(host_configargs)
3252 AC_SUBST(configdirs)
3253 AC_SUBST(target_configdirs)
3254
3255 # Target module lists & subconfigure args.
3256 AC_SUBST(target_configargs)
3257
3258
3259 # Build tools.
3260 AC_SUBST(AR_FOR_BUILD)
3261 AC_SUBST(AS_FOR_BUILD)
3262 AC_SUBST(CC_FOR_BUILD)
3263 AC_SUBST(CFLAGS_FOR_BUILD)
3264 AC_SUBST(CXXFLAGS_FOR_BUILD)
3265 AC_SUBST(CXX_FOR_BUILD)
3266 AC_SUBST(DLLTOOL_FOR_BUILD)
3267 AC_SUBST(GFORTRAN_FOR_BUILD)
3268 AC_SUBST(GOC_FOR_BUILD)
3269 AC_SUBST(LDFLAGS_FOR_BUILD)
3270 AC_SUBST(LD_FOR_BUILD)
3271 AC_SUBST(NM_FOR_BUILD)
3272 AC_SUBST(RANLIB_FOR_BUILD)
3273 AC_SUBST(WINDMC_FOR_BUILD)
3274 AC_SUBST(WINDRES_FOR_BUILD)
3275
3276 # Generate default definitions for YACC, M4, LEX and other programs that run
3277 # on the build machine.  These are used if the Makefile can't locate these
3278 # programs in objdir.
3279 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3280
3281 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3282 case " $build_configdirs " in
3283   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3284 esac
3285
3286 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3287 case " $build_configdirs " in
3288   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3289 esac
3290
3291 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3292 case " $build_configdirs " in
3293   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3294 esac
3295
3296 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3297 case " $build_configdirs " in
3298   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3299   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3300 esac
3301
3302 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3303 case " $build_configdirs " in
3304   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3305 esac
3306
3307 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3308 case " $build_configdirs " in
3309   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3310   *)
3311 changequote(,)
3312     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3313     # higher, else we use the "missing" dummy.
3314     if ${MAKEINFO} --version \
3315        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3316       :
3317     else
3318       MAKEINFO="$MISSING makeinfo"
3319     fi
3320     ;;
3321 changequote([,])
3322 esac
3323
3324 # FIXME: expect and dejagnu may become build tools?
3325
3326 AC_CHECK_PROGS(EXPECT, expect, expect)
3327 case " $configdirs " in
3328   *" expect "*)
3329     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3330     ;;
3331 esac
3332
3333 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3334 case " $configdirs " in
3335   *" dejagnu "*)
3336     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3337     ;;
3338 esac
3339
3340
3341 # Host tools.
3342 NCN_STRICT_CHECK_TOOLS(AR, ar)
3343 NCN_STRICT_CHECK_TOOLS(AS, as)
3344 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3345 NCN_STRICT_CHECK_TOOLS(LD, ld)
3346 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3347 NCN_STRICT_CHECK_TOOLS(NM, nm)
3348 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3349 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3350 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3351 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3352 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3353 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3354 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3355 AC_SUBST(CC)
3356 AC_SUBST(CXX)
3357 AC_SUBST(CFLAGS)
3358 AC_SUBST(CXXFLAGS)
3359
3360 # Target tools.
3361 AC_ARG_WITH([build-time-tools],
3362   [AS_HELP_STRING([--with-build-time-tools=PATH],
3363                   [use given path to find target tools during the build])],
3364   [case x"$withval" in
3365      x/*) ;;
3366      *)
3367        with_build_time_tools=
3368        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3369        ;;
3370    esac],
3371   [with_build_time_tools=])
3372
3373 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3374 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3375 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3376 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3377 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3378
3379 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3380 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3381 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3382 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3383 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3384 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3385 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3386 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3387 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3388 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3389 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3390 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3391 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3392
3393 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3394
3395 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3396 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3397 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3398 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3399 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3400                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3401                 c++)
3402 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3403                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3404                 c++)
3405 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3406 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3407 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3408                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3409 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3410                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3411 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3412 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3413 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3414 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3415 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3416 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3417 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3418 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3419 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3420 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3421
3422 AC_SUBST(FLAGS_FOR_TARGET)
3423 AC_SUBST(RAW_CXX_FOR_TARGET)
3424
3425 # Certain tools may need extra flags.
3426 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3427 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3428 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3429
3430 # When building target libraries, except in a Canadian cross, we use
3431 # the same toolchain as the compiler we just built.
3432 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3433 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3434 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3435 if test $host = $build; then
3436   case " $configdirs " in
3437     *" gcc "*)
3438       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3439       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3440       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3441       ;;
3442   esac
3443 fi
3444
3445 AC_SUBST(COMPILER_AS_FOR_TARGET)
3446 AC_SUBST(COMPILER_LD_FOR_TARGET)
3447 AC_SUBST(COMPILER_NM_FOR_TARGET)
3448
3449 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3450 AC_ARG_ENABLE(maintainer-mode,
3451 [AS_HELP_STRING([--enable-maintainer-mode],
3452                 [enable make rules and dependencies not useful
3453                  (and sometimes confusing) to the casual installer])],
3454       USE_MAINTAINER_MODE=$enableval,
3455       USE_MAINTAINER_MODE=no)
3456 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3457 AC_SUBST(MAINTAINER_MODE_TRUE)
3458 AC_SUBST(MAINTAINER_MODE_FALSE)
3459 if test "$USE_MAINTAINER_MODE" = yes; then
3460   MAINTAINER_MODE_TRUE=
3461   MAINTAINER_MODE_FALSE='#'
3462 else
3463   MAINTAINER_MODE_TRUE='#'
3464   MAINTAINER_MODE_FALSE=
3465 fi
3466 MAINT=$MAINTAINER_MODE_TRUE
3467 AC_SUBST(MAINT)dnl
3468
3469 # ---------------------
3470 # GCC bootstrap support
3471 # ---------------------
3472
3473 # Stage specific cflags for build.
3474 stage1_cflags="-g"
3475 case $build in
3476   vax-*-*)
3477     case ${GCC} in
3478       yes) stage1_cflags="-g -Wa,-J" ;;
3479       *) stage1_cflags="-g -J" ;;
3480     esac ;;
3481 esac
3482
3483 AC_SUBST(stage1_cflags)
3484
3485 # Enable --enable-checking in stage1 of the compiler.
3486 AC_ARG_ENABLE(stage1-checking,
3487 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3488                 [choose additional checking for stage1 of the compiler])],
3489 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3490 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3491   # For --disable-checking or implicit --enable-checking=release, avoid
3492   # setting --enable-checking=gc in the default stage1 checking for LTO
3493   # bootstraps.  See PR62077.
3494   case $BUILD_CONFIG in
3495     *lto*)
3496       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3497     *)
3498       stage1_checking=--enable-checking=yes,types;;
3499   esac
3500   if test "x$enable_checking" = x && \
3501      test -d ${srcdir}/gcc && \
3502      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3503     stage1_checking=--enable-checking=yes,types,extra
3504   fi
3505 else
3506   stage1_checking=--enable-checking=$enable_checking,types
3507 fi])
3508 AC_SUBST(stage1_checking)
3509
3510 # Enable -Werror in bootstrap stage2 and later.
3511 AC_ARG_ENABLE(werror,
3512 [AS_HELP_STRING([--enable-werror],
3513                 [enable -Werror in bootstrap stage2 and later])],
3514 [
3515 case ${enable_werror} in
3516   yes) stage2_werror_flag="--enable-werror-always" ;;
3517   *) stage2_werror_flag="" ;;
3518 esac
3519 ],
3520 [
3521 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3522   case $BUILD_CONFIG in
3523   bootstrap-debug)
3524       stage2_werror_flag="--enable-werror-always" ;;
3525   "")
3526       stage2_werror_flag="--enable-werror-always" ;;
3527   esac
3528 fi
3529 ])
3530
3531 AC_SUBST(stage2_werror_flag)
3532
3533 # Specify what files to not compare during bootstrap.
3534
3535 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3536 case "$target" in
3537   hppa*64*-*-hpux*) ;;
3538   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3539   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3540 esac
3541 AC_SUBST(compare_exclusions)
3542
3543 AC_CONFIG_FILES([Makefile],
3544   [sed "$extrasub_build" Makefile |
3545    sed "$extrasub_host" |
3546    sed "$extrasub_target" > mf$$
3547    mv -f mf$$ Makefile],
3548   [extrasub_build="$extrasub_build"
3549    extrasub_host="$extrasub_host"
3550    extrasub_target="$extrasub_target"])
3551 AC_OUTPUT