ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2016 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([ld], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ldmain.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_CANONICAL_BUILD
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_PROG_GREP
  35 AC_GNU_SOURCE
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_PROG_INSTALL
  38
  39 LT_INIT
  40 ACX_LARGEFILE
  41
  42 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  43 AC_ARG_ENABLE(targets,
  44 [  --enable-targets        alternative target configurations],
  45 [case "${enableval}" in
  46   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  47             ;;
  48   no)       enable_targets= ;;
  49   *)        enable_targets=$enableval ;;
  50 esac])dnl
  51 AC_ARG_ENABLE(64-bit-bfd,
  52 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  53 [case "${enableval}" in
  54   yes)  want64=true  ;;
  55   no)   want64=false ;;
  56   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  57 esac],[want64=false])dnl
  58
  59 AC_ARG_WITH(sysroot,
  60 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  61 [
  62  case ${with_sysroot} in
  63  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  64  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  65  esac
  66
  67  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  68  use_sysroot=yes
  69
  70  if test "x$prefix" = xNONE; then
  71   test_prefix=/usr/local
  72  else
  73   test_prefix=$prefix
  74  fi
  75  if test "x$exec_prefix" = xNONE; then
  76   test_exec_prefix=$test_prefix
  77  else
  78   test_exec_prefix=$exec_prefix
  79  fi
  80  case ${TARGET_SYSTEM_ROOT} in
  81  "${test_prefix}"|"${test_prefix}/"*|\
  82  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  83  '${prefix}'|'${prefix}/'*|\
  84  '${exec_prefix}'|'${exec_prefix}/'*)
  85    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  86    TARGET_SYSTEM_ROOT_DEFINE="$t"
  87    ;;
  88  esac
  89 ], [
  90  use_sysroot=no
  91  TARGET_SYSTEM_ROOT=
  92  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  93 ])
  94 AC_SUBST(use_sysroot)
  95 AC_SUBST(TARGET_SYSTEM_ROOT)
  96 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  97
  98 dnl Use --enable-gold to decide if this linker should be the default.
  99 dnl "install_as_default" is set to false if gold is the default linker.
 100 dnl "installed_linker" is the installed BFD linker name.
 101 AC_ARG_ENABLE(gold,
 102 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 103 [case "${enableval}" in
 104  default)
 105    install_as_default=no
 106    installed_linker=ld.bfd
 107    ;;
 108  yes|no)
 109    install_as_default=yes
 110    installed_linker=ld.bfd
 111    ;;
 112  *)
 113    AC_MSG_ERROR([invalid --enable-gold argument])
 114    ;;
 115  esac],
 116 [install_as_default=yes
 117  installed_linker=ld.bfd])
 118 AC_SUBST(install_as_default)
 119 AC_SUBST(installed_linker)
 120
 121 AC_ARG_ENABLE([got],
 122 AS_HELP_STRING([--enable-got=<type>],
 123                [GOT handling scheme (target, single, negative, multigot)]),
 124 [case "${enableval}" in
 125   target | single | negative | multigot)  got_handling=$enableval ;;
 126   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 127 esac],
 128 [got_handling=target])
 129
 130 case "${got_handling}" in
 131   target)
 132     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 133               [Define to choose default GOT handling scheme]) ;;
 134   single)
 135     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 136               [Define to choose default GOT handling scheme]) ;;
 137   negative)
 138     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 139               [Define to choose default GOT handling scheme]) ;;
 140   multigot)
 141     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 142               [Define to choose default GOT handling scheme]) ;;
 143   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 144 esac
 145
 146 # PR gas/19109
 147 # Decide the default method for compressing debug sections.
 148 ac_default_compressed_debug_sections=unset
 149 # Provide a configure time option to override our default.
 150 AC_ARG_ENABLE(compressed_debug_sections,
 151               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 152               [compress debug sections by default])],
 153 [case ,"${enableval}", in
 154   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 155   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 156 esac])dnl
 157
 158 # Decide if -z relro should be enabled in ELF linker by default.
 159 ac_default_ld_z_relro=unset
 160 # Provide a configure time option to override our default.
 161 AC_ARG_ENABLE(relro,
 162               AS_HELP_STRING([--enable-relro],
 163               [enable -z relro in ELF linker by default]),
 164 [case "${enableval}" in
 165   yes)  ac_default_ld_z_relro=1 ;;
 166   no)  ac_default_ld_z_relro=0 ;;
 167 esac])dnl
 168
 169 AM_BINUTILS_WARNINGS
 170
 171 AM_LC_MESSAGES
 172
 173 AC_CONFIG_HEADERS([config.h:config.in])
 174
 175 # PR 14072
 176 AH_VERBATIM([00_CONFIG_H_CHECK],
 177 [/* Check that config.h is #included before system headers
 178    (this works only for glibc, but that should be enough).  */
 179 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 180 #  error config.h must be #included before system headers
 181 #endif
 182 #define __CONFIG_H__ 1])
 183
 184 if test -z "$target" ; then
 185     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 186 fi
 187 if test -z "$host" ; then
 188     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 189 fi
 190
 191 # host-specific stuff:
 192
 193 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it uk"
 194 ZW_GNU_GETTEXT_SISTER_DIR
 195 AM_PO_SUBDIRS
 196
 197 AC_EXEEXT
 198
 199 AC_PROG_YACC
 200 AM_PROG_LEX
 201
 202 AM_MAINTAINER_MODE
 203 AM_CONDITIONAL(GENINSRC_NEVER, false)
 204 ACX_PROG_CMP_IGNORE_INITIAL
 205
 206 . ${srcdir}/configure.host
 207
 208 AC_SUBST(HDEFINES)
 209 AC_SUBST(HOSTING_CRT0)
 210 AC_SUBST(HOSTING_SCRT0)
 211 AC_SUBST(HOSTING_LIBS)
 212 AC_SUBST(HOSTING_SLIBS)
 213 AC_SUBST(NATIVE_LIB_DIRS)
 214
 215 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 216 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 217 ACX_HEADER_STRING
 218 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 219 AC_CHECK_FUNCS(open lseek close)
 220 AC_HEADER_DIRENT
 221
 222 dnl AC_CHECK_HEADERS(sys/mman.h)
 223 AC_FUNC_MMAP
 224
 225 AC_SEARCH_LIBS([dlopen], [dl])
 226 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$plugins = xyes])
 227
 228 AC_ARG_ENABLE(initfini-array,
 229 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 230 [case "${enableval}" in
 231  yes|no) ;;
 232  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 233  esac], [enable_initfini_array=yes])
 234 AC_SUBST(enable_initfini_array)
 235 if test $enable_initfini_array = yes; then
 236   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 237     [Define .init_array/.fini_array sections are available and working.])
 238 fi
 239
 240 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 241 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 242 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 243 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 244 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 245 if test $ld_cv_decl_getopt_unistd_h = yes; then
 246   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 247             [Is the prototype for getopt in <unistd.h> in the expected format?])
 248 fi
 249
 250 BFD_BINARY_FOPEN
 251
 252 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 253
 254 # When converting linker scripts into strings for use in emulation
 255 # files, use astring.sed if the compiler supports ANSI string
 256 # concatenation, or ostring.sed otherwise.  This is to support the
 257 # broken Microsoft MSVC compiler, which limits the length of string
 258 # constants, while still supporting pre-ANSI compilers which do not
 259 # support string concatenation.
 260 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 261 AC_CACHE_VAL(ld_cv_string_concatenation,
 262 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 263   ld_cv_string_concatenation=yes,
 264   ld_cv_string_concatenation=no)])
 265 AC_MSG_RESULT($ld_cv_string_concatenation)
 266 if test "$ld_cv_string_concatenation" = "yes"; then
 267   STRINGIFY=astring.sed
 268 else
 269   STRINGIFY=ostring.sed
 270 fi
 271 AC_SUBST(STRINGIFY)
 272
 273 # target-specific stuff:
 274
 275 all_targets=
 276 EMUL=
 277 all_emuls=
 278 all_emul_extras=
 279 all_libpath=
 280
 281 dnl We need to get an arbitrary number of tdir definitions into
 282 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 283 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 284 dnl file.
 285 rm -f tdirs
 286
 287 # If the host is 64-bit, then we enable 64-bit targets by default.
 288 # This is consistent with what ../bfd/configure.ac does.
 289 if test x${want64} = xfalse; then
 290   AC_CHECK_SIZEOF(void *)
 291   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 292     want64=true
 293   fi
 294 fi
 295
 296 elf_list_options=FALSE
 297 elf_shlib_list_options=FALSE
 298 elf_plt_unwind_list_options=FALSE
 299 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 300 do
 301   if test "$targ_alias" = "all"; then
 302     all_targets=true
 303     elf_list_options=TRUE
 304     elf_shlib_list_options=TRUE
 305     elf_plt_unwind_list_options=TRUE
 306   else
 307     # Canonicalize the secondary target names.
 308     result=`$ac_config_sub $targ_alias 2>/dev/null`
 309     if test -n "$result"; then
 310         targ=$result
 311     else
 312         targ=$targ_alias
 313     fi
 314
 315     . ${srcdir}/configure.tgt
 316
 317     if test "$targ" = "$target"; then
 318       EMUL=$targ_emul
 319     fi
 320
 321     if test x${want64} = xfalse; then
 322       . ${srcdir}/../bfd/config.bfd
 323     fi
 324
 325     if test x${want64} = xtrue; then
 326       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 327       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 328     fi
 329
 330     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 331         case " $all_emuls " in
 332         *" e${i}.o "*) ;;
 333         *)
 334           all_emuls="$all_emuls e${i}.o"
 335           eval result=\$tdir_$i
 336           test -z "$result" && result=$targ_alias
 337           echo tdir_$i=$result >> tdirs
 338           case "${i}" in
 339           *elf*)
 340             elf_list_options=TRUE
 341             ;;
 342           *)
 343             if $GREP "TEMPLATE_NAME=elf32" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 344               elf_list_options=TRUE
 345             fi
 346             ;;
 347           esac
 348           if test "$elf_list_options" = "TRUE"; then
 349             . ${srcdir}/emulparams/${i}.sh
 350             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 351               elf_shlib_list_options=TRUE
 352             fi
 353             if test x${PLT_UNWIND} = xyes; then
 354               elf_plt_unwind_list_options=TRUE
 355             fi
 356           fi
 357           ;;
 358         esac
 359     done
 360
 361     for i in $targ_emul $targ_extra_libpath; do
 362         case " $all_libpath " in
 363         *" ${i} "*) ;;
 364         *)
 365           if test -z "$all_libpath"; then
 366             all_libpath=${i}
 367           else
 368             all_libpath="$all_libpath ${i}"
 369           fi
 370           ;;
 371         esac
 372     done
 373
 374     for i in $targ_extra_ofiles; do
 375         case " $all_emul_extras " in
 376         *" ${i} "*) ;;
 377         *)
 378           all_emul_extras="$all_emul_extras ${i}"
 379           ;;
 380         esac
 381     done
 382
 383   fi
 384 done
 385
 386 if test x$ac_default_compressed_debug_sections = xyes ; then
 387   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 388 fi
 389
 390 if test "${ac_default_ld_z_relro}" = unset; then
 391   ac_default_ld_z_relro=0
 392 fi
 393 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 394   $ac_default_ld_z_relro,
 395   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 396
 397 AC_SUBST(elf_list_options)
 398 AC_SUBST(elf_shlib_list_options)
 399 AC_SUBST(elf_plt_unwind_list_options)
 400 AC_SUBST(EMUL)
 401
 402 TDIRS=tdirs
 403 AC_SUBST_FILE(TDIRS)
 404
 405 if test x${all_targets} = xtrue; then
 406   if test x${want64} = xtrue; then
 407     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 408     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 409   else
 410     EMULATION_OFILES='$(ALL_EMULATIONS)'
 411     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 412   fi
 413 else
 414   EMULATION_OFILES=$all_emuls
 415   EMUL_EXTRA_OFILES=$all_emul_extras
 416 fi
 417 AC_SUBST(EMULATION_OFILES)
 418 AC_SUBST(EMUL_EXTRA_OFILES)
 419 AC_SUBST(LIB_PATH)
 420
 421 EMULATION_LIBPATH=$all_libpath
 422 AC_SUBST(EMULATION_LIBPATH)
 423
 424 if test x${enable_static} = xno; then
 425   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 426 else
 427   TESTBFDLIB="../bfd/.libs/libbfd.a"
 428 fi
 429 AC_SUBST(TESTBFDLIB)
 430
 431 target_vendor=${target_vendor=$host_vendor}
 432 case "$target_vendor" in
 433   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 434   *)  EXTRA_SHLIB_EXTENSION= ;;
 435 esac
 436
 437 case "$target_os" in
 438   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 439 esac
 440
 441 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 442   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 443    [Additional extension a shared object might have.])
 444 fi
 445
 446 dnl Required by html, pdf, install-pdf and install-html
 447 AC_SUBST(datarootdir)
 448 AC_SUBST(docdir)
 449 AC_SUBST(htmldir)
 450 AC_SUBST(pdfdir)
 451
 452 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 453 AC_OUTPUT