libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 # We may wish to install the target headers somewhere.
 132 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 133 dnl install-libiberty is disabled by default
 134
 135 AC_ARG_ENABLE(install-libiberty,
 136 [  --enable-install-libiberty       Install headers and library for end users],
 137 enable_install_libiberty=$enableval,
 138 enable_install_libiberty=no)dnl
 139
 140 # Option parsed, now set things appropriately.
 141 case x"$enable_install_libiberty" in
 142   xyes|x)
 143     target_header_dir=libiberty
 144     ;;
 145   xno)
 146     target_header_dir=
 147     ;;
 148   *)
 149     # This could be sanity-checked in various ways...
 150     target_header_dir="${enable_install_libiberty}"
 151     ;;
 152 esac
 153 AC_MSG_RESULT($enable_install_libiberty)
 154 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 155
 156 GCC_NO_EXECUTABLES
 157 AC_PROG_CC
 158 AC_GNU_SOURCE
 159 AC_SYS_LARGEFILE
 160 AC_PROG_CPP_WERROR
 161
 162 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 163                           -Wstrict-prototypes \
 164                           -Wshadow=local], [ac_libiberty_warn_cflags])
 165 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 166
 167 AC_PROG_CC_C_O
 168 # autoconf is lame and doesn't give us any substitution variable for this.
 169 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 170   NO_MINUS_C_MINUS_O=yes
 171 else
 172   OUTPUT_OPTION='-o $@'
 173 fi
 174 AC_SUBST(NO_MINUS_C_MINUS_O)
 175 AC_SUBST(OUTPUT_OPTION)
 176
 177 AC_C_CONST
 178 AC_C_INLINE
 179 AC_C_BIGENDIAN
 180
 181 dnl When we start using libtool:
 182 dnl Default to a non shared library.  This may be overridden by the
 183 dnl configure option --enable-shared.
 184 dnl AM_DISABLE_SHARED
 185
 186 dnl When we start using libtool:
 187 dnl AM_PROG_LIBTOOL
 188
 189 dnl When we start using automake:
 190 dnl AM_CONFIG_HEADER(config.h:config.in)
 191 AC_CONFIG_HEADER(config.h:config.in)
 192
 193 dnl When we start using automake:
 194 dnl AM_MAINTAINER_MODE
 195 dnl AC_EXEEXT
 196
 197 dnl When we start using automake:
 198 dnl AM_PROG_INSTALL
 199 AC_PROG_INSTALL
 200
 201 # Don't build the shared library for build.
 202 if [[ -n "${with_build_subdir}" ]]; then
 203   enable_shared=no
 204 fi
 205
 206 frag=
 207 case "${host}" in
 208   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 209                         frag=mh-aix ;;
 210   *-*-cxux7*)           frag=mh-cxux7 ;;
 211   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 212   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 213   i370-*-opened*)       frag=mh-openedition ;;
 214   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 215 esac
 216
 217 if [[ -n "${frag}" ]]; then
 218   frag=${libiberty_topdir}/libiberty/config/$frag
 219 fi
 220
 221 GCC_PICFLAG
 222
 223 # If they didn't specify --enable-shared, don't generate shared libs.
 224 case "${enable_shared}" in
 225   yes) shared=yes ;;
 226   no) shared=no ;;
 227   "") shared=no ;;
 228   *) shared=yes ;;
 229 esac
 230
 231 # ...unless --enable-host-shared was passed from top-level config:
 232 if [[ "${enable_host_shared}" = "yes" ]]; then
 233   shared=yes
 234 fi
 235
 236 if [[ "${shared}" != "yes" ]]; then
 237   PICFLAG=
 238 fi
 239 AC_SUBST(PICFLAG)
 240
 241 NOASANFLAG=
 242 case " ${CFLAGS} " in
 243   *\ -fsanitize=address\ *) NOASANFLAG=-fno-sanitize=address ;;
 244 esac
 245 AC_SUBST(NOASANFLAG)
 246
 247 echo "# Warning: this fragment is automatically generated" > temp-frag
 248
 249 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 250   echo "Appending ${frag} to xhost-mkfrag"
 251   echo "# Following fragment copied from ${frag}" >> temp-frag
 252   cat ${frag} >> temp-frag
 253 fi
 254
 255 # record if we want to build shared libs.
 256 if [[ "${shared}" = "yes" ]]; then
 257   echo enable_shared = yes >> temp-frag
 258 else
 259   echo enable_shared = no >> temp-frag
 260 fi
 261
 262 frag=xhost-mkfrag
 263 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 264
 265 host_makefile_frag=${frag}
 266 AC_SUBST_FILE(host_makefile_frag)
 267
 268 # It's OK to check for header files.  Although the compiler may not be
 269 # able to link anything, it had better be able to at least compile
 270 # something.
 271 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 272 AC_HEADER_SYS_WAIT
 273 AC_HEADER_TIME
 274
 275 libiberty_AC_DECLARE_ERRNO
 276
 277 # Determine sizes of some types.
 278 AC_CHECK_SIZEOF([int])
 279 AC_CHECK_SIZEOF([long])
 280 AC_CHECK_SIZEOF([size_t])
 281
 282 # Check for presense of long long
 283 AC_CHECK_TYPE([long long],
 284   [AC_DEFINE(HAVE_LONG_LONG, 1, [Define if you have the `long long' type.]) AC_CHECK_SIZEOF([long long])],
 285   [])
 286
 287 # Look for a 64-bit type.
 288 AC_MSG_CHECKING([for a 64-bit type])
 289 AC_CACHE_VAL(liberty_cv_uint64,
 290 [AC_TRY_COMPILE(
 291 [#ifdef HAVE_STDINT_H
 292 #include <stdint.h>
 293 #endif],
 294 [extern uint64_t foo;],
 295 liberty_cv_uint64=uint64_t,
 296 [AC_TRY_COMPILE(
 297 [#ifdef HAVE_LIMITS_H
 298 #include <limits.h>
 299 #endif
 300 #ifndef CHAR_BIT
 301 #define CHAR_BIT 8
 302 #endif],
 303 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 304 liberty_cv_uint64="unsigned long",
 305 [AC_TRY_COMPILE(
 306 [#ifdef HAVE_LIMITS_H
 307 #include <limits.h>
 308 #endif
 309 #ifndef CHAR_BIT
 310 #define CHAR_BIT 8
 311 #endif],
 312 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 313 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 314 AC_MSG_RESULT($liberty_cv_uint64)
 315 if test "$liberty_cv_uint64" != none; then
 316   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 317                      [Define to an unsigned 64-bit type available in the compiler.])
 318 fi
 319
 320 AC_TYPE_INTPTR_T
 321 AC_TYPE_UINTPTR_T
 322 AC_TYPE_SSIZE_T
 323
 324 # Given the above check, we always have uintptr_t or a fallback
 325 # definition.  So define HAVE_UINTPTR_T in case any imported code
 326 # relies on it.
 327 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 328
 329 AC_TYPE_PID_T
 330
 331 # This is the list of functions which libiberty will provide if they
 332 # are not available on the host.
 333
 334 funcs="asprintf"
 335 funcs="$funcs atexit"
 336 funcs="$funcs basename"
 337 funcs="$funcs bcmp"
 338 funcs="$funcs bcopy"
 339 funcs="$funcs bsearch"
 340 funcs="$funcs bzero"
 341 funcs="$funcs calloc"
 342 funcs="$funcs clock"
 343 funcs="$funcs ffs"
 344 funcs="$funcs getcwd"
 345 funcs="$funcs getpagesize"
 346 funcs="$funcs gettimeofday"
 347 funcs="$funcs index"
 348 funcs="$funcs insque"
 349 funcs="$funcs memchr"
 350 funcs="$funcs memcmp"
 351 funcs="$funcs memcpy"
 352 funcs="$funcs memmem"
 353 funcs="$funcs memmove"
 354 funcs="$funcs mempcpy"
 355 funcs="$funcs memset"
 356 funcs="$funcs mkstemps"
 357 funcs="$funcs putenv"
 358 funcs="$funcs random"
 359 funcs="$funcs rename"
 360 funcs="$funcs rindex"
 361 funcs="$funcs setenv"
 362 funcs="$funcs snprintf"
 363 funcs="$funcs sigsetmask"
 364 funcs="$funcs stpcpy"
 365 funcs="$funcs stpncpy"
 366 funcs="$funcs strcasecmp"
 367 funcs="$funcs strchr"
 368 funcs="$funcs strdup"
 369 funcs="$funcs strncasecmp"
 370 funcs="$funcs strndup"
 371 funcs="$funcs strnlen"
 372 funcs="$funcs strrchr"
 373 funcs="$funcs strstr"
 374 funcs="$funcs strtod"
 375 funcs="$funcs strtol"
 376 funcs="$funcs strtoul"
 377 funcs="$funcs strtoll"
 378 funcs="$funcs strtoull"
 379 funcs="$funcs strverscmp"
 380 funcs="$funcs tmpnam"
 381 funcs="$funcs vasprintf"
 382 funcs="$funcs vfprintf"
 383 funcs="$funcs vprintf"
 384 funcs="$funcs vsnprintf"
 385 funcs="$funcs vsprintf"
 386 funcs="$funcs waitpid"
 387 funcs="$funcs setproctitle"
 388
 389 # Also in the old function.def file: alloca, vfork, getopt.
 390
 391 vars="sys_errlist sys_nerr sys_siglist"
 392
 393 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 394  getsysinfo gettimeofday on_exit psignal pstat_getdynamic pstat_getstatic \
 395  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 396  sysmp table times wait3 wait4"
 397
 398 # These are neither executed nor required, but they help keep
 399 # autoheader happy without adding a bunch of text to acconfig.h.
 400 if test "x" = "y"; then
 401   AC_CHECK_FUNCS(asprintf atexit \
 402     basename bcmp bcopy bsearch bzero \
 403     calloc canonicalize_file_name clock \
 404     dup3 \
 405     ffs __fsetlocking \
 406     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 407     index insque \
 408     memchr memcmp memcpy memmem memmove memset mkstemps \
 409     on_exit \
 410     psignal pstat_getdynamic pstat_getstatic putenv \
 411     random realpath rename rindex \
 412     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 413      stpcpy stpncpy strcasecmp strchr strdup \
 414      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 415      strtol strtoul strtoll strtoull strverscmp sysconf sysctl sysmp \
 416     table times tmpnam \
 417     vasprintf vfprintf vprintf vsprintf \
 418     wait3 wait4 waitpid)
 419   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf, strtol, strtoul, strtoll, strtoull, strnlen])
 420   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 421   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 422   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 423 fi
 424
 425 # For each of these functions, if the host does not provide the
 426 # function we want to put FN.o in LIBOBJS, and if the host does
 427 # provide the function, we want to define HAVE_FN in config.h.
 428
 429 setobjs=
 430 CHECK=
 431 if test -n "${with_target_subdir}"; then
 432
 433   # We are being configured as a target library.  AC_REPLACE_FUNCS
 434   # may not work correctly, because the compiler may not be able to
 435   # link executables.  Note that we may still be being configured
 436   # native.
 437
 438   # If we are being configured for newlib, we know which functions
 439   # newlib provide and which ones we will be expected to provide.
 440
 441   if test "x${with_newlib}" = "xyes"; then
 442     AC_LIBOBJ([asprintf])
 443     AC_LIBOBJ([basename])
 444     AC_LIBOBJ([insque])
 445     AC_LIBOBJ([random])
 446     AC_LIBOBJ([strdup])
 447     AC_LIBOBJ([vasprintf])
 448
 449     for f in $funcs; do
 450       case "$f" in
 451         asprintf | basename | insque | random | strdup | vasprintf)
 452           ;;
 453         *)
 454           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 455           AC_DEFINE_UNQUOTED($n)
 456           ;;
 457       esac
 458     done
 459
 460     # newlib doesnt provide any of the variables in $vars, so we
 461     # dont have to check them here.
 462
 463     # Of the functions in $checkfuncs, newlib only has strerror.
 464     AC_DEFINE(HAVE_STRERROR)
 465
 466     setobjs=yes
 467
 468   fi
 469
 470   # If we are being configured for Mingw, we know which functions
 471   # Mingw provides and which ones we will be expected to provide.
 472
 473   case "${host}" in
 474   *-*-mingw*)
 475     AC_LIBOBJ([asprintf])
 476     AC_LIBOBJ([basename])
 477     AC_LIBOBJ([bcmp])
 478     AC_LIBOBJ([bcopy])
 479     AC_LIBOBJ([bzero])
 480     AC_LIBOBJ([clock])
 481     AC_LIBOBJ([ffs])
 482     AC_LIBOBJ([getpagesize])
 483     AC_LIBOBJ([index])
 484     AC_LIBOBJ([insque])
 485     AC_LIBOBJ([mempcpy])
 486     AC_LIBOBJ([mkstemps])
 487     AC_LIBOBJ([random])
 488     AC_LIBOBJ([rindex])
 489     AC_LIBOBJ([sigsetmask])
 490     AC_LIBOBJ([stpcpy])
 491     AC_LIBOBJ([stpncpy])
 492     AC_LIBOBJ([strndup])
 493     AC_LIBOBJ([strnlen])
 494     AC_LIBOBJ([strverscmp])
 495     AC_LIBOBJ([vasprintf])
 496     AC_LIBOBJ([waitpid])
 497
 498     for f in $funcs; do
 499       case "$f" in
 500         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 501           ;;
 502         *)
 503           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 504           AC_DEFINE_UNQUOTED($n)
 505           ;;
 506       esac
 507     done
 508
 509     # Mingw doesnt provide any of the variables in $vars, so we
 510     # dont have to check them here.
 511
 512     # Of the functions in $checkfuncs, Mingw only has strerror.
 513     AC_DEFINE(HAVE_STRERROR)
 514
 515     setobjs=yes
 516     ;;
 517
 518   *-*-msdosdjgpp)
 519     AC_LIBOBJ([vasprintf])
 520     AC_LIBOBJ([vsnprintf])
 521     AC_LIBOBJ([snprintf])
 522     AC_LIBOBJ([asprintf])
 523
 524     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 525              getcwd getpagesize getrusage gettimeofday \
 526              index insque memchr memcmp memcpy memmove memset psignal \
 527              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 528              strchr strdup strerror strncasecmp strrchr strstr strtod \
 529              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 530              vsprintf waitpid
 531     do
 532       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 533       AC_DEFINE_UNQUOTED($n)
 534     done
 535
 536
 537     setobjs=yes
 538     ;;
 539
 540   esac
 541
 542 else
 543
 544    # Not a target library, so we set things up to run the test suite.
 545    CHECK=really-check
 546
 547 fi
 548
 549 AC_SUBST(CHECK)
 550 AC_SUBST(target_header_dir)
 551
 552 case "${host}" in
 553   *-*-cygwin* | *-*-mingw*)
 554     AC_DEFINE(HAVE_SYS_ERRLIST)
 555     AC_DEFINE(HAVE_SYS_NERR)
 556     ;;
 557 esac
 558
 559 if test -z "${setobjs}"; then
 560   case "${host}" in
 561
 562   *-*-vxworks*)
 563     # Handle VxWorks configuration specially, since on VxWorks the
 564     # libraries are actually on the target board, not in the file
 565     # system.
 566     AC_LIBOBJ([basename])
 567     AC_LIBOBJ([getpagesize])
 568     AC_LIBOBJ([insque])
 569     AC_LIBOBJ([random])
 570     AC_LIBOBJ([strcasecmp])
 571     AC_LIBOBJ([strncasecmp])
 572     AC_LIBOBJ([strdup])
 573     AC_LIBOBJ([vfork])
 574     AC_LIBOBJ([waitpid])
 575     AC_LIBOBJ([vasprintf])
 576     for f in $funcs; do
 577       case "$f" in
 578         basename | getpagesize | insque | random | strcasecmp)
 579           ;;
 580         strncasecmp | strdup | vfork | waitpid | vasprintf)
 581           ;;
 582         *)
 583           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 584           AC_DEFINE_UNQUOTED($n)
 585           ;;
 586       esac
 587     done
 588
 589     # VxWorks doesn't provide any of the variables in $vars, so we
 590     # don't have to check them here.
 591
 592     # Of the functions in $checkfuncs, VxWorks only has strerror.
 593     AC_DEFINE(HAVE_STRERROR)
 594
 595     setobjs=yes
 596     ;;
 597
 598   esac
 599 fi
 600
 601 if test -z "${setobjs}"; then
 602
 603   case "${host}" in
 604
 605   *-*-android*)
 606     # On android, getpagesize is defined in unistd.h as a static inline
 607     # function, which AC_CHECK_FUNCS does not handle properly.
 608     ac_cv_func_getpagesize=yes
 609     ;;
 610
 611   *-*-mingw32*)
 612     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 613     # macros, so the test below won't find them.
 614     libiberty_cv_var_sys_nerr=yes
 615     libiberty_cv_var_sys_errlist=yes
 616     ;;
 617
 618   *-*-msdosdjgpp*)
 619     # vfork and fork are stubs.
 620     ac_cv_func_vfork_works=no
 621     ;;
 622
 623   *-*-uwin*)
 624     # Under some versions of uwin, vfork is notoriously buggy and the test
 625     # can hang configure; on other versions, vfork exists just as a stub.
 626     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 627     ac_cv_func_vfork_works=no
 628     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 629     # macros (actually, these are imported from a DLL, but the end effect
 630     # is the same), so the test below won't find them.
 631     libiberty_cv_var_sys_nerr=yes
 632     libiberty_cv_var_sys_errlist=yes
 633     ;;
 634
 635   *-*-*vms*)
 636     # Under VMS, vfork works very different than on Unix. The standard test
 637     # won't work, and it isn't easily adaptable. It makes more sense to
 638     # just force it.
 639     ac_cv_func_vfork_works=yes
 640     ;;
 641
 642   esac
 643
 644   # We haven't set the list of objects yet.  Use the standard autoconf
 645   # tests.  This will only work if the compiler works.
 646   AC_ISC_POSIX
 647   AC_REPLACE_FUNCS($funcs)
 648   libiberty_AC_FUNC_C_ALLOCA
 649   AC_FUNC_FORK
 650   if test $ac_cv_func_vfork_works = no; then
 651     AC_LIBOBJ([vfork])
 652   fi
 653   # We only need _doprnt if we might use it to implement v*printf.
 654   if test $ac_cv_func_vprintf != yes \
 655      || test $ac_cv_func_vfprintf != yes \
 656      || test $ac_cv_func_vsprintf != yes; then
 657     AC_REPLACE_FUNCS(_doprnt)
 658   else
 659     AC_CHECK_FUNCS(_doprnt)
 660   fi
 661
 662   for v in $vars; do
 663     AC_MSG_CHECKING([for $v])
 664     AC_CACHE_VAL(libiberty_cv_var_$v,
 665       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 666                       [eval "libiberty_cv_var_$v=yes"],
 667                       [eval "libiberty_cv_var_$v=no"])])
 668     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 669       AC_MSG_RESULT(yes)
 670       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 671       AC_DEFINE_UNQUOTED($n)
 672     else
 673       AC_MSG_RESULT(no)
 674     fi
 675   done
 676
 677   # special check for _system_configuration because AIX <4.3.2 do not
 678   # contain the `physmem' member.
 679   AC_MSG_CHECKING([for external symbol _system_configuration])
 680   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 681                         [[double x = _system_configuration.physmem;]])],
 682     [AC_MSG_RESULT([yes])
 683     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 684               [Define if you have the _system_configuration variable.])],
 685     [AC_MSG_RESULT([no])])
 686
 687   AC_CHECK_FUNCS($checkfuncs)
 688   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 689   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 690   AC_CHECK_DECLS([strtol, strtoul, strtoll, strtoull])
 691   AC_CHECK_DECLS([strverscmp])
 692   AC_CHECK_DECLS([strnlen])
 693   libiberty_NEED_DECLARATION(canonicalize_file_name)
 694 fi
 695
 696 # Figure out which version of pexecute to use.
 697 case "${host}" in
 698      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 699      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 700      *-*-msdos*)                pexecute=pex-msdos  ;;
 701      *)                         pexecute=pex-unix   ;;
 702 esac
 703 AC_SUBST(pexecute)
 704
 705 libiberty_AC_FUNC_STRNCMP
 706
 707 # Install a library built with a cross compiler in $(tooldir) rather
 708 # than $(libdir).
 709 if test -z "${with_cross_host}"; then
 710   INSTALL_DEST=libdir
 711 else
 712   INSTALL_DEST=tooldir
 713 fi
 714 AC_SUBST(INSTALL_DEST)
 715
 716 m4_pattern_allow(LIBOBJS)
 717 L=""
 718 for l in x $LIBOBJS; do
 719   case $l in
 720     x) ;;
 721     *) L="$L ./$l" ;;
 722   esac
 723 done
 724 LIBOBJS="$L"
 725
 726 dnl Required by html and install-html
 727 AC_SUBST(datarootdir)
 728 AC_SUBST(docdir)
 729 AC_SUBST(htmldir)
 730
 731 # We need multilib support, but only if configuring for the target.
 732 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 733 AC_CONFIG_COMMANDS([default],
 734   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 735 if test -n "$CONFIG_FILES"; then
 736   if test -n "${with_target_subdir}"; then
 737     # FIXME: We shouldn't need to set ac_file
 738     ac_file=Makefile
 739     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 740     . ${libiberty_topdir}/config-ml.in
 741   fi
 742 fi]],
 743 [[srcdir=${srcdir}
 744 host=${host}
 745 target=${target}
 746 with_target_subdir=${with_target_subdir}
 747 with_multisubdir=${with_multisubdir}
 748 ac_configure_args="--enable-multilib ${ac_configure_args}"
 749 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 750 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 751 libiberty_topdir=${libiberty_topdir}
 752 ]])
 753 AC_OUTPUT