configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.12.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 AC_PROG_CC_STDC
  25 AC_PROG_CXX
  26 RW_PROG_CXX_WORKS
  27 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  28
  29 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
  30 #
  31 # Pass -Werror as an extra flag during the test: this is needed to make the
  32 # -Wunknown-warning-option diagnostic fatal with clang.
  33 AX_APPEND_COMPILE_FLAGS([ dnl
  34                 -Wall dnl
  35                 dnl We currently get this warning when building with Clang:
  36                 dnl
  37                 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  38                 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  39                 dnl            ^
  40                 -Wno-incomplete-setjmp-declaration dnl
  41                 -Wdiscarded-qualifiers dnl
  42                 -Wmissing-declarations dnl
  43                 -Wmissing-prototypes dnl
  44                 -Wmissing-parameter-type dnl
  45                 -Wold-style-definition dnl
  46                 -Wstrict-prototypes dnl
  47         ],
  48         [WARN_CFLAGS],
  49         [-Werror])
  50
  51 # When given, add -Werror to WARN_CFLAGS.
  52 AC_ARG_ENABLE([Werror],
  53         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
  54 )
  55 AS_IF([test "x$enable_Werror" = "xyes"],
  56         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
  57 )
  58
  59 # Checks for programs.
  60 AC_PROG_GREP
  61 AC_PROG_MAKE_SET
  62 AC_PROG_SED
  63 AC_PATH_PROG([report_fold], [fold])
  64 LT_INIT
  65
  66 # Check for objcopy, required by the base address statedump and dynamic linker tests
  67 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  68 AS_IF([test "x$OBJCOPY" = "xno"],
  69         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  70 )
  71 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  72
  73 # check for pgrep
  74 AC_PATH_PROG([PGREP], [pgrep], [no])
  75 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  76
  77 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  78 # is not distributed in tarballs
  79 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  80 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  81
  82 # check for bison
  83 AC_PROG_YACC
  84 BISON=$YACC
  85 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  86
  87 AS_IF([test "x$have_bison" != "xyes"], [
  88   AS_IF([test "x$in_git_repo" = "xyes"], [
  89     AC_MSG_FAILURE([
  90 Bison >= 2.4 is required when building from the Git repository. You can
  91 set the YACC variable to override automatic detection.
  92     ])
  93   ], [
  94     AC_MSG_WARN([
  95 Missing Bison >= 2.4. Note that the parser files are already built in
  96 this distribution tarball, so Bison is only needed if you intend to
  97 modify their sources. You can set the YACC variable to override automatic
  98 detection.
  99     ])
 100   ])
 101 ])
 102 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 103
 104 # check for flex
 105 AC_PROG_LEX
 106 FLEX=$LEX
 107 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 108
 109 AS_IF([test "x$have_flex" != "xyes"], [
 110   AS_IF([test "x$in_git_repo" = "xyes"], [
 111     AC_MSG_FAILURE([
 112 Flex >= 2.5.35 is required when building from the Git repository. You can
 113 set the LEX variable to override automatic detection.
 114     ])
 115   ], [
 116     AC_MSG_WARN([
 117 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 118 this distribution tarball, so Flex is only needed if you intend to
 119 modify their sources. You can set the LEX variable to override automatic
 120 detection.
 121     ])
 122   ])
 123 ])
 124 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 125
 126
 127 # Checks for typedefs, structures, and compiler characteristics.
 128 AC_C_INLINE
 129 AC_TYPE_INT32_T
 130 AC_TYPE_INT64_T
 131 AC_TYPE_MODE_T
 132 AC_TYPE_OFF_T
 133 AC_TYPE_PID_T
 134 AC_TYPE_SIZE_T
 135 AC_TYPE_SSIZE_T
 136 AC_TYPE_UID_T
 137 AC_TYPE_UINT16_T
 138 AC_TYPE_UINT32_T
 139 AC_TYPE_UINT64_T
 140 AC_TYPE_UINT8_T
 141
 142 AX_C___ATTRIBUTE__
 143 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 144         [:],
 145         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 146
 147 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 148
 149 # Check if linker has the -no-pie option.
 150 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 151 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 152
 153 AX_LIB_SOCKET_NSL
 154
 155 LT_NO_UNDEFINED=""
 156 AS_CASE([$host_os],
 157   [cygwin*],
 158     [
 159       LT_NO_UNDEFINED="-no-undefined"
 160     ],
 161   [cygwin*|darwin*|mingw*|solaris*],
 162     [
 163       # On platforms where we only support the relayd, disable the other binaries by default
 164       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 165       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 166       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 167       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 168       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 169       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 170     ]
 171 )
 172
 173 AC_SUBST(LT_NO_UNDEFINED)
 174
 175 # Compute minor/major/patchlevel version numbers
 176 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 177 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 178 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 179
 180 AC_SUBST([MAJOR_VERSION], [$major_version])
 181 AC_SUBST([MINOR_VERSION], [$minor_version])
 182 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 183 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 184 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 185 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 186
 187 version_name="(Ta) Meilleure"
 188 version_description="Ta Meilleure is a Northeast IPA beer brewed by Lagabière. Translating to \"Your best one\", this beer gives out strong aromas of passion fruit, lemon, and peaches. Tastewise, expect a lot of fruit, a creamy texture, and a smooth lingering hop bitterness."
 189 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 190
 191 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 192 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 193
 194 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 195 AC_ARG_ENABLE(libtool-linkdep-fixup,
 196         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 197                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 198         libtool_fixup=$enableval,
 199         libtool_fixup=yes)
 200
 201 AS_IF([test "x$libtool_fixup" = "xyes"],
 202             [
 203             libtool_m4="$srcdir/m4/libtool.m4"
 204             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 205             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 206             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 207             AS_IF([test $libtool_flag_pattern_count -ne 0],
 208             [
 209                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 210                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 211                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 212                   ],
 213                   [
 214                   AC_MSG_RESULT([none])
 215                   ])
 216             ])
 217
 218 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 219
 220 AC_CHECK_HEADERS([ \
 221         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 222         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 223         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 224         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 225         sys/mount.h sys/param.h sys/time.h elf.h
 226 ])
 227
 228 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 229
 230 # Basic functions check
 231 AC_CHECK_FUNCS([ \
 232         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 233         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 234         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 235         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 236         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 237         sched_getcpu sysconf sync_file_range
 238 ])
 239
 240 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 241 # add -lrt to LIBS
 242 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 243
 244 # Checks for dl.
 245 AC_CHECK_LIB([dl], [dlopen], [
 246         have_libdl=yes
 247         libdl_name=dl
 248         DL_LIBS="-ldl"
 249 ], [
 250         # libdl not found, check for dlopen in libc.
 251         AC_CHECK_LIB([c], [dlopen], [
 252                 have_libc_dl=yes
 253                 libdl_name=c
 254                 DL_LIBS="-lc"
 255         ], [
 256                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 257         ])
 258 ])
 259 AC_SUBST(DL_LIBS)
 260
 261 # Check if libdl has dlmopen support.
 262 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 263 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 264         AC_DEFINE([HAVE_DLMOPEN], [1])
 265         HAVE_DLMOPEN=1
 266 ], [
 267         HAVE_DLMOPEN=0
 268 ])
 269 AC_SUBST(HAVE_DLMOPEN)
 270
 271 # Babeltrace viewer check
 272 AC_ARG_WITH([babeltrace-bin],
 273         AS_HELP_STRING([--with-babeltrace-bin],
 274         [Location of the babeltrace viewer executable (including the filename)]),
 275         [BABELTRACE_BIN="$withval"],
 276         [BABELTRACE_BIN=''])
 277 AC_SUBST([BABELTRACE_BIN])
 278
 279 AC_ARG_WITH([babeltrace2-bin],
 280         AS_HELP_STRING([--with-babeltrace2-bin],
 281         [Location of the babeltrace2 viewer executable (including the filename)]),
 282         [BABELTRACE2_BIN="$withval"],
 283         [BABELTRACE2_BIN=''])
 284 AC_SUBST([BABELTRACE2_BIN])
 285
 286 AC_ARG_WITH([consumerd32-bin],
 287         AS_HELP_STRING([--with-consumerd32-bin],
 288         [Location of the 32-bit consumerd executable (including the filename)]),
 289         [CONSUMERD32_BIN="$withval"],
 290         [CONSUMERD32_BIN=''])
 291 AC_SUBST([CONSUMERD32_BIN])
 292
 293 AC_ARG_WITH([consumerd64-bin],
 294         AS_HELP_STRING([--with-consumerd64-bin],
 295         [Location of the 64-bit consumerd executable (including the filename)]),
 296         [CONSUMERD64_BIN="$withval"],
 297         [CONSUMERD64_BIN=''])
 298 AC_SUBST([CONSUMERD64_BIN])
 299
 300 AC_ARG_WITH([consumerd32-libdir],
 301         AS_HELP_STRING([--with-consumerd32-libdir],
 302         [Directory containing the 32-bit consumerd libraries]),
 303         [CONSUMERD32_LIBDIR="$withval"],
 304         [CONSUMERD32_LIBDIR=''])
 305 AC_SUBST([CONSUMERD32_LIBDIR])
 306
 307 AC_ARG_WITH([consumerd64-libdir],
 308         AS_HELP_STRING([--with-consumerd64-libdir],
 309         [Directory containing the 64-bit consumerd libraries]),
 310         [CONSUMERD64_LIBDIR="$withval"],
 311         [CONSUMERD64_LIBDIR=''])
 312 AC_SUBST([CONSUMERD64_LIBDIR])
 313
 314 AC_ARG_WITH([sessiond-bin],
 315         AS_HELP_STRING([--with-sessiond-bin],
 316         [Location of the sessiond executable (including the filename)]),
 317         [SESSIOND_BIN="$withval"],
 318         [SESSIOND_BIN=''])
 319 AC_SUBST([SESSIOND_BIN])
 320
 321 AC_ARG_WITH([lttng-system-rundir],
 322         AS_HELP_STRING([--with-lttng-system-rundir],
 323         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 324         [LTTNG_SYSTEM_RUNDIR="$withval"],
 325         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 326 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 327
 328 AC_ARG_ENABLE([test-java-agent-jul],
 329         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 330         [test_java_agent_jul=$enableval],
 331         [test_java_agent_jul=no]
 332 )
 333
 334 AC_ARG_ENABLE([test-java-agent-log4j],
 335         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 336         [test_java_agent_log4j=$enableval],
 337         [test_java_agent_log4j=no]
 338 )
 339
 340 AC_ARG_ENABLE([test-java-agent-all],
 341         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 342         [test_java_agent_jul=$enableval
 343          test_java_agent_log4j=$enableval],
 344         [:]
 345 )
 346
 347 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 348 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 349 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 350 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 351 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 352 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 353 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 354 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 355
 356 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 357         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 358         $1="$2"
 359         AC_SUBST([$1])
 360 ])
 361
 362 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 363         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 364         $1="$2"
 365         AC_SUBST([$1])
 366 ])
 367
 368 # Default values
 369 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 370 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 371 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 372 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 373 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 374 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 375 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 376 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 377 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 378 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 379 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 380 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 381 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 382 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 385 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 388 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 391 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 392 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 393 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 394 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 395 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 396 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 397 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 398 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 399 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 400 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 401 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 402 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 403 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 404 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 405 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 406 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 407 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 408 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 409 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 410 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 411 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 412 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 413 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 414 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 415 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 416 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 417 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 418
 419 # Command short descriptions
 420 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 421 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 422 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
 423 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 424 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 425 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 426 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 427 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 428 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 441 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 442 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 443 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 444 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 445 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 446 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 447
 448 if test "x$prefix" = "xNONE"; then
 449         prefix=$ac_default_prefix
 450 fi
 451 CONFDIR=`eval echo $sysconfdir`
 452 AC_SUBST(CONFDIR)
 453 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 454
 455 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 456
 457 # Check libpopt
 458 PKG_CHECK_MODULES([POPT], [popt],
 459   [
 460     dnl PKG_CHECK_MODULES defines POPT_LIBS
 461   ],
 462   [
 463     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 464     AC_MSG_WARN([Finding libpopt without pkg-config.])
 465     AC_CHECK_LIB([popt],
 466       [poptGetContext],
 467       [POPT_LIBS="-lpopt"],
 468       [
 469         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 470       ]
 471     )
 472   ]
 473 )
 474 AC_SUBST(POPT_LIBS)
 475
 476 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 477 PKG_CHECK_MODULES([msgpack], [msgpack])
 478
 479 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 480
 481 # URCU library version needed or newer
 482 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 483
 484 # Check liburcu needed function calls
 485 AC_CHECK_DECL([cds_list_add], [],
 486         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 487 AC_CHECK_DECL([cds_wfcq_init], [],
 488         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 489 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 490         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 491 AC_CHECK_DECL([futex_async], [],
 492         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 493 AC_CHECK_DECL([rcu_thread_offline], [],
 494         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 495 AC_CHECK_DECL([rcu_thread_online], [],
 496         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 497 AC_CHECK_DECL([caa_likely], [],
 498         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 499 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 500         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 501
 502 #Function added in urcu 0.7.0
 503 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 504         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 505 )
 506
 507 #Function added in urcu 0.9.0
 508 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 509         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 510 )
 511
 512 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 513 # it can be explicitly disabled with --without-kmod
 514 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 515 AC_ARG_WITH([kmod],
 516   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 517   [],
 518   [with_kmod=check]
 519 )
 520
 521 AS_IF([test "x$with_kmod" != "xno"],
 522   [
 523     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 524       [
 525         AC_DEFINE([HAVE_KMOD], [1])
 526         KMOD_LIBS="-lkmod"
 527       ],
 528       [
 529         if test "x$with_kmod" != xcheck; then
 530           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 531         else
 532           with_kmod=no
 533         fi
 534       ]
 535     )
 536   ]
 537 )
 538 AC_SUBST(KMOD_LIBS)
 539
 540 # Check for liblttng-ust-ctl, fail if it's not found,
 541 # it can be explicitly disabled with --without-lttng-ust
 542 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 543 AC_ARG_WITH([lttng-ust],
 544   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 545   [],
 546   [with_lttng_ust=yes]
 547 )
 548
 549 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 550   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 551
 552   # Check for liblttng-ust
 553   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 554
 555   # Check for liblttng-ust-ctl
 556   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 557
 558   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 559 ])
 560
 561 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 562
 563
 564 # Check for fmemopen
 565 AC_CHECK_LIB([c], [fmemopen],
 566 [
 567         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 568 ]
 569 )
 570
 571 # check for libpfm
 572 AC_CHECK_LIB([pfm], [pfm_initialize],
 573              [
 574               have_libpfm=yes
 575               ])
 576 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 577
 578 # For Python
 579 # SWIG version needed or newer:
 580 swig_version=2.0.0
 581
 582 AC_ARG_ENABLE([python-bindings],
 583               [AC_HELP_STRING([--enable-python-bindings],
 584                               [compile Python bindings])],
 585               [enable_python_binding=$enableval], [enable_python_binding=no])
 586
 587 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 588
 589 if test "x$enable_python_binding" = xyes; then
 590   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 591   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 592   AM_PATH_PYTHON([3.0])
 593
 594   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 595   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 596   AS_IF([test -z "$PYTHON_INCLUDE"], [
 597     AS_IF([test -z "$PYTHON_CONFIG"], [
 598       AC_PATH_PROGS([PYTHON_CONFIG],
 599                     [python$PYTHON_VERSION-config python-config],
 600                     [no],
 601                     [`dirname $PYTHON`])
 602       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 603     ])
 604     AC_MSG_CHECKING([python include flags])
 605     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 606     AC_MSG_RESULT([$PYTHON_INCLUDE])
 607   ])
 608
 609 else
 610     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 611 [if you want Python bindings.])
 612
 613 fi
 614
 615 # Epoll check. If not present, the build will fallback on poll() API
 616 AX_HAVE_EPOLL(
 617         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 618         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 619 )
 620 AX_CONFIG_FEATURE(
 621         [epoll], [This platform supports epoll(7)],
 622         [HAVE_EPOLL], [This platform supports epoll(7).],
 623         [enable_epoll="yes"], [enable_epoll="no"]
 624 )
 625 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 626
 627 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 628         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 629         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 630 )
 631 AX_CONFIG_FEATURE(
 632         [dirfd], [Use directory file descriptors],
 633         [COMPAT_DIRFD], [This platform supports directory file descriptors.],
 634         [enable_dirfd="yes"], [enable_dirfd="no"]
 635 )
 636 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
 637
 638 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 639 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 640
 641 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 642         AX_JAVA_OPTIONS
 643         AX_PROG_JAVAC
 644         AX_PROG_JAVA
 645         AX_PROG_JAR
 646
 647         AX_CHECK_CLASSPATH
 648
 649         # Check for Java UST agent common class first
 650         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 651         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 652                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 653         fi
 654
 655         if test "x$test_java_agent_jul" = "xyes"; then
 656                 # Check for JUL agent class
 657                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 658                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 659                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 660                 fi
 661         fi
 662
 663         if test "x$test_java_agent_log4j" = "xyes"; then
 664                 # Check for Log4j agent class
 665                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 666                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 667                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 668                 fi
 669
 670                 # Check for Log4j class
 671                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 672                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 673                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 674                 fi
 675         fi
 676 fi
 677
 678 # enable building man pages (user's intention)
 679 AC_ARG_ENABLE(
 680         man-pages,
 681         AS_HELP_STRING(
 682                 [--disable-man-pages],
 683                 [Do not build and install man pages (already built in a distributed tarball)]
 684         ),
 685         [man_pages_opt=$enableval],
 686         [man_pages_opt=yes]
 687 )
 688
 689 # check for asciidoc and xmlto if we enabled building the man pages
 690 have_asciidoc_xmlto=no
 691 warn_prebuilt_man_pages=no
 692
 693 AS_IF([test "x$man_pages_opt" = "xyes"], [
 694         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 695         AC_PATH_PROG([XMLTO], [xmlto], [no])
 696
 697         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 698                 AS_IF([test "x$in_git_repo" = "xyes"], [
 699                         # this is an error because we're in the Git repo, which
 700                         # means the man pages are not already generated for us,
 701                         # thus asciidoc/xmlto are required because we were asked
 702                         # to build the man pages
 703                         AC_MSG_ERROR([
 704 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 705 --disable-man-pages to disable building the man pages, in which case
 706 they will not be installed.
 707                         ])
 708                 ], [
 709                         # only warn here: since we're in the tarball, the man
 710                         # pages should already be generated at this point, thus
 711                         # asciidoc/xmlto are not strictly required
 712                         warn_prebuilt_man_pages=yes
 713                 ])
 714         ], [
 715                 have_asciidoc_xmlto=yes
 716         ])
 717 ])
 718
 719 # export man page build condition: build the man pages if the user
 720 # asked for it, and if the tools are available
 721 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 722 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 723
 724 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 725
 726 # embedded --help message
 727 AC_ARG_ENABLE(
 728         [embedded-help],
 729         AS_HELP_STRING(
 730                 [--enable-embedded-help],
 731                 [Embed the --help messages in the executable files]
 732         ),
 733         [embedded_help=$enableval],
 734         [embedded_help=no]
 735 )
 736 AS_IF([test "x$embedded_help" = "xyes"], [
 737         AS_IF([test "x$man_pages_opt" = "xno"], [
 738                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 739         ])
 740         AC_PATH_PROG([man_prog_path], [man], [no])
 741         AS_IF([test "x$man_prog_path" = "xno"], [
 742                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 743         ])
 744         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 745         AC_SUBST([MANPROG], [$man_prog_path])
 746 ])
 747 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 748
 749 # Python agent test
 750 UST_PYTHON_AGENT="lttngust"
 751
 752 AC_ARG_ENABLE(test-python2-agent,
 753         AS_HELP_STRING([--enable-test-python2-agent],
 754                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 755         ),[:],[test_python2_agent_autodetect=yes]
 756 )
 757
 758 AC_ARG_ENABLE(test-python3-agent,
 759         AS_HELP_STRING([--enable-test-python3-agent],
 760                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 761         ),[:],[test_python3_agent_autodetect=yes]
 762 )
 763
 764 AC_ARG_ENABLE(test-python-agent-all,
 765         AS_HELP_STRING([--enable-test-python-agent-all],
 766                 [enable test for all python{2/3} agent.]
 767         ),
 768 )
 769
 770 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 771        unset test_python2_agent_autodetect
 772        unset test_python3_agent_autodetect
 773 ])
 774
 775 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 776        enable_test_python2_agent=yes
 777        enable_test_python3_agent=yes
 778 ])
 779
 780 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 781        enable_test_python2_agent=no
 782        enable_test_python3_agent=no
 783 ])
 784
 785
 786 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 787         AS_IF([test -z "$PYTHON2"], [
 788                         PYTHON2=python2
 789                 ], [
 790                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 791         ])
 792
 793         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 794         AS_IF([test -z "$PYTHON2_BIN"], [
 795                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 796                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 797                 ])
 798         ], [
 799                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 800                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 801                         PYTHON2_AGENT=$PYTHON2_BIN
 802                         AC_MSG_RESULT([yes])
 803                         RUN_PYTHON_AGENT_TEST=yes
 804                 ], [
 805                         AC_MSG_RESULT([no])
 806                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 807                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 808                         ])
 809                 ])
 810
 811         ])
 812
 813 ])
 814
 815 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 816         AS_IF([test -z "$PYTHON3"], [
 817                 PYTHON3=python3
 818         ], [
 819                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 820         ])
 821
 822         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 823         AS_IF([test -z "$PYTHON3_BIN"], [
 824                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 825                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 826                 ])
 827         ], [
 828                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 829                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 830                         PYTHON3_AGENT=$PYTHON3_BIN
 831                         AC_MSG_RESULT([yes])
 832                         RUN_PYTHON_AGENT_TEST=yes
 833                 ], [
 834                         AC_MSG_RESULT([no])
 835                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 836                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 837                         ])
 838                 ])
 839
 840         ])
 841 ])
 842 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 843 AC_SUBST([PYTHON2_AGENT])
 844 AC_SUBST([PYTHON3_AGENT])
 845
 846 AC_ARG_ENABLE([test-sdt-uprobe],
 847   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 848   [test_sdt_uprobe="$enableval"],
 849   [test_sdt_uprobe=autodetect]
 850 )
 851
 852 AS_IF([test "$test_sdt_uprobe" != "no"], [
 853   LTTNG_CHECK_SDT_WORKS
 854   AC_PATH_PROG([DTRACE], [dtrace])
 855 ])
 856
 857 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 858   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 859     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 860   ])
 861   AS_IF([test "x$DTRACE" = "x"], [
 862     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 863   ])
 864 ])
 865
 866 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 867   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 868     AS_IF([test "x$DTRACE" != "x"], [
 869       test_sdt_uprobe=yes
 870     ])
 871   ])
 872 ])
 873
 874 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 875
 876 # Arguments for binaries build exclusion
 877 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 878 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 879               [Disable the build of lttng-consumerd binaries]))
 880 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 881 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 882               [Disable the build of lttng-relayd binaries]))
 883 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 884               [Disable the build of lttng-sessiond binaries]))
 885 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 886               [Disable the build of the extra components]))
 887
 888
 889 # Always build libconfig since it a dependency of libcommon
 890 build_lib_config=yes
 891
 892 build_lib_compat=no
 893 build_lib_consumer=no
 894 build_lib_hashtable=no
 895 build_lib_health=no
 896 build_lib_index=no
 897 build_lib_kernel_consumer=no
 898 build_lib_kernel_ctl=no
 899 build_lib_lttng_ctl=no
 900 build_lib_relayd=no
 901 build_lib_fd_tracker=no
 902 build_lib_sessiond_comm=no
 903 build_lib_testpoint=no
 904 build_lib_ust_consumer=no
 905
 906 # There is an overlap for enabled dependencies, but this makes everything
 907 # simpler. libcommon and libconfig are always compiled so they are not repeated
 908 # here.
 909
 910 # Enable binary dependencies.
 911 AS_IF([test x$enable_bin_lttng != xno],
 912       [
 913        build_lib_lttng_ctl=yes
 914       ]
 915 )
 916
 917 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 918       [
 919        build_lib_consumer=yes
 920        build_lib_sessiond_comm=yes
 921        build_lib_index=yes
 922        build_lib_health=yes
 923        build_lib_testpoint=yes
 924       ]
 925 )
 926
 927 AS_IF([test x$enable_bin_lttng_crash != xno],
 928       # Do nothing since libconfig and libcommon are built by default.
 929       []
 930 )
 931
 932 AS_IF([test x$enable_bin_lttng_relayd != xno],
 933       [
 934        build_lib_lttng_ctl=yes
 935        build_lib_sessiond_comm=yes
 936        build_lib_hashtable=yes
 937        build_lib_compat=yes
 938        build_lib_index=yes
 939        build_lib_health=yes
 940        build_lib_testpoint=yes
 941        build_lib_fd_tracker=yes
 942       ]
 943 )
 944 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 945       [
 946        build_lib_lttng_ctl=yes
 947        build_lib_sessiond_comm=yes
 948        build_lib_kernel_ctl=yes
 949        build_lib_hashtable=yes
 950        build_lib_compat=yes
 951        build_lib_relayd=yes
 952        build_lib_testpoint=yes
 953        build_lib_health=yes
 954       ]
 955 )
 956
 957 # Libraries dependencies enabling
 958 AS_IF([test x$build_lib_lttng_ctl = xyes],
 959       [
 960        build_lib_sessiond_comm=yes
 961        build_lib_hashtable=yes
 962       ]
 963 )
 964
 965 AS_IF([test x$build_lib_consumer = xyes],
 966       [
 967        build_lib_sessiond_comm=yes
 968        build_lib_kernel_consumer=yes
 969        build_lib_hashtable=yes
 970        build_lib_compat=yes
 971        build_lib_relayd=yes
 972        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 973       ]
 974 )
 975
 976 AS_IF([test x$build_lib_kernel_consumer = xyes],
 977       [
 978        build_lib_kernel_ctl=yes
 979        build_lib_relayd=yes
 980       ]
 981 )
 982
 983 AS_IF([test x$build_lib_relayd = xyes],
 984       [
 985        build_lib_sessiond_comm=yes
 986       ]
 987 )
 988
 989 # Find arch type
 990 AS_CASE([$host_cpu],
 991         [k1om], [ARCHTYPE="x86"],
 992         [i386], [ARCHTYPE="x86"],
 993         [i486], [ARCHTYPE="x86"],
 994         [i586], [ARCHTYPE="x86"],
 995         [i686], [ARCHTYPE="x86"],
 996         [amd64], [ARCHTYPE="x86"],
 997         [x86_64], [ARCHTYPE="x86"],
 998         [powerpc], [ARCHTYPE="ppc"],
 999         [ppc64], [ARCHTYPE="ppc"],
1000         [powerpc64], [ARCHTYPE="ppc"],
1001         [powerpc64le], [ARCHTYPE="ppc"],
1002         [ppc], [ARCHTYPE="ppc"],
1003         [s390], [ARCHTYPE="s390"],
1004         [s390x], [ARCHTYPE="s390"],
1005         [sparc], [ARCHTYPE="sparc64"],
1006         [sparc64], [ARCHTYPE="sparc64"],
1007         [alpha*], [ARCHTYPE="alpha"],
1008         [ia64], [ARCHTYPE="ia64"],
1009         [arm*], [ARCHTYPE="arm"],
1010         [aarch64*], [ARCHTYPE="aarch64"],
1011         [mips*], [ARCHTYPE="mips"],
1012         [nios2*], [ARCHTYPE="nios2"],
1013         [tile*], [ARCHTYPE="tile"],
1014         [hppa*], [ARCHTYPE="hppa"],
1015         [m68k], [ARCHTYPE="m68k"],
1016         [riscv*], [ARCHTYPE="riscv"],
1017         [ARCHTYPE="unknown"]
1018 )
1019
1020 AC_SUBST(ARCHTYPE)
1021
1022 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1023 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1024 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1025         # Userspace callstack capture is only supported by the Linux kernel on x86.
1026         AC_MSG_RESULT([yes])
1027         have_modules_userspace_callstack_context=yes
1028         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1029 ], [
1030         AC_MSG_RESULT([no])
1031         have_modules_userspace_callstack_context=no
1032 ])
1033 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1034
1035 # Export binaries build conditions.
1036 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1037 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1038 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1039 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1040 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1041
1042 # Export the tests and extras build conditions.
1043 AS_IF([\
1044 test "x$enable_bin_lttng" != "xno" && \
1045 test "x$enable_bin_lttng_consumerd" != "xno" && \
1046 test "x$enable_bin_lttng_crash" != "xno" && \
1047 test "x$enable_bin_lttng_relayd" != "xno" && \
1048 test "x$enable_bin_lttng_sessiond" != "xno"],
1049 [build_tests=yes],
1050 [build_tests=no]
1051 )
1052
1053 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1054 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1055
1056 # Export libraries build conditions.
1057 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1058 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1059 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1060 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1061 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1062 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1063 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1064 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1065 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1066 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1067 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1068 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1069 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1070 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1071
1072 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1073 AC_SUBST(AM_CFLAGS)
1074
1075 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1076 AM_LDFLAGS=""
1077 AC_SUBST(AM_LDFLAGS)
1078
1079 # The order in which the include folders are searched is important.
1080 # The top_builddir should always be searched first in the event that a build
1081 # time generated file is included. An example of this is the "version.i" file.
1082 # In a scenario where lttng-tools is built from a distribution tarball and in a
1083 # out-of-tree manner, the generated "version.i" has priority on the one from
1084 # the source (distribution tarball) and must be found first.
1085 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1086 AC_SUBST(AM_CPPFLAGS)
1087
1088 lttngincludedir="${includedir}/lttng"
1089 AC_SUBST(lttngincludedir)
1090
1091 lttngactionincludedir="${includedir}/lttng/action"
1092 AC_SUBST(lttngactionincludedir)
1093
1094 lttngconditionincludedir="${includedir}/lttng/condition"
1095 AC_SUBST(lttngconditionincludedir)
1096
1097 lttngnotificationincludedir="${includedir}/lttng/notification"
1098 AC_SUBST(lttngnotificationincludedir)
1099
1100 lttngtriggerincludedir="${includedir}/lttng/trigger"
1101 AC_SUBST(lttngtriggerincludedir)
1102
1103 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1104 AC_SUBST(lttngeventruleincludedir)
1105
1106 lttnglibexecdir="${libdir}/lttng/libexec"
1107 AC_SUBST(lttnglibexecdir)
1108
1109 AC_CONFIG_FILES([
1110         Makefile
1111         doc/Makefile
1112         doc/man/Makefile
1113         doc/man/asciidoc-attrs.conf
1114         include/Makefile
1115         extras/Makefile
1116         extras/bindings/Makefile
1117         extras/bindings/swig/Makefile
1118         extras/bindings/swig/python/Makefile
1119         extras/core-handler/Makefile
1120         src/Makefile
1121         src/common/Makefile
1122         src/common/argpar/Makefile
1123         src/common/bytecode/Makefile
1124         src/common/kernel-ctl/Makefile
1125         src/common/kernel-consumer/Makefile
1126         src/common/consumer/Makefile
1127         src/common/ust-consumer/Makefile
1128         src/common/hashtable/Makefile
1129         src/common/sessiond-comm/Makefile
1130         src/common/compat/Makefile
1131         src/common/relayd/Makefile
1132         src/common/testpoint/Makefile
1133         src/common/index/Makefile
1134         src/common/health/Makefile
1135         src/common/config/Makefile
1136         src/common/string-utils/Makefile
1137         src/common/fd-tracker/Makefile
1138         src/common/filter/Makefile
1139         src/lib/Makefile
1140         src/lib/lttng-ctl/Makefile
1141         src/lib/lttng-ctl/lttng-ctl.pc
1142         src/bin/Makefile
1143         src/bin/lttng-consumerd/Makefile
1144         src/bin/lttng-sessiond/Makefile
1145         src/bin/lttng-relayd/Makefile
1146         src/bin/lttng/Makefile
1147         src/bin/lttng-crash/Makefile
1148         tests/Makefile
1149         tests/destructive/Makefile
1150         tests/regression/Makefile
1151         tests/regression/kernel/Makefile
1152         tests/regression/tools/Makefile
1153         tests/regression/tools/streaming/Makefile
1154         tests/regression/tools/filtering/Makefile
1155         tests/regression/tools/health/Makefile
1156         tests/regression/tools/tracefile-limits/Makefile
1157         tests/regression/tools/snapshots/Makefile
1158         tests/regression/tools/live/Makefile
1159         tests/regression/tools/exclusion/Makefile
1160         tests/regression/tools/save-load/Makefile
1161         tests/regression/tools/save-load/configuration/Makefile
1162         tests/regression/tools/mi/Makefile
1163         tests/regression/tools/wildcard/Makefile
1164         tests/regression/tools/crash/Makefile
1165         tests/regression/tools/regen-metadata/Makefile
1166         tests/regression/tools/regen-statedump/Makefile
1167         tests/regression/tools/notification/Makefile
1168         tests/regression/tools/rotation/Makefile
1169         tests/regression/tools/base-path/Makefile
1170         tests/regression/tools/metadata/Makefile
1171         tests/regression/tools/tracker/Makefile
1172         tests/regression/tools/working-directory/Makefile
1173         tests/regression/tools/relayd-grouping/Makefile
1174         tests/regression/tools/clear/Makefile
1175         tests/regression/tools/trigger/Makefile
1176         tests/regression/tools/trigger/start-stop/Makefile
1177         tests/regression/tools/trigger/utils/Makefile
1178         tests/regression/ust/Makefile
1179         tests/regression/ust/nprocesses/Makefile
1180         tests/regression/ust/high-throughput/Makefile
1181         tests/regression/ust/low-throughput/Makefile
1182         tests/regression/ust/before-after/Makefile
1183         tests/regression/ust/buffers-pid/Makefile
1184         tests/regression/ust/periodical-metadata-flush/Makefile
1185         tests/regression/ust/multi-session/Makefile
1186         tests/regression/ust/multi-lib/Makefile
1187         tests/regression/ust/overlap/Makefile
1188         tests/regression/ust/overlap/demo/Makefile
1189         tests/regression/ust/linking/Makefile
1190         tests/regression/ust/daemon/Makefile
1191         tests/regression/ust/exit-fast/Makefile
1192         tests/regression/ust/fork/Makefile
1193         tests/regression/ust/libc-wrapper/Makefile
1194         tests/regression/ust/baddr-statedump/Makefile
1195         tests/regression/ust/ust-dl/Makefile
1196         tests/regression/ust/java-jul/Makefile
1197         tests/regression/ust/java-log4j/Makefile
1198         tests/regression/ust/python-logging/Makefile
1199         tests/regression/ust/getcpu-override/Makefile
1200         tests/regression/ust/clock-override/Makefile
1201         tests/regression/ust/type-declarations/Makefile
1202         tests/regression/ust/rotation-destroy-flush/Makefile
1203         tests/regression/ust/blocking/Makefile
1204         tests/regression/ust/namespaces/Makefile
1205         tests/stress/Makefile
1206         tests/unit/Makefile
1207         tests/unit/ini_config/Makefile
1208         tests/perf/Makefile
1209         tests/utils/Makefile
1210         tests/utils/tap/Makefile
1211         tests/utils/testapp/Makefile
1212         tests/utils/testapp/gen-ns-events/Makefile
1213         tests/utils/testapp/gen-kernel-test-events/Makefile
1214         tests/utils/testapp/gen-ust-events/Makefile
1215         tests/utils/testapp/gen-ust-events-ns/Makefile
1216         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1217         tests/utils/testapp/gen-ust-nevents/Makefile
1218         tests/utils/testapp/gen-ust-nevents-str/Makefile
1219         tests/utils/testapp/gen-syscall-events/Makefile
1220         tests/utils/testapp/gen-ust-tracef/Makefile
1221         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1222         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1223         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1224 ])
1225
1226 # Inject variable into python test script.
1227 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1228 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1229 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1230 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1231
1232 AC_OUTPUT
1233
1234 #
1235 # Mini-report on what will be built.
1236 #
1237
1238 PPRINT_INIT
1239 PPRINT_SET_INDENT(1)
1240 PPRINT_SET_TS(38)
1241
1242 AS_ECHO
1243 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1244 AS_ECHO
1245
1246 AS_IF([test -n "$report_fold"], [
1247         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1248 ], [
1249         AS_ECHO("$version_description")
1250 ])
1251
1252 AS_ECHO
1253 PPRINT_SUBTITLE([Features])
1254
1255 # Target architecture we're building for.
1256 target_arch=$host_cpu
1257 [
1258 for f in $CFLAGS; do
1259         if test $f = "-m32"; then
1260                         target_arch="32-bit"
1261         elif test $f = "-m64"; then
1262                         target_arch="64-bit"
1263         fi
1264 done
1265 ]
1266 PPRINT_PROP_STRING([Target architecture], $target_arch)
1267
1268 # kmod enabled/disabled
1269 test "x$with_kmod" != "xno" && value=1 || value=0
1270 PPRINT_PROP_BOOL([libkmod support], $value)
1271
1272 # LTTng-UST enabled/disabled
1273 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1274 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1275
1276 AS_ECHO
1277 PPRINT_SUBTITLE([Binaries])
1278
1279 # List binaries to be built
1280 test x$enable_bin_lttng != xno && value=1 || value=0
1281 PPRINT_PROP_BOOL([lttng], $value)
1282
1283 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1284 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1285
1286 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1287 PPRINT_PROP_BOOL([lttng-crash], $value)
1288
1289 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1290 PPRINT_PROP_BOOL([lttng-relayd], $value)
1291
1292 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1293 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1294
1295 # Extras
1296 test x$enable_extras != xno && value=1 || value=0
1297 AS_ECHO
1298 PPRINT_SET_INDENT(0)
1299 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1300 PPRINT_SET_INDENT(1)
1301
1302 AS_ECHO
1303 PPRINT_SUBTITLE([Tests])
1304
1305 # Print clear message that tests won't be built
1306 AS_IF([test "x$build_tests" = "xno"],[
1307         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1308 ])
1309
1310 # LTTng UST Java agent JUL tests enabled/disabled
1311 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1312 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1313
1314 # LTTng UST Java agent Log4j tests enabled/disabled
1315 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1316 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1317
1318 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1319 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1320
1321 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1322 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1323
1324 # LTTng UST Java agent Log4j tests enabled/disabled
1325 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1326 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1327
1328 #Python binding enabled/disabled
1329 test "x$enable_python_binding" = xyes && value=1 || value=0
1330 AS_ECHO
1331 PPRINT_SET_INDENT(0)
1332 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1333
1334 # man pages build enabled/disabled
1335 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1336
1337 AS_IF([test "x$man_pages_opt" != "xno"], [
1338         AS_IF([test "x$in_git_repo" = "xyes"], [
1339                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1340         ], [
1341                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1342                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1343                 ], [
1344                         PPRINT_PROP_STRING([build_man_pages_msg],
1345                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1346                                 $PPRINT_COLOR_SUBTITLE)
1347                 ])
1348         ])
1349 ], [
1350         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1351 ])
1352
1353 m4_popdef([build_man_pages_msg])
1354
1355 test "x$embedded_help" = xyes && value=1 || value=0
1356 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1357
1358 PPRINT_SET_INDENT(1)
1359
1360 report_bindir="`eval eval echo $bindir`"
1361 report_libdir="`eval eval echo $libdir`"
1362
1363 # Print the bindir and libdir this `make install' will install into.
1364 AS_ECHO
1365 PPRINT_SUBTITLE([Install directories])
1366 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1367 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1368
1369 AS_ECHO
1370 PPRINT_SUBTITLE([Search directories])
1371
1372 # If we build the sessiond, print the paths it will use
1373 AS_IF([test "$SESSIOND_BIN" = ""],[
1374         path="$report_bindir/lttng-sessiond"
1375 ],[
1376         path="$SESSIOND_BIN"
1377 ])
1378 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1379
1380 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1381         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1382 ],[
1383         path="$CONSUMERD32_BIN"
1384 ])
1385 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1386
1387 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1388         path="`eval eval echo $libdir`"
1389 ],[
1390         path="$CONSUMERD32_LIBDIR"
1391 ])
1392 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1393
1394 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1395         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1396 ],[
1397         path="$CONSUMERD64_BIN"
1398 ])
1399 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1400
1401 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1402         path="`eval eval echo $libdir`"
1403 ],[
1404         path="$CONSUMERD64_LIBDIR"
1405 ])
1406 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1407 PPRINT_SET_INDENT(0)
1408
1409 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1410         AS_ECHO
1411         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1412
1413 Note that the man pages are already built in this distribution tarball,
1414 therefore asciidoc and xmlto are only needed if you intend to modify
1415 their sources.
1416
1417 Also note that the installed man pages will contain the project's
1418 default command-line option and environment variable values.
1419
1420 Use --disable-man-pages to completely disable building and installing
1421 the man pages.])
1422 ])