ld/ldlex.l

   1 %option nounput noyywrap
   2
   3 %{
   4
   5 /* Copyright (C) 1991-2020 Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "bfd.h"
  26 #include "safe-ctype.h"
  27 #include "bfdlink.h"
  28 #include "ctf-api.h"
  29 #include "ld.h"
  30 #include "ldmisc.h"
  31 #include "ldexp.h"
  32 #include "ldlang.h"
  33 #include <ldgram.h>
  34 #include "ldfile.h"
  35 #include "ldlex.h"
  36 #include "ldmain.h"
  37 #include "libiberty.h"
  38
  39 /* The type of top-level parser input.
  40    yylex and yyparse (indirectly) both check this.  */
  41 input_type parser_input;
  42
  43 /* Line number in the current input file.  */
  44 unsigned int lineno;
  45
  46 /* The string we are currently lexing, or NULL if we are reading a
  47    file.  */
  48 const char *lex_string = NULL;
  49
  50 /* Support for flex reading from more than one input file (stream).
  51    `include_stack' is flex's input state for each open file;
  52    `file_name_stack' is the file names.  `lineno_stack' is the current
  53    line numbers.
  54
  55    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  56    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  57
  58 #undef YY_INPUT
  59 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  60
  61 #ifndef YY_NO_UNPUT
  62 #define YY_NO_UNPUT
  63 #endif
  64
  65 #define MAX_INCLUDE_DEPTH 10
  66 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  67 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  68 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
  70 static unsigned int include_stack_ptr = 0;
  71 static int vers_node_nesting = 0;
  72
  73 static int yy_input (char *, int);
  74 static void comment (void);
  75 static void lex_warn_invalid (char *where, char *what);
  76
  77 /* STATES
  78         EXPRESSION      definitely in an expression
  79         SCRIPT          definitely in a script
  80         INPUTLIST       definitely in a script, a filename-list
  81         BOTH            either EXPRESSION or SCRIPT
  82         DEFSYMEXP       in an argument to -defsym
  83         MRI             in an MRI script
  84         VERS_START      starting a Sun style mapfile
  85         VERS_SCRIPT     a Sun style mapfile
  86         VERS_NODE       a node within a Sun style mapfile
  87 */
  88 #define RTOKEN(x)  {  yylval.token = x; return x; }
  89
  90 %}
  91
  92 %a 4000
  93 %o 5000
  94
  95 WILDCHAR        [_a-zA-Z0-9\/\.\\\$\~\-\+\:\[\]\,\=\?\*\^\!]
  96 FILENAMECHAR    [_a-zA-Z0-9\/\.\\\$\~\-\+\:\[\]\,\=]
  97 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\\\$\~\-\+\:\[\]]
  98 SYMBOLNAMECHAR  [_a-zA-Z0-9\/\.\\\$\~]
  99 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\~]
 100 SYMBOLNAMECHAR1 [_a-zA-Z\.\\\$]
 101 WHITE           [ \t\n\r]+
 102
 103 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 104 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 105
 106 %s SCRIPT
 107 %s INPUTLIST
 108 %s EXPRESSION
 109 %s BOTH
 110 %s DEFSYMEXP
 111 %s MRI
 112 %s VERS_START
 113 %s VERS_SCRIPT
 114 %s VERS_NODE
 115 %%
 116
 117   if (parser_input != input_selected)
 118     {
 119       /* The first token of the input determines the initial parser state.  */
 120       input_type t = parser_input;
 121       parser_input = input_selected;
 122       switch (t)
 123         {
 124         case input_script: return INPUT_SCRIPT; break;
 125         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 126         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 127         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 128         case input_defsym: return INPUT_DEFSYM; break;
 129         default: abort ();
 130         }
 131     }
 132
 133 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>"/*" { comment (); }
 134
 135
 136 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 137 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 138 <DEFSYMEXP>{SYMBOLNAMECHAR1}{SYMBOLNAMECHAR}* { yylval.name = xstrdup (yytext);
 139                                                 return NAME; }
 140 <DEFSYMEXP>"="                  { RTOKEN('='); }
 141
 142 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 143                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 144                                 yylval.bigint.str = NULL;
 145                                 return INT;
 146                         }
 147
 148 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 149                                    int ibase ;
 150                                    switch (yytext[yyleng - 1]) {
 151                                     case 'X':
 152                                     case 'x':
 153                                     case 'H':
 154                                     case 'h':
 155                                      ibase = 16;
 156                                      break;
 157                                     case 'O':
 158                                     case 'o':
 159                                      ibase = 8;
 160                                      break;
 161                                     case 'B':
 162                                     case 'b':
 163                                      ibase = 2;
 164                                      break;
 165                                     default:
 166                                      ibase = 10;
 167                                    }
 168                                    yylval.integer = bfd_scan_vma (yytext, 0,
 169                                                                   ibase);
 170                                    yylval.bigint.str = NULL;
 171                                    return INT;
 172                                  }
 173 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 174                                   char *s = yytext;
 175                                   int ibase = 0;
 176
 177                                   if (*s == '$')
 178                                     {
 179                                       ++s;
 180                                       ibase = 16;
 181                                     }
 182                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 183                                   yylval.bigint.str = NULL;
 184                                   if (yytext[yyleng - 1] == 'M'
 185                                       || yytext[yyleng - 1] == 'm')
 186                                     {
 187                                       yylval.integer *= 1024 * 1024;
 188                                     }
 189                                   else if (yytext[yyleng - 1] == 'K'
 190                                       || yytext[yyleng - 1]=='k')
 191                                     {
 192                                       yylval.integer *= 1024;
 193                                     }
 194                                   else if (yytext[0] == '0'
 195                                            && (yytext[1] == 'x'
 196                                                || yytext[1] == 'X'))
 197                                     {
 198                                       yylval.bigint.str = xstrdup (yytext + 2);
 199                                     }
 200                                   return INT;
 201                                 }
 202 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 203 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 204 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 205 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 221 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>","               { RTOKEN(',');}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 236 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>")"               { RTOKEN(')');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>"("               { RTOKEN('(');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 239 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 240 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 241 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 242 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
 243 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 244 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 245 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 246 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 247 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 248 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 249 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 250 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 251 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 252 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 253 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 254 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 255 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 256 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 257 <EXPRESSION,BOTH>"LOG2CEIL"             { RTOKEN(LOG2CEIL); }
 258 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 259 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 260 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 261 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 262 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 263 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 264 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 265 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 266 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 267 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 268 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 269 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 270 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 271 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 272 <EXPRESSION,BOTH,SCRIPT,INPUTLIST>"AS_NEEDED"   { RTOKEN(AS_NEEDED);}
 273 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 274 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 275 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 276 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 277 <BOTH,SCRIPT>"FORCE_GROUP_ALLOCATION"   { RTOKEN(FORCE_GROUP_ALLOCATION);}
 278 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 279 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 280 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 281 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 282 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 283 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 284 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 285 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 286 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 287 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 288 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 289 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 290 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 291 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 292 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 293 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 294 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 295 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 296 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 297 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS_TO" { RTOKEN(NOCROSSREFS_TO);}
 298 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 299 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 300 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 301 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 302 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY"    { RTOKEN(SORT_BY_INIT_PRIORITY); }
 303 <BOTH,SCRIPT>"SORT_NONE"                { RTOKEN(SORT_NONE); }
 304 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 305 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 306 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 307 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 308 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 309 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 310 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 311 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 312 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 313 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 314 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 315 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 316 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS"   { RTOKEN(INPUT_SECTION_FLAGS); }
 317 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 318 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 319 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 320 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT"      { RTOKEN(ALIGN_WITH_INPUT);}
 321 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 322 <EXPRESSION,BOTH,SCRIPT>"HIDDEN"        { RTOKEN(HIDDEN); }
 323 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 324 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 325 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 326 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 327 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 328 <MRI>"#".*\n?                   { ++ lineno; }
 329 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 330 <MRI>"*".*                      { /* Mri comment line */ }
 331 <MRI>";".*                      { /* Mri comment line */ }
 332 <MRI>"END"                      { RTOKEN(ENDWORD); }
 333 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 334 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 335 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 336 <MRI>"BASE"                     { RTOKEN(BASE); }
 337 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 338 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 339 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 340 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 341 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 342 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 343 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 344 <MRI>"CASE"                     { RTOKEN(CASE); }
 345 <MRI>"START"                    { RTOKEN(START); }
 346 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 347 <MRI>"SECT"                     { RTOKEN(SECT); }
 348 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 349 <MRI>"end"                      { RTOKEN(ENDWORD); }
 350 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 351 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 352 <MRI>"chip"                     { RTOKEN(CHIP); }
 353 <MRI>"base"                     { RTOKEN(BASE); }
 354 <MRI>"alias"                    { RTOKEN(ALIAS); }
 355 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 356 <MRI>"load"                     { RTOKEN(LOAD); }
 357 <MRI>"public"                   { RTOKEN(PUBLIC); }
 358 <MRI>"order"                    { RTOKEN(ORDER); }
 359 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 360 <MRI>"format"                   { RTOKEN(FORMAT); }
 361 <MRI>"case"                     { RTOKEN(CASE); }
 362 <MRI>"extern"                   { RTOKEN(EXTERN); }
 363 <MRI>"start"                    { RTOKEN(START); }
 364 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 365 <MRI>"sect"                     { RTOKEN(SECT); }
 366 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 367
 368 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 369 /* Filename without commas, needed to parse mri stuff */
 370                                   yylval.name = xstrdup (yytext);
 371                                   return NAME;
 372                                 }
 373
 374
 375 <BOTH,INPUTLIST>{FILENAMECHAR1}{FILENAMECHAR}*  {
 376                                   yylval.name = xstrdup (yytext);
 377                                   return NAME;
 378                                 }
 379 <INPUTLIST>"="{FILENAMECHAR1}{FILENAMECHAR}*    {
 380 /* Filename to be prefixed by --sysroot or when non-sysrooted, nothing.  */
 381                                   yylval.name = xstrdup (yytext);
 382                                   return NAME;
 383                                 }
 384 <BOTH,INPUTLIST>"-l"{FILENAMECHAR}+ {
 385                                   yylval.name = xstrdup (yytext + 2);
 386                                   return LNAME;
 387                                 }
 388 <EXPRESSION>{SYMBOLNAMECHAR1}{NOCFILENAMECHAR}* {
 389                                   yylval.name = xstrdup (yytext);
 390                                   return NAME;
 391                                 }
 392 <EXPRESSION>"/DISCARD/"         {
 393                                   yylval.name = xstrdup (yytext);
 394                                   return NAME;
 395                                 }
 396 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 397                                   yylval.name = xstrdup (yytext + 2);
 398                                   return LNAME;
 399                                 }
 400 <SCRIPT>{WILDCHAR}* {
 401                 /* Annoyingly, this pattern can match comments, and we have
 402                    longest match issues to consider.  So if the first two
 403                    characters are a comment opening, put the input back and
 404                    try again.  */
 405                 if (yytext[0] == '/' && yytext[1] == '*')
 406                   {
 407                     yyless (2);
 408                     comment ();
 409                   }
 410                 else
 411                   {
 412                     yylval.name = xstrdup (yytext);
 413                     return NAME;
 414                   }
 415         }
 416
 417 <EXPRESSION,BOTH,SCRIPT,VERS_NODE,INPUTLIST>"\""[^\"]*"\"" {
 418                                         /* No matter the state, quotes
 419                                            give what's inside.  */
 420                                         bfd_size_type len;
 421                                         yylval.name = xstrdup (yytext + 1);
 422                                         /* PR ld/20906.  A corrupt input file
 423                                            can contain bogus strings.  */
 424                                         len = strlen (yylval.name);
 425                                         if (len > (bfd_size_type) yyleng - 2)
 426                                           len = yyleng - 2;
 427                                         yylval.name[len] = 0;
 428                                         return NAME;
 429                                 }
 430 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 431 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 432
 433 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 434
 435 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 436
 437 <VERS_NODE>local                { RTOKEN(LOCAL); }
 438
 439 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 440
 441 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 442                                   return VERS_IDENTIFIER; }
 443
 444 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 445                                   return VERS_TAG; }
 446
 447 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 448
 449 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 450                                   vers_node_nesting = 0;
 451                                   return *yytext;
 452                                 }
 453 <VERS_SCRIPT>"}"                { return *yytext; }
 454 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 455 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 456                                     BEGIN(VERS_SCRIPT);
 457                                   return *yytext;
 458                                 }
 459
 460 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[\n]        { lineno++; }
 461
 462 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 463
 464 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[ \t\r]+    { /* Eat up whitespace */ }
 465
 466 <<EOF>> {
 467   include_stack_ptr--;
 468   if (include_stack_ptr == 0)
 469     {
 470       lineno = 0;
 471       yyterminate ();
 472     }
 473   else
 474     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 475
 476   lineno = lineno_stack[include_stack_ptr];
 477   input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
 478
 479   return END;
 480 }
 481
 482 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 483 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 484
 485 %%
 486 \f
 487
 488 /* Switch flex to reading script file NAME, open on FILE,
 489    saving the current input info on the include stack.  */
 490
 491 void
 492 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
 493 {
 494   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 495     {
 496       einfo (_("%F:includes nested too deeply\n"));
 497     }
 498   file_name_stack[include_stack_ptr] = name;
 499   lineno_stack[include_stack_ptr] = lineno;
 500   sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
 501   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 502
 503   include_stack_ptr++;
 504   lineno = 1;
 505   input_flags.sysrooted = sysrooted;
 506   yyin = file;
 507   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 508 }
 509
 510 /* Return a newly created flex input buffer containing STRING,
 511    which is SIZE bytes long.  */
 512
 513 static YY_BUFFER_STATE
 514 yy_create_string_buffer (const char *string, size_t size)
 515 {
 516   YY_BUFFER_STATE b;
 517
 518   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 519   b = malloc (sizeof (struct yy_buffer_state));
 520   b->yy_input_file = 0;
 521   b->yy_buf_size = size;
 522
 523   /* yy_ch_buf has to be 2 characters longer than the size given because
 524      we need to put in 2 end-of-buffer characters.  */
 525   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 526
 527   b->yy_ch_buf[0] = '\n';
 528   strcpy (b->yy_ch_buf+1, string);
 529   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 530   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 531   b->yy_n_chars = size+1;
 532   b->yy_buf_pos = &b->yy_ch_buf[1];
 533
 534   b->yy_is_our_buffer = 1;
 535   b->yy_is_interactive = 0;
 536   b->yy_at_bol = 1;
 537   b->yy_fill_buffer = 0;
 538
 539   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 540      a flex internal interface in the first place!  */
 541 #ifdef YY_BUFFER_NEW
 542   b->yy_buffer_status = YY_BUFFER_NEW;
 543 #else
 544   b->yy_eof_status = EOF_NOT_SEEN;
 545 #endif
 546
 547   return b;
 548 }
 549
 550 /* Switch flex to reading from STRING, saving the current input info
 551    on the include stack.  */
 552
 553 void
 554 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
 555 {
 556   YY_BUFFER_STATE tmp;
 557
 558   yy_init = 0;
 559   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 560     {
 561       einfo (_("%F: macros nested too deeply\n"));
 562     }
 563   file_name_stack[include_stack_ptr] = fake_filename;
 564   lineno_stack[include_stack_ptr] = lineno;
 565   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 566   include_stack_ptr++;
 567   lineno = count;
 568   tmp = yy_create_string_buffer (string, strlen (string));
 569   yy_switch_to_buffer (tmp);
 570 }
 571 \f
 572 /* Functions to switch to a different flex start condition,
 573    saving the current start condition on `state_stack'.  */
 574
 575 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 576 static int *state_stack_p = state_stack;
 577
 578 void
 579 ldlex_script (void)
 580 {
 581   *(state_stack_p)++ = yy_start;
 582   BEGIN (SCRIPT);
 583 }
 584
 585 void
 586 ldlex_inputlist (void)
 587 {
 588   *(state_stack_p)++ = yy_start;
 589   BEGIN (INPUTLIST);
 590 }
 591
 592 void
 593 ldlex_mri_script (void)
 594 {
 595   *(state_stack_p)++ = yy_start;
 596   BEGIN (MRI);
 597 }
 598
 599 void
 600 ldlex_version_script (void)
 601 {
 602   *(state_stack_p)++ = yy_start;
 603   BEGIN (VERS_START);
 604 }
 605
 606 void
 607 ldlex_version_file (void)
 608 {
 609   *(state_stack_p)++ = yy_start;
 610   BEGIN (VERS_SCRIPT);
 611 }
 612
 613 void
 614 ldlex_defsym (void)
 615 {
 616   *(state_stack_p)++ = yy_start;
 617   BEGIN (DEFSYMEXP);
 618 }
 619
 620 void
 621 ldlex_expression (void)
 622 {
 623   *(state_stack_p)++ = yy_start;
 624   BEGIN (EXPRESSION);
 625 }
 626
 627 void
 628 ldlex_both (void)
 629 {
 630   *(state_stack_p)++ = yy_start;
 631   BEGIN (BOTH);
 632 }
 633
 634 void
 635 ldlex_popstate (void)
 636 {
 637   yy_start = *(--state_stack_p);
 638 }
 639
 640 /* Return the current file name, or the previous file if no file is
 641    current.  */
 642
 643 const char*
 644 ldlex_filename (void)
 645 {
 646   return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
 647 }
 648 \f
 649
 650 /* Place up to MAX_SIZE characters in BUF and return
 651    either the number of characters read, or 0 to indicate EOF.  */
 652
 653 static int
 654 yy_input (char *buf, int max_size)
 655 {
 656   int result = 0;
 657   if (YY_CURRENT_BUFFER->yy_input_file)
 658     {
 659       if (yyin)
 660         {
 661           result = fread (buf, 1, max_size, yyin);
 662           if (result < max_size && ferror (yyin))
 663             einfo (_("%F%P: read in flex scanner failed\n"));
 664         }
 665     }
 666   return result;
 667 }
 668
 669 /* Eat the rest of a C-style comment.  */
 670
 671 static void
 672 comment (void)
 673 {
 674   int c;
 675
 676   while (1)
 677     {
 678       c = input();
 679       while (c != '*' && c != 0)
 680         {
 681           if (c == '\n')
 682             lineno++;
 683           c = input();
 684         }
 685
 686       if (c == '*')
 687         {
 688           c = input();
 689           while (c == '*')
 690             c = input();
 691           if (c == '/')
 692             break;                      /* found the end */
 693         }
 694
 695       if (c == '\n')
 696         lineno++;
 697
 698       if (c == 0)
 699         {
 700           einfo (_("%F%P: EOF in comment\n"));
 701           break;
 702         }
 703     }
 704 }
 705
 706 /* Warn the user about a garbage character WHAT in the input
 707    in context WHERE.  */
 708
 709 static void
 710 lex_warn_invalid (char *where, char *what)
 711 {
 712   char buf[5];
 713
 714   /* If we have found an input file whose format we do not recognize,
 715      and we are therefore treating it as a linker script, and we find
 716      an invalid character, then most likely this is a real object file
 717      of some different format.  Treat it as such.  */
 718   if (ldfile_assumed_script)
 719     {
 720       bfd_set_error (bfd_error_file_not_recognized);
 721       einfo (_("%F%s: file not recognized: %E\n"), ldlex_filename ());
 722     }
 723
 724   if (! ISPRINT (*what))
 725     {
 726       sprintf (buf, "\\%03o", *(unsigned char *) what);
 727       what = buf;
 728     }
 729
 730   einfo (_("%P:%pS: ignoring invalid character `%s'%s\n"), NULL, what, where);
 731 }