m4/ax_pthread.m4

   1 # ===========================================================================
   2 #        https://www.gnu.org/software/autoconf-archive/ax_pthread.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro figures out how to build C programs using POSIX threads. It
  12 #   sets the PTHREAD_LIBS output variable to the threads library and linker
  13 #   flags, and the PTHREAD_CFLAGS output variable to any special C compiler
  14 #   flags that are needed. (The user can also force certain compiler
  15 #   flags/libs to be tested by setting these environment variables.)
  16 #
  17 #   Also sets PTHREAD_CC to any special C compiler that is needed for
  18 #   multi-threaded programs (defaults to the value of CC otherwise). (This
  19 #   is necessary on AIX to use the special cc_r compiler alias.)
  20 #
  21 #   NOTE: You are assumed to not only compile your program with these flags,
  22 #   but also to link with them as well. For example, you might link with
  23 #   $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  24 #
  25 #   If you are only building threaded programs, you may wish to use these
  26 #   variables in your default LIBS, CFLAGS, and CC:
  27 #
  28 #     LIBS="$PTHREAD_LIBS $LIBS"
  29 #     CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  30 #     CC="$PTHREAD_CC"
  31 #
  32 #   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
  33 #   has a nonstandard name, this macro defines PTHREAD_CREATE_JOINABLE to
  34 #   that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  35 #
  36 #   Also HAVE_PTHREAD_PRIO_INHERIT is defined if pthread is found and the
  37 #   PTHREAD_PRIO_INHERIT symbol is defined when compiling with
  38 #   PTHREAD_CFLAGS.
  39 #
  40 #   ACTION-IF-FOUND is a list of shell commands to run if a threads library
  41 #   is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
  42 #   is not found. If ACTION-IF-FOUND is not specified, the default action
  43 #   will define HAVE_PTHREAD.
  44 #
  45 #   Please let the authors know if this macro fails on any platform, or if
  46 #   you have any other suggestions or comments. This macro was based on work
  47 #   by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
  48 #   from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
  49 #   Alejandro Forero Cuervo to the autoconf macro repository. We are also
  50 #   grateful for the helpful feedback of numerous users.
  51 #
  52 #   Updated for Autoconf 2.68 by Daniel Richard G.
  53 #
  54 # LICENSE
  55 #
  56 #   SPDX-License-Identifier: GPL-3.0-or-later WITH Autoconf-exception-2.0
  57 #
  58 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  59 #   Copyright (c) 2011 Daniel Richard G. <skunk@iSKUNK.ORG>
  60 #   Copyright (c) 2019 Marc Stevens <marc.stevens@cwi.nl>
  61 #
  62 #   This program is free software: you can redistribute it and/or modify it
  63 #   under the terms of the GNU General Public License as published by the
  64 #   Free Software Foundation, either version 3 of the License, or (at your
  65 #   option) any later version.
  66 #
  67 #   This program is distributed in the hope that it will be useful, but
  68 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  69 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  70 #   Public License for more details.
  71 #
  72 #   You should have received a copy of the GNU General Public License along
  73 #   with this program. If not, see <https://www.gnu.org/licenses/>.
  74 #
  75 #   As a special exception, the respective Autoconf Macro's copyright owner
  76 #   gives unlimited permission to copy, distribute and modify the configure
  77 #   scripts that are the output of Autoconf when processing the Macro. You
  78 #   need not follow the terms of the GNU General Public License when using
  79 #   or distributing such scripts, even though portions of the text of the
  80 #   Macro appear in them. The GNU General Public License (GPL) does govern
  81 #   all other use of the material that constitutes the Autoconf Macro.
  82 #
  83 #   This special exception to the GPL applies to versions of the Autoconf
  84 #   Macro released by the Autoconf Archive. When you make and distribute a
  85 #   modified version of the Autoconf Macro, you may extend this special
  86 #   exception to the GPL to apply to your modified version as well.
  87
  88 #serial 27
  89
  90 AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD])
  91 AC_DEFUN([AX_PTHREAD], [
  92 AC_REQUIRE([AC_CANONICAL_HOST])
  93 AC_REQUIRE([AC_PROG_CC])
  94 AC_REQUIRE([AC_PROG_SED])
  95 AC_LANG_PUSH([C])
  96 ax_pthread_ok=no
  97
  98 # We used to check for pthread.h first, but this fails if pthread.h
  99 # requires special compiler flags (e.g. on Tru64 or Sequent).
 100 # It gets checked for in the link test anyway.
 101
 102 # First of all, check if the user has set any of the PTHREAD_LIBS,
 103 # etcetera environment variables, and if threads linking works using
 104 # them:
 105 if test "x$PTHREAD_CFLAGS$PTHREAD_LIBS" != "x"; then
 106         ax_pthread_save_CC="$CC"
 107         ax_pthread_save_CFLAGS="$CFLAGS"
 108         ax_pthread_save_LIBS="$LIBS"
 109         AS_IF([test "x$PTHREAD_CC" != "x"], [CC="$PTHREAD_CC"])
 110         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 111         LIBS="$PTHREAD_LIBS $LIBS"
 112         AC_MSG_CHECKING([for pthread_join using $CC $PTHREAD_CFLAGS $PTHREAD_LIBS])
 113         AC_LINK_IFELSE([AC_LANG_CALL([], [pthread_join])], [ax_pthread_ok=yes])
 114         AC_MSG_RESULT([$ax_pthread_ok])
 115         if test "x$ax_pthread_ok" = "xno"; then
 116                 PTHREAD_LIBS=""
 117                 PTHREAD_CFLAGS=""
 118         fi
 119         CC="$ax_pthread_save_CC"
 120         CFLAGS="$ax_pthread_save_CFLAGS"
 121         LIBS="$ax_pthread_save_LIBS"
 122 fi
 123
 124 # We must check for the threads library under a number of different
 125 # names; the ordering is very important because some systems
 126 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
 127 # libraries is broken (non-POSIX).
 128
 129 # Create a list of thread flags to try. Items with a "," contain both
 130 # C compiler flags (before ",") and linker flags (after ","). Other items
 131 # starting with a "-" are C compiler flags, and remaining items are
 132 # library names, except for "none" which indicates that we try without
 133 # any flags at all, and "pthread-config" which is a program returning
 134 # the flags for the Pth emulation library.
 135
 136 ax_pthread_flags="pthreads none -Kthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
 137
 138 # The ordering *is* (sometimes) important.  Some notes on the
 139 # individual items follow:
 140
 141 # pthreads: AIX (must check this before -lpthread)
 142 # none: in case threads are in libc; should be tried before -Kthread and
 143 #       other compiler flags to prevent continual compiler warnings
 144 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 145 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads), Tru64
 146 #           (Note: HP C rejects this with "bad form for `-t' option")
 147 # -pthreads: Solaris/gcc (Note: HP C also rejects)
 148 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 149 #      doesn't hurt to check since this sometimes defines pthreads and
 150 #      -D_REENTRANT too), HP C (must be checked before -lpthread, which
 151 #      is present but should not be used directly; and before -mthreads,
 152 #      because the compiler interprets this as "-mt" + "-hreads")
 153 # -mthreads: Mingw32/gcc, Lynx/gcc
 154 # pthread: Linux, etcetera
 155 # --thread-safe: KAI C++
 156 # pthread-config: use pthread-config program (for GNU Pth library)
 157
 158 case $host_os in
 159
 160         freebsd*)
 161
 162         # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 163         # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 164
 165         ax_pthread_flags="-kthread lthread $ax_pthread_flags"
 166         ;;
 167
 168         hpux*)
 169
 170         # From the cc(1) man page: "[-mt] Sets various -D flags to enable
 171         # multi-threading and also sets -lpthread."
 172
 173         ax_pthread_flags="-mt -pthread pthread $ax_pthread_flags"
 174         ;;
 175
 176         openedition*)
 177
 178         # IBM z/OS requires a feature-test macro to be defined in order to
 179         # enable POSIX threads at all, so give the user a hint if this is
 180         # not set. (We don't define these ourselves, as they can affect
 181         # other portions of the system API in unpredictable ways.)
 182
 183         AC_EGREP_CPP([AX_PTHREAD_ZOS_MISSING],
 184             [
 185 #            if !defined(_OPEN_THREADS) && !defined(_UNIX03_THREADS)
 186              AX_PTHREAD_ZOS_MISSING
 187 #            endif
 188             ],
 189             [AC_MSG_WARN([IBM z/OS requires -D_OPEN_THREADS or -D_UNIX03_THREADS to enable pthreads support.])])
 190         ;;
 191
 192         solaris*)
 193
 194         # On Solaris (at least, for some versions), libc contains stubbed
 195         # (non-functional) versions of the pthreads routines, so link-based
 196         # tests will erroneously succeed. (N.B.: The stubs are missing
 197         # pthread_cleanup_push, or rather a function called by this macro,
 198         # so we could check for that, but who knows whether they'll stub
 199         # that too in a future libc.)  So we'll check first for the
 200         # standard Solaris way of linking pthreads (-mt -lpthread).
 201
 202         ax_pthread_flags="-mt,-lpthread pthread $ax_pthread_flags"
 203         ;;
 204 esac
 205
 206 # Are we compiling with Clang?
 207
 208 AC_CACHE_CHECK([whether $CC is Clang],
 209     [ax_cv_PTHREAD_CLANG],
 210     [ax_cv_PTHREAD_CLANG=no
 211      # Note that Autoconf sets GCC=yes for Clang as well as GCC
 212      if test "x$GCC" = "xyes"; then
 213         AC_EGREP_CPP([AX_PTHREAD_CC_IS_CLANG],
 214             [/* Note: Clang 2.7 lacks __clang_[a-z]+__ */
 215 #            if defined(__clang__) && defined(__llvm__)
 216              AX_PTHREAD_CC_IS_CLANG
 217 #            endif
 218             ],
 219             [ax_cv_PTHREAD_CLANG=yes])
 220      fi
 221     ])
 222 ax_pthread_clang="$ax_cv_PTHREAD_CLANG"
 223
 224
 225 # GCC generally uses -pthread, or -pthreads on some platforms (e.g. SPARC)
 226
 227 # Note that for GCC and Clang -pthread generally implies -lpthread,
 228 # except when -nostdlib is passed.
 229 # This is problematic using libtool to build C++ shared libraries with pthread:
 230 # [1] https://gcc.gnu.org/bugzilla/show_bug.cgi?id=25460
 231 # [2] https://bugzilla.redhat.com/show_bug.cgi?id=661333
 232 # [3] https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=468555
 233 # To solve this, first try -pthread together with -lpthread for GCC
 234
 235 AS_IF([test "x$GCC" = "xyes"],
 236       [ax_pthread_flags="-pthread,-lpthread -pthread -pthreads $ax_pthread_flags"])
 237
 238 # Clang takes -pthread (never supported any other flag), but we'll try with -lpthread first
 239
 240 AS_IF([test "x$ax_pthread_clang" = "xyes"],
 241       [ax_pthread_flags="-pthread,-lpthread -pthread"])
 242
 243
 244 # The presence of a feature test macro requesting re-entrant function
 245 # definitions is, on some systems, a strong hint that pthreads support is
 246 # correctly enabled
 247
 248 case $host_os in
 249         darwin* | hpux* | linux* | osf* | solaris*)
 250         ax_pthread_check_macro="_REENTRANT"
 251         ;;
 252
 253         aix*)
 254         ax_pthread_check_macro="_THREAD_SAFE"
 255         ;;
 256
 257         *)
 258         ax_pthread_check_macro="--"
 259         ;;
 260 esac
 261 AS_IF([test "x$ax_pthread_check_macro" = "x--"],
 262       [ax_pthread_check_cond=0],
 263       [ax_pthread_check_cond="!defined($ax_pthread_check_macro)"])
 264
 265
 266 if test "x$ax_pthread_ok" = "xno"; then
 267 for ax_pthread_try_flag in $ax_pthread_flags; do
 268
 269         case $ax_pthread_try_flag in
 270                 none)
 271                 AC_MSG_CHECKING([whether pthreads work without any flags])
 272                 ;;
 273
 274                 *,*)
 275                 PTHREAD_CFLAGS=`echo $ax_pthread_try_flag | sed "s/^\(.*\),\(.*\)$/\1/"`
 276                 PTHREAD_LIBS=`echo $ax_pthread_try_flag | sed "s/^\(.*\),\(.*\)$/\2/"`
 277                 AC_MSG_CHECKING([whether pthreads work with "$PTHREAD_CFLAGS" and "$PTHREAD_LIBS"])
 278                 ;;
 279
 280                 -*)
 281                 AC_MSG_CHECKING([whether pthreads work with $ax_pthread_try_flag])
 282                 PTHREAD_CFLAGS="$ax_pthread_try_flag"
 283                 ;;
 284
 285                 pthread-config)
 286                 AC_CHECK_PROG([ax_pthread_config], [pthread-config], [yes], [no])
 287                 AS_IF([test "x$ax_pthread_config" = "xno"], [continue])
 288                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 289                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 290                 ;;
 291
 292                 *)
 293                 AC_MSG_CHECKING([for the pthreads library -l$ax_pthread_try_flag])
 294                 PTHREAD_LIBS="-l$ax_pthread_try_flag"
 295                 ;;
 296         esac
 297
 298         ax_pthread_save_CFLAGS="$CFLAGS"
 299         ax_pthread_save_LIBS="$LIBS"
 300         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 301         LIBS="$PTHREAD_LIBS $LIBS"
 302
 303         # Check for various functions.  We must include pthread.h,
 304         # since some functions may be macros.  (On the Sequent, we
 305         # need a special flag -Kthread to make this header compile.)
 306         # We check for pthread_join because it is in -lpthread on IRIX
 307         # while pthread_create is in libc.  We check for pthread_attr_init
 308         # due to DEC craziness with -lpthreads.  We check for
 309         # pthread_cleanup_push because it is one of the few pthread
 310         # functions on Solaris that doesn't have a non-functional libc stub.
 311         # We try pthread_create on general principles.
 312
 313         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>
 314 #                       if $ax_pthread_check_cond
 315 #                        error "$ax_pthread_check_macro must be defined"
 316 #                       endif
 317                         static void *some_global = NULL;
 318                         static void routine(void *a)
 319                           {
 320                              /* To avoid any unused-parameter or
 321                                 unused-but-set-parameter warning.  */
 322                              some_global = a;
 323                           }
 324                         static void *start_routine(void *a) { return a; }],
 325                        [pthread_t th; pthread_attr_t attr;
 326                         pthread_create(&th, 0, start_routine, 0);
 327                         pthread_join(th, 0);
 328                         pthread_attr_init(&attr);
 329                         pthread_cleanup_push(routine, 0);
 330                         pthread_cleanup_pop(0) /* ; */])],
 331             [ax_pthread_ok=yes],
 332             [])
 333
 334         CFLAGS="$ax_pthread_save_CFLAGS"
 335         LIBS="$ax_pthread_save_LIBS"
 336
 337         AC_MSG_RESULT([$ax_pthread_ok])
 338         AS_IF([test "x$ax_pthread_ok" = "xyes"], [break])
 339
 340         PTHREAD_LIBS=""
 341         PTHREAD_CFLAGS=""
 342 done
 343 fi
 344
 345
 346 # Clang needs special handling, because older versions handle the -pthread
 347 # option in a rather... idiosyncratic way
 348
 349 if test "x$ax_pthread_clang" = "xyes"; then
 350
 351         # Clang takes -pthread; it has never supported any other flag
 352
 353         # (Note 1: This will need to be revisited if a system that Clang
 354         # supports has POSIX threads in a separate library.  This tends not
 355         # to be the way of modern systems, but it's conceivable.)
 356
 357         # (Note 2: On some systems, notably Darwin, -pthread is not needed
 358         # to get POSIX threads support; the API is always present and
 359         # active.  We could reasonably leave PTHREAD_CFLAGS empty.  But
 360         # -pthread does define _REENTRANT, and while the Darwin headers
 361         # ignore this macro, third-party headers might not.)
 362
 363         # However, older versions of Clang make a point of warning the user
 364         # that, in an invocation where only linking and no compilation is
 365         # taking place, the -pthread option has no effect ("argument unused
 366         # during compilation").  They expect -pthread to be passed in only
 367         # when source code is being compiled.
 368         #
 369         # Problem is, this is at odds with the way Automake and most other
 370         # C build frameworks function, which is that the same flags used in
 371         # compilation (CFLAGS) are also used in linking.  Many systems
 372         # supported by AX_PTHREAD require exactly this for POSIX threads
 373         # support, and in fact it is often not straightforward to specify a
 374         # flag that is used only in the compilation phase and not in
 375         # linking.  Such a scenario is extremely rare in practice.
 376         #
 377         # Even though use of the -pthread flag in linking would only print
 378         # a warning, this can be a nuisance for well-run software projects
 379         # that build with -Werror.  So if the active version of Clang has
 380         # this misfeature, we search for an option to squash it.
 381
 382         AC_CACHE_CHECK([whether Clang needs flag to prevent "argument unused" warning when linking with -pthread],
 383             [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG],
 384             [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG=unknown
 385              # Create an alternate version of $ac_link that compiles and
 386              # links in two steps (.c -> .o, .o -> exe) instead of one
 387              # (.c -> exe), because the warning occurs only in the second
 388              # step
 389              ax_pthread_save_ac_link="$ac_link"
 390              ax_pthread_sed='s/conftest\.\$ac_ext/conftest.$ac_objext/g'
 391              ax_pthread_link_step=`AS_ECHO(["$ac_link"]) | sed "$ax_pthread_sed"`
 392              ax_pthread_2step_ac_link="($ac_compile) && (echo ==== >&5) && ($ax_pthread_link_step)"
 393              ax_pthread_save_CFLAGS="$CFLAGS"
 394              for ax_pthread_try in '' -Qunused-arguments -Wno-unused-command-line-argument unknown; do
 395                 AS_IF([test "x$ax_pthread_try" = "xunknown"], [break])
 396                 CFLAGS="-Werror -Wunknown-warning-option $ax_pthread_try -pthread $ax_pthread_save_CFLAGS"
 397                 ac_link="$ax_pthread_save_ac_link"
 398                 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
 399                     [ac_link="$ax_pthread_2step_ac_link"
 400                      AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
 401                          [break])
 402                     ])
 403              done
 404              ac_link="$ax_pthread_save_ac_link"
 405              CFLAGS="$ax_pthread_save_CFLAGS"
 406              AS_IF([test "x$ax_pthread_try" = "x"], [ax_pthread_try=no])
 407              ax_cv_PTHREAD_CLANG_NO_WARN_FLAG="$ax_pthread_try"
 408             ])
 409
 410         case "$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG" in
 411                 no | unknown) ;;
 412                 *) PTHREAD_CFLAGS="$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG $PTHREAD_CFLAGS" ;;
 413         esac
 414
 415 fi # $ax_pthread_clang = yes
 416
 417
 418
 419 # Various other checks:
 420 if test "x$ax_pthread_ok" = "xyes"; then
 421         ax_pthread_save_CFLAGS="$CFLAGS"
 422         ax_pthread_save_LIBS="$LIBS"
 423         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 424         LIBS="$PTHREAD_LIBS $LIBS"
 425
 426         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 427         AC_CACHE_CHECK([for joinable pthread attribute],
 428             [ax_cv_PTHREAD_JOINABLE_ATTR],
 429             [ax_cv_PTHREAD_JOINABLE_ATTR=unknown
 430              for ax_pthread_attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 431                  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>],
 432                                                  [int attr = $ax_pthread_attr; return attr /* ; */])],
 433                                 [ax_cv_PTHREAD_JOINABLE_ATTR=$ax_pthread_attr; break],
 434                                 [])
 435              done
 436             ])
 437         AS_IF([test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xunknown" && \
 438                test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xPTHREAD_CREATE_JOINABLE" && \
 439                test "x$ax_pthread_joinable_attr_defined" != "xyes"],
 440               [AC_DEFINE_UNQUOTED([PTHREAD_CREATE_JOINABLE],
 441                                   [$ax_cv_PTHREAD_JOINABLE_ATTR],
 442                                   [Define to necessary symbol if this constant
 443                                    uses a non-standard name on your system.])
 444                ax_pthread_joinable_attr_defined=yes
 445               ])
 446
 447         AC_CACHE_CHECK([whether more special flags are required for pthreads],
 448             [ax_cv_PTHREAD_SPECIAL_FLAGS],
 449             [ax_cv_PTHREAD_SPECIAL_FLAGS=no
 450              case $host_os in
 451              solaris*)
 452              ax_cv_PTHREAD_SPECIAL_FLAGS="-D_POSIX_PTHREAD_SEMANTICS"
 453              ;;
 454              esac
 455             ])
 456         AS_IF([test "x$ax_cv_PTHREAD_SPECIAL_FLAGS" != "xno" && \
 457                test "x$ax_pthread_special_flags_added" != "xyes"],
 458               [PTHREAD_CFLAGS="$ax_cv_PTHREAD_SPECIAL_FLAGS $PTHREAD_CFLAGS"
 459                ax_pthread_special_flags_added=yes])
 460
 461         AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 462             [ax_cv_PTHREAD_PRIO_INHERIT],
 463             [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
 464                                              [[int i = PTHREAD_PRIO_INHERIT;
 465                                                return i;]])],
 466                             [ax_cv_PTHREAD_PRIO_INHERIT=yes],
 467                             [ax_cv_PTHREAD_PRIO_INHERIT=no])
 468             ])
 469         AS_IF([test "x$ax_cv_PTHREAD_PRIO_INHERIT" = "xyes" && \
 470                test "x$ax_pthread_prio_inherit_defined" != "xyes"],
 471               [AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], [1], [Have PTHREAD_PRIO_INHERIT.])
 472                ax_pthread_prio_inherit_defined=yes
 473               ])
 474
 475         CFLAGS="$ax_pthread_save_CFLAGS"
 476         LIBS="$ax_pthread_save_LIBS"
 477
 478         # More AIX lossage: compile with *_r variant
 479         if test "x$GCC" != "xyes"; then
 480             case $host_os in
 481                 aix*)
 482                 AS_CASE(["x/$CC"],
 483                     [x*/c89|x*/c89_128|x*/c99|x*/c99_128|x*/cc|x*/cc128|x*/xlc|x*/xlc_v6|x*/xlc128|x*/xlc128_v6],
 484                     [#handle absolute path differently from PATH based program lookup
 485                      AS_CASE(["x$CC"],
 486                          [x/*],
 487                          [AS_IF([AS_EXECUTABLE_P([${CC}_r])],[PTHREAD_CC="${CC}_r"])],
 488                          [AC_CHECK_PROGS([PTHREAD_CC],[${CC}_r],[$CC])])])
 489                 ;;
 490             esac
 491         fi
 492 fi
 493
 494 test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
 495
 496 AC_SUBST([PTHREAD_LIBS])
 497 AC_SUBST([PTHREAD_CFLAGS])
 498 AC_SUBST([PTHREAD_CC])
 499
 500 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 501 if test "x$ax_pthread_ok" = "xyes"; then
 502         ifelse([$1],,[AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])],[$1])
 503         :
 504 else
 505         ax_pthread_ok=no
 506         $2
 507 fi
 508 AC_LANG_POP
 509 ])dnl AX_PTHREAD