configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62
  63 AX_LIB_SOCKET_NSL
  64
  65 LT_NO_UNDEFINED=""
  66 AS_CASE([$host_os],
  67   [cygwin*],
  68     [
  69       LT_NO_UNDEFINED="-no-undefined"
  70     ]
  71 )
  72
  73 AC_SUBST(LT_NO_UNDEFINED)
  74
  75 # Compute minor/major/patchlevel version numbers
  76 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  77 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  78 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  79
  80 AC_SUBST([MAJOR_VERSION], [$major_version])
  81 AC_SUBST([MINOR_VERSION], [$minor_version])
  82 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  83 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  84 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  85 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  86
  87 version_name="KeKriek"
  88 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
  89 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  90
  91 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  92 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  93
  94 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  95 AC_ARG_ENABLE(libtool-linkdep-fixup,
  96         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  97                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  98         libtool_fixup=$enableval,
  99         libtool_fixup=yes)
 100
 101 AS_IF([test "x$libtool_fixup" = "xyes"],
 102             [
 103             libtool_m4="$srcdir/m4/libtool.m4"
 104             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 105             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 106             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 107             AS_IF([test $libtool_flag_pattern_count -ne 0],
 108             [
 109                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 110                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 111                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 112                   ],
 113                   [
 114                   AC_MSG_RESULT([none])
 115                   ])
 116             ])
 117
 118 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 119
 120 AC_CHECK_HEADERS([ \
 121         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 122         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 123         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 124         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 125         sys/mount.h sys/param.h sys/time.h
 126 ])
 127
 128 # Basic functions check
 129 AC_CHECK_FUNCS([ \
 130         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 131         gethostbyname gethostname getpagesize localtime_r memchr memset \
 132         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 133         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 134         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 135         sched_getcpu sysconf sync_file_range
 136 ])
 137
 138 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 139 # add -lrt to LIBS
 140 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 141
 142 # Babeltrace viewer check
 143 AC_ARG_WITH([babeltrace-bin],
 144         AS_HELP_STRING([--with-babeltrace-bin],
 145         [Location of the babeltrace viewer executable (including the filename)]),
 146         [BABELTRACE_BIN="$withval"],
 147         [BABELTRACE_BIN=''])
 148 AC_SUBST([BABELTRACE_BIN])
 149
 150 # lttv-gui
 151 AC_ARG_WITH([lttv-gui-bin],
 152         AS_HELP_STRING([--with-lttv-gui-bin],
 153    [Location of the lttv GUI viewer executable (including the filename)]),
 154    [LTTV_GUI_BIN="$withval"],
 155    [LTTV_GUI_BIN=''])
 156 AC_SUBST([LTTV_GUI_BIN])
 157
 158 AC_ARG_WITH([consumerd32-bin],
 159         AS_HELP_STRING([--with-consumerd32-bin],
 160         [Location of the 32-bit consumerd executable (including the filename)]),
 161         [CONSUMERD32_BIN="$withval"],
 162         [CONSUMERD32_BIN=''])
 163 AC_SUBST([CONSUMERD32_BIN])
 164
 165 AC_ARG_WITH([consumerd64-bin],
 166         AS_HELP_STRING([--with-consumerd64-bin],
 167         [Location of the 64-bit consumerd executable (including the filename)]),
 168         [CONSUMERD64_BIN="$withval"],
 169         [CONSUMERD64_BIN=''])
 170 AC_SUBST([CONSUMERD64_BIN])
 171
 172 AC_ARG_WITH([consumerd32-libdir],
 173         AS_HELP_STRING([--with-consumerd32-libdir],
 174         [Directory containing the 32-bit consumerd libraries]),
 175         [CONSUMERD32_LIBDIR="$withval"],
 176         [CONSUMERD32_LIBDIR=''])
 177 AC_SUBST([CONSUMERD32_LIBDIR])
 178
 179 AC_ARG_WITH([consumerd64-libdir],
 180         AS_HELP_STRING([--with-consumerd64-libdir],
 181         [Directory containing the 64-bit consumerd libraries]),
 182         [CONSUMERD64_LIBDIR="$withval"],
 183         [CONSUMERD64_LIBDIR=''])
 184 AC_SUBST([CONSUMERD64_LIBDIR])
 185
 186 AC_ARG_WITH([sessiond-bin],
 187         AS_HELP_STRING([--with-sessiond-bin],
 188         [Location of the sessiond executable (including the filename)]),
 189         [SESSIOND_BIN="$withval"],
 190         [SESSIOND_BIN=''])
 191 AC_SUBST([SESSIOND_BIN])
 192
 193 AC_ARG_WITH([lttng-system-rundir],
 194         AS_HELP_STRING([--with-lttng-system-rundir],
 195         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 196         [LTTNG_SYSTEM_RUNDIR="$withval"],
 197         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 198 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 199
 200 AC_ARG_ENABLE([test-java-agent-jul],
 201         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 202         [test_java_agent_jul=$enableval],
 203         [test_java_agent_jul=no]
 204 )
 205
 206 AC_ARG_ENABLE([test-java-agent-log4j],
 207         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 208         [test_java_agent_log4j=$enableval],
 209         [test_java_agent_log4j=no]
 210 )
 211
 212 AC_ARG_ENABLE([test-java-agent-all],
 213         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 214         [test_java_agent_jul=$enableval
 215          test_java_agent_log4j=$enableval],
 216         [:]
 217 )
 218
 219 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 220 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 221 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 222 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 223 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 224 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 225 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 226 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 227
 228 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 229         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 230         $1="$2"
 231         AC_SUBST([$1])
 232 ])
 233
 234 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 235         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 236         $1="$2"
 237         AC_SUBST([$1])
 238 ])
 239
 240 # Default values
 241 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 242 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 243 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 244 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 245 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 246 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 247 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 248 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 249 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 250 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 251 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 252 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 253 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 254 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 255 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 256 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 257 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 258 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 259 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 260 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 261 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 262 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 263 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 264 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 265 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 266 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 267 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 268 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 269 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 270 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 271 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 272 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 273 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 274 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 275 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 276 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 277 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 278 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 279 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 280 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 281 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 282 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 283
 284 # Command short descriptions
 285 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 286 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 291 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 292 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 293 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 294 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 295 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 296 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 297 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 298 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 299 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 300 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 301 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 302 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 303 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 304 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 305 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 306
 307 if test "x$prefix" = "xNONE"; then
 308         prefix=$ac_default_prefix
 309 fi
 310 CONFDIR=`eval echo $sysconfdir`
 311 AC_SUBST(CONFDIR)
 312 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 313
 314 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 315
 316 #
 317 # Check for pthread
 318 AC_CHECK_LIB([pthread], [pthread_create], [],
 319         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 320 )
 321
 322 # Check libpopt
 323 PKG_CHECK_MODULES([POPT], [popt],
 324         [LIBS="$LIBS $POPT_LIBS"],
 325         [
 326                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 327                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 328                 AC_CHECK_LIB([popt],
 329                         [poptGetContext],
 330                         [],
 331                         [
 332                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 333                         ]
 334                 )
 335         ]
 336 )
 337
 338 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 339
 340 # First, check for uuid in system libs
 341 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 342 AC_CHECK_FUNCS([uuid_generate],
 343   [
 344     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 345     UUID_LIBS=""
 346   ],
 347   [
 348     # Then, check if the pkg-config module is available, otherwise explicitly check
 349     # for libuuid, or uuid support in the C-library.
 350     PKG_CHECK_MODULES([UUID], [uuid],
 351       [
 352         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 353         dnl PKG_CHECK_MODULES defines UUID_LIBS
 354       ],
 355       [
 356         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 357         AC_MSG_WARN([Finding libuuid without pkg-config.])
 358         AC_CHECK_LIB([uuid], [uuid_generate],
 359           [
 360             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 361             UUID_LIBS="-luuid"
 362           ],
 363           [
 364             # libuuid not found, check for uuid_create in libc.
 365             AC_CHECK_LIB([c], [uuid_create],
 366               [
 367                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 368                 UUID_LIBS="-lc"
 369               ],
 370               [
 371                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 372               ]
 373             )
 374           ]
 375         )
 376       ]
 377     )
 378   ]
 379 )
 380 AC_SUBST(UUID_LIBS)
 381
 382 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 383
 384 # URCU library version needed or newer
 385 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 386
 387 # Check liburcu needed function calls
 388 AC_CHECK_DECL([cds_list_add], [],
 389         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 390 AC_CHECK_DECL([cds_wfcq_init], [],
 391         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 392 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 393         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 394 AC_CHECK_DECL([futex_async], [],
 395         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 396 AC_CHECK_DECL([rcu_thread_offline], [],
 397         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 398 AC_CHECK_DECL([rcu_thread_online], [],
 399         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 400 AC_CHECK_DECL([caa_likely], [],
 401         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 402 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 403         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 404
 405 #Function added in urcu 0.7.0
 406 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 407         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 408 )
 409
 410 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 411 # it can be explicitly disabled with --without-kmod
 412 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 413 AC_ARG_WITH([kmod],
 414   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 415   [],
 416   [with_kmod=check]
 417 )
 418
 419 AS_IF([test "x$with_kmod" != "xno"],
 420   [
 421     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 422       [
 423         AC_DEFINE([HAVE_KMOD], [1])
 424         KMOD_LIBS="-lkmod"
 425       ],
 426       [
 427         if test "x$with_kmod" != xcheck; then
 428           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 429         else
 430           with_kmod=no
 431         fi
 432       ]
 433     )
 434   ]
 435 )
 436 AC_SUBST(KMOD_LIBS)
 437
 438 # Check for liblttng-ust-ctl, fail if it's not found,
 439 # it can be explicitly disabled with --without-lttng-ust
 440 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 441 AC_ARG_WITH([lttng-ust],
 442   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 443   [],
 444   [with_lttng_ust=yes]
 445 )
 446
 447 AS_IF([test "x$with_lttng_ust" = "xyes"],
 448   [
 449     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 450       [
 451         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 452       ],
 453       [
 454         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 455       ],
 456       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 457     )
 458   ]
 459 )
 460 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 461
 462
 463
 464 # check for dlopen
 465 AC_CHECK_LIB([dl], [dlopen],
 466   [DL_LIBS="-ldl"],
 467   [
 468     #libdl not found, check for dlopen in libc.
 469     AC_CHECK_LIB([c], [dlopen],
 470       [DL_LIBS="-lc"],
 471       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 472     )
 473   ]
 474 )
 475 AC_SUBST(DL_LIBS)
 476
 477 # Check for fmemopen
 478 AC_CHECK_LIB([c], [fmemopen],
 479 [
 480         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 481 ]
 482 )
 483
 484 # Check for open_memstream
 485 AC_CHECK_LIB([c], [open_memstream],
 486 [
 487         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 488 ]
 489 )
 490
 491 # check for libpfm
 492 AC_CHECK_LIB([pfm], [pfm_initialize],
 493              [
 494               have_libpfm=yes
 495               ])
 496 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 497
 498 AC_ARG_ENABLE([git-version],
 499               [AC_HELP_STRING([--disable-git-version],
 500                               [Do not use the git version for the build])],
 501               [have_git_version=$enableval], [have_git_version=yes]
 502 )
 503
 504 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 505         [test "x${have_git_version}" = "xyes"])
 506
 507 # For Python
 508 # SWIG version needed or newer:
 509 swig_version=2.0.0
 510
 511 AC_ARG_ENABLE([python-bindings],
 512               [AC_HELP_STRING([--enable-python-bindings],
 513                               [compile Python bindings])],
 514               [enable_python_binding=$enableval], [enable_python_binding=no])
 515
 516 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 517
 518 if test "x$enable_python_binding" = xyes; then
 519   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 520   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 521   AM_PATH_PYTHON([3.0])
 522
 523   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 524   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 525   AS_IF([test -z "$PYTHON_INCLUDE"], [
 526     AS_IF([test -z "$PYTHON_CONFIG"], [
 527       AC_PATH_PROGS([PYTHON_CONFIG],
 528                     [python$PYTHON_VERSION-config python-config],
 529                     [no],
 530                     [`dirname $PYTHON`])
 531       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 532     ])
 533     AC_MSG_CHECKING([python include flags])
 534     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 535     AC_MSG_RESULT([$PYTHON_INCLUDE])
 536   ])
 537
 538 else
 539     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 540 [if you want Python bindings.])
 541
 542 fi
 543
 544 # Epoll check. If not present, the build will fallback on poll() API
 545 AX_HAVE_EPOLL(
 546         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 547         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 548 )
 549 AX_CONFIG_FEATURE(
 550         [epoll], [This platform supports epoll(7)],
 551         [HAVE_EPOLL], [This platform supports epoll(7).],
 552         [enable_epoll="yes"], [enable_epoll="no"]
 553 )
 554 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 555
 556 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 557 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 558
 559 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 560         AX_JAVA_OPTIONS
 561         AX_PROG_JAVAC
 562         AX_PROG_JAVA
 563         AX_PROG_JAR
 564
 565         AX_CHECK_CLASSPATH
 566
 567         # Check for Java UST agent common class first
 568         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 569         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 570                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 571         fi
 572
 573         if test "x$test_java_agent_jul" = "xyes"; then
 574                 # Check for JUL agent class
 575                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 576                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 577                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 578                 fi
 579         fi
 580
 581         if test "x$test_java_agent_log4j" = "xyes"; then
 582                 # Check for Log4j agent class
 583                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 584                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 585                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 586                 fi
 587
 588                 # Check for Log4j class
 589                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 590                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 591                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 592                 fi
 593         fi
 594 fi
 595
 596 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 597 # is not distributed in tarballs
 598 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 599 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 600
 601 # enable building man pages (user's intention)
 602 AC_ARG_ENABLE(
 603         man-pages,
 604         AS_HELP_STRING(
 605                 [--disable-man-pages],
 606                 [Do not build and install man pages (already built in a distributed tarball)]
 607         ),
 608         [man_pages_opt=$enableval],
 609         [man_pages_opt=yes]
 610 )
 611
 612 # check for asciidoc and xmlto if we enabled building the man pages
 613 have_asciidoc_xmlto=no
 614 warn_prebuilt_man_pages=no
 615
 616 AS_IF([test "x$man_pages_opt" = "xyes"], [
 617         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 618         AC_PATH_PROG([XMLTO], [xmlto], [no])
 619
 620         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 621                 AS_IF([test "x$in_git_repo" = "xyes"], [
 622                         # this is an error because we're in the Git repo, which
 623                         # means the man pages are not already generated for us,
 624                         # thus asciidoc/xmlto are required because we were asked
 625                         # to build the man pages
 626                         AC_MSG_ERROR([
 627 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 628 --disable-man-pages to disable building the man pages, in which case
 629 they will not be installed.
 630                         ])
 631                 ], [
 632                         # only warn here: since we're in the tarball, the man
 633                         # pages should already be generated at this point, thus
 634                         # asciidoc/xmlto are not strictly required
 635                         warn_prebuilt_man_pages=yes
 636                 ])
 637         ], [
 638                 have_asciidoc_xmlto=yes
 639         ])
 640 ])
 641
 642 # export man page build condition: build the man pages if the user
 643 # asked for it, and if the tools are available
 644 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 645 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 646
 647 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 648
 649 # embedded --help message
 650 AC_ARG_ENABLE(
 651         [embedded-help],
 652         AS_HELP_STRING(
 653                 [--enable-embedded-help],
 654                 [Embed the --help messages in the executable files]
 655         ),
 656         [embedded_help=$enableval],
 657         [embedded_help=no]
 658 )
 659 AS_IF([test "x$embedded_help" = "xyes"], [
 660         AS_IF([test "x$man_pages_opt" = "xno"], [
 661                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 662         ])
 663         AC_PATH_PROG([man_prog_path], [man], [no])
 664         AS_IF([test "x$man_prog_path" = "xno"], [
 665                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 666         ])
 667         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 668         AC_SUBST([MANPROG], [$man_prog_path])
 669 ])
 670 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 671
 672 # Python agent test
 673 UST_PYTHON_AGENT="lttngust"
 674
 675 AC_ARG_ENABLE(test-python2-agent,
 676         AS_HELP_STRING([--enable-test-python2-agent],
 677                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 678         ),[:],[test_python2_agent_autodetect=yes]
 679 )
 680
 681 AC_ARG_ENABLE(test-python3-agent,
 682         AS_HELP_STRING([--enable-test-python3-agent],
 683                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 684         ),[:],[test_python3_agent_autodetect=yes]
 685 )
 686
 687 AC_ARG_ENABLE(test-python-agent-all,
 688         AS_HELP_STRING([--enable-test-python-agent-all],
 689                 [enable test for all python{2/3} agent.]
 690         ),
 691 )
 692
 693 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 694        unset test_python2_agent_autodetect
 695        unset test_python3_agent_autodetect
 696 ])
 697
 698 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 699        enable_test_python2_agent=yes
 700        enable_test_python3_agent=yes
 701 ])
 702
 703 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 704        enable_test_python2_agent=no
 705        enable_test_python3_agent=no
 706 ])
 707
 708
 709 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 710         AS_IF([test -z "$PYTHON2"], [
 711                         PYTHON2=python2
 712                 ], [
 713                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 714         ])
 715
 716         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 717         AS_IF([test -z "$PYTHON2_BIN"], [
 718                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 719                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 720                 ])
 721         ], [
 722                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 723                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 724                         PYTHON2_AGENT=$PYTHON2_BIN
 725                         AC_MSG_RESULT([yes])
 726                         RUN_PYTHON_AGENT_TEST=yes
 727                 ], [
 728                         AC_MSG_RESULT([no])
 729                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 730                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 731                         ])
 732                 ])
 733
 734         ])
 735
 736 ])
 737
 738 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 739         AS_IF([test -z "$PYTHON3"], [
 740                 PYTHON3=python3
 741         ], [
 742                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 743         ])
 744
 745         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 746         AS_IF([test -z "$PYTHON3_BIN"], [
 747                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 748                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 749                 ])
 750         ], [
 751                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 752                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 753                         PYTHON3_AGENT=$PYTHON3_BIN
 754                         AC_MSG_RESULT([yes])
 755                         RUN_PYTHON_AGENT_TEST=yes
 756                 ], [
 757                         AC_MSG_RESULT([no])
 758                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 759                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 760                         ])
 761                 ])
 762
 763         ])
 764 ])
 765 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 766 AC_SUBST([PYTHON2_AGENT])
 767 AC_SUBST([PYTHON3_AGENT])
 768
 769 # Arguments for binaries build exclusion
 770 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 771 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 772               [Disable the build of lttng-consumerd binaries]))
 773 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 774 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 775               [Disable the build of lttng-relayd binaries]))
 776 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 777               [Disable the build of lttng-sessiond binaries]))
 778 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 779               [Disable the build of the extra components]))
 780
 781
 782 # Always build libconfig since it a dependency of libcommon
 783 build_lib_config=yes
 784
 785 build_lib_compat=no
 786 build_lib_consumer=no
 787 build_lib_hashtable=no
 788 build_lib_health=no
 789 build_lib_index=no
 790 build_lib_kernel_consumer=no
 791 build_lib_kernel_ctl=no
 792 build_lib_lttng_ctl=no
 793 build_lib_relayd=no
 794 build_lib_sessiond_comm=no
 795 build_lib_testpoint=no
 796 build_lib_ust_consumer=no
 797
 798 # There is an overlap for enabled dependencies, but this makes everything
 799 # simpler. libcommon and libconfig are always compiled so they are not repeated
 800 # here.
 801
 802 # Enable binary dependencies.
 803 AS_IF([test x$enable_bin_lttng != xno],
 804       [
 805        build_lib_lttng_ctl=yes
 806       ]
 807 )
 808
 809 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 810       [
 811        build_lib_consumer=yes
 812        build_lib_sessiond_comm=yes
 813        build_lib_index=yes
 814        build_lib_health=yes
 815        build_lib_testpoint=yes
 816       ]
 817 )
 818
 819 AS_IF([test x$enable_bin_lttng_crash != xno],
 820       # Do nothing since libconfig and libcommon are built by default.
 821       []
 822 )
 823
 824 AS_IF([test x$enable_bin_lttng_relayd != xno],
 825       [
 826        build_lib_lttng_ctl=yes
 827        build_lib_sessiond_comm=yes
 828        build_lib_hashtable=yes
 829        build_lib_compat=yes
 830        build_lib_index=yes
 831        build_lib_health=yes
 832        build_lib_testpoint=yes
 833       ]
 834 )
 835 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 836       [
 837        build_lib_lttng_ctl=yes
 838        build_lib_sessiond_comm=yes
 839        build_lib_kernel_ctl=yes
 840        build_lib_hashtable=yes
 841        build_lib_compat=yes
 842        build_lib_relayd=yes
 843        build_lib_testpoint=yes
 844        build_lib_health=yes
 845        build_lib_health=yes
 846       ]
 847 )
 848
 849 # Libraries dependencies enabling
 850 AS_IF([test x$build_lib_lttng_ctl = xyes],
 851       [
 852        build_lib_sessiond_comm=yes
 853        build_lib_hashtable=yes
 854       ]
 855 )
 856
 857 AS_IF([test x$build_lib_consumer = xyes],
 858       [
 859        build_lib_sessiond_comm=yes
 860        build_lib_kernel_consumer=yes
 861        build_lib_hashtable=yes
 862        build_lib_compat=yes
 863        build_lib_relayd=yes
 864        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 865       ]
 866 )
 867
 868 AS_IF([test x$build_lib_kernel_consumer = xyes],
 869       [
 870        build_lib_kernel_ctl=yes
 871        build_lib_relayd=yes
 872       ]
 873 )
 874
 875 AS_IF([test x$build_lib_relayd = xyes],
 876       [
 877        build_lib_sessiond_comm=yes
 878       ]
 879 )
 880
 881
 882 # Export binaries build conditions.
 883 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 884 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 885 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 886 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 887 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 888
 889 # Export the tests and extras build conditions.
 890 AS_IF([\
 891 test "x$enable_bin_lttng" != "xno" && \
 892 test "x$enable_bin_lttng_consumerd" != "xno" && \
 893 test "x$enable_bin_lttng_crash" != "xno" && \
 894 test "x$enable_bin_lttng_relayd" != "xno" && \
 895 test "x$enable_bin_lttng_sessiond" != "xno"],
 896 [build_tests=yes],
 897 [build_tests=no]
 898 )
 899
 900 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 901 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 902
 903 # Export libraries build conditions.
 904 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 905 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 906 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 907 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 908 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 909 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 910 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 911 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 912 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 913 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 914 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 915 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 916 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 917
 918 # check for pgrep
 919 AC_PATH_PROG([PGREP], [pgrep], [no])
 920 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 921
 922 # check for bison
 923 have_bison=yes
 924
 925 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
 926 AC_PATH_PROG([BISON], [bison])
 927 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
 928
 929 AS_IF([test "x$have_bison" = "xno"], [
 930         AS_IF([test "x$in_git_repo" = "xyes"], [
 931                 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
 932         ], [
 933                 AC_MSG_WARN([
 934 Missing Bison >= 2.4. Note that the parser files are already built in
 935 this distribution tarball, so Bison is only needed if you intend to
 936 modify their sources.
 937                 ])
 938         ])
 939 ])
 940
 941 # export bison condition
 942 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 943
 944 # check for flex
 945 have_flex=yes
 946
 947 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
 948 AC_PATH_PROG([FLEX], [flex])
 949 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
 950
 951 AS_IF([test "x$have_flex" = "xno"], [
 952         AS_IF([test "x$in_git_repo" = "xyes"], [
 953                 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
 954         ], [
 955                 AC_MSG_WARN([
 956 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 957 this distribution tarball, so Flex is only needed if you intend to
 958 modify their sources.
 959                 ])
 960         ])
 961 ])
 962
 963 # export flex condition
 964 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 965
 966 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
 967 AC_SUBST(AM_CFLAGS)
 968
 969 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
 970 AC_SUBST(AM_CPPFLAGS)
 971
 972 lttngincludedir="${includedir}/lttng"
 973 AC_SUBST(lttngincludedir)
 974
 975 lttngactionincludedir="${includedir}/lttng/action"
 976 AC_SUBST(lttngactionincludedir)
 977
 978 lttngconditionincludedir="${includedir}/lttng/condition"
 979 AC_SUBST(lttngconditionincludedir)
 980
 981 lttngnotificationincludedir="${includedir}/lttng/notification"
 982 AC_SUBST(lttngnotificationincludedir)
 983
 984 lttngtriggerincludedir="${includedir}/lttng/trigger"
 985 AC_SUBST(lttngtriggerincludedir)
 986
 987 lttnglibexecdir="${libdir}/lttng/libexec"
 988 AC_SUBST(lttnglibexecdir)
 989
 990 AC_CONFIG_FILES([
 991         Makefile
 992         doc/Makefile
 993         doc/man/Makefile
 994         doc/man/asciidoc-attrs.conf
 995         include/Makefile
 996         extras/Makefile
 997         extras/bindings/Makefile
 998         extras/bindings/swig/Makefile
 999         extras/bindings/swig/python/Makefile
1000         extras/core-handler/Makefile
1001         src/Makefile
1002         src/common/Makefile
1003         src/common/kernel-ctl/Makefile
1004         src/common/kernel-consumer/Makefile
1005         src/common/consumer/Makefile
1006         src/common/ust-consumer/Makefile
1007         src/common/hashtable/Makefile
1008         src/common/sessiond-comm/Makefile
1009         src/common/compat/Makefile
1010         src/common/relayd/Makefile
1011         src/common/testpoint/Makefile
1012         src/common/index/Makefile
1013         src/common/health/Makefile
1014         src/common/config/Makefile
1015         src/common/string-utils/Makefile
1016         src/lib/Makefile
1017         src/lib/lttng-ctl/Makefile
1018         src/lib/lttng-ctl/filter/Makefile
1019         src/lib/lttng-ctl/lttng-ctl.pc
1020         src/bin/Makefile
1021         src/bin/lttng-consumerd/Makefile
1022         src/bin/lttng-sessiond/Makefile
1023         src/bin/lttng-relayd/Makefile
1024         src/bin/lttng/Makefile
1025         src/bin/lttng-crash/Makefile
1026         tests/Makefile
1027         tests/destructive/Makefile
1028         tests/regression/Makefile
1029         tests/regression/kernel/Makefile
1030         tests/regression/tools/Makefile
1031         tests/regression/tools/streaming/Makefile
1032         tests/regression/tools/filtering/Makefile
1033         tests/regression/tools/health/Makefile
1034         tests/regression/tools/tracefile-limits/Makefile
1035         tests/regression/tools/snapshots/Makefile
1036         tests/regression/tools/live/Makefile
1037         tests/regression/tools/exclusion/Makefile
1038         tests/regression/tools/save-load/Makefile
1039         tests/regression/tools/save-load/configuration/Makefile
1040         tests/regression/tools/mi/Makefile
1041         tests/regression/tools/wildcard/Makefile
1042         tests/regression/tools/crash/Makefile
1043         tests/regression/tools/regen-metadata/Makefile
1044         tests/regression/tools/regen-statedump/Makefile
1045         tests/regression/tools/notification/Makefile
1046         tests/regression/ust/Makefile
1047         tests/regression/ust/nprocesses/Makefile
1048         tests/regression/ust/high-throughput/Makefile
1049         tests/regression/ust/low-throughput/Makefile
1050         tests/regression/ust/before-after/Makefile
1051         tests/regression/ust/buffers-pid/Makefile
1052         tests/regression/ust/periodical-metadata-flush/Makefile
1053         tests/regression/ust/multi-session/Makefile
1054         tests/regression/ust/overlap/Makefile
1055         tests/regression/ust/overlap/demo/Makefile
1056         tests/regression/ust/linking/Makefile
1057         tests/regression/ust/daemon/Makefile
1058         tests/regression/ust/exit-fast/Makefile
1059         tests/regression/ust/fork/Makefile
1060         tests/regression/ust/libc-wrapper/Makefile
1061         tests/regression/ust/baddr-statedump/Makefile
1062         tests/regression/ust/ust-dl/Makefile
1063         tests/regression/ust/java-jul/Makefile
1064         tests/regression/ust/java-log4j/Makefile
1065         tests/regression/ust/python-logging/Makefile
1066         tests/regression/ust/getcpu-override/Makefile
1067         tests/regression/ust/clock-override/Makefile
1068         tests/regression/ust/type-declarations/Makefile
1069         tests/regression/ust/rotation-destroy-flush/Makefile
1070         tests/regression/ust/blocking/Makefile
1071         tests/stress/Makefile
1072         tests/unit/Makefile
1073         tests/unit/ini_config/Makefile
1074         tests/perf/Makefile
1075         tests/utils/Makefile
1076         tests/utils/tap/Makefile
1077         tests/utils/testapp/Makefile
1078         tests/utils/testapp/gen-ust-events/Makefile
1079         tests/utils/testapp/gen-ust-nevents/Makefile
1080         tests/utils/testapp/gen-ust-nevents-str/Makefile
1081         tests/utils/testapp/gen-ust-tracef/Makefile
1082 ])
1083
1084 # Inject variable into python test script.
1085 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1086 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1087 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1088
1089 AC_OUTPUT
1090
1091 #
1092 # Mini-report on what will be built.
1093 #
1094
1095 PPRINT_INIT
1096 PPRINT_SET_INDENT(1)
1097 PPRINT_SET_TS(38)
1098
1099 AS_ECHO
1100 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1101 AS_ECHO
1102
1103 AS_IF([test -n "$report_fold"], [
1104         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1105 ], [
1106         AS_ECHO("$version_description")
1107 ])
1108
1109 AS_ECHO
1110 PPRINT_SUBTITLE([Features])
1111
1112 # Target architecture we're building for.
1113 target_arch=$host_cpu
1114 [
1115 for f in $CFLAGS; do
1116         if test $f = "-m32"; then
1117                         target_arch="32-bit"
1118         elif test $f = "-m64"; then
1119                         target_arch="64-bit"
1120         fi
1121 done
1122 ]
1123 PPRINT_PROP_STRING([Target architecture], $target_arch)
1124
1125 # kmod enabled/disabled
1126 test "x$with_kmod" != "xno" && value=1 || value=0
1127 PPRINT_PROP_BOOL([libkmod support], $value)
1128
1129 # LTTng-UST enabled/disabled
1130 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1131 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1132
1133 AS_ECHO
1134 PPRINT_SUBTITLE([Binaries])
1135
1136 # List binaries to be built
1137 test x$enable_bin_lttng != xno && value=1 || value=0
1138 PPRINT_PROP_BOOL([lttng], $value)
1139
1140 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1141 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1142
1143 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1144 PPRINT_PROP_BOOL([lttng-crash], $value)
1145
1146 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1147 PPRINT_PROP_BOOL([lttng-relayd], $value)
1148
1149 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1150 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1151
1152 # Extras
1153 test x$enable_extras != xno && value=1 || value=0
1154 AS_ECHO
1155 PPRINT_SET_INDENT(0)
1156 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1157 PPRINT_SET_INDENT(1)
1158
1159 AS_ECHO
1160 PPRINT_SUBTITLE([Tests])
1161
1162 # Print clear message that tests won't be built
1163 AS_IF([test "x$build_tests" = "xno"],[
1164         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1165 ])
1166
1167 # LTTng UST Java agent JUL tests enabled/disabled
1168 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1169 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1170
1171 # LTTng UST Java agent Log4j tests enabled/disabled
1172 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1173 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1174
1175 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1176 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1177
1178 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1179 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1180
1181 #Python binding enabled/disabled
1182 test "x$enable_python_binding" = xyes && value=1 || value=0
1183 AS_ECHO
1184 PPRINT_SET_INDENT(0)
1185 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1186
1187 # man pages build enabled/disabled
1188 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1189
1190 AS_IF([test "x$man_pages_opt" != "xno"], [
1191         AS_IF([test "x$in_git_repo" = "xyes"], [
1192                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1193         ], [
1194                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1195                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1196                 ], [
1197                         PPRINT_PROP_STRING([build_man_pages_msg],
1198                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1199                                 $PPRINT_COLOR_SUBTITLE)
1200                 ])
1201         ])
1202 ], [
1203         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1204 ])
1205
1206 m4_popdef([build_man_pages_msg])
1207
1208 test "x$embedded_help" = xyes && value=1 || value=0
1209 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1210
1211 PPRINT_SET_INDENT(1)
1212
1213 report_bindir="`eval eval echo $bindir`"
1214 report_libdir="`eval eval echo $libdir`"
1215
1216 # Print the bindir and libdir this `make install' will install into.
1217 AS_ECHO
1218 PPRINT_SUBTITLE([Install directories])
1219 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1220 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1221
1222 AS_ECHO
1223 PPRINT_SUBTITLE([Search directories])
1224
1225 # If we build the sessiond, print the paths it will use
1226 AS_IF([test "$SESSIOND_BIN" = ""],[
1227         path="$report_bindir/lttng-sessiond"
1228 ],[
1229         path="$SESSIOND_BIN"
1230 ])
1231 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1232
1233 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1234         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1235 ],[
1236         path="$CONSUMERD32_BIN"
1237 ])
1238 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1239
1240 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1241         path="`eval eval echo $libdir`"
1242 ],[
1243         path="$CONSUMERD32_LIBDIR"
1244 ])
1245 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1246
1247 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1248         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1249 ],[
1250         path="$CONSUMERD64_BIN"
1251 ])
1252 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1253
1254 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1255         path="`eval eval echo $libdir`"
1256 ],[
1257         path="$CONSUMERD64_LIBDIR"
1258 ])
1259 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1260 PPRINT_SET_INDENT(0)
1261
1262 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1263         AS_ECHO
1264         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1265
1266 Note that the man pages are already built in this distribution tarball,
1267 therefore asciidoc and xmlto are only needed if you intend to modify
1268 their sources.
1269
1270 Also note that the installed man pages will contain the project's
1271 default command-line option and environment variable values.
1272
1273 Use --disable-man-pages to completely disable building and installing
1274 the man pages.])
1275 ])