configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 #
 153 target_libraries="target-libgcc \
 154                 target-libiberty \
 155                 target-libgloss \
 156                 target-newlib \
 157                 target-libgomp \
 158                 target-libstdc++-v3 \
 159                 target-libmudflap \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-boehm-gc \
 164                 ${libgcj} \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 # Make sure we don't let ZLIB be added if we didn't want it.
 243 if test x$with_system_zlib = xyes ; then
 244   use_included_zlib=no
 245   noconfigdirs="$noconfigdirs zlib"
 246 fi
 247
 248 # some tools are so dependent upon X11 that if we're not building with X,
 249 # it's not even worth trying to configure, much less build, that tool.
 250
 251 case ${with_x} in
 252   yes | "") ;; # the default value for this tree is that X11 is available
 253   no)
 254     skipdirs="${skipdirs} tk itcl libgui"
 255     # We won't be able to build gdbtk without X.
 256     enable_gdbtk=no
 257     ;;
 258   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 259 esac
 260
 261 # Some are only suitable for cross toolchains.
 262 # Remove these if host=target.
 263 cross_only="target-libgloss target-newlib target-opcodes"
 264
 265 case $is_cross_compiler in
 266   no) skipdirs="${skipdirs} ${cross_only}" ;;
 267 esac
 268
 269 # If both --with-headers and --with-libs are specified, default to
 270 # --without-newlib.
 271 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 272    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 273   if test x"${with_newlib}" = x ; then
 274     with_newlib=no
 275   fi
 276 fi
 277
 278 # Recognize --with-newlib/--without-newlib.
 279 case ${with_newlib} in
 280   no) skipdirs="${skipdirs} target-newlib" ;;
 281   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 282 esac
 283
 284 # Handle --enable-gold, --enable-ld.
 285 # --disable-gold [--enable-ld]
 286 #     Build only ld.  Default option.
 287 # --enable-gold [--enable-ld]
 288 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 289 #     as "ld.bfd" and "ld".
 290 # --enable-gold=default [--enable-ld]
 291 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 292 #     install ld as "ld.bfd".
 293 # --enable-gold[=default] --disable-ld
 294 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 295 # --enable-gold --enable-ld=default
 296 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 297 #     and ld.bfd).
 298 #     In other words, ld is default
 299 # --enable-gold=default --enable-ld=default
 300 #     Error.
 301
 302 default_ld=
 303 AC_ARG_ENABLE(gold,
 304 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 305                 [build gold @<:@ARG={default,yes,no}@:>@])],
 306 ENABLE_GOLD=$enableval,
 307 ENABLE_GOLD=no)
 308 case "${ENABLE_GOLD}" in
 309   yes|default)
 310     # Check for ELF target.
 311     is_elf=no
 312     case "${target}" in
 313       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 314       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 315       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 316       | *-*-solaris2* | *-*-nto*)
 317         case "${target}" in
 318           *-*-linux*aout* | *-*-linux*oldld*)
 319             ;;
 320           *)
 321             is_elf=yes
 322             ;;
 323         esac
 324     esac
 325
 326     if test "$is_elf" = "yes"; then
 327       # Check for target supported by gold.
 328       case "${target}" in
 329         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 330           configdirs="$configdirs gold"
 331           if test x${ENABLE_GOLD} = xdefault; then
 332             default_ld=gold
 333           fi
 334           ENABLE_GOLD=yes
 335           ;;
 336       esac
 337     fi
 338     ;;
 339   no)
 340     ;;
 341   *)
 342     AC_MSG_ERROR([invalid --enable-gold argument])
 343     ;;
 344 esac
 345
 346 AC_ARG_ENABLE(ld,
 347 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 348                 [build ld @<:@ARG={default,yes,no}@:>@])],
 349 ENABLE_LD=$enableval,
 350 ENABLE_LD=yes)
 351
 352 case "${ENABLE_LD}" in
 353   default)
 354     if test x${default_ld} != x; then
 355       AC_MSG_ERROR([either gold or ld can be the default ld])
 356     fi
 357     ;;
 358   yes)
 359     ;;
 360   no)
 361     if test x${ENABLE_GOLD} != xyes; then
 362       AC_MSG_WARN([neither ld nor gold are enabled])
 363     fi
 364     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 365     ;;
 366   *)
 367     AC_MSG_ERROR([invalid --enable-ld argument])
 368     ;;
 369 esac
 370
 371 # Configure extra directories which are host specific
 372
 373 case "${host}" in
 374   *-cygwin*)
 375     configdirs="$configdirs libtermcap" ;;
 376 esac
 377
 378 # A target can indicate whether a language isn't supported for some reason.
 379 # Only spaces may be used in this macro; not newlines or tabs.
 380 unsupported_languages=
 381
 382 # Remove more programs from consideration, based on the host or
 383 # target this usually means that a port of the program doesn't
 384 # exist yet.
 385
 386 case "${host}" in
 387   i[[3456789]]86-*-msdosdjgpp*)
 388     noconfigdirs="$noconfigdirs tcl tk itcl"
 389     ;;
 390 esac
 391
 392
 393 AC_ARG_ENABLE(libquadmath,
 394 AS_HELP_STRING([--disable-libquadmath],
 395   [do not build libquadmath directory]),
 396 ENABLE_LIBQUADMATH=$enableval,
 397 ENABLE_LIBQUADMATH=yes)
 398 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 399   noconfigdirs="$noconfigdirs target-libquadmath"
 400 fi
 401
 402
 403 AC_ARG_ENABLE(libquadmath-support,
 404 AS_HELP_STRING([--disable-libquadmath-support],
 405   [disable libquadmath support for Fortran]),
 406 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 407 ENABLE_LIBQUADMATH_SUPPORT=yes)
 408 enable_libquadmath_support=
 409 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 410   enable_libquadmath_support=no
 411 fi
 412
 413
 414 AC_ARG_ENABLE(libada,
 415 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 416 ENABLE_LIBADA=$enableval,
 417 ENABLE_LIBADA=yes)
 418 if test "${ENABLE_LIBADA}" != "yes" ; then
 419   noconfigdirs="$noconfigdirs gnattools"
 420 fi
 421
 422 AC_ARG_ENABLE(libssp,
 423 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 424 ENABLE_LIBSSP=$enableval,
 425 ENABLE_LIBSSP=yes)
 426
 427 # Save it here so that, even in case of --enable-libgcj, if the Java
 428 # front-end isn't enabled, we still get libgcj disabled.
 429 libgcj_saved=$libgcj
 430 case $enable_libgcj in
 431 yes)
 432   # If we reset it here, it won't get added to noconfigdirs in the
 433   # target-specific build rules, so it will be forcibly enabled
 434   # (unless the Java language itself isn't enabled).
 435   libgcj=
 436   ;;
 437 no)
 438   # Make sure we get it printed in the list of not supported target libs.
 439   # Don't disable libffi, though, other languages use it.
 440   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 441   # Clear libgcj_saved so that even if java is enabled libffi won't be
 442   # built.
 443   libgcj_saved=
 444   ;;
 445 esac
 446
 447
 448 # Disable libmudflap on some systems.
 449 if test x$enable_libmudflap = x ; then
 450     case "${target}" in
 451     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 452         # Enable libmudflap by default in GNU and friends.
 453         ;;
 454     *-*-freebsd*)
 455         # Enable libmudflap by default in FreeBSD.
 456         ;;
 457     *)
 458         # Disable it by default everywhere else.
 459         noconfigdirs="$noconfigdirs target-libmudflap"
 460         ;;
 461     esac
 462 fi
 463
 464 # Disable libgomp on non POSIX hosted systems.
 465 if test x$enable_libgomp = x ; then
 466     # Enable libgomp by default on hosted POSIX systems.
 467     case "${target}" in
 468     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 469         ;;
 470     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 471         ;;
 472     *-*-solaris2* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 473         ;;
 474     *-*-darwin* | *-*-aix*)
 475         ;;
 476     *)
 477         noconfigdirs="$noconfigdirs target-libgomp"
 478         ;;
 479     esac
 480 fi
 481
 482 # Disable libssp for some systems.
 483 case "${target}" in
 484   avr-*-*)
 485     # No hosted I/O support.
 486     noconfigdirs="$noconfigdirs target-libssp"
 487     ;;
 488   powerpc-*-aix* | rs6000-*-aix*)
 489     noconfigdirs="$noconfigdirs target-libssp"
 490     ;;
 491 esac
 492
 493 # Disable target libiberty for some systems.
 494 case "${target}" in
 495   *-*-kaos*)
 496     # Remove unsupported stuff on all kaOS configurations.
 497     skipdirs="target-libiberty"
 498     ;;
 499   *-*-netbsd*)
 500     # Skip some stuff on all NetBSD configurations.
 501     noconfigdirs="$noconfigdirs target-libiberty"
 502     ;;
 503   *-*-netware*)
 504     noconfigdirs="$noconfigdirs target-libiberty"
 505     ;;
 506   *-*-rtems*)
 507     skipdirs="${skipdirs} target-libiberty"
 508     ;;
 509   *-*-tpf*)
 510     noconfigdirs="$noconfigdirs target-libiberty"
 511     ;;
 512   *-*-vxworks*)
 513     noconfigdirs="$noconfigdirs target-libiberty"
 514     ;;
 515   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 516     noconfigdirs="$noconfigdirs target-libiberty"
 517     ;;
 518   arm*-*-symbianelf*)
 519     noconfigdirs="$noconfigdirs target-libiberty"
 520     ;;
 521   avr-*-*)
 522     noconfigdirs="$noconfigdirs target-libiberty"
 523     ;;
 524   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 525     noconfigdirs="$noconfigdirs target-libiberty"
 526     ;;
 527   picochip-*-*)
 528     noconfigdirs="$noconfigdirs target-libiberty"
 529     ;;
 530   mips*-sde-elf*)
 531     skipdirs="$skipdirs target-libiberty"
 532     ;;
 533   ip2k-*-*)
 534     noconfigdirs="$noconfigdirs target-libiberty"
 535     ;;
 536 esac
 537
 538 # Disable libstdc++-v3 for some systems.
 539 case "${target}" in
 540   *-*-vxworks*)
 541     # VxWorks uses the Dinkumware C++ library.
 542     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 543     ;;
 544   arm*-wince-pe*)
 545     # the C++ libraries don't build on top of CE's C libraries
 546     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 547     ;;
 548   avr-*-*)
 549     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 550     ;;
 551 esac
 552
 553 # Disable Fortran for some systems.
 554 case "${target}" in
 555   mmix-*-*)
 556     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 557     unsupported_languages="$unsupported_languages fortran"
 558     ;;
 559 esac
 560
 561 # Disable Java if libffi is not supported.
 562 case "${target}" in
 563   alpha*-*-*)
 564     ;;
 565   arm*-*-*)
 566     ;;
 567   cris-*-*)
 568     ;;
 569   frv-*-*)
 570     ;;
 571   hppa*-*-linux*)
 572     ;;
 573   hppa*-*-hpux*)
 574     ;;
 575   i?86-*-*)
 576     ;;
 577   ia64*-*-*)
 578     ;;
 579   m32r*-*-*)
 580     ;;
 581   m68k-*-*)
 582     ;;
 583   mips-sgi-irix6.* | mips*-*-rtems*)
 584     ;;
 585   mips*-*-linux*)
 586     ;;
 587   powerpc*-*-linux*)
 588     ;;
 589   powerpc-*-darwin*)
 590     ;;
 591   powerpc-*-aix* | rs6000-*-aix*)
 592     ;;
 593   powerpc-*-freebsd*)
 594     ;;
 595   powerpc64-*-freebsd*)
 596     ;;
 597   powerpc*-*-rtems*)
 598     ;;
 599   s390-*-* | s390x-*-*)
 600     ;;
 601   sh-*-* | sh[[34]]*-*-*)
 602     ;;
 603   sh64-*-* | sh5*-*-*)
 604     ;;
 605   sparc*-*-*)
 606     ;;
 607   x86_64-*-*)
 608     ;;
 609   *-*-*)
 610     unsupported_languages="$unsupported_languages java"
 611     ;;
 612 esac
 613
 614 # Disable Java, libgcj or related libraries for some systems.
 615 case "${target}" in
 616   powerpc-*-darwin*)
 617     ;;
 618   i[[3456789]]86-*-darwin*)
 619     ;;
 620   x86_64-*-darwin[[912]]*)
 621     ;;
 622   *-*-darwin*)
 623     noconfigdirs="$noconfigdirs ${libgcj}"
 624     ;;
 625   *-*-netware*)
 626     noconfigdirs="$noconfigdirs ${libgcj}"
 627     ;;
 628   *-*-rtems*)
 629     noconfigdirs="$noconfigdirs ${libgcj}"
 630     ;;
 631   *-*-tpf*)
 632     noconfigdirs="$noconfigdirs ${libgcj}"
 633     ;;
 634   *-*-uclinux*)
 635     noconfigdirs="$noconfigdirs ${libgcj}"
 636     ;;
 637   *-*-vxworks*)
 638     noconfigdirs="$noconfigdirs ${libgcj}"
 639     ;;
 640   alpha*-*-*vms*)
 641     noconfigdirs="$noconfigdirs ${libgcj}"
 642     ;;
 643   arm-wince-pe)
 644     noconfigdirs="$noconfigdirs ${libgcj}"
 645     ;;
 646   arm*-*-symbianelf*)
 647     noconfigdirs="$noconfigdirs ${libgcj}"
 648     ;;
 649   bfin-*-*)
 650     noconfigdirs="$noconfigdirs target-boehm-gc"
 651     ;;
 652   cris-*-* | crisv32-*-*)
 653     unsupported_languages="$unsupported_languages java"
 654     case "${target}" in
 655       *-*-linux*)
 656         ;;
 657       *) # See PR46792 regarding target-libffi.
 658         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 659     esac
 660     ;;
 661   hppa*64*-*-linux*)
 662     # In this case, it's because the hppa64-linux target is for
 663     # the kernel only at this point and has no libc, and thus no
 664     # headers, crt*.o, etc., all of which are needed by these.
 665     unsupported_languages="$unsupported_languages java"
 666     ;;
 667   hppa*64*-*-hpux*)
 668     noconfigdirs="$noconfigdirs ${libgcj}"
 669     ;;
 670   hppa*-hp-hpux11*)
 671     ;;
 672   hppa*-*-hpux*)
 673     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 674     # build on HP-UX 10.20.
 675     noconfigdirs="$noconfigdirs ${libgcj}"
 676     ;;
 677   ia64*-*-*vms*)
 678     noconfigdirs="$noconfigdirs ${libgcj}"
 679     ;;
 680   i[[3456789]]86-w64-mingw*)
 681     noconfigdirs="$noconfigdirs ${libgcj}"
 682     ;;
 683   i[[3456789]]86-*-mingw*)
 684     noconfigdirs="$noconfigdirs ${libgcj}"
 685     ;;
 686   x86_64-*-mingw*)
 687     noconfigdirs="$noconfigdirs ${libgcj}"
 688     ;;
 689   mmix-*-*)
 690     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 691     ;;
 692   powerpc-*-aix*)
 693     # copied from rs6000-*-* entry
 694     noconfigdirs="$noconfigdirs ${libgcj}"
 695     ;;
 696   rs6000-*-aix*)
 697     noconfigdirs="$noconfigdirs ${libgcj}"
 698     ;;
 699   mips*-*-irix6*)
 700     # Linking libjava exceeds command-line length limits on at least
 701     # IRIX 6.2, but not on IRIX 6.5.
 702     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 703     # <oldham@codesourcery.com>
 704     noconfigdirs="$noconfigdirs ${libgcj}"
 705     ;;
 706   *-*-lynxos*)
 707     noconfigdirs="$noconfigdirs ${libgcj}"
 708     ;;
 709 esac
 710
 711 # Default libgloss CPU subdirectory.
 712 libgloss_dir="$target_cpu"
 713
 714 case "${target}" in
 715   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 716     libgloss_dir=wince
 717     ;;
 718   arm*-*-*)
 719     libgloss_dir=arm
 720     ;;
 721   cris-*-* | crisv32-*-*)
 722     libgloss_dir=cris
 723     ;;
 724   hppa*-*-*)
 725     libgloss_dir=pa
 726     ;;
 727   i[[3456789]]86-*-*)
 728     libgloss_dir=i386
 729     ;;
 730   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 731     libgloss_dir=m68hc11
 732     ;;
 733   m68*-*-* | fido-*-*)
 734     libgloss_dir=m68k
 735     ;;
 736   mips*-*-*)
 737     libgloss_dir=mips
 738     ;;
 739   powerpc*-*-*)
 740     libgloss_dir=rs6000
 741     ;;
 742   sparc*-*-*)
 743     libgloss_dir=sparc
 744     ;;
 745 esac
 746
 747 # Disable newlib and libgloss for various target OSes.
 748 case "${target}" in
 749   alpha*-dec-osf*)
 750     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 751     ;;
 752   i[[3456789]]86-*-linux*)
 753     # This section makes it possible to build newlib natively on linux.
 754     # If we are using a cross compiler then don't configure newlib.
 755     if test x${is_cross_compiler} != xno ; then
 756       noconfigdirs="$noconfigdirs target-newlib"
 757     fi
 758     noconfigdirs="$noconfigdirs target-libgloss"
 759     # If we are not using a cross compiler, do configure newlib.
 760     # Note however, that newlib will only be configured in this situation
 761     # if the --with-newlib option has been given, because otherwise
 762     # 'target-newlib' will appear in skipdirs.
 763     ;;
 764   i[[3456789]]86-*-rdos*)
 765     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 766     ;;
 767   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 768     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 769     ;;
 770   sparc-*-sunos4*)
 771     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 772     ;;
 773   *-*-aix*)
 774     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 775     ;;
 776   *-*-beos*)
 777     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 778     ;;
 779   *-*-chorusos)
 780     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 781     ;;
 782   *-*-dragonfly*)
 783     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 784     ;;
 785   *-*-freebsd*)
 786     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 787     ;;
 788   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 789     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 790     ;;
 791   *-*-lynxos*)
 792     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 793     ;;
 794   *-*-mingw*)
 795     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 796     ;;
 797   *-*-netbsd*)
 798     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 799     ;;
 800   *-*-netware*)
 801     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 802     ;;
 803   *-*-tpf*)
 804     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 805     ;;
 806   *-*-uclinux*)
 807     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 808     ;;
 809   *-*-vxworks*)
 810     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 811     ;;
 812 esac
 813
 814 case "${target}" in
 815   *-*-chorusos)
 816     ;;
 817   powerpc-*-darwin*)
 818     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 819     noconfigdirs="$noconfigdirs sim target-rda"
 820     ;;
 821   i[[3456789]]86-*-darwin*)
 822     noconfigdirs="$noconfigdirs ld gprof"
 823     noconfigdirs="$noconfigdirs sim target-rda"
 824     ;;
 825   x86_64-*-darwin[[912]]*)
 826     noconfigdirs="$noconfigdirs ld gas gprof"
 827     noconfigdirs="$noconfigdirs sim target-rda"
 828     ;;
 829   *-*-darwin*)
 830     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 831     noconfigdirs="$noconfigdirs sim target-rda"
 832     ;;
 833   *-*-dragonfly*)
 834     ;;
 835   *-*-freebsd*)
 836     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 837         && test -f /usr/local/include/gmp.h; then
 838       with_gmp=/usr/local
 839     fi
 840     ;;
 841   *-*-kaos*)
 842     # Remove unsupported stuff on all kaOS configurations.
 843     noconfigdirs="$noconfigdirs target-libgloss"
 844     ;;
 845   *-*-netbsd*)
 846     ;;
 847   *-*-netware*)
 848     ;;
 849   *-*-rtems*)
 850     noconfigdirs="$noconfigdirs target-libgloss"
 851     ;;
 852     # The tpf target doesn't support gdb yet.
 853   *-*-tpf*)
 854     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 855     ;;
 856   *-*-uclinux*)
 857     noconfigdirs="$noconfigdirs target-rda"
 858     ;;
 859   *-*-vxworks*)
 860     ;;
 861   alpha*-dec-osf*)
 862     # ld works, but does not support shared libraries.
 863     # gas doesn't generate exception information.
 864     noconfigdirs="$noconfigdirs gas ld"
 865     ;;
 866   alpha*-*-*vms*)
 867     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 868     ;;
 869   alpha*-*-*)
 870     # newlib is not 64 bit ready
 871     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 872     ;;
 873   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 874     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 875     ;;
 876   arc-*-*)
 877     noconfigdirs="$noconfigdirs target-libgloss"
 878     ;;
 879   arm-*-pe*)
 880     noconfigdirs="$noconfigdirs target-libgloss"
 881     ;;
 882   arm-*-riscix*)
 883     noconfigdirs="$noconfigdirs ld target-libgloss"
 884     ;;
 885   c4x-*-* | tic4x-*-*)
 886     noconfigdirs="$noconfigdirs target-libgloss"
 887     ;;
 888   tic54x-*-*)
 889     noconfigdirs="$noconfigdirs target-libgloss gdb"
 890     ;;
 891   cr16-*-*)
 892     noconfigdirs="$noconfigdirs gdb"
 893     ;;
 894   d10v-*-*)
 895     noconfigdirs="$noconfigdirs target-libgloss"
 896     ;;
 897   d30v-*-*)
 898     noconfigdirs="$noconfigdirs gdb"
 899     ;;
 900   fr30-*-elf*)
 901     noconfigdirs="$noconfigdirs gdb"
 902     ;;
 903   moxie-*-*)
 904     noconfigdirs="$noconfigdirs gprof"
 905     ;;
 906   h8300*-*-*)
 907     noconfigdirs="$noconfigdirs target-libgloss"
 908     ;;
 909   h8500-*-*)
 910     noconfigdirs="$noconfigdirs target-libgloss"
 911     ;;
 912   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 913     ;;
 914   hppa*64*-*-linux*)
 915     ;;
 916   hppa*-*-linux*)
 917     ;;
 918   hppa*-*-*elf* | \
 919   hppa*-*-lites* | \
 920   hppa*-*-openbsd* | \
 921   hppa*64*-*-*)
 922     ;;
 923   hppa*-hp-hpux11*)
 924     noconfigdirs="$noconfigdirs ld"
 925     ;;
 926   hppa*-*-pro*)
 927     ;;
 928   hppa*-*-*)
 929     noconfigdirs="$noconfigdirs ld"
 930     ;;
 931   i960-*-*)
 932     noconfigdirs="$noconfigdirs gdb"
 933     ;;
 934   ia64*-*-elf*)
 935     # No gdb support yet.
 936     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 937     ;;
 938   ia64*-**-hpux*)
 939     # No ld support yet.
 940     noconfigdirs="$noconfigdirs libgui itcl ld"
 941     ;;
 942   ia64*-*-*vms*)
 943     # No gdb or ld support yet.
 944     noconfigdirs="$noconfigdirs readline libgui itcl gdb ld"
 945     ;;
 946   i[[3456789]]86-w64-mingw*)
 947     ;;
 948   i[[3456789]]86-*-mingw*)
 949     target_configdirs="$target_configdirs target-winsup"
 950     ;;
 951   *-*-cygwin*)
 952     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 953     noconfigdirs="$noconfigdirs target-libgloss"
 954     # always build newlib if winsup directory is present.
 955     if test -d "$srcdir/winsup/cygwin"; then
 956       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 957     elif test -d "$srcdir/newlib"; then
 958       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 959     fi
 960     ;;
 961   i[[3456789]]86-*-pe)
 962     noconfigdirs="$noconfigdirs target-libgloss"
 963     ;;
 964   i[[3456789]]86-*-sco3.2v5*)
 965     # The linker does not yet know about weak symbols in COFF,
 966     # and is not configured to handle mixed ELF and COFF.
 967     noconfigdirs="$noconfigdirs ld target-libgloss"
 968     ;;
 969   i[[3456789]]86-*-sco*)
 970     noconfigdirs="$noconfigdirs gprof target-libgloss"
 971     ;;
 972   i[[3456789]]86-*-solaris2*)
 973     noconfigdirs="$noconfigdirs target-libgloss"
 974     ;;
 975   i[[3456789]]86-*-sysv4*)
 976     noconfigdirs="$noconfigdirs target-libgloss"
 977     ;;
 978   i[[3456789]]86-*-beos*)
 979     noconfigdirs="$noconfigdirs gdb"
 980     ;;
 981   i[[3456789]]86-*-rdos*)
 982     noconfigdirs="$noconfigdirs gdb"
 983     ;;
 984   mmix-*-*)
 985     noconfigdirs="$noconfigdirs gdb"
 986     ;;
 987   mt-*-*)
 988     noconfigdirs="$noconfigdirs sim"
 989     ;;
 990   powerpc-*-aix*)
 991     # copied from rs6000-*-* entry
 992     noconfigdirs="$noconfigdirs gprof"
 993     ;;
 994   powerpc*-*-winnt* | powerpc*-*-pe*)
 995     target_configdirs="$target_configdirs target-winsup"
 996     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 997     # always build newlib.
 998     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 999     ;;
