configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_MAKE_SET
  28 AC_PROG_SED
  29 AC_PATH_PROG([report_fold], [fold])
  30 LT_INIT
  31
  32 # Check for objcopy, required by the base address statedump and dynamic linker tests
  33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  34 AS_IF([test "x$OBJCOPY" = "xno"],
  35         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  36 )
  37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  38
  39 # check for pgrep
  40 AC_PATH_PROG([PGREP], [pgrep], [no])
  41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  42
  43 # check for bison
  44 AC_PROG_YACC
  45 BISON=$YACC
  46 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  47
  48 AS_IF([test "x$have_bison" != "xyes"], [
  49   AS_IF([test "x$in_git_repo" = "xyes"], [
  50     AC_MSG_FAILURE([
  51 Bison >= 2.4 is required when building from the Git repository. You can
  52 set the YACC variable to override automatic detection.
  53     ])
  54   ], [
  55     AC_MSG_WARN([
  56 Missing Bison >= 2.4. Note that the parser files are already built in
  57 this distribution tarball, so Bison is only needed if you intend to
  58 modify their sources. You can set the YACC variable to override automatic
  59 detection.
  60     ])
  61   ])
  62 ])
  63 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  64
  65 # check for flex
  66 AC_PROG_LEX
  67 FLEX=$LEX
  68 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  69
  70 AS_IF([test "x$have_flex" != "xyes"], [
  71   AS_IF([test "x$in_git_repo" = "xyes"], [
  72     AC_MSG_FAILURE([
  73 Flex >= 2.5.35 is required when building from the Git repository. You can
  74 set the LEX variable to override automatic detection.
  75     ])
  76   ], [
  77     AC_MSG_WARN([
  78 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  79 this distribution tarball, so Flex is only needed if you intend to
  80 modify their sources. You can set the LEX variable to override automatic
  81 detection.
  82     ])
  83   ])
  84 ])
  85 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  86
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_INT32_T
  91 AC_TYPE_INT64_T
  92 AC_TYPE_MODE_T
  93 AC_TYPE_OFF_T
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_SSIZE_T
  97 AC_TYPE_UID_T
  98 AC_TYPE_UINT16_T
  99 AC_TYPE_UINT32_T
 100 AC_TYPE_UINT64_T
 101 AC_TYPE_UINT8_T
 102
 103 AX_C___ATTRIBUTE__
 104 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 105         [:],
 106         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 107
 108 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 109
 110 AX_LIB_SOCKET_NSL
 111
 112 LT_NO_UNDEFINED=""
 113 AS_CASE([$host_os],
 114   [cygwin*],
 115     [
 116       LT_NO_UNDEFINED="-no-undefined"
 117     ]
 118 )
 119
 120 AC_SUBST(LT_NO_UNDEFINED)
 121
 122 # Compute minor/major/patchlevel version numbers
 123 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 124 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 125 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 126
 127 AC_SUBST([MAJOR_VERSION], [$major_version])
 128 AC_SUBST([MINOR_VERSION], [$minor_version])
 129 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 130 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 131 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 132 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 133
 134 version_name="KeKriek"
 135 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
 136 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 137
 138 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 139 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 140
 141 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 142 AC_ARG_ENABLE(libtool-linkdep-fixup,
 143         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 144                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 145         libtool_fixup=$enableval,
 146         libtool_fixup=yes)
 147
 148 AS_IF([test "x$libtool_fixup" = "xyes"],
 149             [
 150             libtool_m4="$srcdir/m4/libtool.m4"
 151             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 152             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 153             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 154             AS_IF([test $libtool_flag_pattern_count -ne 0],
 155             [
 156                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 157                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 158                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 159                   ],
 160                   [
 161                   AC_MSG_RESULT([none])
 162                   ])
 163             ])
 164
 165 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 166
 167 AC_CHECK_HEADERS([ \
 168         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 169         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 170         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 171         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 172         sys/mount.h sys/param.h sys/time.h
 173 ])
 174
 175 # Basic functions check
 176 AC_CHECK_FUNCS([ \
 177         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 178         gethostbyname gethostname getpagesize localtime_r memchr memset \
 179         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 180         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 181         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 182         sched_getcpu sysconf sync_file_range
 183 ])
 184
 185 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 186 # add -lrt to LIBS
 187 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 188
 189 # Babeltrace viewer check
 190 AC_ARG_WITH([babeltrace-bin],
 191         AS_HELP_STRING([--with-babeltrace-bin],
 192         [Location of the babeltrace viewer executable (including the filename)]),
 193         [BABELTRACE_BIN="$withval"],
 194         [BABELTRACE_BIN=''])
 195 AC_SUBST([BABELTRACE_BIN])
 196
 197 # lttv-gui
 198 AC_ARG_WITH([lttv-gui-bin],
 199         AS_HELP_STRING([--with-lttv-gui-bin],
 200    [Location of the lttv GUI viewer executable (including the filename)]),
 201    [LTTV_GUI_BIN="$withval"],
 202    [LTTV_GUI_BIN=''])
 203 AC_SUBST([LTTV_GUI_BIN])
 204
 205 AC_ARG_WITH([consumerd32-bin],
 206         AS_HELP_STRING([--with-consumerd32-bin],
 207         [Location of the 32-bit consumerd executable (including the filename)]),
 208         [CONSUMERD32_BIN="$withval"],
 209         [CONSUMERD32_BIN=''])
 210 AC_SUBST([CONSUMERD32_BIN])
 211
 212 AC_ARG_WITH([consumerd64-bin],
 213         AS_HELP_STRING([--with-consumerd64-bin],
 214         [Location of the 64-bit consumerd executable (including the filename)]),
 215         [CONSUMERD64_BIN="$withval"],
 216         [CONSUMERD64_BIN=''])
 217 AC_SUBST([CONSUMERD64_BIN])
 218
 219 AC_ARG_WITH([consumerd32-libdir],
 220         AS_HELP_STRING([--with-consumerd32-libdir],
 221         [Directory containing the 32-bit consumerd libraries]),
 222         [CONSUMERD32_LIBDIR="$withval"],
 223         [CONSUMERD32_LIBDIR=''])
 224 AC_SUBST([CONSUMERD32_LIBDIR])
 225
 226 AC_ARG_WITH([consumerd64-libdir],
 227         AS_HELP_STRING([--with-consumerd64-libdir],
 228         [Directory containing the 64-bit consumerd libraries]),
 229         [CONSUMERD64_LIBDIR="$withval"],
 230         [CONSUMERD64_LIBDIR=''])
 231 AC_SUBST([CONSUMERD64_LIBDIR])
 232
 233 AC_ARG_WITH([sessiond-bin],
 234         AS_HELP_STRING([--with-sessiond-bin],
 235         [Location of the sessiond executable (including the filename)]),
 236         [SESSIOND_BIN="$withval"],
 237         [SESSIOND_BIN=''])
 238 AC_SUBST([SESSIOND_BIN])
 239
 240 AC_ARG_WITH([lttng-system-rundir],
 241         AS_HELP_STRING([--with-lttng-system-rundir],
 242         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 243         [LTTNG_SYSTEM_RUNDIR="$withval"],
 244         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 245 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 246
 247 AC_ARG_ENABLE([test-java-agent-jul],
 248         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 249         [test_java_agent_jul=$enableval],
 250         [test_java_agent_jul=no]
 251 )
 252
 253 AC_ARG_ENABLE([test-java-agent-log4j],
 254         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 255         [test_java_agent_log4j=$enableval],
 256         [test_java_agent_log4j=no]
 257 )
 258
 259 AC_ARG_ENABLE([test-java-agent-all],
 260         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 261         [test_java_agent_jul=$enableval
 262          test_java_agent_log4j=$enableval],
 263         [:]
 264 )
 265
 266 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 267 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 268 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 269 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 270 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 271 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 272 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 273 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 274
 275 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 276         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 277         $1="$2"
 278         AC_SUBST([$1])
 279 ])
 280
 281 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 282         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 283         $1="$2"
 284         AC_SUBST([$1])
 285 ])
 286
 287 # Default values
 288 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 289 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 290 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 291 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 292 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 293 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 294 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 295 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 296 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 297 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 298 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 299 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 300 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 301 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 302 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 303 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 304 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 305 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 306 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 307 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 308 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 309 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 310 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 311 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 312 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 313 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 314 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 315 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 316 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 317 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 318 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 319 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 320 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 321 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 322 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 323 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 324 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 325 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 326 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 327 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 328 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 329 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 330
 331 # Command short descriptions
 332 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 333 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 334 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 335 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 336 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 337 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 338 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 339 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 340 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 341 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 342 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 343 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 344 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 345 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 346 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 347 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 348 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 349 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 350 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 351 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 352 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 353
 354 if test "x$prefix" = "xNONE"; then
 355         prefix=$ac_default_prefix
 356 fi
 357 CONFDIR=`eval echo $sysconfdir`
 358 AC_SUBST(CONFDIR)
 359 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 360
 361 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 362
 363 #
 364 # Check for pthread
 365 AC_CHECK_LIB([pthread], [pthread_create], [],
 366         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 367 )
 368
 369 # Check libpopt
 370 PKG_CHECK_MODULES([POPT], [popt],
 371         [LIBS="$LIBS $POPT_LIBS"],
 372         [
 373                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 374                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 375                 AC_CHECK_LIB([popt],
 376                         [poptGetContext],
 377                         [],
 378                         [
 379                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 380                         ]
 381                 )
 382         ]
 383 )
 384
 385 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 386
 387 # First, check for uuid in system libs
 388 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 389 AC_CHECK_FUNCS([uuid_generate],
 390   [
 391     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 392     UUID_LIBS=""
 393   ],
 394   [
 395     # Then, check if the pkg-config module is available, otherwise explicitly check
 396     # for libuuid, or uuid support in the C-library.
 397     PKG_CHECK_MODULES([UUID], [uuid],
 398       [
 399         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 400         dnl PKG_CHECK_MODULES defines UUID_LIBS
 401       ],
 402       [
 403         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 404         AC_MSG_WARN([Finding libuuid without pkg-config.])
 405         AC_CHECK_LIB([uuid], [uuid_generate],
 406           [
 407             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 408             UUID_LIBS="-luuid"
 409           ],
 410           [
 411             # libuuid not found, check for uuid_create in libc.
 412             AC_CHECK_LIB([c], [uuid_create],
 413               [
 414                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 415                 UUID_LIBS="-lc"
 416               ],
 417               [
 418                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 419               ]
 420             )
 421           ]
 422         )
 423       ]
 424     )
 425   ]
 426 )
 427 AC_SUBST(UUID_LIBS)
 428
 429 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 430
 431 # URCU library version needed or newer
 432 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 433
 434 # Check liburcu needed function calls
 435 AC_CHECK_DECL([cds_list_add], [],
 436         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 437 AC_CHECK_DECL([cds_wfcq_init], [],
 438         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 439 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 440         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 441 AC_CHECK_DECL([futex_async], [],
 442         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 443 AC_CHECK_DECL([rcu_thread_offline], [],
 444         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 445 AC_CHECK_DECL([rcu_thread_online], [],
 446         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 447 AC_CHECK_DECL([caa_likely], [],
 448         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 449 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 450         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 451
 452 #Function added in urcu 0.7.0
 453 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 454         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 455 )
 456
 457 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 458 # it can be explicitly disabled with --without-kmod
 459 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 460 AC_ARG_WITH([kmod],
 461   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 462   [],
 463   [with_kmod=check]
 464 )
 465
 466 AS_IF([test "x$with_kmod" != "xno"],
 467   [
 468     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 469       [
 470         AC_DEFINE([HAVE_KMOD], [1])
 471         KMOD_LIBS="-lkmod"
 472       ],
 473       [
 474         if test "x$with_kmod" != xcheck; then
 475           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 476         else
 477           with_kmod=no
 478         fi
 479       ]
 480     )
 481   ]
 482 )
 483 AC_SUBST(KMOD_LIBS)
 484
 485 # Check for liblttng-ust-ctl, fail if it's not found,
 486 # it can be explicitly disabled with --without-lttng-ust
 487 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 488 AC_ARG_WITH([lttng-ust],
 489   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 490   [],
 491   [with_lttng_ust=yes]
 492 )
 493
 494 AS_IF([test "x$with_lttng_ust" = "xyes"],
 495   [
 496     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 497       [
 498         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 499       ],
 500       [
 501         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 502       ],
 503       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 504     )
 505   ]
 506 )
 507 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 508
 509
 510
 511 # check for dlopen
 512 AC_CHECK_LIB([dl], [dlopen],
 513   [DL_LIBS="-ldl"],
 514   [
 515     #libdl not found, check for dlopen in libc.
 516     AC_CHECK_LIB([c], [dlopen],
 517       [DL_LIBS="-lc"],
 518       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 519     )
 520   ]
 521 )
 522 AC_SUBST(DL_LIBS)
 523
 524 # Check for fmemopen
 525 AC_CHECK_LIB([c], [fmemopen],
 526 [
 527         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 528 ]
 529 )
 530
 531 # Check for open_memstream
 532 AC_CHECK_LIB([c], [open_memstream],
 533 [
 534         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 535 ]
 536 )
 537
 538 # check for libpfm
 539 AC_CHECK_LIB([pfm], [pfm_initialize],
 540              [
 541               have_libpfm=yes
 542               ])
 543 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 544
 545 AC_ARG_ENABLE([git-version],
 546               [AC_HELP_STRING([--disable-git-version],
 547                               [Do not use the git version for the build])],
 548               [have_git_version=$enableval], [have_git_version=yes]
 549 )
 550
 551 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 552         [test "x${have_git_version}" = "xyes"])
 553
 554 # For Python
 555 # SWIG version needed or newer:
 556 swig_version=2.0.0
 557
 558 AC_ARG_ENABLE([python-bindings],
 559               [AC_HELP_STRING([--enable-python-bindings],
 560                               [compile Python bindings])],
 561               [enable_python_binding=$enableval], [enable_python_binding=no])
 562
 563 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 564
 565 if test "x$enable_python_binding" = xyes; then
 566   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 567   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 568   AM_PATH_PYTHON([3.0])
 569
 570   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 571   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 572   AS_IF([test -z "$PYTHON_INCLUDE"], [
 573     AS_IF([test -z "$PYTHON_CONFIG"], [
 574       AC_PATH_PROGS([PYTHON_CONFIG],
 575                     [python$PYTHON_VERSION-config python-config],
 576                     [no],
 577                     [`dirname $PYTHON`])
 578       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 579     ])
 580     AC_MSG_CHECKING([python include flags])
 581     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 582     AC_MSG_RESULT([$PYTHON_INCLUDE])
 583   ])
 584
 585 else
 586     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 587 [if you want Python bindings.])
 588
 589 fi
 590
 591 # Epoll check. If not present, the build will fallback on poll() API
 592 AX_HAVE_EPOLL(
 593         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 594         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 595 )
 596 AX_CONFIG_FEATURE(
 597         [epoll], [This platform supports epoll(7)],
 598         [HAVE_EPOLL], [This platform supports epoll(7).],
 599         [enable_epoll="yes"], [enable_epoll="no"]
 600 )
 601 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 602
 603 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 604 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 605
 606 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 607         AX_JAVA_OPTIONS
 608         AX_PROG_JAVAC
 609         AX_PROG_JAVA
 610         AX_PROG_JAR
 611
 612         AX_CHECK_CLASSPATH
 613
 614         # Check for Java UST agent common class first
 615         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 616         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 617                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 618         fi
 619
 620         if test "x$test_java_agent_jul" = "xyes"; then
 621                 # Check for JUL agent class
 622                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 623                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 624                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 625                 fi
 626         fi
 627
 628         if test "x$test_java_agent_log4j" = "xyes"; then
 629                 # Check for Log4j agent class
 630                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 631                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 632                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 633                 fi
 634
 635                 # Check for Log4j class
 636                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 637                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 638                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 639                 fi
 640         fi
 641 fi
 642
 643 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 644 # is not distributed in tarballs
 645 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 646 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 647
 648 # enable building man pages (user's intention)
 649 AC_ARG_ENABLE(
 650         man-pages,
 651         AS_HELP_STRING(
 652                 [--disable-man-pages],
 653                 [Do not build and install man pages (already built in a distributed tarball)]
 654         ),
 655         [man_pages_opt=$enableval],
 656         [man_pages_opt=yes]
 657 )
 658
 659 # check for asciidoc and xmlto if we enabled building the man pages
 660 have_asciidoc_xmlto=no
 661 warn_prebuilt_man_pages=no
 662
 663 AS_IF([test "x$man_pages_opt" = "xyes"], [
 664         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 665         AC_PATH_PROG([XMLTO], [xmlto], [no])
 666
 667         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 668                 AS_IF([test "x$in_git_repo" = "xyes"], [
 669                         # this is an error because we're in the Git repo, which
 670                         # means the man pages are not already generated for us,
 671                         # thus asciidoc/xmlto are required because we were asked
 672                         # to build the man pages
 673                         AC_MSG_ERROR([
 674 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 675 --disable-man-pages to disable building the man pages, in which case
 676 they will not be installed.
 677                         ])
 678                 ], [
 679                         # only warn here: since we're in the tarball, the man
 680                         # pages should already be generated at this point, thus
 681                         # asciidoc/xmlto are not strictly required
 682                         warn_prebuilt_man_pages=yes
 683                 ])
 684         ], [
 685                 have_asciidoc_xmlto=yes
 686         ])
 687 ])
 688
 689 # export man page build condition: build the man pages if the user
 690 # asked for it, and if the tools are available
 691 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 692 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 693
 694 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 695
 696 # embedded --help message
 697 AC_ARG_ENABLE(
 698         [embedded-help],
 699         AS_HELP_STRING(
 700                 [--enable-embedded-help],
 701                 [Embed the --help messages in the executable files]
 702         ),
 703         [embedded_help=$enableval],
 704         [embedded_help=no]
 705 )
 706 AS_IF([test "x$embedded_help" = "xyes"], [
 707         AS_IF([test "x$man_pages_opt" = "xno"], [
 708                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 709         ])
 710         AC_PATH_PROG([man_prog_path], [man], [no])
 711         AS_IF([test "x$man_prog_path" = "xno"], [
 712                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 713         ])
 714         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 715         AC_SUBST([MANPROG], [$man_prog_path])
 716 ])
 717 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 718
 719 # Python agent test
 720 UST_PYTHON_AGENT="lttngust"
 721
 722 AC_ARG_ENABLE(test-python2-agent,
 723         AS_HELP_STRING([--enable-test-python2-agent],
 724                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 725         ),[:],[test_python2_agent_autodetect=yes]
 726 )
 727
 728 AC_ARG_ENABLE(test-python3-agent,
 729         AS_HELP_STRING([--enable-test-python3-agent],
 730                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 731         ),[:],[test_python3_agent_autodetect=yes]
 732 )
 733
 734 AC_ARG_ENABLE(test-python-agent-all,
 735         AS_HELP_STRING([--enable-test-python-agent-all],
 736                 [enable test for all python{2/3} agent.]
 737         ),
 738 )
 739
 740 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 741        unset test_python2_agent_autodetect
 742        unset test_python3_agent_autodetect
 743 ])
 744
 745 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 746        enable_test_python2_agent=yes
 747        enable_test_python3_agent=yes
 748 ])
 749
 750 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 751        enable_test_python2_agent=no
 752        enable_test_python3_agent=no
 753 ])
 754
 755
 756 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 757         AS_IF([test -z "$PYTHON2"], [
 758                         PYTHON2=python2
 759                 ], [
 760                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 761         ])
 762
 763         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 764         AS_IF([test -z "$PYTHON2_BIN"], [
 765                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 766                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 767                 ])
 768         ], [
 769                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 770                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 771                         PYTHON2_AGENT=$PYTHON2_BIN
 772                         AC_MSG_RESULT([yes])
 773                         RUN_PYTHON_AGENT_TEST=yes
 774                 ], [
 775                         AC_MSG_RESULT([no])
 776                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 777                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 778                         ])
 779                 ])
 780
 781         ])
 782
 783 ])
 784
 785 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 786         AS_IF([test -z "$PYTHON3"], [
 787                 PYTHON3=python3
 788         ], [
 789                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 790         ])
 791
 792         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 793         AS_IF([test -z "$PYTHON3_BIN"], [
 794                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 795                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 796                 ])
 797         ], [
 798                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 799                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 800                         PYTHON3_AGENT=$PYTHON3_BIN
 801                         AC_MSG_RESULT([yes])
 802                         RUN_PYTHON_AGENT_TEST=yes
 803                 ], [
 804                         AC_MSG_RESULT([no])
 805                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 806                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 807                         ])
 808                 ])
 809
 810         ])
 811 ])
 812 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 813 AC_SUBST([PYTHON2_AGENT])
 814 AC_SUBST([PYTHON3_AGENT])
 815
 816 # Arguments for binaries build exclusion
 817 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 818 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 819               [Disable the build of lttng-consumerd binaries]))
 820 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 821 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 822               [Disable the build of lttng-relayd binaries]))
 823 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 824               [Disable the build of lttng-sessiond binaries]))
 825 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 826               [Disable the build of the extra components]))
 827
 828
 829 # Always build libconfig since it a dependency of libcommon
 830 build_lib_config=yes
 831
 832 build_lib_compat=no
 833 build_lib_consumer=no
 834 build_lib_hashtable=no
 835 build_lib_health=no
 836 build_lib_index=no
 837 build_lib_kernel_consumer=no
 838 build_lib_kernel_ctl=no
 839 build_lib_lttng_ctl=no
 840 build_lib_relayd=no
 841 build_lib_sessiond_comm=no
 842 build_lib_testpoint=no
 843 build_lib_ust_consumer=no
 844
 845 # There is an overlap for enabled dependencies, but this makes everything
 846 # simpler. libcommon and libconfig are always compiled so they are not repeated
 847 # here.
 848
 849 # Enable binary dependencies.
 850 AS_IF([test x$enable_bin_lttng != xno],
 851       [
 852        build_lib_lttng_ctl=yes
 853       ]
 854 )
 855
 856 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 857       [
 858        build_lib_consumer=yes
 859        build_lib_sessiond_comm=yes
 860        build_lib_index=yes
 861        build_lib_health=yes
 862        build_lib_testpoint=yes
 863       ]
 864 )
 865
 866 AS_IF([test x$enable_bin_lttng_crash != xno],
 867       # Do nothing since libconfig and libcommon are built by default.
 868       []
 869 )
 870
 871 AS_IF([test x$enable_bin_lttng_relayd != xno],
 872       [
 873        build_lib_lttng_ctl=yes
 874        build_lib_sessiond_comm=yes
 875        build_lib_hashtable=yes
 876        build_lib_compat=yes
 877        build_lib_index=yes
 878        build_lib_health=yes
 879        build_lib_testpoint=yes
 880       ]
 881 )
 882 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 883       [
 884        build_lib_lttng_ctl=yes
 885        build_lib_sessiond_comm=yes
 886        build_lib_kernel_ctl=yes
 887        build_lib_hashtable=yes
 888        build_lib_compat=yes
 889        build_lib_relayd=yes
 890        build_lib_testpoint=yes
 891        build_lib_health=yes
 892        build_lib_health=yes
 893       ]
 894 )
 895
 896 # Libraries dependencies enabling
 897 AS_IF([test x$build_lib_lttng_ctl = xyes],
 898       [
 899        build_lib_sessiond_comm=yes
 900        build_lib_hashtable=yes
 901       ]
 902 )
 903
 904 AS_IF([test x$build_lib_consumer = xyes],
 905       [
 906        build_lib_sessiond_comm=yes
 907        build_lib_kernel_consumer=yes
 908        build_lib_hashtable=yes
 909        build_lib_compat=yes
 910        build_lib_relayd=yes
 911        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 912       ]
 913 )
 914
 915 AS_IF([test x$build_lib_kernel_consumer = xyes],
 916       [
 917        build_lib_kernel_ctl=yes
 918        build_lib_relayd=yes
 919       ]
 920 )
 921
 922 AS_IF([test x$build_lib_relayd = xyes],
 923       [
 924        build_lib_sessiond_comm=yes
 925       ]
 926 )
 927
 928
 929 # Export binaries build conditions.
 930 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 931 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 932 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 933 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 934 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 935
 936 # Export the tests and extras build conditions.
 937 AS_IF([\
 938 test "x$enable_bin_lttng" != "xno" && \
 939 test "x$enable_bin_lttng_consumerd" != "xno" && \
 940 test "x$enable_bin_lttng_crash" != "xno" && \
 941 test "x$enable_bin_lttng_relayd" != "xno" && \
 942 test "x$enable_bin_lttng_sessiond" != "xno"],
 943 [build_tests=yes],
 944 [build_tests=no]
 945 )
 946
 947 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 948 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 949
 950 # Export libraries build conditions.
 951 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 952 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 953 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 954 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 955 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 956 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 957 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 958 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 959 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 960 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 961 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 962 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 963 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 964
 965 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
 966 AC_SUBST(AM_CFLAGS)
 967
 968 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
 969 AC_SUBST(AM_CPPFLAGS)
 970
 971 lttngincludedir="${includedir}/lttng"
 972 AC_SUBST(lttngincludedir)
 973
 974 lttngactionincludedir="${includedir}/lttng/action"
 975 AC_SUBST(lttngactionincludedir)
 976
 977 lttngconditionincludedir="${includedir}/lttng/condition"
 978 AC_SUBST(lttngconditionincludedir)
 979
 980 lttngnotificationincludedir="${includedir}/lttng/notification"
 981 AC_SUBST(lttngnotificationincludedir)
 982
 983 lttngtriggerincludedir="${includedir}/lttng/trigger"
 984 AC_SUBST(lttngtriggerincludedir)
 985
 986 lttnglibexecdir="${libdir}/lttng/libexec"
 987 AC_SUBST(lttnglibexecdir)
 988
 989 AC_CONFIG_FILES([
 990         Makefile
 991         doc/Makefile
 992         doc/man/Makefile
 993         doc/man/asciidoc-attrs.conf
 994         include/Makefile
 995         extras/Makefile
 996         extras/bindings/Makefile
 997         extras/bindings/swig/Makefile
 998         extras/bindings/swig/python/Makefile
 999         extras/core-handler/Makefile
1000         src/Makefile
1001         src/common/Makefile
1002         src/common/kernel-ctl/Makefile
1003         src/common/kernel-consumer/Makefile
1004         src/common/consumer/Makefile
1005         src/common/ust-consumer/Makefile
1006         src/common/hashtable/Makefile
1007         src/common/sessiond-comm/Makefile
1008         src/common/compat/Makefile
1009         src/common/relayd/Makefile
1010         src/common/testpoint/Makefile
1011         src/common/index/Makefile
1012         src/common/health/Makefile
1013         src/common/config/Makefile
1014         src/common/string-utils/Makefile
1015         src/lib/Makefile
1016         src/lib/lttng-ctl/Makefile
1017         src/lib/lttng-ctl/filter/Makefile
1018         src/lib/lttng-ctl/lttng-ctl.pc
1019         src/bin/Makefile
1020         src/bin/lttng-consumerd/Makefile
1021         src/bin/lttng-sessiond/Makefile
1022         src/bin/lttng-relayd/Makefile
1023         src/bin/lttng/Makefile
1024         src/bin/lttng-crash/Makefile
1025         tests/Makefile
1026         tests/destructive/Makefile
1027         tests/regression/Makefile
1028         tests/regression/kernel/Makefile
1029         tests/regression/tools/Makefile
1030         tests/regression/tools/streaming/Makefile
1031         tests/regression/tools/filtering/Makefile
1032         tests/regression/tools/health/Makefile
1033         tests/regression/tools/tracefile-limits/Makefile
1034         tests/regression/tools/snapshots/Makefile
1035         tests/regression/tools/live/Makefile
1036         tests/regression/tools/exclusion/Makefile
1037         tests/regression/tools/save-load/Makefile
1038         tests/regression/tools/save-load/configuration/Makefile
1039         tests/regression/tools/mi/Makefile
1040         tests/regression/tools/wildcard/Makefile
1041         tests/regression/tools/crash/Makefile
1042         tests/regression/tools/regen-metadata/Makefile
1043         tests/regression/tools/regen-statedump/Makefile
1044         tests/regression/tools/notification/Makefile
1045         tests/regression/ust/Makefile
1046         tests/regression/ust/nprocesses/Makefile
1047         tests/regression/ust/high-throughput/Makefile
1048         tests/regression/ust/low-throughput/Makefile
1049         tests/regression/ust/before-after/Makefile
1050         tests/regression/ust/buffers-pid/Makefile
1051         tests/regression/ust/periodical-metadata-flush/Makefile
1052         tests/regression/ust/multi-session/Makefile
1053         tests/regression/ust/overlap/Makefile
1054         tests/regression/ust/overlap/demo/Makefile
1055         tests/regression/ust/linking/Makefile
1056         tests/regression/ust/daemon/Makefile
1057         tests/regression/ust/exit-fast/Makefile
1058         tests/regression/ust/fork/Makefile
1059         tests/regression/ust/libc-wrapper/Makefile
1060         tests/regression/ust/baddr-statedump/Makefile
1061         tests/regression/ust/ust-dl/Makefile
1062         tests/regression/ust/java-jul/Makefile
1063         tests/regression/ust/java-log4j/Makefile
1064         tests/regression/ust/python-logging/Makefile
1065         tests/regression/ust/getcpu-override/Makefile
1066         tests/regression/ust/clock-override/Makefile
1067         tests/regression/ust/type-declarations/Makefile
1068         tests/regression/ust/rotation-destroy-flush/Makefile
1069         tests/regression/ust/blocking/Makefile
1070         tests/stress/Makefile
1071         tests/unit/Makefile
1072         tests/unit/ini_config/Makefile
1073         tests/perf/Makefile
1074         tests/utils/Makefile
1075         tests/utils/tap/Makefile
1076         tests/utils/testapp/Makefile
1077         tests/utils/testapp/gen-ust-events/Makefile
1078         tests/utils/testapp/gen-ust-nevents/Makefile
1079         tests/utils/testapp/gen-ust-nevents-str/Makefile
1080         tests/utils/testapp/gen-ust-tracef/Makefile
1081 ])
1082
1083 # Inject variable into python test script.
1084 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1085 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1086 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1087
1088 AC_OUTPUT
1089
1090 #
1091 # Mini-report on what will be built.
1092 #
1093
1094 PPRINT_INIT
1095 PPRINT_SET_INDENT(1)
1096 PPRINT_SET_TS(38)
1097
1098 AS_ECHO
1099 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1100 AS_ECHO
1101
1102 AS_IF([test -n "$report_fold"], [
1103         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1104 ], [
1105         AS_ECHO("$version_description")
1106 ])
1107
1108 AS_ECHO
1109 PPRINT_SUBTITLE([Features])
1110
1111 # Target architecture we're building for.
1112 target_arch=$host_cpu
1113 [
1114 for f in $CFLAGS; do
1115         if test $f = "-m32"; then
1116                         target_arch="32-bit"
1117         elif test $f = "-m64"; then
1118                         target_arch="64-bit"
1119         fi
1120 done
1121 ]
1122 PPRINT_PROP_STRING([Target architecture], $target_arch)
1123
1124 # kmod enabled/disabled
1125 test "x$with_kmod" != "xno" && value=1 || value=0
1126 PPRINT_PROP_BOOL([libkmod support], $value)
1127
1128 # LTTng-UST enabled/disabled
1129 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1130 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1131
1132 AS_ECHO
1133 PPRINT_SUBTITLE([Binaries])
1134
1135 # List binaries to be built
1136 test x$enable_bin_lttng != xno && value=1 || value=0
1137 PPRINT_PROP_BOOL([lttng], $value)
1138
1139 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1140 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1141
1142 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1143 PPRINT_PROP_BOOL([lttng-crash], $value)
1144
1145 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1146 PPRINT_PROP_BOOL([lttng-relayd], $value)
1147
1148 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1149 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1150
1151 # Extras
1152 test x$enable_extras != xno && value=1 || value=0
1153 AS_ECHO
1154 PPRINT_SET_INDENT(0)
1155 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1156 PPRINT_SET_INDENT(1)
1157
1158 AS_ECHO
1159 PPRINT_SUBTITLE([Tests])
1160
1161 # Print clear message that tests won't be built
1162 AS_IF([test "x$build_tests" = "xno"],[
1163         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1164 ])
1165
1166 # LTTng UST Java agent JUL tests enabled/disabled
1167 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1168 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1169
1170 # LTTng UST Java agent Log4j tests enabled/disabled
1171 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1172 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1173
1174 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1175 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1176
1177 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1178 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1179
1180 #Python binding enabled/disabled
1181 test "x$enable_python_binding" = xyes && value=1 || value=0
1182 AS_ECHO
1183 PPRINT_SET_INDENT(0)
1184 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1185
1186 # man pages build enabled/disabled
1187 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1188
1189 AS_IF([test "x$man_pages_opt" != "xno"], [
1190         AS_IF([test "x$in_git_repo" = "xyes"], [
1191                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1192         ], [
1193                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1194                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1195                 ], [
1196                         PPRINT_PROP_STRING([build_man_pages_msg],
1197                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1198                                 $PPRINT_COLOR_SUBTITLE)
1199                 ])
1200         ])
1201 ], [
1202         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1203 ])
1204
1205 m4_popdef([build_man_pages_msg])
1206
1207 test "x$embedded_help" = xyes && value=1 || value=0
1208 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1209
1210 PPRINT_SET_INDENT(1)
1211
1212 report_bindir="`eval eval echo $bindir`"
1213 report_libdir="`eval eval echo $libdir`"
1214
1215 # Print the bindir and libdir this `make install' will install into.
1216 AS_ECHO
1217 PPRINT_SUBTITLE([Install directories])
1218 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1219 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1220
1221 AS_ECHO
1222 PPRINT_SUBTITLE([Search directories])
1223
1224 # If we build the sessiond, print the paths it will use
1225 AS_IF([test "$SESSIOND_BIN" = ""],[
1226         path="$report_bindir/lttng-sessiond"
1227 ],[
1228         path="$SESSIOND_BIN"
1229 ])
1230 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1231
1232 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1233         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1234 ],[
1235         path="$CONSUMERD32_BIN"
1236 ])
1237 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1238
1239 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1240         path="`eval eval echo $libdir`"
1241 ],[
1242         path="$CONSUMERD32_LIBDIR"
1243 ])
1244 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1245
1246 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1247         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1248 ],[
1249         path="$CONSUMERD64_BIN"
1250 ])
1251 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1252
1253 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1254         path="`eval eval echo $libdir`"
1255 ],[
1256         path="$CONSUMERD64_LIBDIR"
1257 ])
1258 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1259 PPRINT_SET_INDENT(0)
1260
1261 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1262         AS_ECHO
1263         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1264
1265 Note that the man pages are already built in this distribution tarball,
1266 therefore asciidoc and xmlto are only needed if you intend to modify
1267 their sources.
1268
1269 Also note that the installed man pages will contain the project's
1270 default command-line option and environment variable values.
1271
1272 Use --disable-man-pages to completely disable building and installing
1273 the man pages.])
1274 ])