configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_DISABLE_OPTION_CHECKING
  35
  36 progname=$0
  37 # if PWD already has a value, it is probably wrong.
  38 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  39
  40 # Export original configure arguments for use by sub-configures.
  41 # Quote arguments with shell meta charatcers.
  42 TOPLEVEL_CONFIGURE_ARGUMENTS=
  43 set -- "$progname" "$@"
  44 for ac_arg
  45 do
  46   case "$ac_arg" in
  47   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  48     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  49     # if the argument is of the form -foo=baz, quote the baz part only
  50     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  51   *) ;;
  52   esac
  53   # Add the quoted argument to the list.
  54   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  55 done
  56 if test "$silent" = yes; then
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  58 fi
  59 # Remove the initial space we just introduced and, as these will be
  60 # expanded by make, quote '$'.
  61 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  62 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  63
  64 # Find the build, host, and target systems.
  65 ACX_NONCANONICAL_BUILD
  66 ACX_NONCANONICAL_HOST
  67 ACX_NONCANONICAL_TARGET
  68
  69 dnl Autoconf 2.5x and later will set a default program prefix if
  70 dnl --target was used, even if it was the same as --host.  Disable
  71 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  72 dnl to take effect.
  73 test "$host_noncanonical" = "$target_noncanonical" &&
  74   test "$program_prefix$program_suffix$program_transform_name" = \
  75     NONENONEs,x,x, &&
  76   program_transform_name=s,y,y,
  77
  78 AC_CANONICAL_SYSTEM
  79 AC_ARG_PROGRAM
  80
  81 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  82 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  83
  84 # Get 'install' or 'install-sh' and its variants.
  85 AC_PROG_INSTALL
  86 ACX_PROG_LN
  87 AC_PROG_LN_S
  88 AC_PROG_SED
  89 AC_PROG_AWK
  90
  91 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  92
  93 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  94 # a relative path.
  95 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  96   INSTALL="${srcpwd}/install-sh -c"
  97 fi
  98
  99 # Set srcdir to "." if that's what it is.
 100 # This is important for multilib support.
 101 pwd=`${PWDCMD-pwd}`
 102 if test "${pwd}" = "${srcpwd}" ; then
 103   srcdir=.
 104 fi
 105
 106 topsrcdir=$srcpwd
 107
 108 extra_host_args=
 109
 110 ### To add a new directory to the tree, first choose whether it is a target
 111 ### or a host dependent tool.  Then put it into the appropriate list
 112 ### (library or tools, host or target), doing a dependency sort.
 113
 114 # Subdirs will be configured in the order listed in build_configdirs,
 115 # configdirs, or target_configdirs; see the serialization section below.
 116
 117 # Dependency sorting is only needed when *configuration* must be done in
 118 # a particular order.  In all cases a dependency should be specified in
 119 # the Makefile, whether or not it's implicitly specified here.
 120
 121 # Double entries in build_configdirs, configdirs, or target_configdirs may
 122 # cause circular dependencies and break everything horribly.
 123
 124 # these library is used by various programs built for the build
 125 # environment
 126 #
 127 build_libs="build-libiberty build-libcpp"
 128
 129 # these tools are built for the build environment
 130 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 131
 132 # these libraries are used by various programs built for the host environment
 133 #f
 134 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 135
 136 # these tools are built for the host environment
 137 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 138 # know that we are building the simulator.
 139 # binutils, gas and ld appear in that order because it makes sense to run
 140 # "make check" in that particular order.
 141 # If --enable-gold is used, "gold" may replace "ld".
 142 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 143
 144 # these libraries are built for the target environment, and are built after
 145 # the host libraries and the host tools (which may be a cross compiler)
 146 # Note that libiberty is not a target library.
 147 target_libraries="target-libgcc \
 148                 target-libbacktrace \
 149                 target-libgloss \
 150                 target-newlib \
 151                 target-libgomp \
 152                 target-liboffloadmic \
 153                 target-libhsail-rt \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 251 # is provided.
 252 if test x$with_system_readline = xyes ; then
 253   noconfigdirs="$noconfigdirs readline"
 254 fi
 255
 256 # some tools are so dependent upon X11 that if we're not building with X,
 257 # it's not even worth trying to configure, much less build, that tool.
 258
 259 case ${with_x} in
 260   yes | "") ;; # the default value for this tree is that X11 is available
 261   no)
 262     skipdirs="${skipdirs} tk itcl libgui"
 263     # We won't be able to build gdbtk without X.
 264     enable_gdbtk=no
 265     ;;
 266   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 267 esac
 268
 269 # Some are only suitable for cross toolchains.
 270 # Remove these if host=target.
 271 cross_only="target-libgloss target-newlib target-opcodes"
 272
 273 case $is_cross_compiler in
 274   no) skipdirs="${skipdirs} ${cross_only}" ;;
 275 esac
 276
 277 # If both --with-headers and --with-libs are specified, default to
 278 # --without-newlib.
 279 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 280    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 281   if test x"${with_newlib}" = x ; then
 282     with_newlib=no
 283   fi
 284 fi
 285
 286 # Recognize --with-newlib/--without-newlib.
 287 case ${with_newlib} in
 288   no) skipdirs="${skipdirs} target-newlib" ;;
 289   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 290 esac
 291
 292 AC_ARG_ENABLE(as-accelerator-for,
 293 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 294                 [build as offload target compiler.
 295                 Specify offload host triple by ARG])])
 296
 297 AC_ARG_ENABLE(offload-targets,
 298 [AS_HELP_STRING([--enable-offload-targets=LIST],
 299                 [enable offloading to devices from comma-separated LIST of
 300                 TARGET[=DIR]. Use optional path to find offload target compiler
 301                 during the build])],
 302 [
 303   if test x"$enable_offload_targets" = x; then
 304     AC_MSG_ERROR([no offload targets specified])
 305   fi
 306 ], [enable_offload_targets=])
 307
 308 # Handle --enable-gold, --enable-ld.
 309 # --disable-gold [--enable-ld]
 310 #     Build only ld.  Default option.
 311 # --enable-gold [--enable-ld]
 312 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 313 #     as "ld.bfd" and "ld".
 314 # --enable-gold=default [--enable-ld]
 315 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 316 #     install ld as "ld.bfd".
 317 # --enable-gold[=default] --disable-ld
 318 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 319 # --enable-gold --enable-ld=default
 320 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 321 #     and ld.bfd).
 322 #     In other words, ld is default
 323 # --enable-gold=default --enable-ld=default
 324 #     Error.
 325
 326 default_ld=
 327 AC_ARG_ENABLE(gold,
 328 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 329                 [build gold @<:@ARG={default,yes,no}@:>@])],
 330 ENABLE_GOLD=$enableval,
 331 ENABLE_GOLD=no)
 332 case "${ENABLE_GOLD}" in
 333   yes|default)
 334     # Check for ELF target.
 335     is_elf=no
 336     case "${target}" in
 337       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 338       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 339       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 340       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 341         case "${target}" in
 342           *-*-linux*aout* | *-*-linux*oldld*)
 343             ;;
 344           *)
 345             is_elf=yes
 346             ;;
 347         esac
 348     esac
 349
 350     if test "$is_elf" = "yes"; then
 351       # Check for target supported by gold.
 352       case "${target}" in
 353         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 354         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 355           configdirs="$configdirs gold"
 356           if test x${ENABLE_GOLD} = xdefault; then
 357             default_ld=gold
 358           fi
 359           ENABLE_GOLD=yes
 360           ;;
 361       esac
 362     fi
 363     ;;
 364   no)
 365     ;;
 366   *)
 367     AC_MSG_ERROR([invalid --enable-gold argument])
 368     ;;
 369 esac
 370
 371 AC_ARG_ENABLE(ld,
 372 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 373                 [build ld @<:@ARG={default,yes,no}@:>@])],
 374 ENABLE_LD=$enableval,
 375 ENABLE_LD=yes)
 376
 377 case "${ENABLE_LD}" in
 378   default)
 379     if test x${default_ld} != x; then
 380       AC_MSG_ERROR([either gold or ld can be the default ld])
 381     fi
 382     ;;
 383   yes)
 384     ;;
 385   no)
 386     if test x${ENABLE_GOLD} != xyes; then
 387       AC_MSG_WARN([neither ld nor gold are enabled])
 388     fi
 389     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 390     ;;
 391   *)
 392     AC_MSG_ERROR([invalid --enable-ld argument])
 393     ;;
 394 esac
 395
 396 # PR gas/19109
 397 # Decide the default method for compressing debug sections.
 398 # Provide a configure time option to override our default.
 399 AC_ARG_ENABLE(compressed_debug_sections,
 400 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 401                 [Enable compressed debug sections for gas, gold or ld by
 402                  default])],
 403 [
 404   if test x"$enable_compressed_debug_sections" = xyes; then
 405     AC_MSG_ERROR([no program with compressed debug sections specified])
 406   fi
 407 ], [enable_compressed_debug_sections=])
 408
 409 # Configure extra directories which are host specific
 410
 411 case "${host}" in
 412   *-cygwin*)
 413     configdirs="$configdirs libtermcap" ;;
 414 esac
 415
 416 # A target can indicate whether a language isn't supported for some reason.
 417 # Only spaces may be used in this macro; not newlines or tabs.
 418 unsupported_languages=
 419
 420 # Remove more programs from consideration, based on the host or
 421 # target this usually means that a port of the program doesn't
 422 # exist yet.
 423
 424 case "${host}" in
 425   i[[3456789]]86-*-msdosdjgpp*)
 426     noconfigdirs="$noconfigdirs tcl tk itcl"
 427     ;;
 428 esac
 429
 430
 431 AC_ARG_ENABLE(libquadmath,
 432 AS_HELP_STRING([--disable-libquadmath],
 433   [do not build libquadmath directory]),
 434 ENABLE_LIBQUADMATH=$enableval,
 435 ENABLE_LIBQUADMATH=yes)
 436 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 437   noconfigdirs="$noconfigdirs target-libquadmath"
 438 fi
 439
 440
 441 AC_ARG_ENABLE(libquadmath-support,
 442 AS_HELP_STRING([--disable-libquadmath-support],
 443   [disable libquadmath support for Fortran]),
 444 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 445 ENABLE_LIBQUADMATH_SUPPORT=yes)
 446 enable_libquadmath_support=
 447 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 448   enable_libquadmath_support=no
 449 fi
 450
 451
 452 AC_ARG_ENABLE(libada,
 453 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 454 ENABLE_LIBADA=$enableval,
 455 ENABLE_LIBADA=yes)
 456 if test "${ENABLE_LIBADA}" != "yes" ; then
 457   noconfigdirs="$noconfigdirs gnattools"
 458 fi
 459
 460 AC_ARG_ENABLE(libssp,
 461 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 462 ENABLE_LIBSSP=$enableval,
 463 ENABLE_LIBSSP=yes)
 464
 465 AC_ARG_ENABLE(libstdcxx,
 466 AS_HELP_STRING([--disable-libstdcxx],
 467   [do not build libstdc++-v3 directory]),
 468 ENABLE_LIBSTDCXX=$enableval,
 469 ENABLE_LIBSTDCXX=default)
 470 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 471   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 472 fi]
 473
 474 # If this is accelerator compiler and its target is intelmic we enable
 475 # target liboffloadmic by default.  If this is compiler with offloading
 476 # for intelmic we enable host liboffloadmic by default.  Otherwise
 477 # liboffloadmic is disabled by default.
 478 AC_ARG_ENABLE([liboffloadmic],
 479 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 480                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 481 [case "$enableval" in
 482   no | host | target)
 483     enable_liboffloadmic=$enableval ;;
 484   *)
 485     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 486 esac],
 487 [if test x"$enable_as_accelerator_for" != x; then
 488   case "${target}" in
 489     *-intelmic-* | *-intelmicemul-*)
 490       enable_liboffloadmic=target
 491       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 492       ;;
 493     *)
 494       enable_liboffloadmic=no
 495       ;;
 496   esac
 497 else
 498   case "${enable_offload_targets}" in
 499     *-intelmic-* | *-intelmicemul-*)
 500       enable_liboffloadmic=host
 501       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 502       ;;
 503     *)
 504       enable_liboffloadmic=no
 505       ;;
 506     esac
 507 fi])
 508 AC_SUBST(extra_liboffloadmic_configure_flags)
 509
 510 # Enable libgomp by default on hosted POSIX systems, and a few others.
 511 if test x$enable_libgomp = x ; then
 512     case "${target}" in
 513     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 514         ;;
 515     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 516         ;;
 517     *-*-solaris2* | *-*-hpux11*)
 518         ;;
 519     *-*-darwin* | *-*-aix*)
 520         ;;
 521     nvptx*-*-*)
 522         ;;
 523     *)
 524         noconfigdirs="$noconfigdirs target-libgomp"
 525         ;;
 526     esac
 527 fi
 528
 529 # Disable libatomic on unsupported systems.
 530 if test -d ${srcdir}/libatomic; then
 531     if test x$enable_libatomic = x; then
 532         AC_MSG_CHECKING([for libatomic support])
 533         if (srcdir=${srcdir}/libatomic; \
 534                 . ${srcdir}/configure.tgt; \
 535                 test -n "$UNSUPPORTED")
 536         then
 537             AC_MSG_RESULT([no])
 538             noconfigdirs="$noconfigdirs target-libatomic"
 539         else
 540             AC_MSG_RESULT([yes])
 541         fi
 542     fi
 543 fi
 544
 545 # Disable liboffloadmic on unsupported systems.
 546 if test -d ${srcdir}/liboffloadmic; then
 547     if test x$enable_liboffloadmic != xno; then
 548         AC_MSG_CHECKING([for liboffloadmic support])
 549         if (srcdir=${srcdir}/liboffloadmic; \
 550                 . ${srcdir}/configure.tgt; \
 551                 test -n "$UNSUPPORTED")
 552         then
 553             AC_MSG_RESULT([no])
 554             noconfigdirs="$noconfigdirs target-liboffloadmic"
 555         else
 556             AC_MSG_RESULT([yes])
 557         fi
 558     fi
 559 fi
 560
 561 # Disable libitm on unsupported systems.
 562 if test -d ${srcdir}/libitm; then
 563     if test x$enable_libitm = x; then
 564         AC_MSG_CHECKING([for libitm support])
 565         if (srcdir=${srcdir}/libitm; \
 566                 . ${srcdir}/configure.tgt; \
 567                 test -n "$UNSUPPORTED")
 568         then
 569             AC_MSG_RESULT([no])
 570             noconfigdirs="$noconfigdirs target-libitm"
 571         else
 572             AC_MSG_RESULT([yes])
 573         fi
 574     fi
 575 fi
 576
 577 # Disable libsanitizer on unsupported systems.
 578 if test -d ${srcdir}/libsanitizer; then
 579     if test x$enable_libsanitizer = x; then
 580         AC_MSG_CHECKING([for libsanitizer support])
 581         if (srcdir=${srcdir}/libsanitizer; \
 582                 . ${srcdir}/configure.tgt; \
 583                 test -n "$UNSUPPORTED")
 584         then
 585             AC_MSG_RESULT([no])
 586             noconfigdirs="$noconfigdirs target-libsanitizer"
 587         else
 588             AC_MSG_RESULT([yes])
 589         fi
 590     fi
 591 fi
 592
 593 # Disable libvtv on unsupported systems.
 594 if test -d ${srcdir}/libvtv; then
 595     if test x$enable_libvtv = x; then
 596         AC_MSG_CHECKING([for libvtv support])
 597         if (srcdir=${srcdir}/libvtv; \
 598                 . ${srcdir}/configure.tgt; \
 599                 test "$VTV_SUPPORTED" != "yes")
 600         then
 601             AC_MSG_RESULT([no])
 602             noconfigdirs="$noconfigdirs target-libvtv"
 603         else
 604             AC_MSG_RESULT([yes])
 605         fi
 606     fi
 607 fi
 608
 609
 610 # Disable libhsail-rt on unsupported systems.
 611 if test -d ${srcdir}/libhsail-rt; then
 612     if test x$enable_libhsail_rt = x; then
 613         AC_MSG_CHECKING([for libhsail-rt support])
 614         if (srcdir=${srcdir}/libhsail-rt; \
 615                 . ${srcdir}/configure.tgt; \
 616                 test -n "$UNSUPPORTED")
 617         then
 618             AC_MSG_RESULT([no])
 619             unsupported_languages="$unsupported_languages brig"
 620             # This implicitly disables also target-libhsail-rt as it won't
 621             # get added to the build without BRIG FE.
 622         else
 623             AC_MSG_RESULT([yes])
 624         fi
 625     fi
 626 fi
 627
 628
 629 # Disable libquadmath for some systems.
 630 case "${target}" in
 631   avr-*-*)
 632     noconfigdirs="$noconfigdirs target-libquadmath"
 633     ;;
 634   # libquadmath is unused on AIX and libquadmath build process use of
 635   # LD_LIBRARY_PATH can break AIX bootstrap.
 636   powerpc-*-aix* | rs6000-*-aix*)
 637     noconfigdirs="$noconfigdirs target-libquadmath"
 638     ;;
 639 esac
 640
 641 # Disable libssp for some systems.
 642 case "${target}" in
 643   avr-*-*)
 644     # No hosted I/O support.
 645     noconfigdirs="$noconfigdirs target-libssp"
 646     ;;
 647   powerpc-*-aix* | rs6000-*-aix*)
 648     noconfigdirs="$noconfigdirs target-libssp"
 649     ;;
 650   rl78-*-*)
 651     # libssp uses a misaligned load to trigger a fault, but the RL78
 652     # doesn't fault for those - instead, it gives a build-time error
 653     # for explicit misaligned loads.
 654     noconfigdirs="$noconfigdirs target-libssp"
 655     ;;
 656   visium-*-*)
 657     # No hosted I/O support.
 658     noconfigdirs="$noconfigdirs target-libssp"
 659     ;;
 660 esac
 661
 662 # Disable libstdc++-v3 for some systems.
 663 # Allow user to override this if they pass --enable-libstdc++-v3
 664 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 665   case "${target}" in
 666     *-*-vxworks*)
 667       # VxWorks uses the Dinkumware C++ library.
 668       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 669       ;;
 670     arm*-wince-pe*)
 671       # the C++ libraries don't build on top of CE's C libraries
 672       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 673       ;;
 674     avr-*-*)
 675       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 676       ;;
 677     ft32-*-*)
 678       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 679       ;;
 680   esac
 681 fi
 682
 683 # Disable D on systems where it is known to not work.
 684 # For testing, you can override this with --enable-languages=d.
 685 case ,${enable_languages}, in
 686   *,d,*)
 687     ;;
 688   *)
 689     case "${target}" in
 690       *-*-darwin*)
 691         unsupported_languages="$unsupported_languages d"
 692         ;;
 693     esac
 694     ;;
 695 esac
 696
 697 # Disable libphobos on unsupported systems.
 698 # For testing, you can override this with --enable-libphobos.
 699 if test -d ${srcdir}/libphobos; then
 700     if test x$enable_libphobos = x; then
 701         AC_MSG_CHECKING([for libphobos support])
 702         if (srcdir=${srcdir}/libphobos; \
 703                 . ${srcdir}/configure.tgt; \
 704                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 705         then
 706             AC_MSG_RESULT([no])
 707             noconfigdirs="$noconfigdirs target-libphobos"
 708         else
 709             AC_MSG_RESULT([yes])
 710         fi
 711     fi
 712 fi
 713
 714 # Disable Fortran for some systems.
 715 case "${target}" in
 716   mmix-*-*)
 717     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 718     unsupported_languages="$unsupported_languages fortran"
 719     ;;
 720 esac
 721
 722 # Disable libffi for some systems.
 723 case "${target}" in
 724   powerpc-*-darwin*)
 725     ;;
 726   i[[3456789]]86-*-darwin*)
 727     ;;
 728   x86_64-*-darwin[[912]]*)
 729     ;;
 730   *-*-darwin*)
 731     noconfigdirs="$noconfigdirs target-libffi"
 732     ;;
 733   *-*-netware*)
 734     noconfigdirs="$noconfigdirs target-libffi"
 735     ;;
 736   *-*-phoenix*)
 737     noconfigdirs="$noconfigdirs target-libffi"
 738     ;;
 739   *-*-rtems*)
 740     noconfigdirs="$noconfigdirs target-libffi"
 741     ;;
 742   *-*-tpf*)
 743     noconfigdirs="$noconfigdirs target-libffi"
 744     ;;
 745   *-*-uclinux*)
 746     noconfigdirs="$noconfigdirs target-libffi"
 747     ;;
 748   *-*-vxworks*)
 749     noconfigdirs="$noconfigdirs target-libffi"
 750     ;;
 751   aarch64*-*-freebsd*)
 752     noconfigdirs="$noconfigdirs target-libffi"
 753     ;;
 754   alpha*-*-*vms*)
 755     noconfigdirs="$noconfigdirs target-libffi"
 756     ;;
 757   arm*-*-freebsd*)
 758     noconfigdirs="$noconfigdirs target-libffi"
 759     ;;
 760   arm-wince-pe)
 761     noconfigdirs="$noconfigdirs target-libffi"
 762     ;;
 763   arm*-*-symbianelf*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   cris-*-* | crisv32-*-*)
 767     case "${target}" in
 768       *-*-linux*)
 769         ;;
 770       *) # See PR46792 regarding target-libffi.
 771         noconfigdirs="$noconfigdirs target-libffi";;
 772     esac
 773     ;;
 774   hppa*64*-*-hpux*)
 775     noconfigdirs="$noconfigdirs target-libffi"
 776     ;;
 777   hppa*-hp-hpux11*)
 778     ;;
 779   hppa*-*-hpux*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   ia64*-*-*vms*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785   i[[3456789]]86-w64-mingw*)
 786     noconfigdirs="$noconfigdirs target-libffi"
 787     ;;
 788   i[[3456789]]86-*-mingw*)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   x86_64-*-mingw*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794   mmix-*-*)
 795     noconfigdirs="$noconfigdirs target-libffi"
 796     ;;
 797   powerpc-*-aix*)
 798     ;;
 799   rs6000-*-aix*)
 800     ;;
 801   ft32-*-*)
 802     noconfigdirs="$noconfigdirs target-libffi"
 803     ;;
 804   *-*-lynxos*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807 esac
 808
 809 # Disable the go frontend on systems where it is known to not work. Please keep
 810 # this in sync with contrib/config-list.mk.
 811 case "${target}" in
 812 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 813     unsupported_languages="$unsupported_languages go"
 814     ;;
 815 esac
 816
 817 # Disable libgo for some systems where it is known to not work.
 818 # For testing, you can easily override this with --enable-libgo.
 819 if test x$enable_libgo = x; then
 820     case "${target}" in
 821     *-*-darwin*)
 822         # PR 46986
 823         noconfigdirs="$noconfigdirs target-libgo"
 824         ;;
 825     *-*-cygwin* | *-*-mingw*)
 826         noconfigdirs="$noconfigdirs target-libgo"
 827         ;;
 828     esac
 829 fi
 830
 831 # Default libgloss CPU subdirectory.
 832 libgloss_dir="$target_cpu"
 833
 834 case "${target}" in
 835   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 836     libgloss_dir=wince
 837     ;;
 838   aarch64*-*-* )
 839     libgloss_dir=aarch64
 840     ;;
 841   arm*-*-*)
 842     libgloss_dir=arm
 843     ;;
 844   cris-*-* | crisv32-*-*)
 845     libgloss_dir=cris
 846     ;;
 847   hppa*-*-*)
 848     libgloss_dir=pa
 849     ;;
 850   i[[3456789]]86-*-*)
 851     libgloss_dir=i386
 852     ;;
 853   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 854     libgloss_dir=m68hc11
 855     ;;
 856   m68*-*-* | fido-*-*)
 857     libgloss_dir=m68k
 858     ;;
 859   mips*-*-*)
 860     libgloss_dir=mips
 861     ;;
 862   powerpc*-*-*)
 863     libgloss_dir=rs6000
 864     ;;
 865   sparc*-*-*)
 866     libgloss_dir=sparc
 867     ;;
 868 esac
 869
 870 # Disable newlib and libgloss for various target OSes.
 871 case "${target}" in
 872   alpha*-dec-osf*)
 873     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 874     ;;
 875   i[[3456789]]86-*-linux*)
 876     # This section makes it possible to build newlib natively on linux.
 877     # If we are using a cross compiler then don't configure newlib.
 878     if test x${is_cross_compiler} != xno ; then
 879       noconfigdirs="$noconfigdirs target-newlib"
 880     fi
 881     noconfigdirs="$noconfigdirs target-libgloss"
 882     # If we are not using a cross compiler, do configure newlib.
 883     # Note however, that newlib will only be configured in this situation
 884     # if the --with-newlib option has been given, because otherwise
 885     # 'target-newlib' will appear in skipdirs.
 886     ;;
 887   i[[3456789]]86-*-rdos*)
 888     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 889     ;;
 890   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 891     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 892     ;;
 893   sparc-*-sunos4*)
 894     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 895     ;;
 896   *-*-aix*)
 897     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 898     ;;
 899   *-*-beos*)
 900     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 901     ;;
 902   *-*-chorusos)
 903     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 904     ;;
 905   *-*-dragonfly*)
 906     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 907     ;;
 908   *-*-freebsd*)
 909     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 910     ;;
 911   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 912     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 913     ;;
 914   *-*-lynxos*)
 915     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 916     ;;
 917   *-*-mingw*)
 918     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 919     ;;
 920   *-*-netbsd*)
 921     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 922     ;;
 923   *-*-netware*)
 924     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 925     ;;
 926   *-*-tpf*)
 927     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 928     ;;
 929   *-*-uclinux*)
 930     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 931     ;;
 932   *-*-vxworks*)
 933     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 934     ;;
 935 esac
 936
 937 # Targets that do not use the ELF file format cannot support libctf.
 938 case "${target}" in
 939   *-*-pe | *-*-*vms* | *-*-darwin | *-*-*coff* | *-*-wince | *-*-mingw*)
 940     noconfigdirs="$noconfigdirs libctf"
 941     ;;
 942   *-*-aout | *-*-osf* | *-*-go32 | *-*-macos* | *-*-rhapsody*)
 943     noconfigdirs="$noconfigdirs libctf"
 944     ;;
 945   *-*-netbsdpe | *-*-cygwin* | *-*-pep | *-*-msdos | *-*-winnt)
 946     noconfigdirs="$noconfigdirs libctf"
 947     ;;
 948   ns32k-*-* | pdp11-*-* | *-*-aix* | *-*-netbsdaout)
 949     noconfigdirs="$noconfigdirs libctf"
 950     ;;
 951 esac
 952
 953 case "${target}" in
 954   *-*-chorusos)
 955     ;;
 956   aarch64-*-darwin*)
 957     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 958     noconfigdirs="$noconfigdirs sim target-rda"
 959     ;;
 960   amdgcn*-*-*)
 961     ;;
 962   arm-*-darwin*)
 963     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 964     noconfigdirs="$noconfigdirs sim target-rda"
 965     ;;
 966   powerpc-*-darwin*)
 967     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 968     noconfigdirs="$noconfigdirs sim target-rda"
 969     ;;
 970   i[[3456789]]86-*-darwin*)
 971     noconfigdirs="$noconfigdirs ld gprof"
 972     noconfigdirs="$noconfigdirs sim target-rda"
 973     ;;
 974   x86_64-*-darwin[[912]]*)
 975     noconfigdirs="$noconfigdirs ld gas gprof"
 976     noconfigdirs="$noconfigdirs sim target-rda"
 977     ;;
 978   *-*-darwin*)
 979     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 980     noconfigdirs="$noconfigdirs sim target-rda"
 981     ;;
 982   *-*-dragonfly*)
 983     ;;
 984   *-*-freebsd*)
 985     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 986         && test -f /usr/local/include/gmp.h; then
 987       with_gmp=/usr/local
 988     fi
 989     ;;
 990   *-*-kaos*)
 991     # Remove unsupported stuff on all kaOS configurations.
 992     noconfigdirs="$noconfigdirs target-libgloss"
 993     ;;
 994   *-*-netbsd*)
 995     ;;
 996   *-*-netware*)
 997     ;;
 998   *-*-phoenix*)
 999     noconfigdirs="$noconfigdirs target-libgloss"