1000     # This is temporary until we can link against shared libraries
1001   powerpcle-*-solaris*)
1002     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1003     ;;
1004   powerpc-*-beos*)
1005     noconfigdirs="$noconfigdirs gdb"
1006     ;;
1007   rs6000-*-lynxos*)
1008     noconfigdirs="$noconfigdirs gprof"
1009     ;;
1010   rs6000-*-aix*)
1011     noconfigdirs="$noconfigdirs gprof"
1012     ;;
1013   rs6000-*-*)
1014     noconfigdirs="$noconfigdirs gprof"
1015     ;;
1016   m68k-apollo-*)
1017     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1018     ;;
1019   microblaze*)
1020     noconfigdirs="$noconfigdirs gprof"
1021     ;;
1022   mips*-sde-elf*)
1023     if test x$with_newlib = xyes; then
1024       noconfigdirs="$noconfigdirs gprof"
1025     fi
1026     ;;
1027   mips*-*-irix5*)
1028     noconfigdirs="$noconfigdirs gprof target-libgloss"
1029     ;;
1030   mips*-*-irix6*)
1031     noconfigdirs="$noconfigdirs gprof target-libgloss"
1032     ;;
1033   mips*-*-bsd*)
1034     noconfigdirs="$noconfigdirs gprof target-libgloss"
1035     ;;
1036   mips*-*-linux*)
1037     ;;
1038   mips*-*-*)
1039     noconfigdirs="$noconfigdirs gprof"
1040     ;;
1041   sh-*-* | sh64-*-*)
1042     case "${target}" in
1043       sh*-*-elf)
1044          ;;
1045       *)
1046          noconfigdirs="$noconfigdirs target-libgloss" ;;
1047     esac
1048     ;;
1049   sparc-*-sunos4*)
1050     if test x${is_cross_compiler} = xno ; then
1051            use_gnu_ld=no
1052     fi
1053     ;;
1054   tic6x-*-*)
1055     noconfigdirs="$noconfigdirs gdb sim"
1056     ;;
1057   v810-*-*)
1058     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1059     ;;
1060   vax-*-*)
1061     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1062     ;;
1063 esac
1064
1065 # If we aren't building newlib, then don't build libgloss, since libgloss
1066 # depends upon some newlib header files.
1067 case "${noconfigdirs}" in
1068   *target-libgloss*) ;;
1069   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1070 esac
1071
1072 # Work in distributions that contain no compiler tools, like Autoconf.
1073 host_makefile_frag=/dev/null
1074 if test -d ${srcdir}/config ; then
1075 case "${host}" in
1076   i[[3456789]]86-*-msdosdjgpp*)
1077     host_makefile_frag="config/mh-djgpp"
1078     ;;
1079   *-cygwin*)
1080     ACX_CHECK_CYGWIN_CAT_WORKS
1081     host_makefile_frag="config/mh-cygwin"
1082     ;;
1083   *-mingw*)
1084     host_makefile_frag="config/mh-mingw"
1085     ;;
1086   *-interix*)
1087     host_makefile_frag="config/mh-interix"
1088     ;;
1089   hppa*-hp-hpux10*)
1090     host_makefile_frag="config/mh-pa-hpux10"
1091     ;;
1092   hppa*-hp-hpux*)
1093     host_makefile_frag="config/mh-pa"
1094     ;;
1095   hppa*-*)
1096     host_makefile_frag="config/mh-pa"
1097     ;;
1098   *-*-darwin*)
1099     host_makefile_frag="config/mh-darwin"
1100     ;;
1101   powerpc-*-aix*)
1102     host_makefile_frag="config/mh-ppc-aix"
1103     ;;
1104   rs6000-*-aix*)
1105     host_makefile_frag="config/mh-ppc-aix"
1106     ;;
1107 esac
1108 fi
1109
1110 if test "${build}" != "${host}" ; then
1111   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1112   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1113   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1114   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1115   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1116   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1117   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1118   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1119   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1120   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1121   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1122   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1123   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1124 else
1125   AR_FOR_BUILD="\$(AR)"
1126   AS_FOR_BUILD="\$(AS)"
1127   CC_FOR_BUILD="\$(CC)"
1128   CXX_FOR_BUILD="\$(CXX)"
1129   GCJ_FOR_BUILD="\$(GCJ)"
1130   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1131   GOC_FOR_BUILD="\$(GOC)"
1132   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1133   LD_FOR_BUILD="\$(LD)"
1134   NM_FOR_BUILD="\$(NM)"
1135   RANLIB_FOR_BUILD="\$(RANLIB)"
1136   WINDRES_FOR_BUILD="\$(WINDRES)"
1137   WINDMC_FOR_BUILD="\$(WINDMC)"
1138 fi
1139
1140 AC_PROG_CC
1141 AC_PROG_CXX
1142
1143 # We must set the default linker to the linker used by gcc for the correct
1144 # operation of libtool.  If LD is not defined and we are using gcc, try to
1145 # set the LD default to the ld used by gcc.
1146 if test -z "$LD"; then
1147   if test "$GCC" = yes; then
1148     case $build in
1149     *-*-mingw*)
1150       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1151     *)
1152       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1153     esac
1154     case $gcc_prog_ld in
1155     # Accept absolute paths.
1156     [[\\/]* | [A-Za-z]:[\\/]*)]
1157       LD="$gcc_prog_ld" ;;
1158     esac
1159   fi
1160 fi
1161
1162 ACX_PROG_GNAT
1163 ACX_PROG_CMP_IGNORE_INITIAL
1164
1165 # See if we are building gcc with C++.
1166 AC_ARG_ENABLE(build-with-cxx,
1167 [AS_HELP_STRING([--enable-build-with-cxx],
1168                 [build with C++ compiler instead of C compiler])],
1169 ENABLE_BUILD_WITH_CXX=$enableval,
1170 ENABLE_BUILD_WITH_CXX=no)
1171
1172 # Used for setting $lt_cv_objdir
1173 _LT_CHECK_OBJDIR
1174
1175 # Check for GMP, MPFR and MPC
1176 gmplibs="-lmpc -lmpfr -lgmp"
1177 gmpinc=
1178 have_gmp=no
1179
1180 # Specify a location for mpc
1181 # check for this first so it ends up on the link line before mpfr.
1182 AC_ARG_WITH(mpc,
1183 [AS_HELP_STRING([--with-mpc=PATH],
1184                 [specify prefix directory for installed MPC package.
1185                  Equivalent to --with-mpc-include=PATH/include
1186                  plus --with-mpc-lib=PATH/lib])])
1187 AC_ARG_WITH(mpc-include,
1188 [AS_HELP_STRING([--with-mpc-include=PATH],
1189                 [specify directory for installed MPC include files])])
1190 AC_ARG_WITH(mpc-lib,
1191 [AS_HELP_STRING([--with-mpc-lib=PATH],
1192                 [specify directory for the installed MPC library])])
1193
1194 if test "x$with_mpc" != x; then
1195   gmplibs="-L$with_mpc/lib $gmplibs"
1196   gmpinc="-I$with_mpc/include $gmpinc"
1197 fi
1198 if test "x$with_mpc_include" != x; then
1199   gmpinc="-I$with_mpc_include $gmpinc"
1200 fi
1201 if test "x$with_mpc_lib" != x; then
1202   gmplibs="-L$with_mpc_lib $gmplibs"
1203 fi
1204 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1205   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1206   gmpinc='-I$$s/mpc/src '"$gmpinc"
1207   # Do not test the mpc version.  Assume that it is sufficient, since
1208   # it is in the source tree, and the library has not been built yet
1209   # but it would be included on the link line in the version check below
1210   # hence making the test fail.
1211   have_gmp=yes
1212 fi
1213
1214 # Specify a location for mpfr
1215 # check for this first so it ends up on the link line before gmp.
1216 AC_ARG_WITH(mpfr-dir,
1217 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1218 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1219 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1220
1221 AC_ARG_WITH(mpfr,
1222 [AS_HELP_STRING([--with-mpfr=PATH],
1223                 [specify prefix directory for installed MPFR package.
1224                  Equivalent to --with-mpfr-include=PATH/include
1225                  plus --with-mpfr-lib=PATH/lib])])
1226 AC_ARG_WITH(mpfr-include,
1227 [AS_HELP_STRING([--with-mpfr-include=PATH],
1228                 [specify directory for installed MPFR include files])])
1229 AC_ARG_WITH(mpfr-lib,
1230 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1231                 [specify directory for the installed MPFR library])])
1232
1233 if test "x$with_mpfr" != x; then
1234   gmplibs="-L$with_mpfr/lib $gmplibs"
1235   gmpinc="-I$with_mpfr/include $gmpinc"
1236 fi
1237 if test "x$with_mpfr_include" != x; then
1238   gmpinc="-I$with_mpfr_include $gmpinc"
1239 fi
1240 if test "x$with_mpfr_lib" != x; then
1241   gmplibs="-L$with_mpfr_lib $gmplibs"
1242 fi
1243 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1244   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1245   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1246   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1247   # Do not test the mpfr version.  Assume that it is sufficient, since
1248   # it is in the source tree, and the library has not been built yet
1249   # but it would be included on the link line in the version check below
1250   # hence making the test fail.
1251   have_gmp=yes
1252 fi
1253
1254 # Specify a location for gmp
1255 AC_ARG_WITH(gmp-dir,
1256 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1257 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1258 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1259
1260 AC_ARG_WITH(gmp,
1261 [AS_HELP_STRING([--with-gmp=PATH],
1262                 [specify prefix directory for the installed GMP package.
1263                  Equivalent to --with-gmp-include=PATH/include
1264                  plus --with-gmp-lib=PATH/lib])])
1265 AC_ARG_WITH(gmp-include,
1266 [AS_HELP_STRING([--with-gmp-include=PATH],
1267                 [specify directory for installed GMP include files])])
1268 AC_ARG_WITH(gmp-lib,
1269 [AS_HELP_STRING([--with-gmp-lib=PATH],
1270                 [specify directory for the installed GMP library])])
1271
1272
1273 if test "x$with_gmp" != x; then
1274   gmplibs="-L$with_gmp/lib $gmplibs"
1275   gmpinc="-I$with_gmp/include $gmpinc"
1276 fi
1277 if test "x$with_gmp_include" != x; then
1278   gmpinc="-I$with_gmp_include $gmpinc"
1279 fi
1280 if test "x$with_gmp_lib" != x; then
1281   gmplibs="-L$with_gmp_lib $gmplibs"
1282 fi
1283 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1284   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1285   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1286   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1287   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1288   # Do not test the gmp version.  Assume that it is sufficient, since
1289   # it is in the source tree, and the library has not been built yet
1290   # but it would be included on the link line in the version check below
1291   # hence making the test fail.
1292   have_gmp=yes
1293 fi
1294
1295 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1296   have_gmp=yes
1297   saved_CFLAGS="$CFLAGS"
1298   CFLAGS="$CFLAGS $gmpinc"
1299   # Check for the recommended and required versions of GMP.
1300   AC_MSG_CHECKING([for the correct version of gmp.h])
1301   AC_TRY_COMPILE([#include "gmp.h"],[
1302   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1303   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1304   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1305   choke me
1306   #endif
1307   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1308   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1309   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1310   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1311   choke me
1312   #endif
1313   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1314    [AC_MSG_RESULT([no]); have_gmp=no])
1315
1316   # If we have GMP, check the MPFR version.
1317   if test x"$have_gmp" = xyes; then
1318     # Check for the recommended and required versions of MPFR.
1319     AC_MSG_CHECKING([for the correct version of mpfr.h])
1320     AC_TRY_COMPILE([#include <gmp.h>
1321     #include <mpfr.h>],[
1322     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1323     choke me
1324     #endif
1325     ], [AC_TRY_COMPILE([#include <gmp.h>
1326     #include <mpfr.h>],[
1327     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1328     choke me
1329     #endif
1330     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1331      [AC_MSG_RESULT([no]); have_gmp=no])
1332   fi
1333
1334   # Check for the MPC header version.
1335   if test x"$have_gmp" = xyes ; then
1336     # Check for the recommended and required versions of MPC.
1337     AC_MSG_CHECKING([for the correct version of mpc.h])
1338     AC_TRY_COMPILE([#include <mpc.h>],[
1339     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1340     choke me
1341     #endif
1342     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1343     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1344     choke me
1345     #endif
1346     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1347      [AC_MSG_RESULT([no]); have_gmp=no])
1348   fi
1349
1350   # Now check the MPFR library.
1351   if test x"$have_gmp" = xyes; then
1352     saved_LIBS="$LIBS"
1353     LIBS="$LIBS $gmplibs"
1354     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1355     AC_TRY_LINK([#include <mpc.h>],[
1356     mpfr_t n;
1357     mpfr_t x;
1358     mpc_t c;
1359     int t;
1360     mpfr_init (n);
1361     mpfr_init (x);
1362     mpfr_atan2 (n, n, x, GMP_RNDN);
1363     mpfr_erfc (n, x, GMP_RNDN);
1364     mpfr_subnormalize (x, t, GMP_RNDN);
1365     mpfr_clear(n);
1366     mpfr_clear(x);
1367     mpc_init2 (c, 53);
1368     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1369     mpc_cosh (c, c, MPC_RNDNN);
1370     mpc_pow (c, c, c, MPC_RNDNN);
1371     mpc_acosh (c, c, MPC_RNDNN);
1372     mpc_clear (c);
1373     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1374     LIBS="$saved_LIBS"
1375   fi
1376
1377   CFLAGS="$saved_CFLAGS"
1378
1379 # The library versions listed in the error message below should match
1380 # the HARD-minimums enforced above.
1381   if test x$have_gmp != xyes; then
1382     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1383 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1384 their locations.  Source code for these libraries can be found at
1385 their respective hosting sites as well as at
1386 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1387 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1388 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1389 make sure that you have installed both the libraries and the header
1390 files.  They may be located in separate packages.])
1391   fi
1392 fi
1393
1394 # Flags needed for both GMP, MPFR and/or MPC.
1395 AC_SUBST(gmplibs)
1396 AC_SUBST(gmpinc)
1397 AC_SUBST(extra_mpfr_configure_flags)
1398 AC_SUBST(extra_mpc_gmp_configure_flags)
1399 AC_SUBST(extra_mpc_mpfr_configure_flags)
1400
1401 # Allow host libstdc++ to be specified for static linking with PPL.
1402 AC_ARG_WITH(host-libstdcxx,
1403 [AS_HELP_STRING([--with-host-libstdcxx=L],
1404                 [use linker arguments L to link with libstdc++
1405                  when linking with PPL])])
1406
1407 case $with_host_libstdcxx in
1408   no|yes)
1409     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1410     ;;
1411 esac
1412
1413 # Linker flags to use for stage1 or when not boostrapping.
1414 AC_ARG_WITH(stage1-ldflags,
1415 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1416 [if test "$withval" = "no" -o "$withval" = "yes"; then
1417    stage1_ldflags=
1418  else
1419    stage1_ldflags=$withval
1420  fi],
1421 [stage1_ldflags=])
1422 AC_SUBST(stage1_ldflags)
1423
1424 # Libraries to use for stage1 or when not bootstrapping.
1425 AC_ARG_WITH(stage1-libs,
1426 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1427 [if test "$withval" = "no" -o "$withval" = "yes"; then
1428    stage1_libs=
1429  else
1430    stage1_libs=$withval
1431  fi],
1432 [stage1_libs=$with_host_libstdcxx])
1433 AC_SUBST(stage1_libs)
1434
1435 # Libraries to use for stage2 and later builds.  This defaults to the
1436 # argument passed to --with-host-libstdcxx.
1437 AC_ARG_WITH(boot-libs,
1438 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1439 [if test "$withval" = "no" -o "$withval" = "yes"; then
1440    poststage1_libs=
1441  else
1442    poststage1_libs=$withval
1443  fi],
1444 [poststage1_libs=$with_host_libstdcxx])
1445 AC_SUBST(poststage1_libs)
1446
1447 # Linker flags to use for stage2 and later builds.
1448 AC_ARG_WITH(boot-ldflags,
1449 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1450                 [linker flags for stage2 and later])],
1451 [if test "$withval" = "no" -o "$withval" = "yes"; then
1452    poststage1_ldflags=
1453  else
1454    poststage1_ldflags=$withval
1455  fi],
1456 [poststage1_ldflags=
1457  # In stages 2 and 3, default to linking libstdc++ and libgcc
1458  # statically.  But if the user explicitly specified the libraries to
1459  # use, trust that they are doing what they want.
1460  if test "$poststage1_libs" = ""; then
1461    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1462  fi])
1463 AC_SUBST(poststage1_ldflags)
1464
1465 # Check for PPL
1466 ppllibs=
1467 pplinc=
1468 pwllib=
1469
1470 AC_ARG_WITH(ppl,
1471 [AS_HELP_STRING([--with-ppl=PATH],
1472                 [specify prefix directory for the installed PPL package.
1473                  Equivalent to --with-ppl-include=PATH/include
1474                  plus --with-ppl-lib=PATH/lib])])
1475 AC_ARG_WITH(ppl-include,
1476 [AS_HELP_STRING([--with-ppl-include=PATH],
1477                 [specify directory for installed PPL include files])])
1478 AC_ARG_WITH(ppl-lib,
1479 [AS_HELP_STRING([--with-ppl-lib=PATH],
1480                 [specify directory for the installed PPL library])])
1481
1482 AC_ARG_ENABLE(ppl-version-check,
1483 [AS_HELP_STRING([--disable-ppl-version-check],
1484                 [disable check for PPL version])])
1485
1486 case $with_ppl in
1487   yes | no | "")
1488     ;;
1489   *)
1490     ppllibs="-L$with_ppl/lib"
1491     pplinc="-I$with_ppl/include $pplinc"
1492     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1493       with_ppl=yes
1494     else
1495       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1496     fi
1497     ;;
1498 esac
1499
1500 if test x"$with_ppl_include" != x; then
1501   pplinc="-I$with_ppl_include $pplinc"
1502   with_ppl=yes
1503 fi
1504
1505 if test "x$with_ppl_lib" != x; then
1506   ppllibs="-L$with_ppl_lib"
1507   with_ppl=yes
1508 fi
1509
1510 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1511   if test x"$enable_watchdog" = xyes; then
1512     pwllib="-lpwl"
1513   fi
1514   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1515   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1516   enable_ppl_version_check=no
1517   with_ppl=yes
1518 fi
1519
1520 if test "x$with_ppl" != xno; then
1521   if test "x$pwllib" = x; then
1522     saved_LIBS="$LIBS"
1523     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1524     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1525     LIBS="$saved_LIBS"
1526   fi
1527
1528   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1529
1530   if test "$enable_ppl_version_check" != no; then
1531     saved_CFLAGS="$CFLAGS"
1532     CFLAGS="$CFLAGS $pplinc $gmpinc"
1533     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1534     AC_TRY_COMPILE([#include "ppl_c.h"],[
1535     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1536     choke me
1537     #endif
1538     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1539     CFLAGS="$saved_CFLAGS"
1540   fi
1541 fi
1542
1543 # Flags needed for PPL
1544 AC_SUBST(ppllibs)
1545 AC_SUBST(pplinc)
1546
1547
1548 # Check for CLOOG
1549
1550 dnl Provide configure switches and initialize clooginc & clooglibs
1551 dnl with user input.
1552 CLOOG_INIT_FLAGS
1553 if test "x$with_ppl" = "xno"; then
1554   dnl Only execute fail-action, if CLooG has been requested.
1555   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1556   if test "${graphite_requested}" = yes; then
1557     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1558   fi
1559   with_cloog=no
1560 fi
1561 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1562   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1563   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1564   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1565 fi
1566 if test "x$with_cloog" != "xno"; then
1567   dnl The minimal version of CLooG required for Graphite.
1568   dnl
1569   dnl If we use CLooG-Legacy, the provided version information is
1570   dnl ignored.
1571   CLOOG_CHECK_VERSION(0,16,1)
1572
1573   dnl Only execute fail-action, if CLooG has been requested.
1574   CLOOG_IF_FAILED([
1575     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1576 fi
1577
1578 # Check for LTO support.
1579 AC_ARG_ENABLE(lto,
1580 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1581 enable_lto=$enableval,
1582 enable_lto=yes; default_enable_lto=yes)
1583
1584 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1585   build_lto_plugin=yes
1586 ],[if test x"$default_enable_lto" = x"yes" ; then
1587     case $target in
1588       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1589       # On other non-ELF platforms, LTO has yet to be validated.
1590       *) enable_lto=no ;;
1591     esac
1592   else
1593   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1594   # It would also be nice to check the binutils support, but we don't
1595   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1596   # warn during gcc/ subconfigure; unless you're bootstrapping with
1597   # -flto it won't be needed until after installation anyway.
1598     case $target in
1599       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1600       *) if test x"$enable_lto" = x"yes"; then
1601         AC_MSG_ERROR([LTO support is not enabled for this target.])
1602         fi
1603       ;;
1604     esac
1605   fi
1606   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1607   # Build it unless LTO was explicitly disabled.
1608   case $target in
1609     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1610     *) ;;
1611   esac
1612 ])
1613
1614
1615 # By default, C is the only stage 1 language.
1616 stage1_languages=,c,
1617
1618 # Target libraries that we bootstrap.
1619 bootstrap_target_libs=,target-libgcc,
1620
1621 # Figure out what language subdirectories are present.
1622 # Look if the user specified --enable-languages="..."; if not, use
1623 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1624 # go away some day.
1625 # NB:  embedded tabs in this IF block -- do not untabify
1626 if test -d ${srcdir}/gcc; then
1627   if test x"${enable_languages+set}" != xset; then
1628     if test x"${LANGUAGES+set}" = xset; then
1629       enable_languages="${LANGUAGES}"
1630         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1631     else
1632       enable_languages=all
1633     fi
1634   else
1635     if test x"${enable_languages}" = x ||
1636        test x"${enable_languages}" = xyes;
1637        then
1638       echo configure.in: --enable-languages needs at least one language argument 1>&2
1639       exit 1
1640     fi
1641   fi
1642   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1643
1644   # 'f95' is the old name for the 'fortran' language. We issue a warning
1645   # and make the substitution.
1646   case ,${enable_languages}, in
1647     *,f95,*)
1648       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1649       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1650       ;;
1651   esac
1652
1653   # First scan to see if an enabled language requires some other language.
1654   # We assume that a given config-lang.in will list all the language
1655   # front ends it requires, even if some are required indirectly.
1656   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1657     case ${lang_frag} in
1658       ..) ;;
1659       # The odd quoting in the next line works around
1660       # an apparent bug in bash 1.12 on linux.
1661       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1662       *)
1663         # From the config-lang.in, get $language, $lang_requires, and
1664         # $lang_requires_boot_languages.
1665         language=
1666         lang_requires=
1667         lang_requires_boot_languages=
1668         . ${lang_frag}
1669         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1670           case ,${enable_languages}, in
1671             *,$other,*) ;;
1672             *,all,*) ;;
1673             *,$language,*)
1674               echo " \`$other' language required by \`$language'; enabling" 1>&2
1675               enable_languages="${enable_languages},${other}"
1676               ;;
1677           esac
1678         done
1679         for other in ${lang_requires_boot_languages} ; do
1680           if test "$other" != "c"; then
1681             case ,${enable_stage1_languages}, in
1682               *,$other,*) ;;
1683               *,all,*) ;;
1684               *)
1685                 case ,${enable_languages}, in
1686                   *,$language,*)
1687                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1688                     enable_stage1_languages="$enable_stage1_languages,${other}"
1689                     ;;
1690                 esac
1691                 ;;
1692             esac
1693           fi
1694         done
1695         ;;
1696     esac
1697   done
1698
1699   new_enable_languages=,c,
1700
1701   # If LTO is enabled, add the LTO front end.
1702   extra_host_libiberty_configure_flags=
1703   if test "$enable_lto" = "yes" ; then
1704     case ,${enable_languages}, in
1705       *,lto,*) ;;
1706       *) enable_languages="${enable_languages},lto" ;;
1707     esac
1708     if test "${build_lto_plugin}" = "yes" ; then
1709       configdirs="$configdirs lto-plugin"
1710       extra_host_libiberty_configure_flags=--enable-shared
1711     fi
1712   fi
1713   AC_SUBST(extra_host_libiberty_configure_flags)
1714
1715   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1716   potential_languages=,c,
1717
1718   enabled_target_libs=
1719   disabled_target_libs=
1720
1721   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1722     case ${lang_frag} in
1723       ..) ;;
1724       # The odd quoting in the next line works around
1725       # an apparent bug in bash 1.12 on linux.
1726       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1727       *)
1728         # From the config-lang.in, get $language, $target_libs,
1729         # $lang_dirs, $boot_language, and $build_by_default
1730         language=
1731         target_libs=
1732         lang_dirs=
1733         subdir_requires=
1734         boot_language=no
1735         build_by_default=yes
1736         . ${lang_frag}
1737         if test x${language} = x; then
1738           echo "${lang_frag} doesn't set \$language." 1>&2
1739           exit 1
1740         fi
1741
1742         if test "$language" = "c++" \
1743            && test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1744           boot_language=yes
1745         fi
1746
1747         case ,${enable_languages}, in
1748           *,${language},*)
1749             # Language was explicitly selected; include it.
1750             add_this_lang=yes
1751             ;;
1752           *,all,*)
1753             # 'all' was selected, select it if it is a default language
1754             add_this_lang=${build_by_default}
1755             ;;
1756           *)
1757             add_this_lang=no
1758             ;;
1759         esac
1760
1761         # Disable languages that need other directories if these aren't available.
1762         for i in $subdir_requires; do
1763           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1764           case ,${enable_languages}, in
1765             *,${language},*)
1766               # Specifically requested language; tell them.
1767               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1768               ;;
1769             *)
1770               # Silently disable.
1771               add_this_lang=unsupported
1772               ;;
1773           esac
1774         done
1775
1776         # Disable Ada if no preexisting GNAT is available.
1777         case ,${enable_languages},:${language}:${have_gnat} in
1778           *,${language},*:ada:no)
1779             # Specifically requested language; tell them.
1780             AC_MSG_ERROR([GNAT is required to build $language])
1781             ;;
1782           *:ada:no)
1783             # Silently disable.
1784             add_this_lang=unsupported
1785             ;;
1786         esac
1787
1788         # Disable a language that is unsupported by the target.
1789         case " $unsupported_languages " in
1790           *" $language "*)
1791             add_this_lang=unsupported
1792             ;;
1793         esac
1794
1795         case $add_this_lang in
1796           unsupported)
1797             # Remove language-dependent dirs.
1798             disabled_target_libs="$disabled_target_libs $target_libs"
1799             noconfigdirs="$noconfigdirs $lang_dirs"
1800             ;;
1801           no)
1802             # Remove language-dependent dirs; still show language as supported.
1803             disabled_target_libs="$disabled_target_libs $target_libs"
1804             noconfigdirs="$noconfigdirs $lang_dirs"
1805             potential_languages="${potential_languages}${language},"
1806             ;;
1807           yes)
1808             new_enable_languages="${new_enable_languages}${language},"
1809             potential_languages="${potential_languages}${language},"
1810             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1811             enabled_target_libs="$enabled_target_libs $target_libs"
1812             case "${boot_language}:,$enable_stage1_languages," in
1813               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1814                 # Add to (comma-separated) list of stage 1 languages.
1815                 case ",$stage1_languages," in
1816                   *,$language,* | ,yes, | ,all,) ;;
1817                   *) stage1_languages="${stage1_languages}${language}," ;;
1818                 esac
1819                 # We need to bootstrap any supporting libraries.
1820                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1821                 ;;
1822             esac
1823             ;;
1824         esac
1825         ;;
1826     esac
1827   done
1828
1829   # Add target libraries which are only needed for disabled languages
1830   # to noconfigdirs.
1831   if test -n "$disabled_target_libs"; then
1832     for dir in $disabled_target_libs; do
1833       case " $enabled_target_libs " in
1834       *" ${dir} "*) ;;
1835       *) noconfigdirs="$noconfigdirs $dir" ;;
1836       esac
1837     done
1838   fi
1839
1840   AC_ARG_ENABLE(stage1-languages,
1841   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1842                   [choose additional languages to build during
1843                   stage1.  Mostly useful for compiler development])],
1844   [case ,${enable_stage1_languages}, in
1845     ,no,|,,)
1846       # Set it to something that will have no effect in the loop below
1847       enable_stage1_languages=c ;;
1848     ,yes,)
1849       enable_stage1_languages=`echo $new_enable_languages | \
1850         sed -e "s/^,//" -e "s/,$//" ` ;;
1851     *,all,*)
1852       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1853         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1854   esac
1855
1856   # Add "good" languages from enable_stage1_languages to stage1_languages,
1857   # while "bad" languages go in missing_languages.  Leave no duplicates.
1858   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1859     case $potential_languages in
1860       *,$i,*)
1861         case $stage1_languages in
1862           *,$i,*) ;;
1863           *) stage1_languages="$stage1_languages$i," ;;
1864         esac ;;
1865       *)
1866         case $missing_languages in
1867           *,$i,*) ;;
1868           *) missing_languages="$missing_languages$i," ;;
1869         esac ;;
1870      esac
1871   done])
1872
1873   # Remove leading/trailing commas that were added for simplicity
1874   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1875   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1876   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1877   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1878
1879   if test "x$missing_languages" != x; then
1880     AC_MSG_ERROR([
1881 The following requested languages could not be built: ${missing_languages}
1882 Supported languages are: ${potential_languages}])
1883   fi
1884   if test "x$new_enable_languages" != "x$enable_languages"; then
1885     echo The following languages will be built: ${new_enable_languages}
1886     enable_languages="$new_enable_languages"
1887   fi
1888
1889   AC_SUBST(stage1_languages)
1890   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1891 fi
1892
1893 # Handle --disable-<component> generically.
1894 for dir in $configdirs $build_configdirs $target_configdirs ; do
1895   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1896   varname=`echo $dirname | sed -e s/+/_/g`
1897   if eval test x\${enable_${varname}} "=" xno ; then
1898     noconfigdirs="$noconfigdirs $dir"
1899   fi
1900 done
1901
1902 # Check for Boehm's garbage collector
1903 AC_ARG_ENABLE(objc-gc,
1904 [AS_HELP_STRING([--enable-objc-gc],
1905                 [enable use of Boehm's garbage collector with the
1906                  GNU Objective-C runtime])],
1907 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1908   *,objc,*:*:yes:*target-boehm-gc*)
1909     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1910     ;;
1911 esac])
1912
1913 # Make sure we only build Boehm's garbage collector if required.
1914 case ,${enable_languages},:${enable_objc_gc} in
1915   *,objc,*:yes)
1916     # Keep target-boehm-gc if requested for Objective-C.
1917     ;;
1918   *)
1919     # Otherwise remove target-boehm-gc depending on target-libjava.
1920     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1921       noconfigdirs="$noconfigdirs target-boehm-gc"
1922     fi
1923     ;;
1924 esac
1925
1926 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1927 # $build_configdirs and $target_configdirs.
1928 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1929
1930 notsupp=""
1931 for dir in . $skipdirs $noconfigdirs ; do
1932   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1933   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1934     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1935     if test -r $srcdir/$dirname/configure ; then
1936       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1937         true
1938       else
1939         notsupp="$notsupp $dir"
1940       fi
1941     fi
1942   fi
1943   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1944     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1945     if test -r $srcdir/$dirname/configure ; then
1946       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1947         true
1948       else
1949         notsupp="$notsupp $dir"
1950       fi
1951     fi
1952   fi
1953   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1954     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1955     if test -r $srcdir/$dirname/configure ; then
1956       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1957         true
1958       else
1959         notsupp="$notsupp $dir"
1960       fi
1961     fi
1962   fi
1963 done
1964
1965 # Sometimes the tools are distributed with libiberty but with no other
1966 # libraries.  In that case, we don't want to build target-libiberty.
1967 # Don't let libgcc imply libiberty either.
1968 if test -n "${target_configdirs}" ; then
1969   libgcc=
1970   others=
1971   for i in `echo ${target_configdirs} | sed -e s/target-//g` ; do
1972     if test "$i" = "libgcc"; then
1973       libgcc=target-libgcc
1974     elif test "$i" != "libiberty" ; then
1975       if test -r $srcdir/$i/configure ; then
1976         others=yes;
1977         break;
1978       fi
1979     fi
1980   done
1981   if test -z "${others}" ; then
1982     target_configdirs=$libgcc
1983   fi
1984 fi
1985
1986 # Quietly strip out all directories which aren't configurable in this tree.
1987 # This relies on all configurable subdirectories being autoconfiscated, which
1988 # is now the case.
1989 build_configdirs_all="$build_configdirs"
1990 build_configdirs=
1991 for i in ${build_configdirs_all} ; do
1992   j=`echo $i | sed -e s/build-//g`
1993   if test -f ${srcdir}/$j/configure ; then
1994     build_configdirs="${build_configdirs} $i"
1995   fi
1996 done
1997
1998 configdirs_all="$configdirs"
1999 configdirs=
2000 for i in ${configdirs_all} ; do
2001   if test -f ${srcdir}/$i/configure ; then
2002     configdirs="${configdirs} $i"
2003   fi
2004 done
2005
2006 target_configdirs_all="$target_configdirs"
2007 target_configdirs=
2008 for i in ${target_configdirs_all} ; do
2009   j=`echo $i | sed -e s/target-//g`
2010   if test -f ${srcdir}/$j/configure ; then
2011     target_configdirs="${target_configdirs} $i"
2012   fi
2013 done
2014
2015 # Produce a warning message for the subdirs we can't configure.
2016 # This isn't especially interesting in the Cygnus tree, but in the individual
2017 # FSF releases, it's important to let people know when their machine isn't
2018 # supported by the one or two programs in a package.
2019
2020 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2021   # If $appdirs is non-empty, at least one of those directories must still
2022   # be configured, or we error out.  (E.g., if the gas release supports a
2023   # specified target in some subdirs but not the gas subdir, we shouldn't
2024   # pretend that all is well.)
2025   if test -n "$appdirs" ; then
2026     for dir in $appdirs ; do
2027       if test -r $dir/Makefile.in ; then
2028         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2029           appdirs=""
2030           break
2031         fi
2032         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2033           appdirs=""
2034           break
2035         fi
2036       fi
2037     done
2038     if test -n "$appdirs" ; then
2039       echo "*** This configuration is not supported by this package." 1>&2
2040       exit 1
2041     fi
2042   fi
2043   # Okay, some application will build, or we don't care to check.  Still
2044   # notify of subdirs not getting built.
2045   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2046   echo "    ${notsupp}" 1>&2
2047   echo "    (Any other directories should still work fine.)" 1>&2
2048 fi
2049
2050 case "$host" in
2051   *msdosdjgpp*)
2052     enable_gdbtk=no ;;
2053 esac
2054
2055 # To find our prefix, in gcc_cv_tool_prefix.
2056 ACX_TOOL_DIRS
2057
2058 copy_dirs=
2059
2060 AC_ARG_WITH([build-sysroot],
2061   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2062                   [use sysroot as the system root during the build])],
2063   [if test x"$withval" != x ; then
2064      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2065    fi],
2066   [SYSROOT_CFLAGS_FOR_TARGET=])
2067 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2068
2069 AC_ARG_WITH([debug-prefix-map],
2070   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2071                   [map A to B, C to D ... in debug information])],
2072   [if test x"$withval" != x; then
2073      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2074      for debug_map in $withval; do
2075        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2076      done
2077    fi],
2078   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2079 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2080
2081 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2082 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2083 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2084 # We want to ensure that TARGET libraries (which we know are built with
2085 # gcc) are built with "-O2 -g", so include those options when setting
2086 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2087 if test "x$CFLAGS_FOR_TARGET" = x; then
2088   CFLAGS_FOR_TARGET=$CFLAGS
2089   case " $CFLAGS " in
2090     *" -O2 "*) ;;
2091     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2092   esac
2093   case " $CFLAGS " in
2094     *" -g "* | *" -g3 "*) ;;
2095     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2096   esac
2097 fi
2098 AC_SUBST(CFLAGS_FOR_TARGET)
2099
2100 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2101   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2102   case " $CXXFLAGS " in
2103     *" -O2 "*) ;;
2104     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2105   esac
2106   case " $CXXFLAGS " in
2107     *" -g "* | *" -g3 "*) ;;
2108     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2109   esac
2110 fi
2111 AC_SUBST(CXXFLAGS_FOR_TARGET)
2112
2113 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2114 # the named directory are copied to $(tooldir)/sys-include.
2115 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2116   if test x${is_cross_compiler} = xno ; then
2117     echo 1>&2 '***' --with-headers is only supported when cross compiling
2118     exit 1
2119   fi
2120   if test x"${with_headers}" != xyes ; then
2121     x=${gcc_cv_tool_prefix}
2122     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2123   fi
2124 fi
2125
2126 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2127 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2128 # are permitted.
2129 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2130   if test x${is_cross_compiler} = xno ; then
2131     echo 1>&2 '***' --with-libs is only supported when cross compiling
2132     exit 1
2133   fi
2134   if test x"${with_libs}" != xyes ; then
2135     # Copy the libraries in reverse order, so that files in the first named
2136     # library override files in subsequent libraries.
2137     x=${gcc_cv_tool_prefix}
2138     for l in ${with_libs}; do
2139       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2140     done
2141   fi
2142 fi
2143
2144 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2145 #
2146 # This is done by determining whether or not the appropriate directory
2147 # is available, and by checking whether or not specific configurations
2148 # have requested that this magic not happen.
2149 #
2150 # The command line options always override the explicit settings in
2151 # configure.in, and the settings in configure.in override this magic.
2152 #
2153 # If the default for a toolchain is to use GNU as and ld, and you don't
2154 # want to do that, then you should use the --without-gnu-as and
2155 # --without-gnu-ld options for the configure script.  Similarly, if
2156 # the default is to use the included zlib and you don't want to do that,
2157 # you should use the --with-system-zlib option for the configure script.
2158
2159 if test x${use_gnu_as} = x &&
2160    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2161   with_gnu_as=yes
2162   extra_host_args="$extra_host_args --with-gnu-as"
2163 fi
2164
2165 if test x${use_gnu_ld} = x &&
2166    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2167   with_gnu_ld=yes
2168   extra_host_args="$extra_host_args --with-gnu-ld"
2169 fi
2170
2171 if test x${use_included_zlib} = x &&
2172    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2173   :
2174 else
2175   with_system_zlib=yes
2176   extra_host_args="$extra_host_args --with-system-zlib"
2177 fi
2178
2179 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2180 # can detect this case.
2181
2182 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2183   with_newlib=yes
2184   extra_host_args="$extra_host_args --with-newlib"
2185 fi
2186
2187 # Handle ${copy_dirs}
2188 set fnord ${copy_dirs}
2189 shift
2190 while test $# != 0 ; do
2191   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2192     :
2193   else
2194     echo Copying $1 to $2
2195
2196     # Use the install script to create the directory and all required
2197     # parent directories.
2198     if test -d $2 ; then
2199       :
2200     else
2201       echo >config.temp
2202       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2203     fi
2204
2205     # Copy the directory, assuming we have tar.
2206     # FIXME: Should we use B in the second tar?  Not all systems support it.
2207     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2208
2209     # It is the responsibility of the user to correctly adjust all
2210     # symlinks.  If somebody can figure out how to handle them correctly
2211     # here, feel free to add the code.
2212
2213     echo $1 > $2/COPIED
2214   fi
2215   shift; shift
2216 done
2217
2218 # Determine a target-dependent exec_prefix that the installed
2219 # gcc will search in.  Keep this list sorted by triplet, with
2220 # the *-*-osname triplets last.
2221 md_exec_prefix=
2222 case "${target}" in
2223   i[[34567]]86-pc-msdosdjgpp*)
2224     md_exec_prefix=/dev/env/DJDIR/bin
2225     ;;
2226   *-*-hpux* | \
2227   *-*-nto-qnx* | \
2228   *-*-solaris2*)
2229     md_exec_prefix=/usr/ccs/bin
2230     ;;
2231 esac
2232
2233 extra_arflags_for_target=
2234 extra_nmflags_for_target=
2235 extra_ranlibflags_for_target=
2236 target_makefile_frag=/dev/null
2237 case "${target}" in
2238   spu-*-*)
2239     target_makefile_frag="config/mt-spu"
2240     ;;
2241   mips*-sde-elf*)
2242     target_makefile_frag="config/mt-sde"
2243     ;;
2244   mipsisa*-*-elfoabi*)
2245     target_makefile_frag="config/mt-mips-elfoabi"
2246     ;;
2247   mips*-*-*linux* | mips*-*-gnu*)
2248     target_makefile_frag="config/mt-mips-gnu"
2249     ;;
2250   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2251     target_makefile_frag="config/mt-gnu"
2252     ;;
2253   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2254     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2255     # commands to handle both 32-bit and 64-bit objects.  These flags are
2256     # harmless if we're using GNU nm or ar.
2257     extra_arflags_for_target=" -X32_64"
2258     extra_nmflags_for_target=" -B -X32_64"
2259     ;;
2260   *-*-darwin[[3-9]]*)
2261     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2262     extra_ranlibflags_for_target=" -c"
2263     ;;
2264 esac
2265
2266 alphaieee_frag=/dev/null
2267 case $target in
2268   alpha*-*-*)
2269     # This just makes sure to use the -mieee option to build target libs.
2270     # This should probably be set individually by each library.
2271     alphaieee_frag="config/mt-alphaieee"
2272     ;;
2273 esac
2274
2275 # If --enable-target-optspace always use -Os instead of -O2 to build
2276 # the target libraries, similarly if it is not specified, use -Os
2277 # on selected platforms.
2278 ospace_frag=/dev/null
2279 case "${enable_target_optspace}:${target}" in
2280   yes:*)
2281     ospace_frag="config/mt-ospace"
2282     ;;
2283   :d30v-*)
2284     ospace_frag="config/mt-d30v"
2285     ;;
2286   :m32r-* | :d10v-* | :fr30-*)
2287     ospace_frag="config/mt-ospace"
2288     ;;
2289   no:* | :*)
2290     ;;
2291   *)
2292     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2293     ;;
2294 esac
2295
2296 # Default to using --with-stabs for certain targets.
2297 if test x${with_stabs} = x ; then
2298   case "${target}" in
2299   mips*-*-irix[[56]]*)
2300     ;;
2301   mips*-*-* | alpha*-*-osf*)
2302     with_stabs=yes;
2303     extra_host_args="${extra_host_args} --with-stabs"
2304     ;;
2305   esac
2306 fi
2307
2308 # Some systems (e.g., one of the i386-aix systems the gas testers are
2309 # using) don't handle "\$" correctly, so don't use it here.
2310 tooldir='${exec_prefix}'/${target_noncanonical}
2311 build_tooldir=${tooldir}
2312
2313 # Create a .gdbinit file which runs the one in srcdir
2314 # and tells GDB to look there for source files.
2315
2316 if test -r ${srcdir}/.gdbinit ; then
2317   case ${srcdir} in
2318     .) ;;
2319     *) cat > ./.gdbinit <<EOF
2320 # ${NO_EDIT}
2321 dir ${srcdir}
2322 dir .
2323 source ${srcdir}/.gdbinit
2324 EOF
2325     ;;
2326   esac
2327 fi
2328
2329 # Make sure that the compiler is able to generate an executable.  If it
2330 # can't, we are probably in trouble.  We don't care whether we can run the
2331 # executable--we might be using a cross compiler--we only care whether it
2332 # can be created.  At this point the main configure script has set CC.
2333 we_are_ok=no
2334 echo "int main () { return 0; }" > conftest.c
2335 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2336 if test $? = 0 ; then
2337   if test -s conftest || test -s conftest.exe ; then
2338     we_are_ok=yes
2339   fi
2340 fi
2341 case $we_are_ok in
2342   no)
2343     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2344     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2345     rm -f conftest*
2346     exit 1
2347     ;;
2348 esac
2349 rm -f conftest*
2350
2351 # Decide which environment variable is used to find dynamic libraries.
2352 case "${host}" in
2353   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2354   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2355   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2356   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2357 esac
2358
2359 # On systems where the dynamic library environment variable is PATH,
2360 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2361 # built executables to PATH.
2362 if test "$RPATH_ENVVAR" = PATH; then
2363   GCC_SHLIB_SUBDIR=/shlib
2364 else
2365   GCC_SHLIB_SUBDIR=
2366 fi
2367
2368 # Record target_configdirs and the configure arguments for target and
2369 # build configuration in Makefile.
2370 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2371 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2372
2373 # If we are building libgomp, bootstrap it.
2374 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2375   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2376 fi
2377
2378 # Determine whether gdb needs tk/tcl or not.
2379 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2380 # and in that case we want gdb to be built without tk.  Ugh!
2381 # In fact I believe gdb is the *only* package directly dependent on tk,
2382 # so we should be able to put the 'maybe's in unconditionally and
2383 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2384 # 100% sure that that's safe though.
2385
2386 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2387 case "$enable_gdbtk" in
2388   no)
2389     GDB_TK="" ;;
2390   yes)
2391     GDB_TK="${gdb_tk}" ;;
2392   *)
2393     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2394     # distro.  Eventually someone will fix this and move Insight, nee
2395     # gdbtk to a separate directory.
2396     if test -d ${srcdir}/gdb/gdbtk ; then
2397       GDB_TK="${gdb_tk}"
2398     else
2399       GDB_TK=""
2400     fi
2401     ;;
2402 esac
2403 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2404 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2405
2406 # Strip out unwanted targets.
2407
2408 # While at that, we remove Makefiles if we were started for recursive
2409 # configuration, so that the top-level Makefile reconfigures them,
2410 # like we used to do when configure itself was recursive.
2411
2412 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2413 # but now we're fixing up the Makefile ourselves with the additional
2414 # commands passed to AC_CONFIG_FILES.  Use separate variables
2415 # extrasub-{build,host,target} not because there is any reason to split
2416 # the substitutions up that way, but only to remain below the limit of
2417 # 99 commands in a script, for HP-UX sed.
2418 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2419
2420 AC_ARG_ENABLE([bootstrap],
2421 [AS_HELP_STRING([--enable-bootstrap],
2422                 [enable bootstrapping @<:@yes if native build@:>@])],,
2423 enable_bootstrap=default)
2424
2425 # Issue errors and warnings for invalid/strange bootstrap combinations.
2426 case "$configdirs" in
2427   *gcc*) have_compiler=yes ;;
2428   *) have_compiler=no ;;
2429 esac
2430
2431 case "$have_compiler:$host:$target:$enable_bootstrap" in
2432   *:*:*:no) ;;
2433
2434   # Default behavior.  Enable bootstrap if we have a compiler
2435   # and we are in a native configuration.
2436   yes:$build:$build:default)
2437     enable_bootstrap=yes ;;
2438
2439   *:*:*:default)
2440     enable_bootstrap=no ;;
2441
2442   # We have a compiler and we are in a native configuration, bootstrap is ok
2443   yes:$build:$build:yes)
2444     ;;
2445
2446   # Other configurations, but we have a compiler.  Assume the user knows
2447   # what he's doing.
2448   yes:*:*:yes)
2449     AC_MSG_WARN([trying to bootstrap a cross compiler])
2450     ;;
2451
2452   # No compiler: if they passed --enable-bootstrap explicitly, fail
2453   no:*:*:yes)
2454     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2455
2456   # Fail if wrong command line
2457   *)
2458     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2459     ;;
2460 esac
2461
2462 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2463   *,c++,*:yes:yes) ;;
2464   *:yes:yes)
2465     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2466     ;;
2467 esac
2468
2469 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2470   yes:yes:*\ gold\ *:*,c++,*) ;;
2471   yes:yes:*\ gold\ *:*)
2472     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2473     ;;
2474 esac
2475
2476 # Adjust the toplevel makefile according to whether bootstrap was selected.
2477 case $enable_bootstrap in
2478   yes)
2479     bootstrap_suffix=bootstrap
2480     BUILD_CONFIG=bootstrap-debug
2481     ;;
2482   no)
2483     bootstrap_suffix=no-bootstrap
2484     BUILD_CONFIG=
2485     ;;
2486 esac
2487
2488 AC_MSG_CHECKING(for default BUILD_CONFIG)
2489
2490 AC_ARG_WITH([build-config],
2491   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2492                   [use config/NAME.mk build configuration])],
2493   [case $with_build_config in
2494    yes) with_build_config= ;;
2495    no) with_build_config= BUILD_CONFIG= ;;
2496    esac])
2497
2498 if test "x${with_build_config}" != x; then
2499   BUILD_CONFIG=$with_build_config
2500 else
2501   case $BUILD_CONFIG in
2502   bootstrap-debug)
2503     if echo "int f (void) { return 0; }" > conftest.c &&
2504        ${CC} -c conftest.c &&
2505        mv conftest.o conftest.o.g0 &&
2506        ${CC} -c -g conftest.c &&
2507        mv conftest.o conftest.o.g &&
2508        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2509       :
2510     else
2511       BUILD_CONFIG=
2512     fi
2513     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2514     ;;
2515   esac
2516 fi
2517 AC_MSG_RESULT($BUILD_CONFIG)
2518 AC_SUBST(BUILD_CONFIG)
2519
2520 extrasub_build=
2521 for module in ${build_configdirs} ; do
2522   if test -z "${no_recursion}" \
2523      && test -f ${build_subdir}/${module}/Makefile; then
2524     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2525     rm -f ${build_subdir}/${module}/Makefile
2526   fi
2527   extrasub_build="$extrasub_build
2528 /^@if build-$module\$/d
2529 /^@endif build-$module\$/d
2530 /^@if build-$module-$bootstrap_suffix\$/d
2531 /^@endif build-$module-$bootstrap_suffix\$/d"
2532 done
2533 extrasub_host=
2534 for module in ${configdirs} ; do
2535   if test -z "${no_recursion}"; then
2536     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2537       if test -f ${file}; then
2538         echo 1>&2 "*** removing ${file} to force reconfigure"
2539         rm -f ${file}
2540       fi
2541     done
2542   fi
2543   extrasub_host="$extrasub_host
2544 /^@if $module\$/d
2545 /^@endif $module\$/d
2546 /^@if $module-$bootstrap_suffix\$/d
2547 /^@endif $module-$bootstrap_suffix\$/d"
2548 done
2549 extrasub_target=
2550 for module in ${target_configdirs} ; do
2551   if test -z "${no_recursion}" \
2552      && test -f ${target_subdir}/${module}/Makefile; then
2553     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2554     rm -f ${target_subdir}/${module}/Makefile
2555   fi
2556
2557   # We only bootstrap target libraries listed in bootstrap_target_libs.
2558   case $bootstrap_target_libs in
2559     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2560     *) target_bootstrap_suffix=no-bootstrap ;;
2561   esac
2562
2563   extrasub_target="$extrasub_target
2564 /^@if target-$module\$/d
2565 /^@endif target-$module\$/d
2566 /^@if target-$module-$target_bootstrap_suffix\$/d
2567 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2568 done
2569
2570 # Do the final fixup along with target modules.
2571 extrasub_target="$extrasub_target
2572 /^@if /,/^@endif /d"
2573
2574 # Create the serialization dependencies.  This uses a temporary file.
2575
2576 AC_ARG_ENABLE([serial-configure],
2577 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2578                 [force sequential configuration of
2579                  sub-packages for the host, target or build
2580                  machine, or all sub-packages])])
2581
2582 case ${enable_serial_configure} in
2583   yes)
2584     enable_serial_build_configure=yes
2585     enable_serial_host_configure=yes
2586     enable_serial_target_configure=yes
2587     ;;
2588 esac
2589
2590 # These force 'configure's to be done one at a time, to avoid problems
2591 # with contention over a shared config.cache.
2592 rm -f serdep.tmp
2593 echo '# serdep.tmp' > serdep.tmp
2594 olditem=
2595 test "x${enable_serial_build_configure}" = xyes &&
2596 for item in ${build_configdirs} ; do
2597   case ${olditem} in
2598     "") ;;
2599     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2600   esac
2601   olditem=${item}
2602 done
2603 olditem=
2604 test "x${enable_serial_host_configure}" = xyes &&
2605 for item in ${configdirs} ; do
2606   case ${olditem} in
2607     "") ;;
2608     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2609   esac
2610   olditem=${item}
2611 done
2612 olditem=
2613 test "x${enable_serial_target_configure}" = xyes &&
2614 for item in ${target_configdirs} ; do
2615   case ${olditem} in
2616     "") ;;
2617     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2618   esac
2619   olditem=${item}
2620 done
2621 serialization_dependencies=serdep.tmp
2622 AC_SUBST_FILE(serialization_dependencies)
2623
2624 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2625 # target, nonopt, and variable assignments.  These are the ones we
2626 # might not want to pass down to subconfigures.  The exception being
2627 # --cache-file=/dev/null, which is used to turn off the use of cache
2628 # files altogether, and which should be passed on to subconfigures.
2629 # Also strip program-prefix, program-suffix, and program-transform-name,
2630 # so that we can pass down a consistent program-transform-name.
2631 baseargs=
2632 tbaseargs=
2633 keep_next=no
2634 skip_next=no
2635 eval "set -- $ac_configure_args"
2636 for ac_arg
2637 do
2638   if test X"$skip_next" = X"yes"; then
2639     skip_next=no
2640     continue
2641   fi
2642   if test X"$keep_next" = X"yes"; then
2643     case $ac_arg in
2644       *\'*)
2645         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2646     esac
2647     baseargs="$baseargs '$ac_arg'"
2648     tbaseargs="$tbaseargs '$ac_arg'"
2649     keep_next=no
2650     continue
2651   fi
2652
2653   # Handle separated arguments.  Based on the logic generated by
2654   # autoconf 2.59.
2655   case $ac_arg in
2656     *=* | --config-cache | -C | -disable-* | --disable-* \
2657       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2658       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2659       | -with-* | --with-* | -without-* | --without-* | --x)
2660       separate_arg=no
2661       ;;
2662     -*)
2663       separate_arg=yes
2664       ;;
2665     *)
2666       separate_arg=no
2667       ;;
2668   esac
2669
2670   skip_targ=no
2671   case $ac_arg in
2672 changequote(,)
2673   --with-* | --without-*)
2674     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2675
2676     case $libopt in
2677     *[-_]include)
2678       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2679       ;;
2680     *[-_]lib)
2681       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2682       ;;
2683     *)
2684       lib=$libopt
2685       ;;
2686     esac
2687 changequote([,])
2688
2689     case $lib in
2690     mpc | mpfr | gmp | ppl | cloog)
2691       # If we're processing --with-$lib, --with-$lib-include or
2692       # --with-$lib-lib, for one of the libs above, and target is
2693       # different from host, don't pass the current argument to any
2694       # target library's configure.
2695       if test x$is_cross_compiler = xyes; then
2696         skip_targ=yes
2697       fi
2698       ;;
2699     esac
2700     ;;
2701   esac
2702
2703   case "$ac_arg" in
2704     --cache-file=/dev/null | \
2705     -cache-file=/dev/null )
2706       # Handled here to avoid the test to skip args below.
2707       baseargs="$baseargs '$ac_arg'"
2708       tbaseargs="$tbaseargs '$ac_arg'"
2709       # Assert: $separate_arg should always be no.
2710       keep_next=$separate_arg
2711       ;;
2712     --no*)
2713       continue
2714       ;;
2715     --c* | \
2716     --sr* | \
2717     --ho* | \
2718     --bu* | \
2719     --t* | \
2720     --program-* | \
2721     -cache_file* | \
2722     -srcdir* | \
2723     -host* | \
2724     -build* | \
2725     -target* | \
2726     -program-prefix* | \
2727     -program-suffix* | \
2728     -program-transform-name* )
2729       skip_next=$separate_arg
2730       continue
2731       ;;
2732     -*)
2733       # An option.  Add it.
2734       case $ac_arg in
2735         *\'*)
2736           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2737       esac
2738       baseargs="$baseargs '$ac_arg'"
2739       if test X"$skip_targ" = Xno; then
2740         tbaseargs="$tbaseargs '$ac_arg'"
2741       fi
2742       keep_next=$separate_arg
2743       ;;
2744     *)
2745       # Either a variable assignment, or a nonopt (triplet).  Don't
2746       # pass it down; let the Makefile handle this.
2747       continue
2748       ;;
2749   esac
2750 done
2751 # Remove the initial space we just introduced and, as these will be
2752 # expanded by make, quote '$'.
2753 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2754
2755 # Add in --program-transform-name, after --program-prefix and
2756 # --program-suffix have been applied to it.  Autoconf has already
2757 # doubled dollar signs and backslashes in program_transform_name; we want
2758 # the backslashes un-doubled, and then the entire thing wrapped in single
2759 # quotes, because this will be expanded first by make and then by the shell.
2760 # Also, because we want to override the logic in subdir configure scripts to
2761 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2762 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2763 ${program_transform_name}
2764 EOF_SED
2765 gcc_transform_name=`cat conftestsed.out`
2766 rm -f conftestsed.out
2767 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2768 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2769 if test "$silent" = yes; then
2770   baseargs="$baseargs --silent"
2771   tbaseargs="$tbaseargs --silent"
2772 fi
2773 baseargs="$baseargs --disable-option-checking"
2774 tbaseargs="$tbaseargs --disable-option-checking"
2775
2776 # Record and document user additions to sub configure arguments.
2777 AC_ARG_VAR([build_configargs],
2778            [additional configure arguments for build directories])
2779 AC_ARG_VAR([host_configargs],
2780            [additional configure arguments for host directories])
2781 AC_ARG_VAR([target_configargs],
2782            [additional configure arguments for target directories])
2783
2784 # For the build-side libraries, we just need to pretend we're native,
2785 # and not use the same cache file.  Multilibs are neither needed nor
2786 # desired.
2787 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2788
2789 # For host modules, accept cache file option, or specification as blank.
2790 case "${cache_file}" in
2791 "") # empty
2792   cache_file_option="" ;;
2793 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2794   cache_file_option="--cache-file=${cache_file}" ;;
2795 *) # relative path
2796   cache_file_option="--cache-file=../${cache_file}" ;;
2797 esac
2798
2799 # Host dirs don't like to share a cache file either, horribly enough.
2800 # This seems to be due to autoconf 2.5x stupidity.
2801 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2802
2803 target_configargs="$target_configargs ${tbaseargs}"
2804
2805 # Passing a --with-cross-host argument lets the target libraries know
2806 # whether they are being built with a cross-compiler or being built
2807 # native.  However, it would be better to use other mechanisms to make the
2808 # sorts of decisions they want to make on this basis.  Please consider
2809 # this option to be deprecated.  FIXME.
2810 if test x${is_cross_compiler} = xyes ; then
2811   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2812 fi
2813
2814 # Default to --enable-multilib.
2815 if test x${enable_multilib} = x ; then
2816   target_configargs="--enable-multilib ${target_configargs}"
2817 fi
2818
2819 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2820 # changed from the earlier setting of with_newlib.
2821 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2822   target_configargs="--with-newlib ${target_configargs}"
2823 fi
2824
2825 # Different target subdirs use different values of certain variables
2826 # (notably CXX).  Worse, multilibs use *lots* of different values.
2827 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2828 # it doesn't automatically accept command-line overrides of them.
2829 # This means it's not safe for target subdirs to share a cache file,
2830 # which is disgusting, but there you have it.  Hopefully this can be
2831 # fixed in future.  It's still worthwhile to use a cache file for each
2832 # directory.  I think.
2833
2834 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2835 # We need to pass --target, as newer autoconf's requires consistency
2836 # for target_alias and gcc doesn't manage it consistently.
2837 target_configargs="--cache-file=./config.cache ${target_configargs}"
2838
2839 FLAGS_FOR_TARGET=
2840 case " $target_configdirs " in
2841  *" newlib "*)
2842   case " $target_configargs " in
2843   *" --with-newlib "*)
2844    case "$target" in
2845     *-cygwin*)
2846       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2847       ;;
2848    esac
2849
2850    # If we're not building GCC, don't discard standard headers.
2851    if test -d ${srcdir}/gcc; then
2852      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2853
2854      if test "${build}" != "${host}"; then
2855        # On Canadian crosses, CC_FOR_TARGET will have already been set
2856        # by `configure', so we won't have an opportunity to add -Bgcc/
2857        # to it.  This is right: we don't want to search that directory
2858        # for binaries, but we want the header files in there, so add
2859        # them explicitly.
2860        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2861
2862        # Someone might think of using the pre-installed headers on
2863        # Canadian crosses, in case the installed compiler is not fully
2864        # compatible with the compiler being built.  In this case, it
2865        # would be better to flag an error than risking having
2866        # incompatible object files being constructed.  We can't
2867        # guarantee that an error will be flagged, but let's hope the
2868        # compiler will do it, when presented with incompatible header
2869        # files.
2870      fi
2871    fi
2872
2873    case "${target}-${is_cross_compiler}" in
2874    i[[3456789]]86-*-linux*-no)
2875       # Here host == target, so we don't need to build gcc,
2876       # so we don't want to discard standard headers.
2877       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2878       ;;
2879    *)
2880       # If we're building newlib, use its generic headers last, but search
2881       # for any libc-related directories first (so make it the last -B
2882       # switch).
2883       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2884
2885       # If we're building libgloss, find the startup file, simulator library
2886       # and linker script.
2887       case " $target_configdirs " in
2888         *" libgloss "*)
2889         # Look for startup file, simulator library and maybe linker script.
2890         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2891         # Look for libnosys.a in case the target needs it.
2892         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2893         # Most targets have the linker script in the source directory.
2894         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2895         ;;
2896       esac
2897       ;;
2898    esac
2899    ;;
2900   esac
2901   ;;
2902 esac
2903
2904 case "$target" in
2905   x86_64-*mingw* | *-w64-mingw*)
2906   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2907   # however, use a symlink named 'mingw' in ${prefix} .
2908     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2909     ;;
2910   *-mingw*)
2911   # MinGW can't be handled as Cygwin above since it does not use newlib.
2912     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2913     ;;
2914 esac
2915
2916 # Allow the user to override the flags for
2917 # our build compiler if desired.
2918 if test x"${build}" = x"${host}" ; then
2919   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2920   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2921   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2922 fi
2923
2924 # On Canadian crosses, we'll be searching the right directories for
2925 # the previously-installed cross compiler, so don't bother to add
2926 # flags for directories within the install tree of the compiler
2927 # being built; programs in there won't even run.
2928 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2929   # Search for pre-installed headers if nothing else fits.
2930   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2931 fi
2932
2933 if test "x${use_gnu_ld}" = x &&
2934    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2935   # Arrange for us to find uninstalled linker scripts.
2936   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2937 fi
2938
2939 # Search for other target-specific linker scripts and such.
2940 case "${target}" in
2941   mep*)
2942     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2943     ;;
2944 esac
2945
2946 # Makefile fragments.
2947 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2948 do
2949   eval fragval=\$$frag
2950   if test $fragval != /dev/null; then
2951     eval $frag=${srcdir}/$fragval
2952   fi
2953 done
2954 AC_SUBST_FILE(host_makefile_frag)
2955 AC_SUBST_FILE(target_makefile_frag)
2956 AC_SUBST_FILE(alphaieee_frag)
2957 AC_SUBST_FILE(ospace_frag)
2958
2959 # Miscellanea: directories, flags, etc.
2960 AC_SUBST(RPATH_ENVVAR)
2961 AC_SUBST(GCC_SHLIB_SUBDIR)
2962 AC_SUBST(tooldir)
2963 AC_SUBST(build_tooldir)
2964 AC_SUBST(CONFIGURE_GDB_TK)
2965 AC_SUBST(GDB_TK)
2966 AC_SUBST(INSTALL_GDB_TK)
2967
2968 # Build module lists & subconfigure args.
2969 AC_SUBST(build_configargs)
2970 AC_SUBST(build_configdirs)
2971
2972 # Host module lists & subconfigure args.
2973 AC_SUBST(host_configargs)
2974 AC_SUBST(configdirs)
2975 AC_SUBST(target_configdirs)
2976
2977 # Target module lists & subconfigure args.
2978 AC_SUBST(target_configargs)
2979
2980
2981 # Build tools.
2982 AC_SUBST(AR_FOR_BUILD)
2983 AC_SUBST(AS_FOR_BUILD)
2984 AC_SUBST(CC_FOR_BUILD)
2985 AC_SUBST(CFLAGS_FOR_BUILD)
2986 AC_SUBST(CXXFLAGS_FOR_BUILD)
2987 AC_SUBST(CXX_FOR_BUILD)
2988 AC_SUBST(DLLTOOL_FOR_BUILD)
2989 AC_SUBST(GCJ_FOR_BUILD)
2990 AC_SUBST(GFORTRAN_FOR_BUILD)
2991 AC_SUBST(GOC_FOR_BUILD)
2992 AC_SUBST(LDFLAGS_FOR_BUILD)
2993 AC_SUBST(LD_FOR_BUILD)
2994 AC_SUBST(NM_FOR_BUILD)
2995 AC_SUBST(RANLIB_FOR_BUILD)
2996 AC_SUBST(WINDMC_FOR_BUILD)
2997 AC_SUBST(WINDRES_FOR_BUILD)
2998
2999 # Generate default definitions for YACC, M4, LEX and other programs that run
3000 # on the build machine.  These are used if the Makefile can't locate these
3001 # programs in objdir.
3002 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3003
3004 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3005 case " $build_configdirs " in
3006   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3007 esac
3008
3009 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3010 case " $build_configdirs " in
3011   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3012 esac
3013
3014 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3015 case " $build_configdirs " in
3016   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3017 esac
3018
3019 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3020 case " $build_configdirs " in
3021   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3022   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3023 esac
3024
3025 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3026 case " $build_configdirs " in
3027   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3028 esac
3029
3030 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3031 case " $build_configdirs " in
3032   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3033   *)
3034 changequote(,)
3035     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3036     # higher, else we use the "missing" dummy.
3037     if ${MAKEINFO} --version \
3038        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3039       :
3040     else
3041       MAKEINFO="$MISSING makeinfo"
3042     fi
3043     ;;
3044 changequote([,])
3045 esac
3046
3047 # FIXME: expect and dejagnu may become build tools?
3048
3049 AC_CHECK_PROGS(EXPECT, expect, expect)
3050 case " $configdirs " in
3051   *" expect "*)
3052     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3053     ;;
3054 esac
3055
3056 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3057 case " $configdirs " in
3058   *" dejagnu "*)
3059     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3060     ;;
3061 esac
3062
3063
3064 # Host tools.
3065 NCN_STRICT_CHECK_TOOLS(AR, ar)
3066 NCN_STRICT_CHECK_TOOLS(AS, as)
3067 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3068 NCN_STRICT_CHECK_TOOLS(LD, ld)
3069 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3070 NCN_STRICT_CHECK_TOOLS(NM, nm)
3071 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3072 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3073 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3074 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3075 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3076 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3077 AC_SUBST(CC)
3078 AC_SUBST(CXX)
3079 AC_SUBST(CFLAGS)
3080 AC_SUBST(CXXFLAGS)
3081
3082 # Target tools.
3083 AC_ARG_WITH([build-time-tools],
3084   [AS_HELP_STRING([--with-build-time-tools=PATH],
3085                   [use given path to find target tools during the build])],
3086   [case x"$withval" in
3087      x/*) ;;
3088      *)
3089        with_build_time_tools=
3090        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3091        ;;
3092    esac],
3093   [with_build_time_tools=])
3094
3095 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3096 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3097 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3098 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3099 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3100 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3101
3102 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3103 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3104 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3105 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3106 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3107 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3108 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3109 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3110 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3111 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3112 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3113
3114 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3115
3116 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3117 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3118 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3119 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3120 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3121                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3122                 c++)
3123 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3124                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3125                 c++)
3126 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3127 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3128 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3129                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3130 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3131                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3132 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3133                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3134 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3135 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3136 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3137 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3138 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3139 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3140 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3141 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3142
3143 AC_SUBST(FLAGS_FOR_TARGET)
3144 AC_SUBST(RAW_CXX_FOR_TARGET)
3145
3146 # Certain tools may need extra flags.
3147 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3148 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3149 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3150
3151 # When building target libraries, except in a Canadian cross, we use
3152 # the same toolchain as the compiler we just built.
3153 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3154 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3155 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3156 if test $host = $build; then
3157   case " $configdirs " in
3158     *" gcc "*)
3159       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3160       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3161       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3162       ;;
3163   esac
3164 fi
3165
3166 AC_SUBST(COMPILER_AS_FOR_TARGET)
3167 AC_SUBST(COMPILER_LD_FOR_TARGET)
3168 AC_SUBST(COMPILER_NM_FOR_TARGET)
3169
3170 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3171 AC_ARG_ENABLE(maintainer-mode,
3172 [AS_HELP_STRING([--enable-maintainer-mode],
3173                 [enable make rules and dependencies not useful
3174                  (and sometimes confusing) to the casual installer])],
3175       USE_MAINTAINER_MODE=$enableval,
3176       USE_MAINTAINER_MODE=no)
3177 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3178 AC_SUBST(MAINTAINER_MODE_TRUE)
3179 AC_SUBST(MAINTAINER_MODE_FALSE)
3180 if test "$USE_MAINTAINER_MODE" = yes; then
3181   MAINTAINER_MODE_TRUE=
3182   MAINTAINER_MODE_FALSE='#'
3183 else
3184   MAINTAINER_MODE_TRUE='#'
3185   MAINTAINER_MODE_FALSE=
3186 fi
3187 MAINT=$MAINTAINER_MODE_TRUE
3188 AC_SUBST(MAINT)dnl
3189
3190 # ---------------------
3191 # GCC bootstrap support
3192 # ---------------------
3193
3194 # Stage specific cflags for build.
3195 stage1_cflags="-g"
3196 case $build in
3197   vax-*-*)
3198     case ${GCC} in
3199       yes) stage1_cflags="-g -Wa,-J" ;;
3200       *) stage1_cflags="-g -J" ;;
3201     esac ;;
3202 esac
3203
3204 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3205 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3206   saved_CFLAGS="$CFLAGS"
3207
3208   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3209   CFLAGS="$CFLAGS -fkeep-inline-functions"
3210   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3211   AC_TRY_COMPILE([
3212 #if (__GNUC__ < 3) \
3213     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3214                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3215 #error http://gcc.gnu.org/PR29382
3216 #endif
3217     ],,
3218     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3219     [AC_MSG_RESULT([no])])
3220
3221   CFLAGS="$saved_CFLAGS"
3222 fi
3223
3224 AC_SUBST(stage1_cflags)
3225
3226 # Enable --enable-checking in stage1 of the compiler.
3227 AC_ARG_ENABLE(stage1-checking,
3228 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3229                 [choose additional checking for stage1 of the compiler])],
3230 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3231 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3232   stage1_checking=--enable-checking=yes,types
3233 else
3234   stage1_checking=--enable-checking=$enable_checking,types
3235 fi])
3236 AC_SUBST(stage1_checking)
3237
3238 # Enable -Werror in bootstrap stage2 and later.
3239 AC_ARG_ENABLE(werror,
3240 [AS_HELP_STRING([--enable-werror],
3241                 [enable -Werror in bootstrap stage2 and later])], [],
3242 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3243   enable_werror=yes
3244 else
3245   enable_werror=no
3246 fi])
3247 case ${enable_werror} in
3248   yes) stage2_werror_flag="--enable-werror-always" ;;
3249   *) stage2_werror_flag="" ;;
3250 esac
3251 AC_SUBST(stage2_werror_flag)
3252
3253 # Specify what files to not compare during bootstrap.
3254
3255 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3256 case "$target" in
3257   hppa*64*-*-hpux*) ;;
3258   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3259 esac
3260 case " $configdirs " in
3261 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3262 esac
3263 AC_SUBST(compare_exclusions)
3264
3265 AC_CONFIG_FILES([Makefile],
3266   [sed "$extrasub_build" Makefile |
3267    sed "$extrasub_host" |
3268    sed "$extrasub_target" > mf$$
3269    mv -f mf$$ Makefile],
3270   [extrasub_build="$extrasub_build"
3271    extrasub_host="$extrasub_host"
3272    extrasub_target="$extrasub_target"])
3273 AC_OUTPUT