arch/parisc/kernel/syscall.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  * System call entry code / Linux gateway page
   5  * Copyright (c) Matthew Wilcox 1999 <willy@bofh.ai>
   6  * Licensed under the GNU GPL.
   7  * thanks to Philipp Rumpf, Mike Shaver and various others
   8  * sorry about the wall, puffin..
   9  */
  10
  11 /*
  12 How does the Linux gateway page on PA-RISC work?
  13 ------------------------------------------------
  14 The Linux gateway page on PA-RISC is "special".
  15 It actually has PAGE_GATEWAY bits set (this is linux terminology; in parisc
  16 terminology it's Execute, promote to PL0) in the page map.  So anything
  17 executing on this page executes with kernel level privilege (there's more to it
  18 than that: to have this happen, you also have to use a branch with a ,gate
  19 completer to activate the privilege promotion).  The upshot is that everything
  20 that runs on the gateway page runs at kernel privilege but with the current
  21 user process address space (although you have access to kernel space via %sr2).
  22 For the 0x100 syscall entry, we redo the space registers to point to the kernel
  23 address space (preserving the user address space in %sr3), move to wide mode if
  24 required, save the user registers and branch into the kernel syscall entry
  25 point.  For all the other functions, we execute at kernel privilege but don't
  26 flip address spaces. The basic upshot of this is that these code snippets are
  27 executed atomically (because the kernel can't be pre-empted) and they may
  28 perform architecturally forbidden (to PL3) operations (like setting control
  29 registers).
  30 */
  31
  32
  33 #include <asm/asm-offsets.h>
  34 #include <asm/unistd.h>
  35 #include <asm/errno.h>
  36 #include <asm/page.h>
  37 #include <asm/psw.h>
  38 #include <asm/thread_info.h>
  39 #include <asm/assembly.h>
  40 #include <asm/processor.h>
  41 #include <asm/cache.h>
  42
  43 #include <linux/linkage.h>
  44
  45         /* We fill the empty parts of the gateway page with
  46          * something that will kill the kernel or a
  47          * userspace application.
  48          */
  49 #define KILL_INSN       break   0,0
  50
  51         .level          LEVEL
  52
  53         .text
  54
  55         .import syscall_exit,code
  56         .import syscall_exit_rfi,code
  57
  58         /* Linux gateway page is aliased to virtual page 0 in the kernel
  59          * address space. Since it is a gateway page it cannot be
  60          * dereferenced, so null pointers will still fault. We start
  61          * the actual entry point at 0x100. We put break instructions
  62          * at the beginning of the page to trap null indirect function
  63          * pointers.
  64          */
  65
  66         .align PAGE_SIZE
  67 ENTRY(linux_gateway_page)
  68
  69         /* ADDRESS 0x00 to 0xb0 = 176 bytes / 4 bytes per insn = 44 insns */
  70         .rept 44
  71         KILL_INSN
  72         .endr
  73
  74         /* ADDRESS 0xb0 to 0xb8, lws uses two insns for entry */
  75         /* Light-weight-syscall entry must always be located at 0xb0 */
  76         /* WARNING: Keep this number updated with table size changes */
  77 #define __NR_lws_entries (3)
  78
  79 lws_entry:
  80         gate    lws_start, %r0          /* increase privilege */
  81         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  82
  83         /* Fill from 0xb8 to 0xe0 */
  84         .rept 10
  85         KILL_INSN
  86         .endr
  87
  88         /* This function MUST be located at 0xe0 for glibc's threading
  89         mechanism to work. DO NOT MOVE THIS CODE EVER! */
  90 set_thread_pointer:
  91         gate    .+8, %r0                /* increase privilege */
  92         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  93         be      0(%sr7,%r31)            /* return to user space */
  94         mtctl   %r26, %cr27             /* move arg0 to the control register */
  95
  96         /* Increase the chance of trapping if random jumps occur to this
  97         address, fill from 0xf0 to 0x100 */
  98         .rept 4
  99         KILL_INSN
 100         .endr
 101
 102 /* This address must remain fixed at 0x100 for glibc's syscalls to work */
 103         .align 256
 104 linux_gateway_entry:
 105         gate    .+8, %r0                        /* become privileged */
 106         mtsp    %r0,%sr4                        /* get kernel space into sr4 */
 107         mtsp    %r0,%sr5                        /* get kernel space into sr5 */
 108         mtsp    %r0,%sr6                        /* get kernel space into sr6 */
 109         mfsp    %sr7,%r1                        /* save user sr7 */
 110         mtsp    %r1,%sr3                        /* and store it in sr3 */
 111
 112 #ifdef CONFIG_64BIT
 113         /* for now we can *always* set the W bit on entry to the syscall
 114          * since we don't support wide userland processes.  We could
 115          * also save the current SM other than in r0 and restore it on
 116          * exit from the syscall, and also use that value to know
 117          * whether to do narrow or wide syscalls. -PB
 118          */
 119         ssm     PSW_SM_W, %r1
 120         extrd,u %r1,PSW_W_BIT,1,%r1
 121         /* sp must be aligned on 4, so deposit the W bit setting into
 122          * the bottom of sp temporarily */
 123         or,ev   %r1,%r30,%r30
 124         b,n     1f
 125         /* The top halves of argument registers must be cleared on syscall
 126          * entry from narrow executable.
 127          */
 128         depdi   0, 31, 32, %r26
 129         depdi   0, 31, 32, %r25
 130         depdi   0, 31, 32, %r24
 131         depdi   0, 31, 32, %r23
 132         depdi   0, 31, 32, %r22
 133         depdi   0, 31, 32, %r21
 134 1:
 135 #endif
 136         mfctl   %cr30,%r1
 137         xor     %r1,%r30,%r30                   /* ye olde xor trick */
 138         xor     %r1,%r30,%r1
 139         xor     %r1,%r30,%r30
 140
 141         ldo     THREAD_SZ_ALGN+FRAME_SIZE(%r30),%r30  /* set up kernel stack */
 142
 143         /* N.B.: It is critical that we don't set sr7 to 0 until r30
 144          *       contains a valid kernel stack pointer. It is also
 145          *       critical that we don't start using the kernel stack
 146          *       until after sr7 has been set to 0.
 147          */
 148
 149         mtsp    %r0,%sr7                        /* get kernel space into sr7 */
 150         STREGM  %r1,FRAME_SIZE(%r30)            /* save r1 (usp) here for now */
 151         mfctl   %cr30,%r1                       /* get task ptr in %r1 */
 152         LDREG   TI_TASK(%r1),%r1
 153
 154         /* Save some registers for sigcontext and potential task
 155            switch (see entry.S for the details of which ones are
 156            saved/restored).  TASK_PT_PSW is zeroed so we can see whether
 157            a process is on a syscall or not.  For an interrupt the real
 158            PSW value is stored.  This is needed for gdb and sys_ptrace. */
 159         STREG   %r0,  TASK_PT_PSW(%r1)
 160         STREG   %r2,  TASK_PT_GR2(%r1)          /* preserve rp */
 161         STREG   %r19, TASK_PT_GR19(%r1)
 162
 163         LDREGM  -FRAME_SIZE(%r30), %r2          /* get users sp back */
 164 #ifdef CONFIG_64BIT
 165         extrd,u %r2,63,1,%r19                   /* W hidden in bottom bit */
 166 #if 0
 167         xor     %r19,%r2,%r2                    /* clear bottom bit */
 168         depd,z  %r19,1,1,%r19
 169         std     %r19,TASK_PT_PSW(%r1)
 170 #endif
 171 #endif
 172         STREG   %r2,  TASK_PT_GR30(%r1)         /* ... and save it */
 173
 174         STREG   %r20, TASK_PT_GR20(%r1)         /* Syscall number */
 175         STREG   %r21, TASK_PT_GR21(%r1)
 176         STREG   %r22, TASK_PT_GR22(%r1)
 177         STREG   %r23, TASK_PT_GR23(%r1)         /* 4th argument */
 178         STREG   %r24, TASK_PT_GR24(%r1)         /* 3rd argument */
 179         STREG   %r25, TASK_PT_GR25(%r1)         /* 2nd argument */
 180         STREG   %r26, TASK_PT_GR26(%r1)         /* 1st argument */
 181         STREG   %r27, TASK_PT_GR27(%r1)         /* user dp */
 182         STREG   %r28, TASK_PT_GR28(%r1)         /* return value 0 */
 183         STREG   %r0, TASK_PT_ORIG_R28(%r1)      /* don't prohibit restarts */
 184         STREG   %r29, TASK_PT_GR29(%r1)         /* return value 1 */
 185         STREG   %r31, TASK_PT_GR31(%r1)         /* preserve syscall return ptr */
 186
 187         ldo     TASK_PT_FR0(%r1), %r27          /* save fpregs from the kernel */
 188         save_fp %r27                            /* or potential task switch  */
 189
 190         mfctl   %cr11, %r27                     /* i.e. SAR */
 191         STREG   %r27, TASK_PT_SAR(%r1)
 192
 193         loadgp
 194
 195 #ifdef CONFIG_64BIT
 196         ldo     -16(%r30),%r29                  /* Reference param save area */
 197         copy    %r19,%r2                        /* W bit back to r2 */
 198 #else
 199         /* no need to save these on stack in wide mode because the first 8
 200          * args are passed in registers */
 201         stw     %r22, -52(%r30)                 /* 5th argument */
 202         stw     %r21, -56(%r30)                 /* 6th argument */
 203 #endif
 204
 205         /* Are we being ptraced? */
 206         mfctl   %cr30, %r1
 207         LDREG   TI_FLAGS(%r1),%r1
 208         ldi     _TIF_SYSCALL_TRACE_MASK, %r19
 209         and,COND(=) %r1, %r19, %r0
 210         b,n     .Ltracesys
 211
 212         /* Note!  We cannot use the syscall table that is mapped
 213         nearby since the gateway page is mapped execute-only. */
 214
 215 #ifdef CONFIG_64BIT
 216         ldil    L%sys_call_table, %r1
 217         or,=    %r2,%r2,%r2
 218         addil   L%(sys_call_table64-sys_call_table), %r1
 219         ldo     R%sys_call_table(%r1), %r19
 220         or,=    %r2,%r2,%r2
 221         ldo     R%sys_call_table64(%r1), %r19
 222 #else
 223         ldil    L%sys_call_table, %r1
 224         ldo     R%sys_call_table(%r1), %r19
 225 #endif
 226         comiclr,>>      __NR_Linux_syscalls, %r20, %r0
 227         b,n     .Lsyscall_nosys
 228
 229         LDREGX  %r20(%r19), %r19
 230
 231         /* If this is a sys_rt_sigreturn call, and the signal was received
 232          * when not in_syscall, then we want to return via syscall_exit_rfi,
 233          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 234          * trampoline code in signal.c).
 235          */
 236         ldi     __NR_rt_sigreturn,%r2
 237         comb,=  %r2,%r20,.Lrt_sigreturn
 238 .Lin_syscall:
 239         ldil    L%syscall_exit,%r2
 240         be      0(%sr7,%r19)
 241         ldo     R%syscall_exit(%r2),%r2
 242 .Lrt_sigreturn:
 243         comib,<> 0,%r25,.Lin_syscall
 244         ldil    L%syscall_exit_rfi,%r2
 245         be      0(%sr7,%r19)
 246         ldo     R%syscall_exit_rfi(%r2),%r2
 247
 248         /* Note!  Because we are not running where we were linked, any
 249         calls to functions external to this file must be indirect.  To
 250         be safe, we apply the opposite rule to functions within this
 251         file, with local labels given to them to ensure correctness. */
 252
 253 .Lsyscall_nosys:
 254 syscall_nosys:
 255         ldil    L%syscall_exit,%r1
 256         be      R%syscall_exit(%sr7,%r1)
 257         ldo     -ENOSYS(%r0),%r28                  /* set errno */
 258
 259
 260 /* Warning! This trace code is a virtual duplicate of the code above so be
 261  * sure to maintain both! */
 262 .Ltracesys:
 263 tracesys:
 264         /* Need to save more registers so the debugger can see where we
 265          * are.  This saves only the lower 8 bits of PSW, so that the C
 266          * bit is still clear on syscalls, and the D bit is set if this
 267          * full register save path has been executed.  We check the D
 268          * bit on syscall_return_rfi to determine which registers to
 269          * restore.  An interrupt results in a full PSW saved with the
 270          * C bit set, a non-straced syscall entry results in C and D clear
 271          * in the saved PSW.
 272          */
 273         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 274         LDREG   TI_TASK(%r1), %r1
 275         ssm     0,%r2
 276         STREG   %r2,TASK_PT_PSW(%r1)            /* Lower 8 bits only!! */
 277         mfsp    %sr0,%r2
 278         STREG   %r2,TASK_PT_SR0(%r1)
 279         mfsp    %sr1,%r2
 280         STREG   %r2,TASK_PT_SR1(%r1)
 281         mfsp    %sr2,%r2
 282         STREG   %r2,TASK_PT_SR2(%r1)
 283         mfsp    %sr3,%r2
 284         STREG   %r2,TASK_PT_SR3(%r1)
 285         STREG   %r2,TASK_PT_SR4(%r1)
 286         STREG   %r2,TASK_PT_SR5(%r1)
 287         STREG   %r2,TASK_PT_SR6(%r1)
 288         STREG   %r2,TASK_PT_SR7(%r1)
 289         STREG   %r2,TASK_PT_IASQ0(%r1)
 290         STREG   %r2,TASK_PT_IASQ1(%r1)
 291         LDREG   TASK_PT_GR31(%r1),%r2
 292         STREG   %r2,TASK_PT_IAOQ0(%r1)
 293         ldo     4(%r2),%r2
 294         STREG   %r2,TASK_PT_IAOQ1(%r1)
 295         ldo     TASK_REGS(%r1),%r2
 296         /* reg_save %r2 */
 297         STREG   %r3,PT_GR3(%r2)
 298         STREG   %r4,PT_GR4(%r2)
 299         STREG   %r5,PT_GR5(%r2)
 300         STREG   %r6,PT_GR6(%r2)
 301         STREG   %r7,PT_GR7(%r2)
 302         STREG   %r8,PT_GR8(%r2)
 303         STREG   %r9,PT_GR9(%r2)
 304         STREG   %r10,PT_GR10(%r2)
 305         STREG   %r11,PT_GR11(%r2)
 306         STREG   %r12,PT_GR12(%r2)
 307         STREG   %r13,PT_GR13(%r2)
 308         STREG   %r14,PT_GR14(%r2)
 309         STREG   %r15,PT_GR15(%r2)
 310         STREG   %r16,PT_GR16(%r2)
 311         STREG   %r17,PT_GR17(%r2)
 312         STREG   %r18,PT_GR18(%r2)
 313         /* Finished saving things for the debugger */
 314
 315         copy    %r2,%r26
 316         ldil    L%do_syscall_trace_enter,%r1
 317         ldil    L%tracesys_next,%r2
 318         be      R%do_syscall_trace_enter(%sr7,%r1)
 319         ldo     R%tracesys_next(%r2),%r2
 320
 321 tracesys_next:
 322         /* do_syscall_trace_enter either returned the syscallno, or -1L,
 323          *  so we skip restoring the PT_GR20 below, since we pulled it from
 324          *  task->thread.regs.gr[20] above.
 325          */
 326         copy    %ret0,%r20
 327         ldil    L%sys_call_table,%r1
 328         ldo     R%sys_call_table(%r1), %r19
 329
 330         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 331         LDREG   TI_TASK(%r1), %r1
 332         LDREG   TASK_PT_GR26(%r1), %r26         /* Restore the users args */
 333         LDREG   TASK_PT_GR25(%r1), %r25
 334         LDREG   TASK_PT_GR24(%r1), %r24
 335         LDREG   TASK_PT_GR23(%r1), %r23
 336         LDREG   TASK_PT_GR22(%r1), %r22
 337         LDREG   TASK_PT_GR21(%r1), %r21
 338 #ifdef CONFIG_64BIT
 339         ldo     -16(%r30),%r29                  /* Reference param save area */
 340 #else
 341         stw     %r22, -52(%r30)                 /* 5th argument */
 342         stw     %r21, -56(%r30)                 /* 6th argument */
 343 #endif
 344
 345         comiclr,>>=     __NR_Linux_syscalls, %r20, %r0
 346         b,n     .Ltracesys_nosys
 347
 348         LDREGX  %r20(%r19), %r19
 349
 350         /* If this is a sys_rt_sigreturn call, and the signal was received
 351          * when not in_syscall, then we want to return via syscall_exit_rfi,
 352          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 353          * trampoline code in signal.c).
 354          */
 355         ldi     __NR_rt_sigreturn,%r2
 356         comb,=  %r2,%r20,.Ltrace_rt_sigreturn
 357 .Ltrace_in_syscall:
 358         ldil    L%tracesys_exit,%r2
 359         be      0(%sr7,%r19)
 360         ldo     R%tracesys_exit(%r2),%r2
 361
 362 .Ltracesys_nosys:
 363         ldo     -ENOSYS(%r0),%r28               /* set errno */
 364
 365         /* Do *not* call this function on the gateway page, because it
 366         makes a direct call to syscall_trace. */
 367
 368 tracesys_exit:
 369         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 370         LDREG   TI_TASK(%r1), %r1
 371 #ifdef CONFIG_64BIT
 372         ldo     -16(%r30),%r29                  /* Reference param save area */
 373 #endif
 374         ldo     TASK_REGS(%r1),%r26
 375         BL      do_syscall_trace_exit,%r2
 376         STREG   %r28,TASK_PT_GR28(%r1)          /* save return value now */
 377         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 378         LDREG   TI_TASK(%r1), %r1
 379         LDREG   TASK_PT_GR28(%r1), %r28         /* Restore return val. */
 380
 381         ldil    L%syscall_exit,%r1
 382         be,n    R%syscall_exit(%sr7,%r1)
 383
 384 .Ltrace_rt_sigreturn:
 385         comib,<> 0,%r25,.Ltrace_in_syscall
 386         ldil    L%tracesys_sigexit,%r2
 387         be      0(%sr7,%r19)
 388         ldo     R%tracesys_sigexit(%r2),%r2
 389
 390 tracesys_sigexit:
 391         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 392         LDREG   TI_TASK(%r1), %r1
 393 #ifdef CONFIG_64BIT
 394         ldo     -16(%r30),%r29                  /* Reference param save area */
 395 #endif
 396         BL      do_syscall_trace_exit,%r2
 397         ldo     TASK_REGS(%r1),%r26
 398
 399         ldil    L%syscall_exit_rfi,%r1
 400         be,n    R%syscall_exit_rfi(%sr7,%r1)
 401
 402
 403         /*********************************************************
 404                 32/64-bit Light-Weight-Syscall ABI
 405
 406                 * - Indicates a hint for userspace inline asm
 407                 implementations.
 408
 409                 Syscall number (caller-saves)
 410                 - %r20
 411                 * In asm clobber.
 412
 413                 Argument registers (caller-saves)
 414                 - %r26, %r25, %r24, %r23, %r22
 415                 * In asm input.
 416
 417                 Return registers (caller-saves)
 418                 - %r28 (return), %r21 (errno)
 419                 * In asm output.
 420
 421                 Caller-saves registers
 422                 - %r1, %r27, %r29
 423                 - %r2 (return pointer)
 424                 - %r31 (ble link register)
 425                 * In asm clobber.
 426
 427                 Callee-saves registers
 428                 - %r3-%r18
 429                 - %r30 (stack pointer)
 430                 * Not in asm clobber.
 431
 432                 If userspace is 32-bit:
 433                 Callee-saves registers
 434                 - %r19 (32-bit PIC register)
 435
 436                 Differences from 32-bit calling convention:
 437                 - Syscall number in %r20
 438                 - Additional argument register %r22 (arg4)
 439                 - Callee-saves %r19.
 440
 441                 If userspace is 64-bit:
 442                 Callee-saves registers
 443                 - %r27 (64-bit PIC register)
 444
 445                 Differences from 64-bit calling convention:
 446                 - Syscall number in %r20
 447                 - Additional argument register %r22 (arg4)
 448                 - Callee-saves %r27.
 449
 450                 Error codes returned by entry path:
 451
 452                 ENOSYS - r20 was an invalid LWS number.
 453
 454         *********************************************************/
 455 lws_start:
 456
 457 #ifdef CONFIG_64BIT
 458         /* FIXME: If we are a 64-bit kernel just
 459          *        turn this on unconditionally.
 460          */
 461         ssm     PSW_SM_W, %r1
 462         extrd,u %r1,PSW_W_BIT,1,%r1
 463         /* sp must be aligned on 4, so deposit the W bit setting into
 464          * the bottom of sp temporarily */
 465         or,ev   %r1,%r30,%r30
 466
 467         /* Clip LWS number to a 32-bit value always */
 468         depdi   0, 31, 32, %r20
 469 #endif
 470
 471         /* Is the lws entry number valid? */
 472         comiclr,>>      __NR_lws_entries, %r20, %r0
 473         b,n     lws_exit_nosys
 474
 475         /* WARNING: Trashing sr2 and sr3 */
 476         mfsp    %sr7,%r1                        /* get userspace into sr3 */
 477         mtsp    %r1,%sr3
 478         mtsp    %r0,%sr2                        /* get kernel space into sr2 */
 479
 480         /* Load table start */
 481         ldil    L%lws_table, %r1
 482         ldo     R%lws_table(%r1), %r28  /* Scratch use of r28 */
 483         LDREGX  %r20(%sr2,r28), %r21    /* Scratch use of r21 */
 484
 485         /* Jump to lws, lws table pointers already relocated */
 486         be,n    0(%sr2,%r21)
 487
 488 lws_exit_nosys:
 489         ldo     -ENOSYS(%r0),%r21                  /* set errno */
 490         /* Fall through: Return to userspace */
 491
 492 lws_exit:
 493 #ifdef CONFIG_64BIT
 494         /* decide whether to reset the wide mode bit
 495          *
 496          * For a syscall, the W bit is stored in the lowest bit
 497          * of sp.  Extract it and reset W if it is zero */
 498         extrd,u,*<>     %r30,63,1,%r1
 499         rsm     PSW_SM_W, %r0
 500         /* now reset the lowest bit of sp if it was set */
 501         xor     %r30,%r1,%r30
 502 #endif
 503         be,n    0(%sr7, %r31)
 504
 505
 506
 507         /***************************************************
 508                 Implementing 32bit CAS as an atomic operation:
 509
 510                 %r26 - Address to examine
 511                 %r25 - Old value to check (old)
 512                 %r24 - New value to set (new)
 513                 %r28 - Return prev through this register.
 514                 %r21 - Kernel error code
 515
 516                 If debugging is DISabled:
 517
 518                 %r21 has the following meanings:
 519
 520                 EAGAIN - CAS is busy, ldcw failed, try again.
 521                 EFAULT - Read or write failed.
 522
 523                 If debugging is enabled:
 524
 525                 EDEADLOCK - CAS called recursively.
 526                 EAGAIN && r28 == 1 - CAS is busy. Lock contended.
 527                 EAGAIN && r28 == 2 - CAS is busy. ldcw failed.
 528                 EFAULT - Read or write failed.
 529
 530                 Scratch: r20, r28, r1
 531
 532         ****************************************************/
 533
 534         /* Do not enable LWS debugging */
 535 #define ENABLE_LWS_DEBUG 0
 536
 537         /* ELF64 Process entry path */
 538 lws_compare_and_swap64:
 539 #ifdef CONFIG_64BIT
 540         b,n     lws_compare_and_swap
 541 #else
 542         /* If we are not a 64-bit kernel, then we don't
 543          * have 64-bit input registers, and calling
 544          * the 64-bit LWS CAS returns ENOSYS.
 545          */
 546         b,n     lws_exit_nosys
 547 #endif
 548
 549         /* ELF32 Process entry path */
 550 lws_compare_and_swap32:
 551 #ifdef CONFIG_64BIT
 552         /* Clip all the input registers */
 553         depdi   0, 31, 32, %r26
 554         depdi   0, 31, 32, %r25
 555         depdi   0, 31, 32, %r24
 556 #endif
 557
 558 lws_compare_and_swap:
 559         /* Load start of lock table */
 560         ldil    L%lws_lock_start, %r20
 561         ldo     R%lws_lock_start(%r20), %r28
 562
 563         /* Extract four bits from r26 and hash lock (Bits 4-7) */
 564         extru  %r26, 27, 4, %r20
 565
 566         /* Find lock to use, the hash is either one of 0 to
 567            15, multiplied by 16 (keep it 16-byte aligned)
 568            and add to the lock table offset. */
 569         shlw    %r20, 4, %r20
 570         add     %r20, %r28, %r20
 571
 572 # if ENABLE_LWS_DEBUG
 573         /*
 574                 DEBUG, check for deadlock!
 575                 If the thread register values are the same
 576                 then we were the one that locked it last and
 577                 this is a recurisve call that will deadlock.
 578                 We *must* giveup this call and fail.
 579         */
 580         ldw     4(%sr2,%r20), %r28                      /* Load thread register */
 581         /* WARNING: If cr27 cycles to the same value we have problems */
 582         mfctl   %cr27, %r21                             /* Get current thread register */
 583         cmpb,<>,n       %r21, %r28, cas_lock            /* Called recursive? */
 584         b       lws_exit                                /* Return error! */
 585         ldo     -EDEADLOCK(%r0), %r21
 586 cas_lock:
 587         cmpb,=,n        %r0, %r28, cas_nocontend        /* Is nobody using it? */
 588         ldo     1(%r0), %r28                            /* 1st case */
 589         b       lws_exit                                /* Contended... */
 590         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 591 cas_nocontend:
 592 # endif
 593 /* ENABLE_LWS_DEBUG */
 594
 595         rsm     PSW_SM_I, %r0                           /* Disable interrupts */
 596         /* COW breaks can cause contention on UP systems */
 597         LDCW    0(%sr2,%r20), %r28                      /* Try to acquire the lock */
 598         cmpb,<>,n       %r0, %r28, cas_action           /* Did we get it? */
 599 cas_wouldblock:
 600         ldo     2(%r0), %r28                            /* 2nd case */
 601         ssm     PSW_SM_I, %r0
 602         b       lws_exit                                /* Contended... */
 603         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 604
 605         /*
 606                 prev = *addr;
 607                 if ( prev == old )
 608                   *addr = new;
 609                 return prev;
 610         */
 611
 612         /* NOTES:
 613                 This all works becuse intr_do_signal
 614                 and schedule both check the return iasq
 615                 and see that we are on the kernel page
 616                 so this process is never scheduled off
 617                 or is ever sent any signal of any sort,
 618                 thus it is wholly atomic from usrspaces
 619                 perspective
 620         */
 621 cas_action:
 622 #if defined CONFIG_SMP && ENABLE_LWS_DEBUG
 623         /* DEBUG */
 624         mfctl   %cr27, %r1
 625         stw     %r1, 4(%sr2,%r20)
 626 #endif
 627         /* The load and store could fail */
 628 1:      ldw,ma  0(%sr3,%r26), %r28
 629         sub,<>  %r28, %r25, %r0
 630 2:      stw,ma  %r24, 0(%sr3,%r26)
 631         /* Free lock */
 632         stw,ma  %r20, 0(%sr2,%r20)
 633 #if ENABLE_LWS_DEBUG
 634         /* Clear thread register indicator */
 635         stw     %r0, 4(%sr2,%r20)
 636 #endif
 637         /* Enable interrupts */
 638         ssm     PSW_SM_I, %r0
 639         /* Return to userspace, set no error */
 640         b       lws_exit
 641         copy    %r0, %r21
 642
 643 3:
 644         /* Error occurred on load or store */
 645         /* Free lock */
 646         stw     %r20, 0(%sr2,%r20)
 647 #if ENABLE_LWS_DEBUG
 648         stw     %r0, 4(%sr2,%r20)
 649 #endif
 650         ssm     PSW_SM_I, %r0
 651         b       lws_exit
 652         ldo     -EFAULT(%r0),%r21       /* set errno */
 653         nop
 654         nop
 655         nop
 656         nop
 657
 658         /* Two exception table entries, one for the load,
 659            the other for the store. Either return -EFAULT.
 660            Each of the entries must be relocated. */
 661         ASM_EXCEPTIONTABLE_ENTRY(1b-linux_gateway_page, 3b-linux_gateway_page)
 662         ASM_EXCEPTIONTABLE_ENTRY(2b-linux_gateway_page, 3b-linux_gateway_page)
 663
 664
 665         /***************************************************
 666                 New CAS implementation which uses pointers and variable size
 667                 information. The value pointed by old and new MUST NOT change
 668                 while performing CAS. The lock only protect the value at %r26.
 669
 670                 %r26 - Address to examine
 671                 %r25 - Pointer to the value to check (old)
 672                 %r24 - Pointer to the value to set (new)
 673                 %r23 - Size of the variable (0/1/2/3 for 8/16/32/64 bit)
 674                 %r28 - Return non-zero on failure
 675                 %r21 - Kernel error code
 676
 677                 %r21 has the following meanings:
 678
 679                 EAGAIN - CAS is busy, ldcw failed, try again.
 680                 EFAULT - Read or write failed.
 681
 682                 Scratch: r20, r22, r28, r29, r1, fr4 (32bit for 64bit CAS only)
 683
 684         ****************************************************/
 685
 686         /* ELF32 Process entry path */
 687 lws_compare_and_swap_2:
 688 #ifdef CONFIG_64BIT
 689         /* Clip the input registers */
 690         depdi   0, 31, 32, %r26
 691         depdi   0, 31, 32, %r25
 692         depdi   0, 31, 32, %r24
 693         depdi   0, 31, 32, %r23
 694 #endif
 695
 696         /* Check the validity of the size pointer */
 697         subi,>>= 4, %r23, %r0
 698         b,n     lws_exit_nosys
 699
 700         /* Jump to the functions which will load the old and new values into
 701            registers depending on the their size */
 702         shlw    %r23, 2, %r29
 703         blr     %r29, %r0
 704         nop
 705
 706         /* 8bit load */
 707 4:      ldb     0(%sr3,%r25), %r25
 708         b       cas2_lock_start
 709 5:      ldb     0(%sr3,%r24), %r24
 710         nop
 711         nop
 712         nop
 713         nop
 714         nop
 715
 716         /* 16bit load */
 717 6:      ldh     0(%sr3,%r25), %r25
 718         b       cas2_lock_start
 719 7:      ldh     0(%sr3,%r24), %r24
 720         nop
 721         nop
 722         nop
 723         nop
 724         nop
 725
 726         /* 32bit load */
 727 8:      ldw     0(%sr3,%r25), %r25
 728         b       cas2_lock_start
 729 9:      ldw     0(%sr3,%r24), %r24
 730         nop
 731         nop
 732         nop
 733         nop
 734         nop
 735
 736         /* 64bit load */
 737 #ifdef CONFIG_64BIT
 738 10:     ldd     0(%sr3,%r25), %r25
 739 11:     ldd     0(%sr3,%r24), %r24
 740 #else
 741         /* Load new value into r22/r23 - high/low */
 742 10:     ldw     0(%sr3,%r25), %r22
 743 11:     ldw     4(%sr3,%r25), %r23
 744         /* Load new value into fr4 for atomic store later */
 745 12:     flddx   0(%sr3,%r24), %fr4
 746 #endif
 747
 748 cas2_lock_start:
 749         /* Load start of lock table */
 750         ldil    L%lws_lock_start, %r20
 751         ldo     R%lws_lock_start(%r20), %r28
 752
 753         /* Extract four bits from r26 and hash lock (Bits 4-7) */
 754         extru  %r26, 27, 4, %r20
 755
 756         /* Find lock to use, the hash is either one of 0 to
 757            15, multiplied by 16 (keep it 16-byte aligned)
 758            and add to the lock table offset. */
 759         shlw    %r20, 4, %r20
 760         add     %r20, %r28, %r20
 761
 762         rsm     PSW_SM_I, %r0                   /* Disable interrupts */
 763         /* COW breaks can cause contention on UP systems */
 764         LDCW    0(%sr2,%r20), %r28              /* Try to acquire the lock */
 765         cmpb,<>,n       %r0, %r28, cas2_action  /* Did we get it? */
 766 cas2_wouldblock:
 767         ldo     2(%r0), %r28                    /* 2nd case */
 768         ssm     PSW_SM_I, %r0
 769         b       lws_exit                        /* Contended... */
 770         ldo     -EAGAIN(%r0), %r21              /* Spin in userspace */
 771
 772         /*
 773                 prev = *addr;
 774                 if ( prev == old )
 775                   *addr = new;
 776                 return prev;
 777         */
 778
 779         /* NOTES:
 780                 This all works becuse intr_do_signal
 781                 and schedule both check the return iasq
 782                 and see that we are on the kernel page
 783                 so this process is never scheduled off
 784                 or is ever sent any signal of any sort,
 785                 thus it is wholly atomic from usrspaces
 786                 perspective
 787         */
 788 cas2_action:
 789         /* Jump to the correct function */
 790         blr     %r29, %r0
 791         /* Set %r28 as non-zero for now */
 792         ldo     1(%r0),%r28
 793
 794         /* 8bit CAS */
 795 13:     ldb,ma  0(%sr3,%r26), %r29
 796         sub,=   %r29, %r25, %r0
 797         b,n     cas2_end
 798 14:     stb,ma  %r24, 0(%sr3,%r26)
 799         b       cas2_end
 800         copy    %r0, %r28
 801         nop
 802         nop
 803
 804         /* 16bit CAS */
 805 15:     ldh,ma  0(%sr3,%r26), %r29
 806         sub,=   %r29, %r25, %r0
 807         b,n     cas2_end
 808 16:     sth,ma  %r24, 0(%sr3,%r26)
 809         b       cas2_end
 810         copy    %r0, %r28
 811         nop
 812         nop
 813
 814         /* 32bit CAS */
 815 17:     ldw,ma  0(%sr3,%r26), %r29
 816         sub,=   %r29, %r25, %r0
 817         b,n     cas2_end
 818 18:     stw,ma  %r24, 0(%sr3,%r26)
 819         b       cas2_end
 820         copy    %r0, %r28
 821         nop
 822         nop
 823
 824         /* 64bit CAS */
 825 #ifdef CONFIG_64BIT
 826 19:     ldd,ma  0(%sr3,%r26), %r29
 827         sub,*=  %r29, %r25, %r0
 828         b,n     cas2_end
 829 20:     std,ma  %r24, 0(%sr3,%r26)
 830         copy    %r0, %r28
 831 #else
 832         /* Compare first word */
 833 19:     ldw,ma  0(%sr3,%r26), %r29
 834         sub,=   %r29, %r22, %r0
 835         b,n     cas2_end
 836         /* Compare second word */
 837 20:     ldw,ma  4(%sr3,%r26), %r29
 838         sub,=   %r29, %r23, %r0
 839         b,n     cas2_end
 840         /* Perform the store */
 841 21:     fstdx   %fr4, 0(%sr3,%r26)
 842         copy    %r0, %r28
 843 #endif
 844
 845 cas2_end:
 846         /* Free lock */
 847         stw,ma  %r20, 0(%sr2,%r20)
 848         /* Enable interrupts */
 849         ssm     PSW_SM_I, %r0
 850         /* Return to userspace, set no error */
 851         b       lws_exit
 852         copy    %r0, %r21
 853
 854 22:
 855         /* Error occurred on load or store */
 856         /* Free lock */
 857         stw     %r20, 0(%sr2,%r20)
 858         ssm     PSW_SM_I, %r0
 859         ldo     1(%r0),%r28
 860         b       lws_exit
 861         ldo     -EFAULT(%r0),%r21       /* set errno */
 862         nop
 863         nop
 864         nop
 865
 866         /* Exception table entries, for the load and store, return EFAULT.
 867            Each of the entries must be relocated. */
 868         ASM_EXCEPTIONTABLE_ENTRY(4b-linux_gateway_page, 22b-linux_gateway_page)
 869         ASM_EXCEPTIONTABLE_ENTRY(5b-linux_gateway_page, 22b-linux_gateway_page)
 870         ASM_EXCEPTIONTABLE_ENTRY(6b-linux_gateway_page, 22b-linux_gateway_page)
 871         ASM_EXCEPTIONTABLE_ENTRY(7b-linux_gateway_page, 22b-linux_gateway_page)
 872         ASM_EXCEPTIONTABLE_ENTRY(8b-linux_gateway_page, 22b-linux_gateway_page)
 873         ASM_EXCEPTIONTABLE_ENTRY(9b-linux_gateway_page, 22b-linux_gateway_page)
 874         ASM_EXCEPTIONTABLE_ENTRY(10b-linux_gateway_page, 22b-linux_gateway_page)
 875         ASM_EXCEPTIONTABLE_ENTRY(11b-linux_gateway_page, 22b-linux_gateway_page)
 876         ASM_EXCEPTIONTABLE_ENTRY(13b-linux_gateway_page, 22b-linux_gateway_page)
 877         ASM_EXCEPTIONTABLE_ENTRY(14b-linux_gateway_page, 22b-linux_gateway_page)
 878         ASM_EXCEPTIONTABLE_ENTRY(15b-linux_gateway_page, 22b-linux_gateway_page)
 879         ASM_EXCEPTIONTABLE_ENTRY(16b-linux_gateway_page, 22b-linux_gateway_page)
 880         ASM_EXCEPTIONTABLE_ENTRY(17b-linux_gateway_page, 22b-linux_gateway_page)
 881         ASM_EXCEPTIONTABLE_ENTRY(18b-linux_gateway_page, 22b-linux_gateway_page)
 882         ASM_EXCEPTIONTABLE_ENTRY(19b-linux_gateway_page, 22b-linux_gateway_page)
 883         ASM_EXCEPTIONTABLE_ENTRY(20b-linux_gateway_page, 22b-linux_gateway_page)
 884 #ifndef CONFIG_64BIT
 885         ASM_EXCEPTIONTABLE_ENTRY(12b-linux_gateway_page, 22b-linux_gateway_page)
 886         ASM_EXCEPTIONTABLE_ENTRY(21b-linux_gateway_page, 22b-linux_gateway_page)
 887 #endif
 888
 889         /* Make sure nothing else is placed on this page */
 890         .align PAGE_SIZE
 891 END(linux_gateway_page)
 892 ENTRY(end_linux_gateway_page)
 893
 894         /* Relocate symbols assuming linux_gateway_page is mapped
 895            to virtual address 0x0 */
 896
 897 #define LWS_ENTRY(_name_) ASM_ULONG_INSN (lws_##_name_ - linux_gateway_page)
 898
 899         .section .rodata,"a"
 900
 901         .align 8
 902         /* Light-weight-syscall table */
 903         /* Start of lws table. */
 904 ENTRY(lws_table)
 905         LWS_ENTRY(compare_and_swap32)           /* 0 - ELF32 Atomic 32bit CAS */
 906         LWS_ENTRY(compare_and_swap64)           /* 1 - ELF64 Atomic 32bit CAS */
 907         LWS_ENTRY(compare_and_swap_2)           /* 2 - ELF32 Atomic 64bit CAS */
 908 END(lws_table)
 909         /* End of lws table */
 910
 911         .align 8
 912 ENTRY(sys_call_table)
 913 #include "syscall_table.S"
 914 END(sys_call_table)
 915
 916 #ifdef CONFIG_64BIT
 917         .align 8
 918 ENTRY(sys_call_table64)
 919 #define SYSCALL_TABLE_64BIT
 920 #include "syscall_table.S"
 921 END(sys_call_table64)
 922 #endif
 923
 924         /*
 925                 All light-weight-syscall atomic operations
 926                 will use this set of locks
 927
 928                 NOTE: The lws_lock_start symbol must be
 929                 at least 16-byte aligned for safe use
 930                 with ldcw.
 931         */
 932         .section .data
 933         .align  L1_CACHE_BYTES
 934 ENTRY(lws_lock_start)
 935         /* lws locks */
 936         .rept 16
 937         /* Keep locks aligned at 16-bytes */
 938         .word 1
 939         .word 0
 940         .word 0
 941         .word 0
 942         .endr
 943 END(lws_lock_start)
 944         .previous
 945
 946 .end
 947
 948