1000     ;;
1001   *-*-rtems*)
1002     noconfigdirs="$noconfigdirs target-libgloss"
1003     ;;
1004     # The tpf target doesn't support gdb yet.
1005   *-*-tpf*)
1006     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1007     ;;
1008   *-*-uclinux*)
1009     noconfigdirs="$noconfigdirs target-rda"
1010     ;;
1011   *-*-vxworks*)
1012     ;;
1013   alpha*-dec-osf*)
1014     # ld works, but does not support shared libraries.
1015     # gas doesn't generate exception information.
1016     noconfigdirs="$noconfigdirs gas ld"
1017     ;;
1018   alpha*-*-*vms*)
1019     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1020     ;;
1021   alpha*-*-*)
1022     # newlib is not 64 bit ready
1023     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1024     ;;
1025   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1026     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1027     ;;
1028   arc*-*-*)
1029     noconfigdirs="$noconfigdirs sim"
1030     ;;
1031   arm-*-pe*)
1032     noconfigdirs="$noconfigdirs target-libgloss"
1033     ;;
1034   arm-*-riscix*)
1035     noconfigdirs="$noconfigdirs ld target-libgloss"
1036     ;;
1037   avr-*-*)
1038     if test x${with_avrlibc} != xno; then
1039       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1040     fi
1041     ;;
1042   c4x-*-* | tic4x-*-*)
1043     noconfigdirs="$noconfigdirs target-libgloss"
1044     ;;
1045   tic54x-*-*)
1046     noconfigdirs="$noconfigdirs target-libgloss gdb"
1047     ;;
1048   d10v-*-*)
1049     noconfigdirs="$noconfigdirs target-libgloss"
1050     ;;
1051   d30v-*-*)
1052     noconfigdirs="$noconfigdirs gdb"
1053     ;;
1054   fr30-*-elf*)
1055     noconfigdirs="$noconfigdirs gdb"
1056     ;;
1057   ft32-*-*)
1058     noconfigdirs="$noconfigdirs target-rda gprof"
1059     ;;
1060   moxie-*-*)
1061     noconfigdirs="$noconfigdirs"
1062     ;;
1063   h8300*-*-*)
1064     noconfigdirs="$noconfigdirs target-libgloss"
1065     ;;
1066   h8500-*-*)
1067     noconfigdirs="$noconfigdirs target-libgloss"
1068     ;;
1069   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1070     ;;
1071   hppa*64*-*-hpux*)
1072     noconfigdirs="$noconfigdirs gdb"
1073     ;;
1074   hppa*-*-hpux11*)
1075     noconfigdirs="$noconfigdirs gdb ld"
1076     ;;
1077   hppa*64*-*-linux*)
1078     ;;
1079   hppa*-*-linux*)
1080     ;;
1081   hppa*-*-*elf* | \
1082   hppa*-*-lites* | \
1083   hppa*-*-openbsd* | \
1084   hppa*64*-*-*)
1085     ;;
1086   hppa*-*-pro*)
1087     ;;
1088   hppa*-*-*)
1089     noconfigdirs="$noconfigdirs ld"
1090     ;;
1091   i960-*-*)
1092     noconfigdirs="$noconfigdirs gdb"
1093     ;;
1094   ia64*-*-elf*)
1095     # No gdb support yet.
1096     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1097     ;;
1098   ia64*-**-hpux*)
1099     # No ld support yet.
1100     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1101     ;;
1102   ia64*-*-*vms*)
1103     # No ld support yet.
1104     noconfigdirs="$noconfigdirs libgui itcl ld"
1105     ;;
1106   i[[3456789]]86-w64-mingw*)
1107     ;;
1108   i[[3456789]]86-*-mingw*)
1109     target_configdirs="$target_configdirs target-winsup"
1110     ;;
1111   *-*-cygwin*)
1112     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1113     noconfigdirs="$noconfigdirs target-libgloss"
1114     # always build newlib if winsup directory is present.
1115     if test -d "$srcdir/winsup/cygwin"; then
1116       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1117     elif test -d "$srcdir/newlib"; then
1118       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1119     fi
1120     ;;
1121   i[[3456789]]86-*-pe)
1122     noconfigdirs="$noconfigdirs target-libgloss"
1123     ;;
1124   i[[3456789]]86-*-sco3.2v5*)
1125     # The linker does not yet know about weak symbols in COFF,
1126     # and is not configured to handle mixed ELF and COFF.
1127     noconfigdirs="$noconfigdirs ld target-libgloss"
1128     ;;
1129   i[[3456789]]86-*-sco*)
1130     noconfigdirs="$noconfigdirs gprof target-libgloss"
1131     ;;
1132   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1133     noconfigdirs="$noconfigdirs target-libgloss"
1134     ;;
1135   i[[3456789]]86-*-sysv4*)
1136     noconfigdirs="$noconfigdirs target-libgloss"
1137     ;;
1138   i[[3456789]]86-*-beos*)
1139     noconfigdirs="$noconfigdirs gdb"
1140     ;;
1141   i[[3456789]]86-*-rdos*)
1142     noconfigdirs="$noconfigdirs gdb"
1143     ;;
1144   mmix-*-*)
1145     noconfigdirs="$noconfigdirs gdb"
1146     ;;
1147   mt-*-*)
1148     noconfigdirs="$noconfigdirs sim"
1149     ;;
1150   nfp-*-*)
1151     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1152     noconfigdirs="$noconfigdirs $target_libraries"
1153     ;;
1154   powerpc-*-aix*)
1155     # copied from rs6000-*-* entry
1156     noconfigdirs="$noconfigdirs gprof"
1157     ;;
1158   powerpc*-*-winnt* | powerpc*-*-pe*)
1159     target_configdirs="$target_configdirs target-winsup"
1160     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1161     # always build newlib.
1162     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1163     ;;
1164     # This is temporary until we can link against shared libraries
1165   powerpcle-*-solaris*)
1166     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1167     ;;
1168   powerpc-*-beos*)
1169     noconfigdirs="$noconfigdirs gdb"
1170     ;;
1171   rs6000-*-lynxos*)
1172     noconfigdirs="$noconfigdirs gprof"
1173     ;;
1174   rs6000-*-aix*)
1175     noconfigdirs="$noconfigdirs gprof"
1176     ;;
1177   rs6000-*-*)
1178     noconfigdirs="$noconfigdirs gprof"
1179     ;;
1180   m68k-apollo-*)
1181     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1182     ;;
1183   microblaze*)
1184     noconfigdirs="$noconfigdirs gprof"
1185     ;;
1186   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1187     if test x$with_newlib = xyes; then
1188       noconfigdirs="$noconfigdirs gprof"
1189     fi
1190     ;;
1191   mips*-*-irix5*)
1192     noconfigdirs="$noconfigdirs gprof target-libgloss"
1193     ;;
1194   mips*-*-irix6*)
1195     noconfigdirs="$noconfigdirs gprof target-libgloss"
1196     ;;
1197   mips*-*-bsd*)
1198     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1199     ;;
1200   mips*-*-linux*)
1201     ;;
1202   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1203   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1204     noconfigdirs="$noconfigdirs ld gas gprof"
1205     ;;
1206   mips*-*-*)
1207     noconfigdirs="$noconfigdirs gprof"
1208     ;;
1209   nvptx*-*-*)
1210     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1211     ;;
1212   sh-*-*)
1213     case "${target}" in
1214       sh*-*-elf)
1215          ;;
1216       *)
1217          noconfigdirs="$noconfigdirs target-libgloss" ;;
1218     esac
1219     ;;
1220   sparc-*-sunos4*)
1221     if test x${is_cross_compiler} = xno ; then
1222            use_gnu_ld=no
1223     fi
1224     ;;
1225   tic6x-*-*)
1226     noconfigdirs="$noconfigdirs sim"
1227     ;;
1228   tilepro*-*-* | tilegx*-*-*)
1229     noconfigdirs="$noconfigdirs sim"
1230     ;;
1231   v810-*-*)
1232     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1233     ;;
1234   vax-*-*)
1235     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1236     ;;
1237   wasm32-*-*)
1238     noconfigdirs="$noconfigdirs ld"
1239     ;;
1240 esac
1241
1242 # If we aren't building newlib, then don't build libgloss, since libgloss
1243 # depends upon some newlib header files.
1244 case "${noconfigdirs}" in
1245   *target-libgloss*) ;;
1246   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1247 esac
1248
1249 # Work in distributions that contain no compiler tools, like Autoconf.
1250 host_makefile_frag=/dev/null
1251 if test -d ${srcdir}/config ; then
1252 case "${host}" in
1253   i[[3456789]]86-*-msdosdjgpp*)
1254     host_makefile_frag="config/mh-djgpp"
1255     ;;
1256   *-cygwin*)
1257     ACX_CHECK_CYGWIN_CAT_WORKS
1258     host_makefile_frag="config/mh-cygwin"
1259     ;;
1260   *-mingw*)
1261     host_makefile_frag="config/mh-mingw"
1262     ;;
1263   alpha*-linux*)
1264     host_makefile_frag="config/mh-alpha-linux"
1265     ;;
1266   hppa*-hp-hpux10*)
1267     host_makefile_frag="config/mh-pa-hpux10"
1268     ;;
1269   hppa*-hp-hpux*)
1270     host_makefile_frag="config/mh-pa"
1271     ;;
1272   hppa*-*)
1273     host_makefile_frag="config/mh-pa"
1274     ;;
1275   *-*-darwin*)
1276     host_makefile_frag="config/mh-darwin"
1277     ;;
1278   powerpc-*-aix*)
1279     host_makefile_frag="config/mh-ppc-aix"
1280     ;;
1281   rs6000-*-aix*)
1282     host_makefile_frag="config/mh-ppc-aix"
1283     ;;
1284 esac
1285 fi
1286
1287 if test "${build}" != "${host}" ; then
1288   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1289   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1290   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1291   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1292   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1293   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1294   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1295   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1296   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1297   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1298   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1299   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1300   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1301 else
1302   AR_FOR_BUILD="\$(AR)"
1303   AS_FOR_BUILD="\$(AS)"
1304   CC_FOR_BUILD="\$(CC)"
1305   CXX_FOR_BUILD="\$(CXX)"
1306   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1307   GOC_FOR_BUILD="\$(GOC)"
1308   GDC_FOR_BUILD="\$(GDC)"
1309   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1310   LD_FOR_BUILD="\$(LD)"
1311   NM_FOR_BUILD="\$(NM)"
1312   RANLIB_FOR_BUILD="\$(RANLIB)"
1313   WINDRES_FOR_BUILD="\$(WINDRES)"
1314   WINDMC_FOR_BUILD="\$(WINDMC)"
1315 fi
1316
1317 AC_PROG_CC
1318 AC_PROG_CXX
1319
1320 # We must set the default linker to the linker used by gcc for the correct
1321 # operation of libtool.  If LD is not defined and we are using gcc, try to
1322 # set the LD default to the ld used by gcc.
1323 if test -z "$LD"; then
1324   if test "$GCC" = yes; then
1325     case $build in
1326     *-*-mingw*)
1327       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1328     *)
1329       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1330     esac
1331     case $gcc_prog_ld in
1332     # Accept absolute paths.
1333     [[\\/]* | [A-Za-z]:[\\/]*)]
1334       LD="$gcc_prog_ld" ;;
1335     esac
1336   fi
1337 fi
1338
1339 # Check whether -static-libstdc++ -static-libgcc is supported.
1340 have_static_libs=no
1341 if test "$GCC" = yes; then
1342   saved_LDFLAGS="$LDFLAGS"
1343
1344   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1345   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1346   AC_LANG_PUSH(C++)
1347   AC_LINK_IFELSE([AC_LANG_SOURCE([
1348 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1349 #error -static-libstdc++ not implemented
1350 #endif
1351 int main() {}])],
1352     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1353     [AC_MSG_RESULT([no])])
1354   AC_LANG_POP(C++)
1355
1356   LDFLAGS="$saved_LDFLAGS"
1357 fi
1358
1359 ACX_PROG_GNAT
1360 ACX_PROG_CMP_IGNORE_INITIAL
1361
1362 AC_ARG_ENABLE([bootstrap],
1363 [AS_HELP_STRING([--enable-bootstrap],
1364                 [enable bootstrapping @<:@yes if native build@:>@])],,
1365 enable_bootstrap=default)
1366
1367 # Issue errors and warnings for invalid/strange bootstrap combinations.
1368 if test -r $srcdir/gcc/configure; then
1369   have_compiler=yes
1370 else
1371   have_compiler=no
1372 fi
1373
1374 case "$have_compiler:$host:$target:$enable_bootstrap" in
1375   *:*:*:no) ;;
1376
1377   # Default behavior.  Enable bootstrap if we have a compiler
1378   # and we are in a native configuration.
1379   yes:$build:$build:default)
1380     enable_bootstrap=yes ;;
1381
1382   *:*:*:default)
1383     enable_bootstrap=no ;;
1384
1385   # We have a compiler and we are in a native configuration, bootstrap is ok
1386   yes:$build:$build:yes)
1387     ;;
1388
1389   # Other configurations, but we have a compiler.  Assume the user knows
1390   # what he's doing.
1391   yes:*:*:yes)
1392     AC_MSG_WARN([trying to bootstrap a cross compiler])
1393     ;;
1394
1395   # No compiler: if they passed --enable-bootstrap explicitly, fail
1396   no:*:*:yes)
1397     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1398
1399   # Fail if wrong command line
1400   *)
1401     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1402     ;;
1403 esac
1404
1405 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1406 # C++98 compiler can still start the bootstrap.
1407 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1408   CXX="$CXX -std=gnu++98"
1409 fi
1410
1411 # Used for setting $lt_cv_objdir
1412 _LT_CHECK_OBJDIR
1413
1414 # Check for GMP, MPFR and MPC
1415 gmplibs="-lmpc -lmpfr -lgmp"
1416 gmpinc=
1417 have_gmp=no
1418
1419 # Specify a location for mpc
1420 # check for this first so it ends up on the link line before mpfr.
1421 AC_ARG_WITH(mpc,
1422 [AS_HELP_STRING([--with-mpc=PATH],
1423                 [specify prefix directory for installed MPC package.
1424                  Equivalent to --with-mpc-include=PATH/include
1425                  plus --with-mpc-lib=PATH/lib])])
1426 AC_ARG_WITH(mpc-include,
1427 [AS_HELP_STRING([--with-mpc-include=PATH],
1428                 [specify directory for installed MPC include files])])
1429 AC_ARG_WITH(mpc-lib,
1430 [AS_HELP_STRING([--with-mpc-lib=PATH],
1431                 [specify directory for the installed MPC library])])
1432
1433 if test "x$with_mpc" != x; then
1434   gmplibs="-L$with_mpc/lib $gmplibs"
1435   gmpinc="-I$with_mpc/include $gmpinc"
1436 fi
1437 if test "x$with_mpc_include" != x; then
1438   gmpinc="-I$with_mpc_include $gmpinc"
1439 fi
1440 if test "x$with_mpc_lib" != x; then
1441   gmplibs="-L$with_mpc_lib $gmplibs"
1442 fi
1443 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1444   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1445   gmpinc='-I$$s/mpc/src '"$gmpinc"
1446   # Do not test the mpc version.  Assume that it is sufficient, since
1447   # it is in the source tree, and the library has not been built yet
1448   # but it would be included on the link line in the version check below
1449   # hence making the test fail.
1450   have_gmp=yes
1451 fi
1452
1453 # Specify a location for mpfr
1454 # check for this first so it ends up on the link line before gmp.
1455 AC_ARG_WITH(mpfr-dir,
1456 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1457 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1458 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1459
1460 AC_ARG_WITH(mpfr,
1461 [AS_HELP_STRING([--with-mpfr=PATH],
1462                 [specify prefix directory for installed MPFR package.
1463                  Equivalent to --with-mpfr-include=PATH/include
1464                  plus --with-mpfr-lib=PATH/lib])])
1465 AC_ARG_WITH(mpfr-include,
1466 [AS_HELP_STRING([--with-mpfr-include=PATH],
1467                 [specify directory for installed MPFR include files])])
1468 AC_ARG_WITH(mpfr-lib,
1469 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1470                 [specify directory for the installed MPFR library])])
1471
1472 if test "x$with_mpfr" != x; then
1473   gmplibs="-L$with_mpfr/lib $gmplibs"
1474   gmpinc="-I$with_mpfr/include $gmpinc"
1475 fi
1476 if test "x$with_mpfr_include" != x; then
1477   gmpinc="-I$with_mpfr_include $gmpinc"
1478 fi
1479 if test "x$with_mpfr_lib" != x; then
1480   gmplibs="-L$with_mpfr_lib $gmplibs"
1481 fi
1482 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1483   # MPFR v3.1.0 moved the sources into a src sub-directory.
1484   if ! test -d ${srcdir}/mpfr/src; then
1485     AC_MSG_ERROR([dnl
1486 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1487   fi
1488   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1489   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1490   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1491   # Do not test the mpfr version.  Assume that it is sufficient, since
1492   # it is in the source tree, and the library has not been built yet
1493   # but it would be included on the link line in the version check below
1494   # hence making the test fail.
1495   have_gmp=yes
1496 fi
1497
1498 # Specify a location for gmp
1499 AC_ARG_WITH(gmp-dir,
1500 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1501 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1502 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1503
1504 AC_ARG_WITH(gmp,
1505 [AS_HELP_STRING([--with-gmp=PATH],
1506                 [specify prefix directory for the installed GMP package.
1507                  Equivalent to --with-gmp-include=PATH/include
1508                  plus --with-gmp-lib=PATH/lib])])
1509 AC_ARG_WITH(gmp-include,
1510 [AS_HELP_STRING([--with-gmp-include=PATH],
1511                 [specify directory for installed GMP include files])])
1512 AC_ARG_WITH(gmp-lib,
1513 [AS_HELP_STRING([--with-gmp-lib=PATH],
1514                 [specify directory for the installed GMP library])])
1515
1516
1517 if test "x$with_gmp" != x; then
1518   gmplibs="-L$with_gmp/lib $gmplibs"
1519   gmpinc="-I$with_gmp/include $gmpinc"
1520 fi
1521 if test "x$with_gmp_include" != x; then
1522   gmpinc="-I$with_gmp_include $gmpinc"
1523 fi
1524 if test "x$with_gmp_lib" != x; then
1525   gmplibs="-L$with_gmp_lib $gmplibs"
1526 fi
1527 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1528   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1529   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1530   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1531   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1532   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1533   # Do not test the gmp version.  Assume that it is sufficient, since
1534   # it is in the source tree, and the library has not been built yet
1535   # but it would be included on the link line in the version check below
1536   # hence making the test fail.
1537   have_gmp=yes
1538 fi
1539
1540 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1541   have_gmp=yes
1542   saved_CFLAGS="$CFLAGS"
1543   CFLAGS="$CFLAGS $gmpinc"
1544   # Check for the recommended and required versions of GMP.
1545   AC_MSG_CHECKING([for the correct version of gmp.h])
1546   AC_TRY_COMPILE([#include "gmp.h"],[
1547   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1548   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1549   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1550   choke me
1551   #endif
1552   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1553   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1554   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1555   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1556   choke me
1557   #endif
1558   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1559    [AC_MSG_RESULT([no]); have_gmp=no])
1560
1561   # If we have GMP, check the MPFR version.
1562   if test x"$have_gmp" = xyes; then
1563     # Check for the recommended and required versions of MPFR.
1564     AC_MSG_CHECKING([for the correct version of mpfr.h])
1565     AC_TRY_COMPILE([#include <gmp.h>
1566     #include <mpfr.h>],[
1567     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1568     choke me
1569     #endif
1570     ], [AC_TRY_COMPILE([#include <gmp.h>
1571     #include <mpfr.h>],[
1572     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1573     choke me
1574     #endif
1575     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1576      [AC_MSG_RESULT([no]); have_gmp=no])
1577   fi
1578
1579   # Check for the MPC header version.
1580   if test x"$have_gmp" = xyes ; then
1581     # Check for the recommended and required versions of MPC.
1582     AC_MSG_CHECKING([for the correct version of mpc.h])
1583     AC_TRY_COMPILE([#include <mpc.h>],[
1584     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1585     choke me
1586     #endif
1587     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1588     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1589     choke me
1590     #endif
1591     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1592      [AC_MSG_RESULT([no]); have_gmp=no])
1593   fi
1594
1595   # Now check the MPFR library.
1596   if test x"$have_gmp" = xyes; then
1597     saved_LIBS="$LIBS"
1598     LIBS="$LIBS $gmplibs"
1599     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1600     AC_TRY_LINK([#include <mpc.h>],[
1601     mpfr_t n;
1602     mpfr_t x;
1603     mpc_t c;
1604     int t;
1605     mpfr_init (n);
1606     mpfr_init (x);
1607     mpfr_atan2 (n, n, x, GMP_RNDN);
1608     mpfr_erfc (n, x, GMP_RNDN);
1609     mpfr_subnormalize (x, t, GMP_RNDN);
1610     mpfr_clear(n);
1611     mpfr_clear(x);
1612     mpc_init2 (c, 53);
1613     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1614     mpc_cosh (c, c, MPC_RNDNN);
1615     mpc_pow (c, c, c, MPC_RNDNN);
1616     mpc_acosh (c, c, MPC_RNDNN);
1617     mpc_clear (c);
1618     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1619     LIBS="$saved_LIBS"
1620   fi
1621
1622   CFLAGS="$saved_CFLAGS"
1623
1624 # The library versions listed in the error message below should match
1625 # the HARD-minimums enforced above.
1626   if test x$have_gmp != xyes; then
1627     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1628 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1629 their locations.  Source code for these libraries can be found at
1630 their respective hosting sites as well as at
1631 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1632 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1633 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1634 make sure that you have installed both the libraries and the header
1635 files.  They may be located in separate packages.])
1636   fi
1637 fi
1638
1639 # Flags needed for both GMP, MPFR and/or MPC.
1640 AC_SUBST(gmplibs)
1641 AC_SUBST(gmpinc)
1642 AC_SUBST(extra_mpfr_configure_flags)
1643 AC_SUBST(extra_mpc_gmp_configure_flags)
1644 AC_SUBST(extra_mpc_mpfr_configure_flags)
1645 AC_SUBST(extra_isl_gmp_configure_flags)
1646
1647 # Libraries to use for stage1 or when not bootstrapping.
1648 AC_ARG_WITH(stage1-libs,
1649 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1650 [if test "$withval" = "no" -o "$withval" = "yes"; then
1651    stage1_libs=
1652  else
1653    stage1_libs=$withval
1654  fi],
1655 [stage1_libs=])
1656 AC_SUBST(stage1_libs)
1657
1658 # Linker flags to use for stage1 or when not bootstrapping.
1659 AC_ARG_WITH(stage1-ldflags,
1660 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1661 [if test "$withval" = "no" -o "$withval" = "yes"; then
1662    stage1_ldflags=
1663  else
1664    stage1_ldflags=$withval
1665  fi],
1666 [stage1_ldflags=
1667  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1668  # if supported.  But if the user explicitly specified the libraries to use,
1669  # trust that they are doing what they want.
1670  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1671    stage1_ldflags="-static-libstdc++ -static-libgcc"
1672  fi])
1673 AC_SUBST(stage1_ldflags)
1674
1675 # Libraries to use for stage2 and later builds.
1676 AC_ARG_WITH(boot-libs,
1677 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1678 [if test "$withval" = "no" -o "$withval" = "yes"; then
1679    poststage1_libs=
1680  else
1681    poststage1_libs=$withval
1682  fi],
1683 [poststage1_libs=])
1684 AC_SUBST(poststage1_libs)
1685
1686 # Linker flags to use for stage2 and later builds.
1687 AC_ARG_WITH(boot-ldflags,
1688 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1689                 [linker flags for stage2 and later])],
1690 [if test "$withval" = "no" -o "$withval" = "yes"; then
1691    poststage1_ldflags=
1692  else
1693    poststage1_ldflags=$withval
1694  fi],
1695 [poststage1_ldflags=
1696  # In stages 2 and 3, default to linking libstdc++ and libgcc
1697  # statically.  But if the user explicitly specified the libraries to
1698  # use, trust that they are doing what they want.
1699  if test "$poststage1_libs" = ""; then
1700    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1701  fi])
1702 AC_SUBST(poststage1_ldflags)
1703
1704 # GCC GRAPHITE dependency isl.
1705 # Basic setup is inlined here, actual checks are in config/isl.m4
1706
1707 AC_ARG_WITH(isl,
1708   [AS_HELP_STRING(
1709    [--with-isl=PATH],
1710    [Specify prefix directory for the installed isl package.
1711     Equivalent to --with-isl-include=PATH/include
1712     plus --with-isl-lib=PATH/lib])])
1713
1714 # Treat --without-isl as a request to disable
1715 # GRAPHITE support and skip all following checks.
1716 if test "x$with_isl" != "xno"; then
1717   # Check for isl
1718   dnl Provide configure switches and initialize islinc & isllibs
1719   dnl with user input.
1720   ISL_INIT_FLAGS
1721   dnl The versions of isl that work for Graphite
1722   ISL_CHECK_VERSION()
1723   dnl Only execute fail-action, if isl has been requested.
1724   ISL_IF_FAILED([
1725     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1726 fi
1727
1728 # If the isl check failed, disable builds of in-tree variant of isl
1729 if test "x$with_isl" = xno ||
1730    test "x$gcc_cv_isl" = xno; then
1731   noconfigdirs="$noconfigdirs isl"
1732   islinc=
1733 fi
1734
1735 AC_SUBST(isllibs)
1736 AC_SUBST(islinc)
1737
1738 # Check for LTO support.
1739 AC_ARG_ENABLE(lto,
1740 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1741 enable_lto=$enableval,
1742 enable_lto=yes; default_enable_lto=yes)
1743
1744 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1745   build_lto_plugin=yes
1746 ],[if test x"$default_enable_lto" = x"yes" ; then
1747     case $target in
1748       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1749       # On other non-ELF platforms, LTO has yet to be validated.
1750       *) enable_lto=no ;;
1751     esac
1752   else
1753   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1754   # It would also be nice to check the binutils support, but we don't
1755   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1756   # warn during gcc/ subconfigure; unless you're bootstrapping with
1757   # -flto it won't be needed until after installation anyway.
1758     case $target in
1759       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1760       *) if test x"$enable_lto" = x"yes"; then
1761         AC_MSG_ERROR([LTO support is not enabled for this target.])
1762         fi
1763       ;;
1764     esac
1765   fi
1766   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1767   # Build it unless LTO was explicitly disabled.
1768   case $target in
1769     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1770     *) ;;
1771   esac
1772 ])
1773
1774 AC_ARG_ENABLE(linker-plugin-configure-flags,
1775   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1776     [additional flags for configuring linker plugins @<:@none@:>@])],
1777   extra_linker_plugin_configure_flags=$enableval,
1778   extra_linker_plugin_configure_flags=)
1779 AC_SUBST(extra_linker_plugin_configure_flags)
1780 AC_ARG_ENABLE(linker-plugin-flags,
1781   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1782     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1783   extra_linker_plugin_flags=$enableval,
1784   extra_linker_plugin_flags=)
1785 AC_SUBST(extra_linker_plugin_flags)
1786
1787 # Enable --enable-host-shared.
1788 # Checked early to determine whether jit is an 'all' language
1789 AC_ARG_ENABLE(host-shared,
1790 [AS_HELP_STRING([--enable-host-shared],
1791                 [build host code as shared libraries])],
1792 [host_shared=$enableval], [host_shared=no])
1793 AC_SUBST(host_shared)
1794
1795 # By default, C and C++ are the only stage 1 languages.
1796 stage1_languages=,c,
1797
1798 # Target libraries that we bootstrap.
1799 bootstrap_target_libs=,target-libgcc,
1800
1801 # Figure out what language subdirectories are present.
1802 # Look if the user specified --enable-languages="..."; if not, use
1803 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1804 # go away some day.
1805 # NB:  embedded tabs in this IF block -- do not untabify
1806 if test -d ${srcdir}/gcc; then
1807   if test x"${enable_languages+set}" != xset; then
1808     if test x"${LANGUAGES+set}" = xset; then
1809       enable_languages="${LANGUAGES}"
1810         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1811     else
1812       enable_languages=default
1813     fi
1814   else
1815     if test x"${enable_languages}" = x ||
1816        test x"${enable_languages}" = xyes;
1817        then
1818       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1819       exit 1
1820     fi
1821   fi
1822   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1823
1824   # 'f95' is the old name for the 'fortran' language. We issue a warning
1825   # and make the substitution.
1826   case ,${enable_languages}, in
1827     *,f95,*)
1828       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1829       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1830       ;;
1831   esac
1832
1833   # If bootstrapping, C++ must be enabled.
1834   case ",$enable_languages,:$enable_bootstrap" in
1835     *,c++,*:*) ;;
1836     *:yes)
1837       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1838         enable_languages="${enable_languages},c++"
1839       else
1840         AC_MSG_ERROR([bootstrapping requires c++ sources])
1841       fi
1842       ;;
1843   esac
1844
1845   # First scan to see if an enabled language requires some other language.
1846   # We assume that a given config-lang.in will list all the language
1847   # front ends it requires, even if some are required indirectly.
1848   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1849     case ${lang_frag} in
1850       ..) ;;
1851       # The odd quoting in the next line works around
1852       # an apparent bug in bash 1.12 on linux.
1853       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1854       *)
1855         # From the config-lang.in, get $language, $lang_requires, and
1856         # $lang_requires_boot_languages.
1857         language=
1858         lang_requires=
1859         lang_requires_boot_languages=
1860         # set srcdir during sourcing lang_frag to the gcc dir.
1861         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1862         # polutes this shell
1863         saved_srcdir=${srcdir}
1864         srcdir=${srcdir}/gcc . ${lang_frag}
1865         srcdir=${saved_srcdir}
1866         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1867           case ,${enable_languages}, in
1868             *,$other,*) ;;
1869             *,default,*) ;;
1870             *,all,*) ;;
1871             *,$language,*)
1872               echo " \`$other' language required by \`$language'; enabling" 1>&2
1873               enable_languages="${enable_languages},${other}"
1874               ;;
1875           esac
1876         done
1877         for other in ${lang_requires_boot_languages} ; do
1878           if test "$other" != "c"; then
1879             case ,${enable_stage1_languages}, in
1880               *,$other,*) ;;
1881               *,default,*) ;;
1882               *,all,*) ;;
1883               *)
1884                 case ,${enable_languages}, in
1885                   *,$language,*)
1886                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1887                     enable_stage1_languages="$enable_stage1_languages,${other}"
1888                     ;;
1889                 esac
1890                 ;;
1891             esac
1892           fi
1893         done
1894         ;;
1895     esac
1896   done
1897
1898   new_enable_languages=,c,
1899
1900   # If LTO is enabled, add the LTO front end.
1901   if test "$enable_lto" = "yes" ; then
1902     case ,${enable_languages}, in
1903       *,lto,*) ;;
1904       *) enable_languages="${enable_languages},lto" ;;
1905     esac
1906     if test "${build_lto_plugin}" = "yes" ; then
1907       configdirs="$configdirs lto-plugin"
1908     fi
1909   fi
1910
1911   # If we're building an offloading compiler, add the LTO front end.
1912   if test x"$enable_as_accelerator_for" != x ; then
1913     case ,${enable_languages}, in
1914       *,lto,*) ;;
1915       *) enable_languages="${enable_languages},lto" ;;
1916     esac
1917   fi
1918
1919   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1920   potential_languages=,c,
1921
1922   enabled_target_libs=
1923   disabled_target_libs=
1924
1925   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1926     case ${lang_frag} in
1927       ..) ;;
1928       # The odd quoting in the next line works around
1929       # an apparent bug in bash 1.12 on linux.
1930       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1931       *)
1932         # From the config-lang.in, get $language, $target_libs,
1933         # $lang_dirs, $boot_language, and $build_by_default
1934         language=
1935         target_libs=
1936         lang_dirs=
1937         subdir_requires=
1938         boot_language=no
1939         build_by_default=yes
1940         # set srcdir during sourcing.  See above about save & restore
1941         saved_srcdir=${srcdir}
1942         srcdir=${srcdir}/gcc . ${lang_frag}
1943         srcdir=${saved_srcdir}
1944         if test x${language} = x; then
1945           echo "${lang_frag} doesn't set \$language." 1>&2
1946           exit 1
1947         fi
1948
1949         if test "$language" = "c++"; then
1950           boot_language=yes
1951         fi
1952
1953         add_this_lang=no
1954         # C is always enabled, so no need to add it again
1955         if test "$language" != "c"; then
1956           case ,${enable_languages}, in
1957             *,${language},*)
1958               # Language was explicitly selected; include it
1959               add_this_lang=yes
1960               ;;
1961             *,all,*)
1962               # All languages are enabled
1963               add_this_lang=all
1964               ;;
1965             *,default,*)
1966               # 'default' was selected, select it if it is a default language
1967               add_this_lang=${build_by_default}
1968               ;;
1969           esac
1970         fi
1971
1972         # Disable languages that need other directories if these aren't available.
1973         for i in $subdir_requires; do
1974           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1975           case ${add_this_lang} in
1976             yes)
1977               # Specifically requested language; tell them.
1978               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1979               ;;
1980             all)
1981               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1982               add_this_lang=unsupported
1983               ;;
1984             *)
1985               # Silently disable.
1986               add_this_lang=unsupported
1987               ;;
1988           esac
1989         done
1990
1991         # Disable Ada if no preexisting GNAT is available.
1992         case ${add_this_lang}:${language}:${have_gnat} in
1993           yes:ada:no)
1994             # Specifically requested language; tell them.
1995             AC_MSG_ERROR([GNAT is required to build $language])
1996             ;;
1997           all:ada:no)
1998             AC_MSG_WARN([GNAT is required to build $language])
1999             add_this_lang=unsupported
2000             ;;
2001           *:ada:no)
2002             # Silently disable.
2003             add_this_lang=unsupported
2004             ;;
2005         esac
2006
2007         # Disable jit if -enable-host-shared not specified
2008         case ${add_this_lang}:${language}:${host_shared} in
2009           yes:jit:no)
2010             # PR jit/64780: explicitly specify --enable-host-shared
2011             AC_MSG_ERROR([
2012 Enabling language "jit" requires --enable-host-shared.
2013
2014 --enable-host-shared typically slows the rest of the compiler down by
2015 a few %, so you must explicitly enable it.
2016
2017 If you want to build both the jit and the regular compiler, it is often
2018 best to do this via two separate configure/builds, in separate
2019 directories, to avoid imposing the performance cost of
2020 --enable-host-shared on the regular compiler.])
2021             ;;
2022           all:jit:no)
2023             AC_MSG_WARN([--enable-host-shared required to build $language])
2024             add_this_lang=unsupported
2025             ;;
2026           *:jit:no)
2027             # Silently disable.
2028             add_this_lang=unsupported
2029             ;;
2030         esac
2031
2032         # Disable a language that is unsupported by the target.
2033         case "${add_this_lang}: $unsupported_languages " in
2034           no:*) ;;
2035           unsupported:*) ;;
2036           *:*" $language "*)
2037             AC_MSG_WARN([${language} not supported for this target])
2038             add_this_lang=unsupported
2039             ;;
2040         esac
2041
2042         case $add_this_lang in
2043           unsupported)
2044             # Remove language-dependent dirs.
2045             disabled_target_libs="$disabled_target_libs $target_libs"
2046             noconfigdirs="$noconfigdirs $lang_dirs"
2047             ;;
2048           no)
2049             # Remove language-dependent dirs; still show language as supported.
2050             disabled_target_libs="$disabled_target_libs $target_libs"
2051             noconfigdirs="$noconfigdirs $lang_dirs"
2052             potential_languages="${potential_languages}${language},"
2053             ;;
2054           all|yes)
2055             new_enable_languages="${new_enable_languages}${language},"
2056             potential_languages="${potential_languages}${language},"
2057             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2058             enabled_target_libs="$enabled_target_libs $target_libs"
2059             case "${boot_language}:,$enable_stage1_languages," in
2060               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2061                 # Add to (comma-separated) list of stage 1 languages.
2062                 case ",$stage1_languages," in
2063                   *,$language,* | ,yes, | ,all,) ;;
2064                   *) stage1_languages="${stage1_languages}${language}," ;;
2065                 esac
2066                 # We need to bootstrap any supporting libraries.
2067                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2068                 ;;
2069             esac
2070             ;;
2071         esac
2072         ;;
2073     esac
2074   done
2075
2076   # Add target libraries which are only needed for disabled languages
2077   # to noconfigdirs.
2078   if test -n "$disabled_target_libs"; then
2079     for dir in $disabled_target_libs; do
2080       case " $enabled_target_libs " in
2081       *" ${dir} "*) ;;
2082       *) noconfigdirs="$noconfigdirs $dir" ;;
2083       esac
2084     done
2085   fi
2086
2087   AC_ARG_ENABLE(stage1-languages,
2088   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2089                   [choose additional languages to build during
2090                   stage1.  Mostly useful for compiler development])],
2091   [case ,${enable_stage1_languages}, in
2092     ,no,|,,)
2093       # Set it to something that will have no effect in the loop below
2094       enable_stage1_languages=c ;;
2095     ,yes,)
2096       enable_stage1_languages=`echo $new_enable_languages | \
2097         sed -e "s/^,//" -e "s/,$//" ` ;;
2098     *,all,*)
2099       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2100         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2101   esac
2102
2103   # Add "good" languages from enable_stage1_languages to stage1_languages,
2104   # while "bad" languages go in missing_languages.  Leave no duplicates.
2105   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2106     case $potential_languages in
2107       *,$i,*)
2108         case $stage1_languages in
2109           *,$i,*) ;;
2110           *) stage1_languages="$stage1_languages$i," ;;
2111         esac ;;
2112       *)
2113         case $missing_languages in
2114           *,$i,*) ;;
2115           *) missing_languages="$missing_languages$i," ;;
2116         esac ;;
2117      esac
2118   done])
2119
2120   # Remove leading/trailing commas that were added for simplicity
2121   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2122   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2123   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2124   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2125
2126   if test "x$missing_languages" != x; then
2127     AC_MSG_ERROR([
2128 The following requested languages could not be built: ${missing_languages}
2129 Supported languages are: ${potential_languages}])
2130   fi
2131   if test "x$new_enable_languages" != "x$enable_languages"; then
2132     echo The following languages will be built: ${new_enable_languages}
2133     enable_languages="$new_enable_languages"
2134   fi
2135
2136   AC_SUBST(stage1_languages)
2137   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2138 fi
2139
2140 # Handle --disable-<component> generically.
2141 for dir in $configdirs $build_configdirs $target_configdirs ; do
2142   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2143   varname=`echo $dirname | sed -e s/+/_/g`
2144   if eval test x\${enable_${varname}} "=" xno ; then
2145     noconfigdirs="$noconfigdirs $dir"
2146   fi
2147 done
2148
2149 # Check for Boehm's garbage collector
2150 AC_ARG_ENABLE(objc-gc,
2151 [AS_HELP_STRING([--enable-objc-gc],
2152                 [enable use of Boehm's garbage collector with the
2153                  GNU Objective-C runtime])])
2154 AC_ARG_WITH([target-bdw-gc],
2155 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2156                 [specify prefix directory for installed bdw-gc package.
2157                  Equivalent to --with-target-bdw-gc-include=PATH/include
2158                  plus --with-target-bdw-gc-lib=PATH/lib])])
2159 AC_ARG_WITH([target-bdw-gc-include],
2160 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2161                 [specify directories for installed bdw-gc include files])])
2162 AC_ARG_WITH([target-bdw-gc-lib],
2163 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2164                 [specify directories for installed bdw-gc library])])
2165
2166 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2167   AC_MSG_CHECKING([for bdw garbage collector])
2168   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2169     dnl no bdw-gw options, assume default locations
2170     AC_MSG_RESULT([using bdw-gc in default locations])
2171   else
2172     dnl bdw-gw options, first error checking, complete checking in libobjc
2173     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2174       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2175     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2176       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2177     else
2178       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2179     fi
2180   fi
2181 esac
2182
2183 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2184 case ,${enable_languages}, in
2185   *,c++,*)
2186     # Disable libitm, libsanitizer if we're not building libstdc++
2187     case "${noconfigdirs}" in
2188       *target-libstdc++-v3*)
2189         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2190         ;;
2191       *) ;;
2192     esac
2193     ;;
2194   *)
2195     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2196     ;;
2197 esac
2198
2199 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2200 # $build_configdirs and $target_configdirs.
2201 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2202
2203 notsupp=""
2204 for dir in . $skipdirs $noconfigdirs ; do
2205   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2206   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2207     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2208     if test -r $srcdir/$dirname/configure ; then
2209       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2210         true
2211       else
2212         notsupp="$notsupp $dir"
2213       fi
2214     fi
2215   fi
2216   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2217     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2218     if test -r $srcdir/$dirname/configure ; then
2219       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2220         true
2221       else
2222         notsupp="$notsupp $dir"
2223       fi
2224     fi
2225   fi
2226   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2227     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2228     if test -r $srcdir/$dirname/configure ; then
2229       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2230         true
2231       else
2232         notsupp="$notsupp $dir"
2233       fi
2234     fi
2235   fi
2236 done
2237
2238 # Quietly strip out all directories which aren't configurable in this tree.
2239 # This relies on all configurable subdirectories being autoconfiscated, which
2240 # is now the case.
2241 build_configdirs_all="$build_configdirs"
2242 build_configdirs=
2243 for i in ${build_configdirs_all} ; do
2244   j=`echo $i | sed -e s/build-//g`
2245   if test -f ${srcdir}/$j/configure ; then
2246     build_configdirs="${build_configdirs} $i"
2247   fi
2248 done
2249
2250 configdirs_all="$configdirs"
2251 configdirs=
2252 for i in ${configdirs_all} ; do
2253   if test -f ${srcdir}/$i/configure ; then
2254     configdirs="${configdirs} $i"
2255   fi
2256 done
2257
2258 target_configdirs_all="$target_configdirs"
2259 target_configdirs=
2260 for i in ${target_configdirs_all} ; do
2261   j=`echo $i | sed -e s/target-//g`
2262   if test -f ${srcdir}/$j/configure ; then
2263     target_configdirs="${target_configdirs} $i"
2264   fi
2265 done
2266
2267 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2268 # so we have to add it after the preceding checks.
2269 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2270 then
2271   case " $configdirs " in
2272     *" libiberty "*)
2273       # If we can build libiberty, we can also build libiberty-linker-plugin.
2274       configdirs="$configdirs libiberty-linker-plugin"
2275       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2276         --with-libiberty=../libiberty-linker-plugin";;
2277     *)
2278       AC_MSG_ERROR([libiberty missing]);;
2279   esac
2280 fi
2281
2282 # Sometimes we have special requirements for the host libiberty.
2283 extra_host_libiberty_configure_flags=
2284 extra_host_zlib_configure_flags=
2285 case " $configdirs " in
2286   *" lto-plugin "* | *" libcc1 "*)
2287     # When these are to be built as shared libraries, the same applies to
2288     # libiberty.
2289     extra_host_libiberty_configure_flags=--enable-shared
2290     ;;
2291   *" bfd "*)
2292     # When bfd is to be built as a shared library, the same applies to
2293     # zlib.
2294     if test "$enable_shared" = "yes"; then
2295       extra_host_zlib_configure_flags=--enable-host-shared
2296     fi
2297     ;;
2298 esac
2299 AC_SUBST(extra_host_libiberty_configure_flags)
2300 AC_SUBST(extra_host_zlib_configure_flags)
2301
2302 # Produce a warning message for the subdirs we can't configure.
2303 # This isn't especially interesting in the Cygnus tree, but in the individual
2304 # FSF releases, it's important to let people know when their machine isn't
2305 # supported by the one or two programs in a package.
2306
2307 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2308   # If $appdirs is non-empty, at least one of those directories must still
2309   # be configured, or we error out.  (E.g., if the gas release supports a
2310   # specified target in some subdirs but not the gas subdir, we shouldn't
2311   # pretend that all is well.)
2312   if test -n "$appdirs" ; then
2313     for dir in $appdirs ; do
2314       if test -r $dir/Makefile.in ; then
2315         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2316           appdirs=""
2317           break
2318         fi
2319         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2320           appdirs=""
2321           break
2322         fi
2323       fi
2324     done
2325     if test -n "$appdirs" ; then
2326       echo "*** This configuration is not supported by this package." 1>&2
2327       exit 1
2328     fi
2329   fi
2330   # Okay, some application will build, or we don't care to check.  Still
2331   # notify of subdirs not getting built.
2332   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2333   echo "    ${notsupp}" 1>&2
2334   echo "    (Any other directories should still work fine.)" 1>&2
2335 fi
2336
2337 case "$host" in
2338   *msdosdjgpp*)
2339     enable_gdbtk=no ;;
2340 esac
2341
2342 # To find our prefix, in gcc_cv_tool_prefix.
2343 ACX_TOOL_DIRS
2344
2345 copy_dirs=
2346
2347 AC_ARG_WITH([build-sysroot],
2348   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2349                   [use sysroot as the system root during the build])],
2350   [if test x"$withval" != x ; then
2351      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2352    fi],
2353   [SYSROOT_CFLAGS_FOR_TARGET=])
2354 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2355
2356 AC_ARG_WITH([debug-prefix-map],
2357   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2358                   [map A to B, C to D ... in debug information])],
2359   [if test x"$withval" != x; then
2360      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2361      for debug_map in $withval; do
2362        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2363      done
2364    fi],
2365   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2366 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2367
2368 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2369 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2370 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2371 # We want to ensure that TARGET libraries (which we know are built with
2372 # gcc) are built with "-O2 -g", so include those options when setting
2373 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2374 if test "x$CFLAGS_FOR_TARGET" = x; then
2375   if test "x${is_cross_compiler}" = xyes; then
2376     CFLAGS_FOR_TARGET="-g -O2"
2377   else
2378     CFLAGS_FOR_TARGET=$CFLAGS
2379     case " $CFLAGS " in
2380       *" -O2 "*) ;;
2381       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2382     esac
2383     case " $CFLAGS " in
2384       *" -g "* | *" -g3 "*) ;;
2385       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2386     esac
2387   fi
2388 fi
2389 AC_SUBST(CFLAGS_FOR_TARGET)
2390
2391 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2392   if test "x${is_cross_compiler}" = xyes; then
2393     CXXFLAGS_FOR_TARGET="-g -O2"
2394   else
2395     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2396     case " $CXXFLAGS " in
2397       *" -O2 "*) ;;
2398       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2399     esac
2400     case " $CXXFLAGS " in
2401       *" -g "* | *" -g3 "*) ;;
2402       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2403     esac
2404   fi
2405 fi
2406 AC_SUBST(CXXFLAGS_FOR_TARGET)
2407
2408 AC_SUBST(LDFLAGS_FOR_TARGET)
2409
2410 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2411 # the named directory are copied to $(tooldir)/sys-include.
2412 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2413   if test x${is_cross_compiler} = xno ; then
2414     echo 1>&2 '***' --with-headers is only supported when cross compiling
2415     exit 1
2416   fi
2417   if test x"${with_headers}" != xyes ; then
2418     x=${gcc_cv_tool_prefix}
2419     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2420   fi
2421 fi
2422
2423 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2424 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2425 # are permitted.
2426 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2427   if test x${is_cross_compiler} = xno ; then
2428     echo 1>&2 '***' --with-libs is only supported when cross compiling
2429     exit 1
2430   fi
2431   if test x"${with_libs}" != xyes ; then
2432     # Copy the libraries in reverse order, so that files in the first named
2433     # library override files in subsequent libraries.
2434     x=${gcc_cv_tool_prefix}
2435     for l in ${with_libs}; do
2436       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2437     done
2438   fi
2439 fi
2440
2441 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2442 #
2443 # This is done by determining whether or not the appropriate directory
2444 # is available, and by checking whether or not specific configurations
2445 # have requested that this magic not happen.
2446 #
2447 # The command line options always override the explicit settings in
2448 # configure.ac, and the settings in configure.ac override this magic.
2449 #
2450 # If the default for a toolchain is to use GNU as and ld, and you don't
2451 # want to do that, then you should use the --without-gnu-as and
2452 # --without-gnu-ld options for the configure script.  Similarly, if
2453 # the default is to use the included zlib and you don't want to do that,
2454 # you should use the --with-system-zlib option for the configure script.
2455
2456 if test x${use_gnu_as} = x &&
2457    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2458   with_gnu_as=yes
2459   extra_host_args="$extra_host_args --with-gnu-as"
2460 fi
2461
2462 if test x${use_gnu_ld} = x &&
2463    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2464   with_gnu_ld=yes
2465   extra_host_args="$extra_host_args --with-gnu-ld"
2466 fi
2467
2468 if test x${use_included_zlib} = x &&
2469    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2470   :
2471 else
2472   with_system_zlib=yes
2473   extra_host_args="$extra_host_args --with-system-zlib"
2474 fi
2475
2476 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2477 # can detect this case.
2478
2479 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2480   with_newlib=yes
2481   extra_host_args="$extra_host_args --with-newlib"
2482 fi
2483
2484 # Handle ${copy_dirs}
2485 set fnord ${copy_dirs}
2486 shift
2487 while test $# != 0 ; do
2488   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2489     :
2490   else
2491     echo Copying $1 to $2
2492
2493     # Use the install script to create the directory and all required
2494     # parent directories.
2495     if test -d $2 ; then
2496       :
2497     else
2498       echo >config.temp
2499       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2500     fi
2501
2502     # Copy the directory, assuming we have tar.
2503     # FIXME: Should we use B in the second tar?  Not all systems support it.
2504     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2505
2506     # It is the responsibility of the user to correctly adjust all
2507     # symlinks.  If somebody can figure out how to handle them correctly
2508     # here, feel free to add the code.
2509
2510     echo $1 > $2/COPIED
2511   fi
2512   shift; shift
2513 done
2514
2515 # Determine a target-dependent exec_prefix that the installed
2516 # gcc will search in.  Keep this list sorted by triplet, with
2517 # the *-*-osname triplets last.
2518 md_exec_prefix=
2519 case "${target}" in
2520   i[[34567]]86-pc-msdosdjgpp*)
2521     md_exec_prefix=/dev/env/DJDIR/bin
2522     ;;
2523   *-*-hpux* | \
2524   *-*-nto-qnx* | \
2525   *-*-solaris2*)
2526     md_exec_prefix=/usr/ccs/bin
2527     ;;
2528 esac
2529
2530 extra_arflags_for_target=
2531 extra_nmflags_for_target=
2532 extra_ranlibflags_for_target=
2533 target_makefile_frag=/dev/null
2534 case "${target}" in
2535   spu-*-*)
2536     target_makefile_frag="config/mt-spu"
2537     ;;
2538   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2539     target_makefile_frag="config/mt-sde"
2540     ;;
2541   mipsisa*-*-elfoabi*)
2542     target_makefile_frag="config/mt-mips-elfoabi"
2543     ;;
2544   mips*-*-*linux* | mips*-*-gnu*)
2545     target_makefile_frag="config/mt-mips-gnu"
2546     ;;
2547   nios2-*-elf*)
2548     target_makefile_frag="config/mt-nios2-elf"
2549     ;;
2550   *-*-linux-android*)
2551     target_makefile_frag="config/mt-android"
2552     ;;
2553   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2554     target_makefile_frag="config/mt-gnu"
2555     ;;
2556   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2557     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2558     # commands to handle both 32-bit and 64-bit objects.  These flags are
2559     # harmless if we're using GNU nm or ar.
2560     extra_arflags_for_target=" -X32_64"
2561     extra_nmflags_for_target=" -B -X32_64"
2562     ;;
2563 esac
2564
2565 alphaieee_frag=/dev/null
2566 case $target in
2567   alpha*-*-*)
2568     # This just makes sure to use the -mieee option to build target libs.
2569     # This should probably be set individually by each library.
2570     alphaieee_frag="config/mt-alphaieee"
2571     ;;
2572 esac
2573
2574 # If --enable-target-optspace always use -Os instead of -O2 to build
2575 # the target libraries, similarly if it is not specified, use -Os
2576 # on selected platforms.
2577 ospace_frag=/dev/null
2578 case "${enable_target_optspace}:${target}" in
2579   yes:*)
2580     ospace_frag="config/mt-ospace"
2581     ;;
2582   :d30v-*)
2583     ospace_frag="config/mt-d30v"
2584     ;;
2585   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2586     ospace_frag="config/mt-ospace"
2587     ;;
2588   no:* | :*)
2589     ;;
2590   *)
2591     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2592     ;;
2593 esac
2594
2595 # Some systems (e.g., one of the i386-aix systems the gas testers are
2596 # using) don't handle "\$" correctly, so don't use it here.
2597 tooldir='${exec_prefix}'/${target_noncanonical}
2598 build_tooldir=${tooldir}
2599
2600 # Create a .gdbinit file which runs the one in srcdir
2601 # and tells GDB to look there for source files.
2602
2603 if test -r ${srcdir}/.gdbinit ; then
2604   case ${srcdir} in
2605     .) ;;
2606     *) cat > ./.gdbinit <<EOF
2607 # ${NO_EDIT}
2608 dir ${srcdir}
2609 dir .
2610 source ${srcdir}/.gdbinit
2611 EOF
2612     ;;
2613   esac
2614 fi
2615
2616 # Make sure that the compiler is able to generate an executable.  If it
2617 # can't, we are probably in trouble.  We don't care whether we can run the
2618 # executable--we might be using a cross compiler--we only care whether it
2619 # can be created.  At this point the main configure script has set CC.
2620 we_are_ok=no
2621 echo "int main () { return 0; }" > conftest.c
2622 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2623 if test $? = 0 ; then
2624   if test -s conftest || test -s conftest.exe ; then
2625     we_are_ok=yes
2626   fi
2627 fi
2628 case $we_are_ok in
2629   no)
2630     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2631     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2632     rm -f conftest*
2633     exit 1
2634     ;;
2635 esac
2636 rm -f conftest*
2637
2638 # Decide which environment variable is used to find dynamic libraries.
2639 case "${host}" in
2640   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2641   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2642   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2643   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2644 esac
2645
2646 # On systems where the dynamic library environment variable is PATH,
2647 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2648 # built executables to PATH.
2649 if test "$RPATH_ENVVAR" = PATH; then
2650   GCC_SHLIB_SUBDIR=/shlib
2651 else
2652   GCC_SHLIB_SUBDIR=
2653 fi
2654
2655 # Adjust the toplevel makefile according to whether bootstrap was selected.
2656 case $enable_bootstrap in
2657   yes)
2658     bootstrap_suffix=bootstrap
2659     BUILD_CONFIG=bootstrap-debug
2660     ;;
2661   no)
2662     bootstrap_suffix=no-bootstrap
2663     BUILD_CONFIG=
2664     ;;
2665 esac
2666
2667 AC_MSG_CHECKING(for default BUILD_CONFIG)
2668
2669 AC_ARG_WITH([build-config],
2670   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2671                   [use config/NAME.mk build configuration])],
2672   [case $with_build_config in
2673    yes) with_build_config= ;;
2674    no) with_build_config= BUILD_CONFIG= ;;
2675    esac])
2676
2677 if test "x${with_build_config}" != x; then
2678   BUILD_CONFIG=$with_build_config
2679 else
2680   case $BUILD_CONFIG in
2681   bootstrap-debug)
2682     if echo "int f (void) { return 0; }" > conftest.c &&
2683        ${CC} -c conftest.c &&
2684        mv conftest.o conftest.o.g0 &&
2685        ${CC} -c -g conftest.c &&
2686        mv conftest.o conftest.o.g &&
2687        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2688       :
2689     else
2690       BUILD_CONFIG=
2691     fi
2692     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2693     ;;
2694   esac
2695 fi
2696 AC_MSG_RESULT($BUILD_CONFIG)
2697 AC_SUBST(BUILD_CONFIG)
2698
2699 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2700 AC_MSG_CHECKING([for --enable-vtable-verify])
2701 AC_ARG_ENABLE(vtable-verify,
2702 [AS_HELP_STRING([--enable-vtable-verify],
2703                 [Enable vtable verification feature])],
2704 [case "$enableval" in
2705  yes) enable_vtable_verify=yes ;;
2706  no)  enable_vtable_verify=no ;;
2707  *)   enable_vtable_verify=no;;
2708  esac],
2709 [enable_vtable_verify=no])
2710 AC_MSG_RESULT($enable_vtable_verify)
2711
2712 # Record target_configdirs and the configure arguments for target and
2713 # build configuration in Makefile.
2714 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2715 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2716 bootstrap_fixincludes=no
2717
2718 # If we are building libgomp, bootstrap it.
2719 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2720   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2721 fi
2722
2723 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2724 # or bootstrap-ubsan, bootstrap it.
2725 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2726   case "$BUILD_CONFIG" in
2727     *bootstrap-asan* | *bootstrap-ubsan* )
2728       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2729       bootstrap_fixincludes=yes
2730       ;;
2731   esac
2732 fi
2733
2734 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2735 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2736    test "$enable_vtable_verify" != no; then
2737   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2738 fi
2739
2740 # Determine whether gdb needs tk/tcl or not.
2741 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2742 # and in that case we want gdb to be built without tk.  Ugh!
2743 # In fact I believe gdb is the *only* package directly dependent on tk,
2744 # so we should be able to put the 'maybe's in unconditionally and
2745 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2746 # 100% sure that that's safe though.
2747
2748 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2749 case "$enable_gdbtk" in
2750   no)
2751     GDB_TK="" ;;
2752   yes)
2753     GDB_TK="${gdb_tk}" ;;
2754   *)
2755     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2756     # distro.  Eventually someone will fix this and move Insight, nee
2757     # gdbtk to a separate directory.
2758     if test -d ${srcdir}/gdb/gdbtk ; then
2759       GDB_TK="${gdb_tk}"
2760     else
2761       GDB_TK=""
2762     fi
2763     ;;
2764 esac
2765 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2766 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2767
2768 # Strip out unwanted targets.
2769
2770 # While at that, we remove Makefiles if we were started for recursive
2771 # configuration, so that the top-level Makefile reconfigures them,
2772 # like we used to do when configure itself was recursive.
2773
2774 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2775 # but now we're fixing up the Makefile ourselves with the additional
2776 # commands passed to AC_CONFIG_FILES.  Use separate variables
2777 # extrasub-{build,host,target} not because there is any reason to split
2778 # the substitutions up that way, but only to remain below the limit of
2779 # 99 commands in a script, for HP-UX sed.
2780
2781 # Do not nest @if/@endif or @unless/@endunless pairs, because
2782 # configure will not warn you at all.
2783
2784 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2785   yes:yes:*\ gold\ *:*,c++,*) ;;
2786   yes:yes:*\ gold\ *:*)
2787     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2788     ;;
2789 esac
2790
2791 extrasub_build=
2792 for module in ${build_configdirs} ; do
2793   if test -z "${no_recursion}" \
2794      && test -f ${build_subdir}/${module}/Makefile; then
2795     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2796     rm -f ${build_subdir}/${module}/Makefile
2797   fi
2798   extrasub_build="$extrasub_build
2799 /^@if build-$module\$/d
2800 /^@endif build-$module\$/d
2801 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2802 /^@if build-$module-$bootstrap_suffix\$/d
2803 /^@endif build-$module-$bootstrap_suffix\$/d
2804 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2805 done
2806 extrasub_host=
2807 for module in ${configdirs} ; do
2808   if test -z "${no_recursion}"; then
2809     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2810       if test -f ${file}; then
2811         echo 1>&2 "*** removing ${file} to force reconfigure"
2812         rm -f ${file}
2813       fi
2814     done
2815   fi
2816   case ${module},${bootstrap_fixincludes} in
2817     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2818     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2819   esac
2820   extrasub_host="$extrasub_host
2821 /^@if $module\$/d
2822 /^@endif $module\$/d
2823 /^@unless $module\$/,/^@endunless $module\$/d
2824 /^@if $module-$host_bootstrap_suffix\$/d
2825 /^@endif $module-$host_bootstrap_suffix\$/d
2826 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2827 done
2828 extrasub_target=
2829 for module in ${target_configdirs} ; do
2830   if test -z "${no_recursion}" \
2831      && test -f ${target_subdir}/${module}/Makefile; then
2832     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2833     rm -f ${target_subdir}/${module}/Makefile
2834   fi
2835
2836   # We only bootstrap target libraries listed in bootstrap_target_libs.
2837   case $bootstrap_target_libs in
2838     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2839     *) target_bootstrap_suffix=no-bootstrap ;;
2840   esac
2841
2842   extrasub_target="$extrasub_target
2843 /^@if target-$module\$/d
2844 /^@endif target-$module\$/d
2845 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2846 /^@if target-$module-$target_bootstrap_suffix\$/d
2847 /^@endif target-$module-$target_bootstrap_suffix\$/d
2848 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2849 done
2850
2851 # Do the final fixup along with target modules.
2852 extrasub_target="$extrasub_target
2853 /^@if /,/^@endif /d
2854 /^@unless /d
2855 /^@endunless /d"
2856
2857 # Create the serialization dependencies.  This uses a temporary file.
2858
2859 AC_ARG_ENABLE([serial-configure],
2860 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2861                 [force sequential configuration of
2862                  sub-packages for the host, target or build
2863                  machine, or all sub-packages])])
2864
2865 case ${enable_serial_configure} in
2866   yes)
2867     enable_serial_build_configure=yes
2868     enable_serial_host_configure=yes
2869     enable_serial_target_configure=yes
2870     ;;
2871 esac
2872
2873 # These force 'configure's to be done one at a time, to avoid problems
2874 # with contention over a shared config.cache.
2875 rm -f serdep.tmp
2876 echo '# serdep.tmp' > serdep.tmp
2877 olditem=
2878 test "x${enable_serial_build_configure}" = xyes &&
2879 for item in ${build_configdirs} ; do
2880   case ${olditem} in
2881     "") ;;
2882     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2883   esac
2884   olditem=${item}
2885 done
2886 olditem=
2887 test "x${enable_serial_host_configure}" = xyes &&
2888 for item in ${configdirs} ; do
2889   case ${olditem} in
2890     "") ;;
2891     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2892   esac
2893   olditem=${item}
2894 done
2895 olditem=
2896 test "x${enable_serial_target_configure}" = xyes &&
2897 for item in ${target_configdirs} ; do
2898   case ${olditem} in
2899     "") ;;
2900     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2901   esac
2902   olditem=${item}
2903 done
2904 serialization_dependencies=serdep.tmp
2905 AC_SUBST_FILE(serialization_dependencies)
2906
2907 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2908 # target, nonopt, and variable assignments.  These are the ones we
2909 # might not want to pass down to subconfigures.  The exception being
2910 # --cache-file=/dev/null, which is used to turn off the use of cache
2911 # files altogether, and which should be passed on to subconfigures.
2912 # Also strip program-prefix, program-suffix, and program-transform-name,
2913 # so that we can pass down a consistent program-transform-name.
2914 baseargs=
2915 tbaseargs=
2916 keep_next=no
2917 skip_next=no
2918 eval "set -- $ac_configure_args"
2919 for ac_arg
2920 do
2921   if test X"$skip_next" = X"yes"; then
2922     skip_next=no
2923     continue
2924   fi
2925   if test X"$keep_next" = X"yes"; then
2926     case $ac_arg in
2927       *\'*)
2928         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2929     esac
2930     baseargs="$baseargs '$ac_arg'"
2931     tbaseargs="$tbaseargs '$ac_arg'"
2932     keep_next=no
2933     continue
2934   fi
2935
2936   # Handle separated arguments.  Based on the logic generated by
2937   # autoconf 2.59.
2938   case $ac_arg in
2939     *=* | --config-cache | -C | -disable-* | --disable-* \
2940       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2941       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2942       | -with-* | --with-* | -without-* | --without-* | --x)
2943       separate_arg=no
2944       ;;
2945     -*)
2946       separate_arg=yes
2947       ;;
2948     *)
2949       separate_arg=no
2950       ;;
2951   esac
2952
2953   skip_targ=no
2954   case $ac_arg in
2955 changequote(,)
2956   --with-* | --without-*)
2957     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2958
2959     case $libopt in
2960     *[-_]include)
2961       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2962       ;;
2963     *[-_]lib)
2964       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2965       ;;
2966     *)
2967       lib=$libopt
2968       ;;
2969     esac
2970 changequote([,])
2971
2972     case $lib in
2973     mpc | mpfr | gmp | isl)
2974       # If we're processing --with-$lib, --with-$lib-include or
2975       # --with-$lib-lib, for one of the libs above, and target is
2976       # different from host, don't pass the current argument to any
2977       # target library's configure.
2978       if test x$is_cross_compiler = xyes; then
2979         skip_targ=yes
2980       fi
2981       ;;
2982     esac
2983     ;;
2984   esac
2985
2986   case "$ac_arg" in
2987     --cache-file=/dev/null | \
2988     -cache-file=/dev/null )
2989       # Handled here to avoid the test to skip args below.
2990       baseargs="$baseargs '$ac_arg'"
2991       tbaseargs="$tbaseargs '$ac_arg'"
2992       # Assert: $separate_arg should always be no.
2993       keep_next=$separate_arg
2994       ;;
2995     --no*)
2996       continue
2997       ;;
2998     --c* | \
2999     --sr* | \
3000     --ho* | \
3001     --bu* | \
3002     --t* | \
3003     --program-* | \
3004     -cache_file* | \
3005     -srcdir* | \
3006     -host* | \
3007     -build* | \
3008     -target* | \
3009     -program-prefix* | \
3010     -program-suffix* | \
3011     -program-transform-name* )
3012       skip_next=$separate_arg
3013       continue
3014       ;;
3015     -*)
3016       # An option.  Add it.
3017       case $ac_arg in
3018         *\'*)
3019           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3020       esac
3021       baseargs="$baseargs '$ac_arg'"
3022       if test X"$skip_targ" = Xno; then
3023         tbaseargs="$tbaseargs '$ac_arg'"
3024       fi
3025       keep_next=$separate_arg
3026       ;;
3027     *)
3028       # Either a variable assignment, or a nonopt (triplet).  Don't
3029       # pass it down; let the Makefile handle this.
3030       continue
3031       ;;
3032   esac
3033 done
3034 # Remove the initial space we just introduced and, as these will be
3035 # expanded by make, quote '$'.
3036 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3037
3038 # Add in --program-transform-name, after --program-prefix and
3039 # --program-suffix have been applied to it.  Autoconf has already
3040 # doubled dollar signs and backslashes in program_transform_name; we want
3041 # the backslashes un-doubled, and then the entire thing wrapped in single
3042 # quotes, because this will be expanded first by make and then by the shell.
3043 # Also, because we want to override the logic in subdir configure scripts to
3044 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3045 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3046 ${program_transform_name}
3047 EOF_SED
3048 gcc_transform_name=`cat conftestsed.out`
3049 rm -f conftestsed.out
3050 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3051 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3052 if test "$silent" = yes; then
3053   baseargs="$baseargs --silent"
3054   tbaseargs="$tbaseargs --silent"
3055 fi
3056 baseargs="$baseargs --disable-option-checking"
3057 tbaseargs="$tbaseargs --disable-option-checking"
3058
3059 # Record and document user additions to sub configure arguments.
3060 AC_ARG_VAR([build_configargs],
3061            [additional configure arguments for build directories])
3062 AC_ARG_VAR([host_configargs],
3063            [additional configure arguments for host directories])
3064 AC_ARG_VAR([target_configargs],
3065            [additional configure arguments for target directories])
3066
3067 # For the build-side libraries, we just need to pretend we're native,
3068 # and not use the same cache file.  Multilibs are neither needed nor
3069 # desired.  We can't even use the same cache file for all build-side
3070 # libraries, as they're compiled differently; some with C, some with
3071 # C++ or with different feature-enabling options.
3072 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3073
3074 # For host modules, accept cache file option, or specification as blank.
3075 case "${cache_file}" in
3076 "") # empty
3077   cache_file_option="" ;;
3078 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3079   cache_file_option="--cache-file=${cache_file}" ;;
3080 *) # relative path
3081   cache_file_option="--cache-file=../${cache_file}" ;;
3082 esac
3083
3084 # Host dirs don't like to share a cache file either, horribly enough.
3085 # This seems to be due to autoconf 2.5x stupidity.
3086 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3087
3088 target_configargs="$target_configargs ${tbaseargs}"
3089
3090 # Passing a --with-cross-host argument lets the target libraries know
3091 # whether they are being built with a cross-compiler or being built
3092 # native.  However, it would be better to use other mechanisms to make the
3093 # sorts of decisions they want to make on this basis.  Please consider
3094 # this option to be deprecated.  FIXME.
3095 if test x${is_cross_compiler} = xyes ; then
3096   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3097 fi
3098
3099 # Special user-friendly check for native x86_64-linux build, if
3100 # multilib is not explicitly enabled.
3101 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3102   x86_64-*linux*:yes:$build:$build:)
3103     # Make sure we have a development environment that handles 32-bit
3104     dev64=no
3105     echo "int main () { return 0; }" > conftest.c
3106     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3107     if test $? = 0 ; then
3108       if test -s conftest || test -s conftest.exe ; then
3109         dev64=yes
3110       fi
3111     fi
3112     rm -f conftest*
3113     if test x${dev64} != xyes ; then
3114       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3115     fi
3116     ;;
3117 esac
3118
3119 # Default to --enable-multilib.
3120 if test x${enable_multilib} = x ; then
3121   target_configargs="--enable-multilib ${target_configargs}"
3122 fi
3123
3124 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3125 # changed from the earlier setting of with_newlib.
3126 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3127   target_configargs="--with-newlib ${target_configargs}"
3128 fi
3129
3130 # Different target subdirs use different values of certain variables
3131 # (notably CXX).  Worse, multilibs use *lots* of different values.
3132 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3133 # it doesn't automatically accept command-line overrides of them.
3134 # This means it's not safe for target subdirs to share a cache file,
3135 # which is disgusting, but there you have it.  Hopefully this can be
3136 # fixed in future.  It's still worthwhile to use a cache file for each
3137 # directory.  I think.
3138
3139 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3140 # We need to pass --target, as newer autoconf's requires consistency
3141 # for target_alias and gcc doesn't manage it consistently.
3142 target_configargs="--cache-file=./config.cache ${target_configargs}"
3143
3144 FLAGS_FOR_TARGET=
3145 case " $target_configdirs " in
3146  *" newlib "*)
3147   case " $target_configargs " in
3148   *" --with-newlib "*)
3149    case "$target" in
3150     *-cygwin*)
3151       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3152       ;;
3153    esac
3154
3155    # If we're not building GCC, don't discard standard headers.
3156    if test -d ${srcdir}/gcc; then
3157      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3158
3159      if test "${build}" != "${host}"; then
3160        # On Canadian crosses, CC_FOR_TARGET will have already been set
3161        # by `configure', so we won't have an opportunity to add -Bgcc/
3162        # to it.  This is right: we don't want to search that directory
3163        # for binaries, but we want the header files in there, so add
3164        # them explicitly.
3165        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3166
3167        # Someone might think of using the pre-installed headers on
3168        # Canadian crosses, in case the installed compiler is not fully
3169        # compatible with the compiler being built.  In this case, it
3170        # would be better to flag an error than risking having
3171        # incompatible object files being constructed.  We can't
3172        # guarantee that an error will be flagged, but let's hope the
3173        # compiler will do it, when presented with incompatible header
3174        # files.
3175      fi
3176    fi
3177
3178    case "${target}-${is_cross_compiler}" in
3179    i[[3456789]]86-*-linux*-no)
3180       # Here host == target, so we don't need to build gcc,
3181       # so we don't want to discard standard headers.
3182       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3183       ;;
3184    *)
3185       # If we're building newlib, use its generic headers last, but search
3186       # for any libc-related directories first (so make it the last -B
3187       # switch).
3188       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3189
3190       # If we're building libgloss, find the startup file, simulator library
3191       # and linker script.
3192       case " $target_configdirs " in
3193         *" libgloss "*)
3194         # Look for startup file, simulator library and maybe linker script.
3195         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3196         # Look for libnosys.a in case the target needs it.
3197         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3198         # Most targets have the linker script in the source directory.
3199         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3200         ;;
3201       esac
3202       ;;
3203    esac
3204    ;;
3205   esac
3206   ;;
3207 esac
3208
3209 case "$target" in
3210   x86_64-*mingw* | *-w64-mingw*)
3211   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3212   # however, use a symlink named 'mingw' in ${prefix} .
3213     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3214     ;;
3215   *-mingw*)
3216   # MinGW can't be handled as Cygwin above since it does not use newlib.
3217     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3218     ;;
3219 esac
3220
3221 # Allow the user to override the flags for
3222 # our build compiler if desired.
3223 if test x"${build}" = x"${host}" ; then
3224   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3225   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3226   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3227 fi
3228
3229 # On Canadian crosses, we'll be searching the right directories for
3230 # the previously-installed cross compiler, so don't bother to add
3231 # flags for directories within the install tree of the compiler
3232 # being built; programs in there won't even run.
3233 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3234   # Search for pre-installed headers if nothing else fits.
3235   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3236 fi
3237
3238 if test "x${use_gnu_ld}" = x &&
3239    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3240   # Arrange for us to find uninstalled linker scripts.
3241   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3242 fi
3243
3244 # Search for other target-specific linker scripts and such.
3245 case "${target}" in
3246   mep*)
3247     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3248     ;;
3249 esac
3250
3251 # Makefile fragments.
3252 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3253 do
3254   eval fragval=\$$frag
3255   if test $fragval != /dev/null; then
3256     eval $frag=${srcdir}/$fragval
3257   fi
3258 done
3259 AC_SUBST_FILE(host_makefile_frag)
3260 AC_SUBST_FILE(target_makefile_frag)
3261 AC_SUBST_FILE(alphaieee_frag)
3262 AC_SUBST_FILE(ospace_frag)
3263
3264 # Miscellanea: directories, flags, etc.
3265 AC_SUBST(RPATH_ENVVAR)
3266 AC_SUBST(GCC_SHLIB_SUBDIR)
3267 AC_SUBST(tooldir)
3268 AC_SUBST(build_tooldir)
3269 AC_SUBST(CONFIGURE_GDB_TK)
3270 AC_SUBST(GDB_TK)
3271 AC_SUBST(INSTALL_GDB_TK)
3272
3273 # Build module lists & subconfigure args.
3274 AC_SUBST(build_configargs)
3275 AC_SUBST(build_configdirs)
3276
3277 # Host module lists & subconfigure args.
3278 AC_SUBST(host_configargs)
3279 AC_SUBST(configdirs)
3280 AC_SUBST(target_configdirs)
3281
3282 # Target module lists & subconfigure args.
3283 AC_SUBST(target_configargs)
3284
3285
3286 # Build tools.
3287 AC_SUBST(AR_FOR_BUILD)
3288 AC_SUBST(AS_FOR_BUILD)
3289 AC_SUBST(CC_FOR_BUILD)
3290 AC_SUBST(CFLAGS_FOR_BUILD)
3291 AC_SUBST(CXXFLAGS_FOR_BUILD)
3292 AC_SUBST(CXX_FOR_BUILD)
3293 AC_SUBST(DLLTOOL_FOR_BUILD)
3294 AC_SUBST(GFORTRAN_FOR_BUILD)
3295 AC_SUBST(GOC_FOR_BUILD)
3296 AC_SUBST(GDC_FOR_BUILD)
3297 AC_SUBST(LDFLAGS_FOR_BUILD)
3298 AC_SUBST(LD_FOR_BUILD)
3299 AC_SUBST(NM_FOR_BUILD)
3300 AC_SUBST(RANLIB_FOR_BUILD)
3301 AC_SUBST(WINDMC_FOR_BUILD)
3302 AC_SUBST(WINDRES_FOR_BUILD)
3303
3304 # Generate default definitions for YACC, M4, LEX and other programs that run
3305 # on the build machine.  These are used if the Makefile can't locate these
3306 # programs in objdir.
3307 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3308
3309 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3310 case " $build_configdirs " in
3311   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3312 esac
3313
3314 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3315 case " $build_configdirs " in
3316   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3317 esac
3318
3319 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3320 case " $build_configdirs " in
3321   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3322 esac
3323
3324 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3325 case " $build_configdirs " in
3326   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3327   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3328 esac
3329
3330 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3331 case " $build_configdirs " in
3332   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3333 esac
3334
3335 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3336 case " $build_configdirs " in
3337   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3338   *)
3339 changequote(,)
3340     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3341     # higher, else we use the "missing" dummy.
3342     if ${MAKEINFO} --version \
3343        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3344       :
3345     else
3346       MAKEINFO="$MISSING makeinfo"
3347     fi
3348     ;;
3349 changequote([,])
3350 esac
3351
3352 # FIXME: expect and dejagnu may become build tools?
3353
3354 AC_CHECK_PROGS(EXPECT, expect, expect)
3355 case " $configdirs " in
3356   *" expect "*)
3357     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3358     ;;
3359 esac
3360
3361 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3362 case " $configdirs " in
3363   *" dejagnu "*)
3364     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3365     ;;
3366 esac
3367
3368
3369 # Host tools.
3370 NCN_STRICT_CHECK_TOOLS(AR, ar)
3371 NCN_STRICT_CHECK_TOOLS(AS, as)
3372 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3373 NCN_STRICT_CHECK_TOOLS(LD, ld)
3374 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3375 NCN_STRICT_CHECK_TOOLS(NM, nm)
3376 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3377 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3378 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3379 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3380 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3381 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3382 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3383 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3384 AC_SUBST(CC)
3385 AC_SUBST(CXX)
3386 AC_SUBST(CFLAGS)
3387 AC_SUBST(CXXFLAGS)
3388
3389 # Target tools.
3390 AC_ARG_WITH([build-time-tools],
3391   [AS_HELP_STRING([--with-build-time-tools=PATH],
3392                   [use given path to find target tools during the build])],
3393   [case x"$withval" in
3394      x/*) ;;
3395      *)
3396        with_build_time_tools=
3397        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3398        ;;
3399    esac],
3400   [with_build_time_tools=])
3401
3402 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3403 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3404 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3405 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3406 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3407 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3408
3409 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3410 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3411 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3412 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3413 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3414 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3415 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3416 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3417 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3418 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3419 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3420 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3421 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3422 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3423
3424 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3425
3426 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3427 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3428 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3429 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3430 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3431                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3432                 c++)
3433 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3434                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3435                 c++)
3436 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3437 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3438 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3439                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3440 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3441                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3442 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3443                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3444 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3445 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3446 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3447 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3448 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3449 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3450 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3451 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3452 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3453 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3454 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3455
3456 AC_SUBST(FLAGS_FOR_TARGET)
3457 AC_SUBST(RAW_CXX_FOR_TARGET)
3458
3459 # Certain tools may need extra flags.
3460 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3461 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3462 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3463
3464 # When building target libraries, except in a Canadian cross, we use
3465 # the same toolchain as the compiler we just built.
3466 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3467 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3468 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3469 if test $host = $build; then
3470   case " $configdirs " in
3471     *" gcc "*)
3472       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3473       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3474       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3475       ;;
3476   esac
3477 fi
3478
3479 AC_SUBST(COMPILER_AS_FOR_TARGET)
3480 AC_SUBST(COMPILER_LD_FOR_TARGET)
3481 AC_SUBST(COMPILER_NM_FOR_TARGET)
3482
3483 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3484 AC_ARG_ENABLE(maintainer-mode,
3485 [AS_HELP_STRING([--enable-maintainer-mode],
3486                 [enable make rules and dependencies not useful
3487                  (and sometimes confusing) to the casual installer])],
3488       USE_MAINTAINER_MODE=$enableval,
3489       USE_MAINTAINER_MODE=no)
3490 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3491 AC_SUBST(MAINTAINER_MODE_TRUE)
3492 AC_SUBST(MAINTAINER_MODE_FALSE)
3493 if test "$USE_MAINTAINER_MODE" = yes; then
3494   MAINTAINER_MODE_TRUE=
3495   MAINTAINER_MODE_FALSE='#'
3496 else
3497   MAINTAINER_MODE_TRUE='#'
3498   MAINTAINER_MODE_FALSE=
3499 fi
3500 MAINT=$MAINTAINER_MODE_TRUE
3501 AC_SUBST(MAINT)dnl
3502
3503 # ---------------------
3504 # GCC bootstrap support
3505 # ---------------------
3506
3507 # Stage specific cflags for build.
3508 stage1_cflags="-g"
3509 case $build in
3510   vax-*-*)
3511     case ${GCC} in
3512       yes) stage1_cflags="-g -Wa,-J" ;;
3513       *) stage1_cflags="-g -J" ;;
3514     esac ;;
3515 esac
3516
3517 AC_SUBST(stage1_cflags)
3518
3519 # Enable --enable-checking in stage1 of the compiler.
3520 AC_ARG_ENABLE(stage1-checking,
3521 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3522                 [choose additional checking for stage1 of the compiler])],
3523 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3524 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3525   # For --disable-checking or implicit --enable-checking=release, avoid
3526   # setting --enable-checking=gc in the default stage1 checking for LTO
3527   # bootstraps.  See PR62077.
3528   case $BUILD_CONFIG in
3529     *lto*)
3530       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3531     *)
3532       stage1_checking=--enable-checking=yes,types;;
3533   esac
3534   if test "x$enable_checking" = x && \
3535      test -d ${srcdir}/gcc && \
3536      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3537     stage1_checking=--enable-checking=yes,types,extra
3538   fi
3539 else
3540   stage1_checking=--enable-checking=$enable_checking,types
3541 fi])
3542 AC_SUBST(stage1_checking)
3543
3544 # Enable -Werror in bootstrap stage2 and later.
3545 AC_ARG_ENABLE(werror,
3546 [AS_HELP_STRING([--enable-werror],
3547                 [enable -Werror in bootstrap stage2 and later])],
3548 [
3549 case ${enable_werror} in
3550   yes) stage2_werror_flag="--enable-werror-always" ;;
3551   *) stage2_werror_flag="" ;;
3552 esac
3553 ],
3554 [
3555 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3556   case $BUILD_CONFIG in
3557   bootstrap-debug)
3558       stage2_werror_flag="--enable-werror-always" ;;
3559   "")
3560       stage2_werror_flag="--enable-werror-always" ;;
3561   esac
3562 fi
3563 ])
3564
3565 AC_SUBST(stage2_werror_flag)
3566
3567 # Specify what files to not compare during bootstrap.
3568
3569 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3570 case "$target" in
3571   hppa*64*-*-hpux*) ;;
3572   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3573   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3574 esac
3575 AC_SUBST(compare_exclusions)
3576
3577 AC_CONFIG_FILES([Makefile],
3578   [sed "$extrasub_build" Makefile |
3579    sed "$extrasub_host" |
3580    sed "$extrasub_target" > mf$$
3581    mv -f mf$$ Makefile],
3582   [extrasub_build="$extrasub_build"
3583    extrasub_host="$extrasub_host"
3584    extrasub_target="$extrasub_target"])
3585 AC_OUTPUT