gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(server.cc)
  22 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  23
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_GNU_SOURCE
  29 AC_SYS_LARGEFILE
  30 AM_PROG_INSTALL_STRIP
  31
  32 AC_CANONICAL_SYSTEM
  33
  34 AC_PROG_INSTALL
  35 AC_CHECK_TOOL(AR, ar)
  36 AC_PROG_RANLIB
  37
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 AC_HEADER_STDC
  45
  46 GDB_AC_COMMON
  47 # This is set by GDB_AC_COMMON.
  48 AC_SUBST(WIN32APILIBS)
  49
  50 GDB_AC_SELFTEST
  51
  52 ACX_NONCANONICAL_TARGET
  53 ACX_NONCANONICAL_HOST
  54
  55 # Dependency checking.
  56 ZW_CREATE_DEPDIR
  57
  58 dnl Set up for gettext.
  59 ZW_GNU_GETTEXT_SISTER_DIR
  60
  61 # Create sub-directories for objects and dependencies.
  62 CONFIG_SRC_SUBDIR="arch gdbsupport nat target"
  63 AC_SUBST(CONFIG_SRC_SUBDIR)
  64
  65 AC_CONFIG_COMMANDS([gdbdepdir],[
  66   for subdir in ${CONFIG_SRC_SUBDIR}
  67   do
  68       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  69   done],
  70   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  71
  72 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  73
  74 AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl
  75                  sys/procfs.h linux/elf.h dnl
  76                  fcntl.h signal.h sys/file.h dnl
  77                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  78                  netinet/tcp.h arpa/inet.h)
  79 AC_FUNC_FORK
  80 AC_CHECK_FUNCS(pread pwrite pread64)
  81
  82 # Check the return and argument types of ptrace.
  83 GDB_AC_PTRACE
  84
  85 # Check for UST
  86 ustlibs=""
  87 ustinc=""
  88
  89 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
  90                           Equivalent to --with-ust-include=PATH/include
  91                           plus --with-ust-lib=PATH/lib])
  92 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
  93 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
  94
  95 case $with_ust in
  96   no)
  97     ustlibs=
  98     ustinc=
  99     ;;
 100   "" | yes)
 101     ustlibs=" -lust "
 102     ustinc=""
 103     ;;
 104   *)
 105     ustlibs="-L$with_ust/lib -lust"
 106     ustinc="-I$with_ust/include "
 107     ;;
 108 esac
 109 if test "x$with_ust_include" != x; then
 110   ustinc="-I$with_ust_include "
 111 fi
 112 if test "x$with_ust_lib" != x; then
 113   ustlibs="-L$with_ust_lib -lust"
 114 fi
 115
 116 if test "x$with_ust" != "xno"; then
 117   saved_CFLAGS="$CFLAGS"
 118   CFLAGS="$CFLAGS $ustinc"
 119   AC_MSG_CHECKING([for ust])
 120   AC_TRY_COMPILE([
 121 #define CONFIG_UST_GDB_INTEGRATION
 122 #include <ust/ust.h>
 123   ],[],
 124   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 125   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 126   CFLAGS="$saved_CFLAGS"
 127 fi
 128
 129 # Flags needed for UST
 130 AC_SUBST(ustlibs)
 131 AC_SUBST(ustinc)
 132
 133 AM_GDB_WARNINGS
 134
 135 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 136 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 137 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 138 dnl augment LIBS.
 139 old_LIBS="$LIBS"
 140 LIBS="$LIBS -ldl"
 141 AC_CHECK_FUNCS(dladdr)
 142 LIBS="$old_LIBS"
 143
 144 libiberty_INIT
 145
 146 AC_CHECK_DECLS([perror, vasprintf, vsnprintf])
 147
 148 AC_CHECK_TYPES(socklen_t, [], [],
 149 [#include <sys/types.h>
 150 #include <sys/socket.h>
 151 ])
 152
 153 case "${target}" in
 154   *-android*)
 155     # Starting with NDK version 9, <elf.h> actually includes definitions
 156     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 157     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 158     # leading to conflicts with the defintions from <linux/elf.h>.
 159     # This makes it impossible for us to include both <elf.h> and
 160     # <linux/elf.h>, which means that, in practice, we do not have
 161     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 162     # Therefore, do not try to auto-detect availability, as it would
 163     # get it wrong on this platform.
 164     ;;
 165   *)
 166     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 167     #include <elf.h>
 168     )
 169 esac
 170
 171 ACX_PKGVERSION([GDB])
 172 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 173 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 174 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 175
 176 # Check for various supplementary target information (beyond the
 177 # triplet) which might affect the choices in configure.srv.
 178 case "${target}" in
 179 changequote(,)dnl
 180   i[34567]86-*-linux*)
 181 changequote([,])dnl
 182     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 183                    [save_CPPFLAGS="$CPPFLAGS"
 184                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 185                     AC_EGREP_CPP([got it], [
 186 #if __x86_64__
 187 got it
 188 #endif
 189                  ], [gdb_cv_i386_is_x86_64=yes],
 190                     [gdb_cv_i386_is_x86_64=no])
 191                     CPPFLAGS="$save_CPPFLAGS"])
 192     ;;
 193
 194   x86_64-*-linux*)
 195     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 196                    [save_CPPFLAGS="$CPPFLAGS"
 197                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 198                     AC_EGREP_CPP([got it], [
 199 #if __x86_64__ && __ILP32__
 200 got it
 201 #endif
 202                  ], [gdb_cv_x86_is_x32=yes],
 203                     [gdb_cv_x86_is_x32=no])
 204                     CPPFLAGS="$save_CPPFLAGS"])
 205     ;;
 206
 207   m68k-*-*)
 208     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 209                    [save_CPPFLAGS="$CPPFLAGS"
 210                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 211                     AC_EGREP_CPP([got it], [
 212 #ifdef __mcoldfire__
 213 got it
 214 #endif
 215                  ], [gdb_cv_m68k_is_coldfire=yes],
 216                     [gdb_cv_m68k_is_coldfire=no])
 217                     CPPFLAGS="$save_CPPFLAGS"])
 218     ;;
 219 esac
 220
 221 . ${srcdir}/configure.srv
 222
 223 if test "${srv_mingwce}" = "yes"; then
 224   LIBS="$LIBS -lws2"
 225 elif test "${srv_mingw}" = "yes"; then
 226   # WIN32APILIBS is set by GDB_AC_COMMON.
 227   LIBS="$LIBS $WIN32APILIBS"
 228 elif test "${srv_qnx}" = "yes"; then
 229   LIBS="$LIBS -lsocket"
 230 elif test "${srv_lynxos}" = "yes"; then
 231   LIBS="$LIBS -lnetinet"
 232 fi
 233
 234 if test "${srv_linux_usrregs}" = "yes"; then
 235   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 236             [Define if the target supports PTRACE_PEEKUSR for register ]
 237             [access.])
 238 fi
 239
 240 if test "${srv_linux_regsets}" = "yes"; then
 241   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 242             [Define if the target supports register sets.])
 243
 244   AC_MSG_CHECKING(for PTRACE_GETREGS)
 245   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 246   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 247                   [PTRACE_GETREGS;],
 248                   [gdbsrv_cv_have_ptrace_getregs=yes],
 249                   [gdbsrv_cv_have_ptrace_getregs=no])])
 250   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 251   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 252     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 253               [Define if the target supports PTRACE_GETREGS for register ]
 254               [access.])
 255   fi
 256
 257   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 258   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 259   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 260                   [PTRACE_GETFPXREGS;],
 261                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 262                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 263   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 264   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 265     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 266               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 267               [register access.])
 268   fi
 269 fi
 270
 271 if test "${srv_linux_btrace}" = "yes"; then
 272   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 273             [Define if the target supports branch tracing.])
 274 fi
 275
 276 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 277 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 278   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 279 fi
 280
 281 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 282 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 283   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 284 fi
 285
 286 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 287 dnl needs it (and gdbreplay doesn't).
 288 old_LIBS="$LIBS"
 289 AC_CHECK_LIB(dl, dlopen)
 290 LIBS="$old_LIBS"
 291
 292 srv_thread_depfiles=
 293 srv_libs=
 294
 295 if test "$srv_linux_thread_db" = "yes"; then
 296   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 297     srv_libs="-ldl"
 298     AC_MSG_CHECKING(for the dynamic export flag)
 299     old_LDFLAGS="$LDFLAGS"
 300     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 301     # supported there.
 302     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 303     LDFLAGS="$LDFLAGS $RDYNAMIC"
 304     AC_TRY_LINK([], [],
 305                 [found="-Wl,--dynamic-list"
 306                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 307                 [RDYNAMIC="-rdynamic"
 308                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 309                  AC_TRY_LINK([], [],
 310                              [found="-rdynamic"],
 311                              [found="no"
 312                               RDYNAMIC=""])])
 313     AC_SUBST(RDYNAMIC)
 314     LDFLAGS="$old_LDFLAGS"
 315     AC_MSG_RESULT($found)
 316   else
 317     srv_libs="-lthread_db"
 318   fi
 319
 320   srv_thread_depfiles="thread-db.o proc-service.o"
 321   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 322   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 323   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 324                   [gdbsrv_cv_have_td_version=yes],
 325                   [gdbsrv_cv_have_td_version=no])])
 326   if test "$gdbsrv_cv_have_td_version" = yes; then
 327     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 328   fi
 329 fi
 330
 331 AC_ARG_WITH(libthread-db,
 332 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 333 [srv_libthread_db_path="${withval}"
 334   srv_libs="$srv_libthread_db_path"
 335 ])
 336
 337 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 338   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 339 fi
 340
 341 if test "$srv_xmlfiles" != ""; then
 342   srv_xmlbuiltin="xml-builtin.o"
 343   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 344
 345   tmp_xmlfiles=$srv_xmlfiles
 346   srv_xmlfiles=""
 347   for f in $tmp_xmlfiles; do
 348     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 349   done
 350 fi
 351
 352 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles"
 353 GDBSERVER_LIBS="$srv_libs"
 354
 355 dnl Check whether the target supports __sync_*_compare_and_swap.
 356 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 357                 gdbsrv_cv_have_sync_builtins, [
 358 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 359                 gdbsrv_cv_have_sync_builtins=yes,
 360                 gdbsrv_cv_have_sync_builtins=no)])
 361 if test "$gdbsrv_cv_have_sync_builtins" = yes; then
 362   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 363     [Define to 1 if the target supports __sync_*_compare_and_swap])
 364 fi
 365
 366 dnl Check for -fvisibility=hidden support in the compiler.
 367 saved_cflags="$CFLAGS"
 368 CFLAGS="$CFLAGS -fvisibility=hidden"
 369 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 370                         [gdbsrv_cv_have_visibility_hidden=yes],
 371                         [gdbsrv_cv_have_visibility_hidden=no])
 372 CFLAGS="$saved_cflags"
 373
 374 IPA_DEPFILES=""
 375 extra_libraries=""
 376
 377 # check whether to enable the inprocess agent
 378 if test "$ipa_obj" != "" \
 379    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 380    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 381    have_ipa=true
 382 else
 383    have_ipa=false
 384 fi
 385
 386 AC_ARG_ENABLE(inprocess-agent,
 387 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 388 [case "$enableval" in
 389   yes) want_ipa=true ;;
 390   no) want_ipa=false ;;
 391   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 392 esac],
 393 [want_ipa=$have_ipa])
 394
 395 if $want_ipa ; then
 396    if $have_ipa ; then
 397      IPA_DEPFILES="$ipa_obj"
 398      extra_libraries="$extra_libraries libinproctrace.so"
 399    else
 400      AC_MSG_ERROR([inprocess agent not supported for this target])
 401    fi
 402 fi
 403
 404 AC_SUBST(GDBSERVER_DEPFILES)
 405 AC_SUBST(GDBSERVER_LIBS)
 406 AC_SUBST(srv_xmlbuiltin)
 407 AC_SUBST(srv_xmlfiles)
 408 AC_SUBST(IPA_DEPFILES)
 409 AC_SUBST(extra_libraries)
 410
 411 GNULIB=../gnulib/import
 412
 413 GNULIB_STDINT_H=
 414 if test x"$STDINT_H" != x; then
 415   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 416 fi
 417 AC_SUBST(GNULIB_STDINT_H)
 418
 419 AC_CONFIG_FILES([Makefile])
 420
 421 AC_OUTPUT