projects / deliverable / linux.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
Merge branch 'akpm-current/current'
[deliverable/linux.git] / include / asm-generic / vmlinux.lds.h
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 #include <linux/export.h>
58
59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
60 #define ALIGN_FUNCTION() . = ALIGN(8)
61
62 /*
63 * Align to a 32 byte boundary equal to the
64 * alignment gcc 4.5 uses for a struct
65 */
66 #define STRUCT_ALIGNMENT 32
67 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
68
69 /* The actual configuration determine if the init/exit sections
70 * are handled as text/data or they can be discarded (which
71 * often happens at runtime)
72 */
73 #ifdef CONFIG_HOTPLUG_CPU
74 #define CPU_KEEP(sec) *(.cpu##sec)
75 #define CPU_DISCARD(sec)
76 #else
77 #define CPU_KEEP(sec)
78 #define CPU_DISCARD(sec) *(.cpu##sec)
79 #endif
80
81 #if defined(CONFIG_MEMORY_HOTPLUG)
82 #define MEM_KEEP(sec) *(.mem##sec)
83 #define MEM_DISCARD(sec)
84 #else
85 #define MEM_KEEP(sec)
86 #define MEM_DISCARD(sec) *(.mem##sec)
87 #endif
88
89 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
90 #define MCOUNT_REC() . = ALIGN(8); \
91 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
92 *(__mcount_loc) \
93 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
94 #else
95 #define MCOUNT_REC()
96 #endif
97
98 #ifdef CONFIG_TRACE_BRANCH_PROFILING
99 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
100 *(_ftrace_annotated_branch) \
101 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
102 #else
103 #define LIKELY_PROFILE()
104 #endif
105
106 #ifdef CONFIG_PROFILE_ALL_BRANCHES
107 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
108 *(_ftrace_branch) \
109 VMLINUX_SYMBOL(__stop_branch_profile) = .;
110 #else
111 #define BRANCH_PROFILE()
112 #endif
113
114 #ifdef CONFIG_KPROBES
115 #define KPROBE_BLACKLIST() . = ALIGN(8); \
116 VMLINUX_SYMBOL(__start_kprobe_blacklist) = .; \
117 *(_kprobe_blacklist) \
118 VMLINUX_SYMBOL(__stop_kprobe_blacklist) = .;
119 #else
120 #define KPROBE_BLACKLIST()
121 #endif
122
123 #ifdef CONFIG_EVENT_TRACING
124 #define FTRACE_EVENTS() . = ALIGN(8); \
125 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
126 *(_ftrace_events) \
127 VMLINUX_SYMBOL(__stop_ftrace_events) = .; \
128 VMLINUX_SYMBOL(__start_ftrace_enum_maps) = .; \
129 *(_ftrace_enum_map) \
130 VMLINUX_SYMBOL(__stop_ftrace_enum_maps) = .;
131 #else
132 #define FTRACE_EVENTS()
133 #endif
134
135 #ifdef CONFIG_TRACING
136 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
137 *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
138 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
139 #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \
140 *(__tracepoint_str) /* Trace_printk fmt' pointer */ \
141 VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
142 #else
143 #define TRACE_PRINTKS()
144 #define TRACEPOINT_STR()
145 #endif
146
147 #ifdef CONFIG_FTRACE_SYSCALLS
148 #define TRACE_SYSCALLS() . = ALIGN(8); \
149 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
150 *(__syscalls_metadata) \
151 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
152 #else
153 #define TRACE_SYSCALLS()
154 #endif
155
156 #ifdef CONFIG_SERIAL_EARLYCON
157 #define EARLYCON_TABLE() STRUCT_ALIGN(); \
158 VMLINUX_SYMBOL(__earlycon_table) = .; \
159 *(__earlycon_table) \
160 VMLINUX_SYMBOL(__earlycon_table_end) = .;
161 #else
162 #define EARLYCON_TABLE()
163 #endif
164
165 #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
166 #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
167 #define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
168 #define _OF_TABLE_0(name)
169 #define _OF_TABLE_1(name) \
170 . = ALIGN(8); \
171 VMLINUX_SYMBOL(__##name##_of_table) = .; \
172 *(__##name##_of_table) \
173 *(__##name##_of_table_end)
174
175 #define CLKSRC_OF_TABLES() OF_TABLE(CONFIG_CLKSRC_OF, clksrc)
176 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
177 #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
178 #define IOMMU_OF_TABLES() OF_TABLE(CONFIG_OF_IOMMU, iommu)
179 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
180 #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
181 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
182
183 #ifdef CONFIG_ACPI
184 #define ACPI_PROBE_TABLE(name) \
185 . = ALIGN(8); \
186 VMLINUX_SYMBOL(__##name##_acpi_probe_table) = .; \
187 *(__##name##_acpi_probe_table) \
188 VMLINUX_SYMBOL(__##name##_acpi_probe_table_end) = .;
189 #else
190 #define ACPI_PROBE_TABLE(name)
191 #endif
192
193 #define KERNEL_DTB() \
194 STRUCT_ALIGN(); \
195 VMLINUX_SYMBOL(__dtb_start) = .; \
196 *(.dtb.init.rodata) \
197 VMLINUX_SYMBOL(__dtb_end) = .;
198
199 /*
200 * .data section
201 * -fdata-sections generates .data.identifier which needs to be pulled in
202 * with .data, but don't want to pull in .data..stuff which has its own
203 * requirements. Same for bss.
204 */
205 #define DATA_DATA \
206 *(.data .data.[0-9a-zA-Z_]*) \
207 *(.ref.data) \
208 *(.data..shared_aligned) /* percpu related */ \
209 MEM_KEEP(init.data) \
210 MEM_KEEP(exit.data) \
211 *(.data.unlikely) \
212 STRUCT_ALIGN(); \
213 *(__tracepoints) \
214 /* implement dynamic printk debug */ \
215 . = ALIGN(8); \
216 VMLINUX_SYMBOL(__start___jump_table) = .; \
217 *(__jump_table) \
218 VMLINUX_SYMBOL(__stop___jump_table) = .; \
219 . = ALIGN(8); \
220 VMLINUX_SYMBOL(__start___verbose) = .; \
221 *(__verbose) \
222 VMLINUX_SYMBOL(__stop___verbose) = .; \
223 LIKELY_PROFILE() \
224 BRANCH_PROFILE() \
225 TRACE_PRINTKS() \
226 TRACEPOINT_STR()
227
228 /*
229 * Data section helpers
230 */
231 #define NOSAVE_DATA \
232 . = ALIGN(PAGE_SIZE); \
233 VMLINUX_SYMBOL(__nosave_begin) = .; \
234 *(.data..nosave) \
235 . = ALIGN(PAGE_SIZE); \
236 VMLINUX_SYMBOL(__nosave_end) = .;
237
238 #define PAGE_ALIGNED_DATA(page_align) \
239 . = ALIGN(page_align); \
240 *(.data..page_aligned)
241
242 #define READ_MOSTLY_DATA(align) \
243 . = ALIGN(align); \
244 *(.data..read_mostly) \
245 . = ALIGN(align);
246
247 #define CACHELINE_ALIGNED_DATA(align) \
248 . = ALIGN(align); \
249 *(.data..cacheline_aligned)
250
251 #define INIT_TASK_DATA(align) \
252 . = ALIGN(align); \
253 VMLINUX_SYMBOL(__start_init_task) = .; \
254 *(.data..init_task) \
255 VMLINUX_SYMBOL(__end_init_task) = .;
256
257 /*
258 * Allow architectures to handle ro_after_init data on their
259 * own by defining an empty RO_AFTER_INIT_DATA.
260 */
261 #ifndef RO_AFTER_INIT_DATA
262 #define RO_AFTER_INIT_DATA *(.data..ro_after_init)
263 #endif
264
265 /*
266 * Read only Data
267 */
268 #define RO_DATA_SECTION(align) \
269 . = ALIGN((align)); \
270 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
271 VMLINUX_SYMBOL(__start_rodata) = .; \
272 *(.rodata) *(.rodata.*) \
273 RO_AFTER_INIT_DATA /* Read only after init */ \
274 *(__vermagic) /* Kernel version magic */ \
275 . = ALIGN(8); \
276 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
277 *(__tracepoints_ptrs) /* Tracepoints: pointer array */\
278 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
279 *(__tracepoints_strings)/* Tracepoints: strings */ \
280 } \
281 \
282 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
283 *(.rodata1) \
284 } \
285 \
286 BUG_TABLE \
287 \
288 /* PCI quirks */ \
289 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
290 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
291 *(.pci_fixup_early) \
292 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
293 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
294 *(.pci_fixup_header) \
295 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
296 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
297 *(.pci_fixup_final) \
298 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
299 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
300 *(.pci_fixup_enable) \
301 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
302 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
303 *(.pci_fixup_resume) \
304 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
305 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
306 *(.pci_fixup_resume_early) \
307 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
308 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
309 *(.pci_fixup_suspend) \
310 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
311 VMLINUX_SYMBOL(__start_pci_fixups_suspend_late) = .; \
312 *(.pci_fixup_suspend_late) \
313 VMLINUX_SYMBOL(__end_pci_fixups_suspend_late) = .; \
314 } \
315 \
316 /* Built-in firmware blobs */ \
317 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
318 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
319 *(.builtin_fw) \
320 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
321 } \
322 \
323 TRACEDATA \
324 \
325 /* Kernel symbol table: Normal symbols */ \
326 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
327 VMLINUX_SYMBOL(__start___ksymtab) = .; \
328 KEEP(*(SORT(___ksymtab+*))) \
329 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
330 } \
331 \
332 /* Kernel symbol table: GPL-only symbols */ \
333 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
334 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
335 KEEP(*(SORT(___ksymtab_gpl+*))) \
336 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
337 } \
338 \
339 /* Kernel symbol table: Normal unused symbols */ \
340 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
341 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
342 KEEP(*(SORT(___ksymtab_unused+*))) \
343 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
344 } \
345 \
346 /* Kernel symbol table: GPL-only unused symbols */ \
347 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
348 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
349 KEEP(*(SORT(___ksymtab_unused_gpl+*))) \
350 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
351 } \
352 \
353 /* Kernel symbol table: GPL-future-only symbols */ \
354 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
355 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
356 KEEP(*(SORT(___ksymtab_gpl_future+*))) \
357 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
358 } \
359 \
360 /* Kernel symbol table: Normal symbols */ \
361 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
362 VMLINUX_SYMBOL(__start___kcrctab) = .; \
363 KEEP(*(SORT(___kcrctab+*))) \
364 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
365 } \
366 \
367 /* Kernel symbol table: GPL-only symbols */ \
368 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
369 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
370 KEEP(*(SORT(___kcrctab_gpl+*))) \
371 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
372 } \
373 \
374 /* Kernel symbol table: Normal unused symbols */ \
375 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
376 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
377 KEEP(*(SORT(___kcrctab_unused+*))) \
378 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
379 } \
380 \
381 /* Kernel symbol table: GPL-only unused symbols */ \
382 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
383 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
384 KEEP(*(SORT(___kcrctab_unused_gpl+*))) \
385 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
386 } \
387 \
388 /* Kernel symbol table: GPL-future-only symbols */ \
389 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
390 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
391 KEEP(*(SORT(___kcrctab_gpl_future+*))) \
392 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
393 } \
394 \
395 /* Kernel symbol table: strings */ \
396 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
397 KEEP(*(__ksymtab_strings)) \
398 } \
399 \
400 /* __*init sections */ \
401 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
402 *(.ref.rodata) \
403 MEM_KEEP(init.rodata) \
404 MEM_KEEP(exit.rodata) \
405 } \
406 \
407 /* Built-in module parameters. */ \
408 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
409 VMLINUX_SYMBOL(__start___param) = .; \
410 *(__param) \
411 VMLINUX_SYMBOL(__stop___param) = .; \
412 } \
413 \
414 /* Built-in module versions. */ \
415 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
416 VMLINUX_SYMBOL(__start___modver) = .; \
417 *(__modver) \
418 VMLINUX_SYMBOL(__stop___modver) = .; \
419 . = ALIGN((align)); \
420 VMLINUX_SYMBOL(__end_rodata) = .; \
421 } \
422 . = ALIGN((align));
423
424 /* RODATA & RO_DATA provided for backward compatibility.
425 * All archs are supposed to use RO_DATA() */
426 #define RODATA RO_DATA_SECTION(4096)
427 #define RO_DATA(align) RO_DATA_SECTION(align)
428
429 #define SECURITY_INIT \
430 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
431 VMLINUX_SYMBOL(__security_initcall_start) = .; \
432 KEEP(*(.security_initcall.init)) \
433 VMLINUX_SYMBOL(__security_initcall_end) = .; \
434 }
435
436 /* .text section. Map to function alignment to avoid address changes
437 * during second ld run in second ld pass when generating System.map */
438 #define TEXT_TEXT \
439 ALIGN_FUNCTION(); \
440 *(.text.hot .text .text.fixup .text.unlikely .text.*) \
441 *(.ref.text) \
442 MEM_KEEP(init.text) \
443 MEM_KEEP(exit.text) \
444
445
446 /* sched.text is aling to function alignment to secure we have same
447 * address even at second ld pass when generating System.map */
448 #define SCHED_TEXT \
449 ALIGN_FUNCTION(); \
450 VMLINUX_SYMBOL(__sched_text_start) = .; \
451 *(.sched.text) \
452 VMLINUX_SYMBOL(__sched_text_end) = .;
453
454 /* spinlock.text is aling to function alignment to secure we have same
455 * address even at second ld pass when generating System.map */
456 #define LOCK_TEXT \
457 ALIGN_FUNCTION(); \
458 VMLINUX_SYMBOL(__lock_text_start) = .; \
459 *(.spinlock.text) \
460 VMLINUX_SYMBOL(__lock_text_end) = .;
461
462 #define CPUIDLE_TEXT \
463 ALIGN_FUNCTION(); \
464 VMLINUX_SYMBOL(__cpuidle_text_start) = .; \
465 *(.cpuidle.text) \
466 VMLINUX_SYMBOL(__cpuidle_text_end) = .;
467
468 #define KPROBES_TEXT \
469 ALIGN_FUNCTION(); \
470 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
471 *(.kprobes.text) \
472 VMLINUX_SYMBOL(__kprobes_text_end) = .;
473
474 #define ENTRY_TEXT \
475 ALIGN_FUNCTION(); \
476 VMLINUX_SYMBOL(__entry_text_start) = .; \
477 *(.entry.text) \
478 VMLINUX_SYMBOL(__entry_text_end) = .;
479
480 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
481 #define IRQENTRY_TEXT \
482 ALIGN_FUNCTION(); \
483 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
484 *(.irqentry.text) \
485 VMLINUX_SYMBOL(__irqentry_text_end) = .;
486 #else
487 #define IRQENTRY_TEXT
488 #endif
489
490 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
491 #define SOFTIRQENTRY_TEXT \
492 ALIGN_FUNCTION(); \
493 VMLINUX_SYMBOL(__softirqentry_text_start) = .; \
494 *(.softirqentry.text) \
495 VMLINUX_SYMBOL(__softirqentry_text_end) = .;
496 #else
497 #define SOFTIRQENTRY_TEXT
498 #endif
499
500 /* Section used for early init (in .S files) */
501 #define HEAD_TEXT *(.head.text)
502
503 #define HEAD_TEXT_SECTION \
504 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
505 HEAD_TEXT \
506 }
507
508 /*
509 * Exception table
510 */
511 #define EXCEPTION_TABLE(align) \
512 . = ALIGN(align); \
513 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
514 VMLINUX_SYMBOL(__start___ex_table) = .; \
515 *(__ex_table) \
516 VMLINUX_SYMBOL(__stop___ex_table) = .; \
517 }
518
519 /*
520 * Init task
521 */
522 #define INIT_TASK_DATA_SECTION(align) \
523 . = ALIGN(align); \
524 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
525 INIT_TASK_DATA(align) \
526 }
527
528 #ifdef CONFIG_CONSTRUCTORS
529 #define KERNEL_CTORS() . = ALIGN(8); \
530 VMLINUX_SYMBOL(__ctors_start) = .; \
531 *(.ctors) \
532 *(SORT(.init_array.*)) \
533 *(.init_array) \
534 VMLINUX_SYMBOL(__ctors_end) = .;
535 #else
536 #define KERNEL_CTORS()
537 #endif
538
539 /* init and exit section handling */
540 #define INIT_DATA \
541 KEEP(*(SORT(___kentry+*))) \
542 *(.init.data) \
543 MEM_DISCARD(init.data) \
544 KERNEL_CTORS() \
545 MCOUNT_REC() \
546 *(.init.rodata) \
547 FTRACE_EVENTS() \
548 TRACE_SYSCALLS() \
549 KPROBE_BLACKLIST() \
550 MEM_DISCARD(init.rodata) \
551 CLK_OF_TABLES() \
552 RESERVEDMEM_OF_TABLES() \
553 CLKSRC_OF_TABLES() \
554 IOMMU_OF_TABLES() \
555 CPU_METHOD_OF_TABLES() \
556 CPUIDLE_METHOD_OF_TABLES() \
557 KERNEL_DTB() \
558 IRQCHIP_OF_MATCH_TABLE() \
559 ACPI_PROBE_TABLE(irqchip) \
560 ACPI_PROBE_TABLE(clksrc) \
561 EARLYCON_TABLE()
562
563 #define INIT_TEXT \
564 *(.init.text) \
565 *(.text.startup) \
566 MEM_DISCARD(init.text)
567
568 #define EXIT_DATA \
569 *(.exit.data) \
570 *(.fini_array) \
571 *(.dtors) \
572 MEM_DISCARD(exit.data) \
573 MEM_DISCARD(exit.rodata)
574
575 #define EXIT_TEXT \
576 *(.exit.text) \
577 *(.text.exit) \
578 MEM_DISCARD(exit.text)
579
580 #define EXIT_CALL \
581 *(.exitcall.exit)
582
583 /*
584 * bss (Block Started by Symbol) - uninitialized data
585 * zeroed during startup
586 */
587 #define SBSS(sbss_align) \
588 . = ALIGN(sbss_align); \
589 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
590 *(.sbss) \
591 *(.scommon) \
592 }
593
594 /*
595 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
596 * sections to the front of bss.
597 */
598 #ifndef BSS_FIRST_SECTIONS
599 #define BSS_FIRST_SECTIONS
600 #endif
601
602 #define BSS(bss_align) \
603 . = ALIGN(bss_align); \
604 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
605 BSS_FIRST_SECTIONS \
606 *(.bss..page_aligned) \
607 *(.dynbss) \
608 *(.bss .bss.[0-9a-zA-Z_]*) \
609 *(COMMON) \
610 }
611
612 /*
613 * DWARF debug sections.
614 * Symbols in the DWARF debugging sections are relative to
615 * the beginning of the section so we begin them at 0.
616 */
617 #define DWARF_DEBUG \
618 /* DWARF 1 */ \
619 .debug 0 : { *(.debug) } \
620 .line 0 : { *(.line) } \
621 /* GNU DWARF 1 extensions */ \
622 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
623 .debug_sfnames 0 : { *(.debug_sfnames) } \
624 /* DWARF 1.1 and DWARF 2 */ \
625 .debug_aranges 0 : { *(.debug_aranges) } \
626 .debug_pubnames 0 : { *(.debug_pubnames) } \
627 /* DWARF 2 */ \
628 .debug_info 0 : { *(.debug_info \
629 .gnu.linkonce.wi.*) } \
630 .debug_abbrev 0 : { *(.debug_abbrev) } \
631 .debug_line 0 : { *(.debug_line) } \
632 .debug_frame 0 : { *(.debug_frame) } \
633 .debug_str 0 : { *(.debug_str) } \
634 .debug_loc 0 : { *(.debug_loc) } \
635 .debug_macinfo 0 : { *(.debug_macinfo) } \
636 /* SGI/MIPS DWARF 2 extensions */ \
637 .debug_weaknames 0 : { *(.debug_weaknames) } \
638 .debug_funcnames 0 : { *(.debug_funcnames) } \
639 .debug_typenames 0 : { *(.debug_typenames) } \
640 .debug_varnames 0 : { *(.debug_varnames) } \
641
642 /* Stabs debugging sections. */
643 #define STABS_DEBUG \
644 .stab 0 : { *(.stab) } \
645 .stabstr 0 : { *(.stabstr) } \
646 .stab.excl 0 : { *(.stab.excl) } \
647 .stab.exclstr 0 : { *(.stab.exclstr) } \
648 .stab.index 0 : { *(.stab.index) } \
649 .stab.indexstr 0 : { *(.stab.indexstr) } \
650 .comment 0 : { *(.comment) }
651
652 #ifdef CONFIG_GENERIC_BUG
653 #define BUG_TABLE \
654 . = ALIGN(8); \
655 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
656 VMLINUX_SYMBOL(__start___bug_table) = .; \
657 *(__bug_table) \
658 VMLINUX_SYMBOL(__stop___bug_table) = .; \
659 }
660 #else
661 #define BUG_TABLE
662 #endif
663
664 #ifdef CONFIG_PM_TRACE
665 #define TRACEDATA \
666 . = ALIGN(4); \
667 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
668 VMLINUX_SYMBOL(__tracedata_start) = .; \
669 *(.tracedata) \
670 VMLINUX_SYMBOL(__tracedata_end) = .; \
671 }
672 #else
673 #define TRACEDATA
674 #endif
675
676 #define NOTES \
677 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
678 VMLINUX_SYMBOL(__start_notes) = .; \
679 *(.note.*) \
680 VMLINUX_SYMBOL(__stop_notes) = .; \
681 }
682
683 #define INIT_SETUP(initsetup_align) \
684 . = ALIGN(initsetup_align); \
685 VMLINUX_SYMBOL(__setup_start) = .; \
686 *(.init.setup) \
687 VMLINUX_SYMBOL(__setup_end) = .;
688
689 #define INIT_CALLS_LEVEL(level) \
690 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
691 KEEP(*(.initcall##level##.init)) \
692 KEEP(*(.initcall##level##s.init)) \
693
694 #define INIT_CALLS \
695 VMLINUX_SYMBOL(__initcall_start) = .; \
696 KEEP(*(.initcallearly.init)) \
697 INIT_CALLS_LEVEL(0) \
698 INIT_CALLS_LEVEL(1) \
699 INIT_CALLS_LEVEL(2) \
700 INIT_CALLS_LEVEL(3) \
701 INIT_CALLS_LEVEL(4) \
702 INIT_CALLS_LEVEL(5) \
703 INIT_CALLS_LEVEL(rootfs) \
704 INIT_CALLS_LEVEL(6) \
705 INIT_CALLS_LEVEL(7) \
706 VMLINUX_SYMBOL(__initcall_end) = .;
707
708 #define CON_INITCALL \
709 VMLINUX_SYMBOL(__con_initcall_start) = .; \
710 KEEP(*(.con_initcall.init)) \
711 VMLINUX_SYMBOL(__con_initcall_end) = .;
712
713 #define SECURITY_INITCALL \
714 VMLINUX_SYMBOL(__security_initcall_start) = .; \
715 KEEP(*(.security_initcall.init)) \
716 VMLINUX_SYMBOL(__security_initcall_end) = .;
717
718 #ifdef CONFIG_BLK_DEV_INITRD
719 #define INIT_RAM_FS \
720 . = ALIGN(4); \
721 VMLINUX_SYMBOL(__initramfs_start) = .; \
722 KEEP(*(.init.ramfs)) \
723 . = ALIGN(8); \
724 KEEP(*(.init.ramfs.info))
725 #else
726 #define INIT_RAM_FS
727 #endif
728
729 /*
730 * Default discarded sections.
731 *
732 * Some archs want to discard exit text/data at runtime rather than
733 * link time due to cross-section references such as alt instructions,
734 * bug table, eh_frame, etc. DISCARDS must be the last of output
735 * section definitions so that such archs put those in earlier section
736 * definitions.
737 */
738 #define DISCARDS \
739 /DISCARD/ : { \
740 EXIT_TEXT \
741 EXIT_DATA \
742 EXIT_CALL \
743 *(.discard) \
744 *(.discard.*) \
745 }
746
747 /**
748 * PERCPU_INPUT - the percpu input sections
749 * @cacheline: cacheline size
750 *
751 * The core percpu section names and core symbols which do not rely
752 * directly upon load addresses.
753 *
754 * @cacheline is used to align subsections to avoid false cacheline
755 * sharing between subsections for different purposes.
756 */
757 #define PERCPU_INPUT(cacheline) \
758 VMLINUX_SYMBOL(__per_cpu_start) = .; \
759 *(.data..percpu..first) \
760 . = ALIGN(PAGE_SIZE); \
761 *(.data..percpu..page_aligned) \
762 . = ALIGN(cacheline); \
763 *(.data..percpu..read_mostly) \
764 . = ALIGN(cacheline); \
765 *(.data..percpu) \
766 *(.data..percpu..shared_aligned) \
767 VMLINUX_SYMBOL(__per_cpu_end) = .;
768
769 /**
770 * PERCPU_VADDR - define output section for percpu area
771 * @cacheline: cacheline size
772 * @vaddr: explicit base address (optional)
773 * @phdr: destination PHDR (optional)
774 *
775 * Macro which expands to output section for percpu area.
776 *
777 * @cacheline is used to align subsections to avoid false cacheline
778 * sharing between subsections for different purposes.
779 *
780 * If @vaddr is not blank, it specifies explicit base address and all
781 * percpu symbols will be offset from the given address. If blank,
782 * @vaddr always equals @laddr + LOAD_OFFSET.
783 *
784 * @phdr defines the output PHDR to use if not blank. Be warned that
785 * output PHDR is sticky. If @phdr is specified, the next output
786 * section in the linker script will go there too. @phdr should have
787 * a leading colon.
788 *
789 * Note that this macros defines __per_cpu_load as an absolute symbol.
790 * If there is no need to put the percpu section at a predetermined
791 * address, use PERCPU_SECTION.
792 */
793 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
794 VMLINUX_SYMBOL(__per_cpu_load) = .; \
795 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
796 - LOAD_OFFSET) { \
797 PERCPU_INPUT(cacheline) \
798 } phdr \
799 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
800
801 /**
802 * PERCPU_SECTION - define output section for percpu area, simple version
803 * @cacheline: cacheline size
804 *
805 * Align to PAGE_SIZE and outputs output section for percpu area. This
806 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
807 * __per_cpu_start will be identical.
808 *
809 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
810 * except that __per_cpu_load is defined as a relative symbol against
811 * .data..percpu which is required for relocatable x86_32 configuration.
812 */
813 #define PERCPU_SECTION(cacheline) \
814 . = ALIGN(PAGE_SIZE); \
815 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
816 VMLINUX_SYMBOL(__per_cpu_load) = .; \
817 PERCPU_INPUT(cacheline) \
818 }
819
820
821 /*
822 * Definition of the high level *_SECTION macros
823 * They will fit only a subset of the architectures
824 */
825
826
827 /*
828 * Writeable data.
829 * All sections are combined in a single .data section.
830 * The sections following CONSTRUCTORS are arranged so their
831 * typical alignment matches.
832 * A cacheline is typical/always less than a PAGE_SIZE so
833 * the sections that has this restriction (or similar)
834 * is located before the ones requiring PAGE_SIZE alignment.
835 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
836 * matches the requirement of PAGE_ALIGNED_DATA.
837 *
838 * use 0 as page_align if page_aligned data is not used */
839 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
840 . = ALIGN(PAGE_SIZE); \
841 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
842 INIT_TASK_DATA(inittask) \
843 NOSAVE_DATA \
844 PAGE_ALIGNED_DATA(pagealigned) \
845 CACHELINE_ALIGNED_DATA(cacheline) \
846 READ_MOSTLY_DATA(cacheline) \
847 DATA_DATA \
848 CONSTRUCTORS \
849 }
850
851 #define INIT_TEXT_SECTION(inittext_align) \
852 . = ALIGN(inittext_align); \
853 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
854 VMLINUX_SYMBOL(_sinittext) = .; \
855 INIT_TEXT \
856 VMLINUX_SYMBOL(_einittext) = .; \
857 }
858
859 #define INIT_DATA_SECTION(initsetup_align) \
860 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
861 INIT_DATA \
862 INIT_SETUP(initsetup_align) \
863 INIT_CALLS \
864 CON_INITCALL \
865 SECURITY_INITCALL \
866 INIT_RAM_FS \
867 }
868
869 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
870 . = ALIGN(sbss_align); \
871 VMLINUX_SYMBOL(__bss_start) = .; \
872 SBSS(sbss_align) \
873 BSS(bss_align) \
874 . = ALIGN(stop_align); \
875 VMLINUX_SYMBOL(__bss_stop) = .;
Linux kernel - Deliverables
This page took 0.05926 seconds and 5 git commands to generate.