configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.0],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_MAKE_SET
  28 AC_PROG_SED
  29 AC_PATH_PROG([report_fold], [fold])
  30 LT_INIT
  31
  32 # Check for objcopy, required by the base address statedump and dynamic linker tests
  33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  34 AS_IF([test "x$OBJCOPY" = "xno"],
  35         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  36 )
  37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  38
  39 # check for pgrep
  40 AC_PATH_PROG([PGREP], [pgrep], [no])
  41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  42
  43 # check for bison
  44 AC_PROG_YACC
  45 BISON=$YACC
  46 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  47
  48 AS_IF([test "x$have_bison" != "xyes"], [
  49   AS_IF([test "x$in_git_repo" = "xyes"], [
  50     AC_MSG_FAILURE([
  51 Bison >= 2.4 is required when building from the Git repository. You can
  52 set the YACC variable to override automatic detection.
  53     ])
  54   ], [
  55     AC_MSG_WARN([
  56 Missing Bison >= 2.4. Note that the parser files are already built in
  57 this distribution tarball, so Bison is only needed if you intend to
  58 modify their sources. You can set the YACC variable to override automatic
  59 detection.
  60     ])
  61   ])
  62 ])
  63 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  64
  65 # check for flex
  66 AC_PROG_LEX
  67 FLEX=$LEX
  68 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  69
  70 AS_IF([test "x$have_flex" != "xyes"], [
  71   AS_IF([test "x$in_git_repo" = "xyes"], [
  72     AC_MSG_FAILURE([
  73 Flex >= 2.5.35 is required when building from the Git repository. You can
  74 set the LEX variable to override automatic detection.
  75     ])
  76   ], [
  77     AC_MSG_WARN([
  78 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  79 this distribution tarball, so Flex is only needed if you intend to
  80 modify their sources. You can set the LEX variable to override automatic
  81 detection.
  82     ])
  83   ])
  84 ])
  85 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  86
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_INT32_T
  91 AC_TYPE_INT64_T
  92 AC_TYPE_MODE_T
  93 AC_TYPE_OFF_T
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_SSIZE_T
  97 AC_TYPE_UID_T
  98 AC_TYPE_UINT16_T
  99 AC_TYPE_UINT32_T
 100 AC_TYPE_UINT64_T
 101 AC_TYPE_UINT8_T
 102
 103 AX_C___ATTRIBUTE__
 104 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 105         [:],
 106         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 107
 108 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 109
 110 AX_LIB_SOCKET_NSL
 111
 112 LT_NO_UNDEFINED=""
 113 AS_CASE([$host_os],
 114   [cygwin*],
 115     [
 116       LT_NO_UNDEFINED="-no-undefined"
 117     ],
 118   [cygwin*|darwin*|mingw*|solaris*],
 119     [
 120       # On platforms where we only support the relayd, disable the other binaries by default
 121       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 122       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 123       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 124       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 125       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 126       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 127     ]
 128 )
 129
 130 AC_SUBST(LT_NO_UNDEFINED)
 131
 132 # Compute minor/major/patchlevel version numbers
 133 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 134 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 135 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 136
 137 AC_SUBST([MAJOR_VERSION], [$major_version])
 138 AC_SUBST([MINOR_VERSION], [$minor_version])
 139 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 140 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 141 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 142 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 143
 144 version_name="KeKriek"
 145 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
 146 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 147
 148 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 149 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 150
 151 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 152 AC_ARG_ENABLE(libtool-linkdep-fixup,
 153         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 154                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 155         libtool_fixup=$enableval,
 156         libtool_fixup=yes)
 157
 158 AS_IF([test "x$libtool_fixup" = "xyes"],
 159             [
 160             libtool_m4="$srcdir/m4/libtool.m4"
 161             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 162             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 163             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 164             AS_IF([test $libtool_flag_pattern_count -ne 0],
 165             [
 166                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 167                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 168                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 169                   ],
 170                   [
 171                   AC_MSG_RESULT([none])
 172                   ])
 173             ])
 174
 175 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 176
 177 AC_CHECK_HEADERS([ \
 178         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 179         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 180         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 181         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 182         sys/mount.h sys/param.h sys/time.h
 183 ])
 184
 185 # Basic functions check
 186 AC_CHECK_FUNCS([ \
 187         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 188         gethostbyname gethostname getpagesize localtime_r memchr memset \
 189         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 190         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 191         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 192         sched_getcpu sysconf sync_file_range
 193 ])
 194
 195 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 196 # add -lrt to LIBS
 197 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 198
 199 # Babeltrace viewer check
 200 AC_ARG_WITH([babeltrace-bin],
 201         AS_HELP_STRING([--with-babeltrace-bin],
 202         [Location of the babeltrace viewer executable (including the filename)]),
 203         [BABELTRACE_BIN="$withval"],
 204         [BABELTRACE_BIN=''])
 205 AC_SUBST([BABELTRACE_BIN])
 206
 207 # lttv-gui
 208 AC_ARG_WITH([lttv-gui-bin],
 209         AS_HELP_STRING([--with-lttv-gui-bin],
 210    [Location of the lttv GUI viewer executable (including the filename)]),
 211    [LTTV_GUI_BIN="$withval"],
 212    [LTTV_GUI_BIN=''])
 213 AC_SUBST([LTTV_GUI_BIN])
 214
 215 AC_ARG_WITH([consumerd32-bin],
 216         AS_HELP_STRING([--with-consumerd32-bin],
 217         [Location of the 32-bit consumerd executable (including the filename)]),
 218         [CONSUMERD32_BIN="$withval"],
 219         [CONSUMERD32_BIN=''])
 220 AC_SUBST([CONSUMERD32_BIN])
 221
 222 AC_ARG_WITH([consumerd64-bin],
 223         AS_HELP_STRING([--with-consumerd64-bin],
 224         [Location of the 64-bit consumerd executable (including the filename)]),
 225         [CONSUMERD64_BIN="$withval"],
 226         [CONSUMERD64_BIN=''])
 227 AC_SUBST([CONSUMERD64_BIN])
 228
 229 AC_ARG_WITH([consumerd32-libdir],
 230         AS_HELP_STRING([--with-consumerd32-libdir],
 231         [Directory containing the 32-bit consumerd libraries]),
 232         [CONSUMERD32_LIBDIR="$withval"],
 233         [CONSUMERD32_LIBDIR=''])
 234 AC_SUBST([CONSUMERD32_LIBDIR])
 235
 236 AC_ARG_WITH([consumerd64-libdir],
 237         AS_HELP_STRING([--with-consumerd64-libdir],
 238         [Directory containing the 64-bit consumerd libraries]),
 239         [CONSUMERD64_LIBDIR="$withval"],
 240         [CONSUMERD64_LIBDIR=''])
 241 AC_SUBST([CONSUMERD64_LIBDIR])
 242
 243 AC_ARG_WITH([sessiond-bin],
 244         AS_HELP_STRING([--with-sessiond-bin],
 245         [Location of the sessiond executable (including the filename)]),
 246         [SESSIOND_BIN="$withval"],
 247         [SESSIOND_BIN=''])
 248 AC_SUBST([SESSIOND_BIN])
 249
 250 AC_ARG_WITH([lttng-system-rundir],
 251         AS_HELP_STRING([--with-lttng-system-rundir],
 252         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 253         [LTTNG_SYSTEM_RUNDIR="$withval"],
 254         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 255 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 256
 257 AC_ARG_ENABLE([test-java-agent-jul],
 258         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 259         [test_java_agent_jul=$enableval],
 260         [test_java_agent_jul=no]
 261 )
 262
 263 AC_ARG_ENABLE([test-java-agent-log4j],
 264         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 265         [test_java_agent_log4j=$enableval],
 266         [test_java_agent_log4j=no]
 267 )
 268
 269 AC_ARG_ENABLE([test-java-agent-all],
 270         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 271         [test_java_agent_jul=$enableval
 272          test_java_agent_log4j=$enableval],
 273         [:]
 274 )
 275
 276 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 277 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 278 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 279 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 280 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 281 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 282 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 283 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 284
 285 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 286         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 287         $1="$2"
 288         AC_SUBST([$1])
 289 ])
 290
 291 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 292         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 293         $1="$2"
 294         AC_SUBST([$1])
 295 ])
 296
 297 # Default values
 298 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 299 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 300 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 301 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 302 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 303 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 304 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 305 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 306 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 307 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 308 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 309 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 310 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 311 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 312 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 313 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 314 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 315 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 316 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 317 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 318 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 319 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 320 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 321 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 322 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 323 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 324 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 325 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 326 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 327 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 328 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 329 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 330 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 331 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 332 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 333 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 334 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 335 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 336 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 337 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 338 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 339 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 340 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 341 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 342 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 343 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 344
 345 # Command short descriptions
 346 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 347 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 348 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 349 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 350 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 351 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 352 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 353 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 354 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 355 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 356 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 357 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 358 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 359 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 360 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 361 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 362 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 363 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 364 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 365 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 366 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 367
 368 if test "x$prefix" = "xNONE"; then
 369         prefix=$ac_default_prefix
 370 fi
 371 CONFDIR=`eval echo $sysconfdir`
 372 AC_SUBST(CONFDIR)
 373 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 374
 375 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 376
 377 # Check libpopt
 378 PKG_CHECK_MODULES([POPT], [popt],
 379   [
 380     dnl PKG_CHECK_MODULES defines POPT_LIBS
 381   ],
 382   [
 383     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 384     AC_MSG_WARN([Finding libpopt without pkg-config.])
 385     AC_CHECK_LIB([popt],
 386       [poptGetContext],
 387       [POPT_LIBS="-lpopt"],
 388       [
 389         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 390       ]
 391     )
 392   ]
 393 )
 394 AC_SUBST(POPT_LIBS)
 395
 396 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 397
 398 # First, check for uuid in system libs
 399 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 400 AC_CHECK_FUNCS([uuid_generate],
 401   [
 402     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 403     UUID_LIBS=""
 404   ],
 405   [
 406     # Then, check if the pkg-config module is available, otherwise explicitly check
 407     # for libuuid, or uuid support in the C-library.
 408     PKG_CHECK_MODULES([UUID], [uuid],
 409       [
 410         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 411         dnl PKG_CHECK_MODULES defines UUID_LIBS
 412       ],
 413       [
 414         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 415         AC_MSG_WARN([Finding libuuid without pkg-config.])
 416         AC_CHECK_LIB([uuid], [uuid_generate],
 417           [
 418             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 419             UUID_LIBS="-luuid"
 420           ],
 421           [
 422             # libuuid not found, check for uuid_create in libc.
 423             AC_CHECK_LIB([c], [uuid_create],
 424               [
 425                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 426                 UUID_LIBS="-lc"
 427               ],
 428               [
 429                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 430               ]
 431             )
 432           ]
 433         )
 434       ]
 435     )
 436   ]
 437 )
 438 AC_SUBST(UUID_LIBS)
 439
 440 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 441
 442 # URCU library version needed or newer
 443 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 444
 445 # Check liburcu needed function calls
 446 AC_CHECK_DECL([cds_list_add], [],
 447         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 448 AC_CHECK_DECL([cds_wfcq_init], [],
 449         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 450 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 451         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 452 AC_CHECK_DECL([futex_async], [],
 453         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 454 AC_CHECK_DECL([rcu_thread_offline], [],
 455         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 456 AC_CHECK_DECL([rcu_thread_online], [],
 457         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 458 AC_CHECK_DECL([caa_likely], [],
 459         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 460 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 461         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 462
 463 #Function added in urcu 0.7.0
 464 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 465         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 466 )
 467
 468 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 469 # it can be explicitly disabled with --without-kmod
 470 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 471 AC_ARG_WITH([kmod],
 472   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 473   [],
 474   [with_kmod=check]
 475 )
 476
 477 AS_IF([test "x$with_kmod" != "xno"],
 478   [
 479     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 480       [
 481         AC_DEFINE([HAVE_KMOD], [1])
 482         KMOD_LIBS="-lkmod"
 483       ],
 484       [
 485         if test "x$with_kmod" != xcheck; then
 486           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 487         else
 488           with_kmod=no
 489         fi
 490       ]
 491     )
 492   ]
 493 )
 494 AC_SUBST(KMOD_LIBS)
 495
 496 # Check for liblttng-ust-ctl, fail if it's not found,
 497 # it can be explicitly disabled with --without-lttng-ust
 498 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 499 AC_ARG_WITH([lttng-ust],
 500   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 501   [],
 502   [with_lttng_ust=yes]
 503 )
 504
 505 AS_IF([test "x$with_lttng_ust" = "xyes"],
 506   [
 507     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 508       [
 509         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 510       ],
 511       [
 512         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 513       ],
 514       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 515     )
 516   ]
 517 )
 518 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 519
 520
 521
 522 # check for dlopen
 523 AC_CHECK_LIB([dl], [dlopen],
 524   [DL_LIBS="-ldl"],
 525   [
 526     #libdl not found, check for dlopen in libc.
 527     AC_CHECK_LIB([c], [dlopen],
 528       [DL_LIBS="-lc"],
 529       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 530     )
 531   ]
 532 )
 533 AC_SUBST(DL_LIBS)
 534
 535 # Check for fmemopen
 536 AC_CHECK_LIB([c], [fmemopen],
 537 [
 538         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 539 ]
 540 )
 541
 542 # Check for open_memstream
 543 AC_CHECK_LIB([c], [open_memstream],
 544 [
 545         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 546 ]
 547 )
 548
 549 # check for libpfm
 550 AC_CHECK_LIB([pfm], [pfm_initialize],
 551              [
 552               have_libpfm=yes
 553               ])
 554 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 555
 556 AC_ARG_ENABLE([git-version],
 557               [AC_HELP_STRING([--disable-git-version],
 558                               [Do not use the git version for the build])],
 559               [have_git_version=$enableval], [have_git_version=yes]
 560 )
 561
 562 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 563         [test "x${have_git_version}" = "xyes"])
 564
 565 # For Python
 566 # SWIG version needed or newer:
 567 swig_version=2.0.0
 568
 569 AC_ARG_ENABLE([python-bindings],
 570               [AC_HELP_STRING([--enable-python-bindings],
 571                               [compile Python bindings])],
 572               [enable_python_binding=$enableval], [enable_python_binding=no])
 573
 574 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 575
 576 if test "x$enable_python_binding" = xyes; then
 577   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 578   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 579   AM_PATH_PYTHON([3.0])
 580
 581   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 582   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 583   AS_IF([test -z "$PYTHON_INCLUDE"], [
 584     AS_IF([test -z "$PYTHON_CONFIG"], [
 585       AC_PATH_PROGS([PYTHON_CONFIG],
 586                     [python$PYTHON_VERSION-config python-config],
 587                     [no],
 588                     [`dirname $PYTHON`])
 589       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 590     ])
 591     AC_MSG_CHECKING([python include flags])
 592     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 593     AC_MSG_RESULT([$PYTHON_INCLUDE])
 594   ])
 595
 596 else
 597     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 598 [if you want Python bindings.])
 599
 600 fi
 601
 602 # Epoll check. If not present, the build will fallback on poll() API
 603 AX_HAVE_EPOLL(
 604         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 605         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 606 )
 607 AX_CONFIG_FEATURE(
 608         [epoll], [This platform supports epoll(7)],
 609         [HAVE_EPOLL], [This platform supports epoll(7).],
 610         [enable_epoll="yes"], [enable_epoll="no"]
 611 )
 612 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 613
 614 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 615 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 616
 617 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 618         AX_JAVA_OPTIONS
 619         AX_PROG_JAVAC
 620         AX_PROG_JAVA
 621         AX_PROG_JAR
 622
 623         AX_CHECK_CLASSPATH
 624
 625         # Check for Java UST agent common class first
 626         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 627         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 628                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 629         fi
 630
 631         if test "x$test_java_agent_jul" = "xyes"; then
 632                 # Check for JUL agent class
 633                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 634                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 635                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 636                 fi
 637         fi
 638
 639         if test "x$test_java_agent_log4j" = "xyes"; then
 640                 # Check for Log4j agent class
 641                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 642                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 643                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 644                 fi
 645
 646                 # Check for Log4j class
 647                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 648                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 649                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 650                 fi
 651         fi
 652 fi
 653
 654 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 655 # is not distributed in tarballs
 656 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 657 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 658
 659 # enable building man pages (user's intention)
 660 AC_ARG_ENABLE(
 661         man-pages,
 662         AS_HELP_STRING(
 663                 [--disable-man-pages],
 664                 [Do not build and install man pages (already built in a distributed tarball)]
 665         ),
 666         [man_pages_opt=$enableval],
 667         [man_pages_opt=yes]
 668 )
 669
 670 # check for asciidoc and xmlto if we enabled building the man pages
 671 have_asciidoc_xmlto=no
 672 warn_prebuilt_man_pages=no
 673
 674 AS_IF([test "x$man_pages_opt" = "xyes"], [
 675         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 676         AC_PATH_PROG([XMLTO], [xmlto], [no])
 677
 678         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 679                 AS_IF([test "x$in_git_repo" = "xyes"], [
 680                         # this is an error because we're in the Git repo, which
 681                         # means the man pages are not already generated for us,
 682                         # thus asciidoc/xmlto are required because we were asked
 683                         # to build the man pages
 684                         AC_MSG_ERROR([
 685 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 686 --disable-man-pages to disable building the man pages, in which case
 687 they will not be installed.
 688                         ])
 689                 ], [
 690                         # only warn here: since we're in the tarball, the man
 691                         # pages should already be generated at this point, thus
 692                         # asciidoc/xmlto are not strictly required
 693                         warn_prebuilt_man_pages=yes
 694                 ])
 695         ], [
 696                 have_asciidoc_xmlto=yes
 697         ])
 698 ])
 699
 700 # export man page build condition: build the man pages if the user
 701 # asked for it, and if the tools are available
 702 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 703 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 704
 705 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 706
 707 # embedded --help message
 708 AC_ARG_ENABLE(
 709         [embedded-help],
 710         AS_HELP_STRING(
 711                 [--enable-embedded-help],
 712                 [Embed the --help messages in the executable files]
 713         ),
 714         [embedded_help=$enableval],
 715         [embedded_help=no]
 716 )
 717 AS_IF([test "x$embedded_help" = "xyes"], [
 718         AS_IF([test "x$man_pages_opt" = "xno"], [
 719                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 720         ])
 721         AC_PATH_PROG([man_prog_path], [man], [no])
 722         AS_IF([test "x$man_prog_path" = "xno"], [
 723                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 724         ])
 725         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 726         AC_SUBST([MANPROG], [$man_prog_path])
 727 ])
 728 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 729
 730 # Python agent test
 731 UST_PYTHON_AGENT="lttngust"
 732
 733 AC_ARG_ENABLE(test-python2-agent,
 734         AS_HELP_STRING([--enable-test-python2-agent],
 735                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 736         ),[:],[test_python2_agent_autodetect=yes]
 737 )
 738
 739 AC_ARG_ENABLE(test-python3-agent,
 740         AS_HELP_STRING([--enable-test-python3-agent],
 741                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 742         ),[:],[test_python3_agent_autodetect=yes]
 743 )
 744
 745 AC_ARG_ENABLE(test-python-agent-all,
 746         AS_HELP_STRING([--enable-test-python-agent-all],
 747                 [enable test for all python{2/3} agent.]
 748         ),
 749 )
 750
 751 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 752        unset test_python2_agent_autodetect
 753        unset test_python3_agent_autodetect
 754 ])
 755
 756 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 757        enable_test_python2_agent=yes
 758        enable_test_python3_agent=yes
 759 ])
 760
 761 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 762        enable_test_python2_agent=no
 763        enable_test_python3_agent=no
 764 ])
 765
 766
 767 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 768         AS_IF([test -z "$PYTHON2"], [
 769                         PYTHON2=python2
 770                 ], [
 771                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 772         ])
 773
 774         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 775         AS_IF([test -z "$PYTHON2_BIN"], [
 776                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 777                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 778                 ])
 779         ], [
 780                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 781                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 782                         PYTHON2_AGENT=$PYTHON2_BIN
 783                         AC_MSG_RESULT([yes])
 784                         RUN_PYTHON_AGENT_TEST=yes
 785                 ], [
 786                         AC_MSG_RESULT([no])
 787                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 788                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 789                         ])
 790                 ])
 791
 792         ])
 793
 794 ])
 795
 796 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 797         AS_IF([test -z "$PYTHON3"], [
 798                 PYTHON3=python3
 799         ], [
 800                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 801         ])
 802
 803         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 804         AS_IF([test -z "$PYTHON3_BIN"], [
 805                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 806                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 807                 ])
 808         ], [
 809                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 810                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 811                         PYTHON3_AGENT=$PYTHON3_BIN
 812                         AC_MSG_RESULT([yes])
 813                         RUN_PYTHON_AGENT_TEST=yes
 814                 ], [
 815                         AC_MSG_RESULT([no])
 816                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 817                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 818                         ])
 819                 ])
 820
 821         ])
 822 ])
 823 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 824 AC_SUBST([PYTHON2_AGENT])
 825 AC_SUBST([PYTHON3_AGENT])
 826
 827 # Arguments for binaries build exclusion
 828 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 829 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 830               [Disable the build of lttng-consumerd binaries]))
 831 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 832 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 833               [Disable the build of lttng-relayd binaries]))
 834 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 835               [Disable the build of lttng-sessiond binaries]))
 836 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 837               [Disable the build of the extra components]))
 838
 839
 840 # Always build libconfig since it a dependency of libcommon
 841 build_lib_config=yes
 842
 843 build_lib_compat=no
 844 build_lib_consumer=no
 845 build_lib_hashtable=no
 846 build_lib_health=no
 847 build_lib_index=no
 848 build_lib_kernel_consumer=no
 849 build_lib_kernel_ctl=no
 850 build_lib_lttng_ctl=no
 851 build_lib_relayd=no
 852 build_lib_sessiond_comm=no
 853 build_lib_testpoint=no
 854 build_lib_ust_consumer=no
 855
 856 # There is an overlap for enabled dependencies, but this makes everything
 857 # simpler. libcommon and libconfig are always compiled so they are not repeated
 858 # here.
 859
 860 # Enable binary dependencies.
 861 AS_IF([test x$enable_bin_lttng != xno],
 862       [
 863        build_lib_lttng_ctl=yes
 864       ]
 865 )
 866
 867 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 868       [
 869        build_lib_consumer=yes
 870        build_lib_sessiond_comm=yes
 871        build_lib_index=yes
 872        build_lib_health=yes
 873        build_lib_testpoint=yes
 874       ]
 875 )
 876
 877 AS_IF([test x$enable_bin_lttng_crash != xno],
 878       # Do nothing since libconfig and libcommon are built by default.
 879       []
 880 )
 881
 882 AS_IF([test x$enable_bin_lttng_relayd != xno],
 883       [
 884        build_lib_lttng_ctl=yes
 885        build_lib_sessiond_comm=yes
 886        build_lib_hashtable=yes
 887        build_lib_compat=yes
 888        build_lib_index=yes
 889        build_lib_health=yes
 890        build_lib_testpoint=yes
 891       ]
 892 )
 893 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 894       [
 895        build_lib_lttng_ctl=yes
 896        build_lib_sessiond_comm=yes
 897        build_lib_kernel_ctl=yes
 898        build_lib_hashtable=yes
 899        build_lib_compat=yes
 900        build_lib_relayd=yes
 901        build_lib_testpoint=yes
 902        build_lib_health=yes
 903        build_lib_health=yes
 904       ]
 905 )
 906
 907 # Libraries dependencies enabling
 908 AS_IF([test x$build_lib_lttng_ctl = xyes],
 909       [
 910        build_lib_sessiond_comm=yes
 911        build_lib_hashtable=yes
 912       ]
 913 )
 914
 915 AS_IF([test x$build_lib_consumer = xyes],
 916       [
 917        build_lib_sessiond_comm=yes
 918        build_lib_kernel_consumer=yes
 919        build_lib_hashtable=yes
 920        build_lib_compat=yes
 921        build_lib_relayd=yes
 922        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 923       ]
 924 )
 925
 926 AS_IF([test x$build_lib_kernel_consumer = xyes],
 927       [
 928        build_lib_kernel_ctl=yes
 929        build_lib_relayd=yes
 930       ]
 931 )
 932
 933 AS_IF([test x$build_lib_relayd = xyes],
 934       [
 935        build_lib_sessiond_comm=yes
 936       ]
 937 )
 938
 939
 940 # Export binaries build conditions.
 941 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 942 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 943 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 944 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 945 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 946
 947 # Export the tests and extras build conditions.
 948 AS_IF([\
 949 test "x$enable_bin_lttng" != "xno" && \
 950 test "x$enable_bin_lttng_consumerd" != "xno" && \
 951 test "x$enable_bin_lttng_crash" != "xno" && \
 952 test "x$enable_bin_lttng_relayd" != "xno" && \
 953 test "x$enable_bin_lttng_sessiond" != "xno"],
 954 [build_tests=yes],
 955 [build_tests=no]
 956 )
 957
 958 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 959 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 960
 961 # Export libraries build conditions.
 962 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 963 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 964 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 965 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 966 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 967 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 968 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 969 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 970 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 971 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 972 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 973 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 974 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 975
 976 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
 977 AC_SUBST(AM_CFLAGS)
 978
 979 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
 980 AC_SUBST(AM_CPPFLAGS)
 981
 982 lttngincludedir="${includedir}/lttng"
 983 AC_SUBST(lttngincludedir)
 984
 985 lttngactionincludedir="${includedir}/lttng/action"
 986 AC_SUBST(lttngactionincludedir)
 987
 988 lttngconditionincludedir="${includedir}/lttng/condition"
 989 AC_SUBST(lttngconditionincludedir)
 990
 991 lttngnotificationincludedir="${includedir}/lttng/notification"
 992 AC_SUBST(lttngnotificationincludedir)
 993
 994 lttngtriggerincludedir="${includedir}/lttng/trigger"
 995 AC_SUBST(lttngtriggerincludedir)
 996
 997 lttnglibexecdir="${libdir}/lttng/libexec"
 998 AC_SUBST(lttnglibexecdir)
 999
1000 AC_CONFIG_FILES([
1001         Makefile
1002         doc/Makefile
1003         doc/man/Makefile
1004         doc/man/asciidoc-attrs.conf
1005         include/Makefile
1006         extras/Makefile
1007         extras/bindings/Makefile
1008         extras/bindings/swig/Makefile
1009         extras/bindings/swig/python/Makefile
1010         extras/core-handler/Makefile
1011         src/Makefile
1012         src/common/Makefile
1013         src/common/kernel-ctl/Makefile
1014         src/common/kernel-consumer/Makefile
1015         src/common/consumer/Makefile
1016         src/common/ust-consumer/Makefile
1017         src/common/hashtable/Makefile
1018         src/common/sessiond-comm/Makefile
1019         src/common/compat/Makefile
1020         src/common/relayd/Makefile
1021         src/common/testpoint/Makefile
1022         src/common/index/Makefile
1023         src/common/health/Makefile
1024         src/common/config/Makefile
1025         src/common/string-utils/Makefile
1026         src/lib/Makefile
1027         src/lib/lttng-ctl/Makefile
1028         src/lib/lttng-ctl/filter/Makefile
1029         src/lib/lttng-ctl/lttng-ctl.pc
1030         src/bin/Makefile
1031         src/bin/lttng-consumerd/Makefile
1032         src/bin/lttng-sessiond/Makefile
1033         src/bin/lttng-relayd/Makefile
1034         src/bin/lttng/Makefile
1035         src/bin/lttng-crash/Makefile
1036         tests/Makefile
1037         tests/destructive/Makefile
1038         tests/regression/Makefile
1039         tests/regression/kernel/Makefile
1040         tests/regression/tools/Makefile
1041         tests/regression/tools/streaming/Makefile
1042         tests/regression/tools/filtering/Makefile
1043         tests/regression/tools/health/Makefile
1044         tests/regression/tools/tracefile-limits/Makefile
1045         tests/regression/tools/snapshots/Makefile
1046         tests/regression/tools/live/Makefile
1047         tests/regression/tools/exclusion/Makefile
1048         tests/regression/tools/save-load/Makefile
1049         tests/regression/tools/save-load/configuration/Makefile
1050         tests/regression/tools/mi/Makefile
1051         tests/regression/tools/wildcard/Makefile
1052         tests/regression/tools/crash/Makefile
1053         tests/regression/tools/regen-metadata/Makefile
1054         tests/regression/tools/regen-statedump/Makefile
1055         tests/regression/tools/notification/Makefile
1056         tests/regression/ust/Makefile
1057         tests/regression/ust/nprocesses/Makefile
1058         tests/regression/ust/high-throughput/Makefile
1059         tests/regression/ust/low-throughput/Makefile
1060         tests/regression/ust/before-after/Makefile
1061         tests/regression/ust/buffers-pid/Makefile
1062         tests/regression/ust/periodical-metadata-flush/Makefile
1063         tests/regression/ust/multi-session/Makefile
1064         tests/regression/ust/overlap/Makefile
1065         tests/regression/ust/overlap/demo/Makefile
1066         tests/regression/ust/linking/Makefile
1067         tests/regression/ust/daemon/Makefile
1068         tests/regression/ust/exit-fast/Makefile
1069         tests/regression/ust/fork/Makefile
1070         tests/regression/ust/libc-wrapper/Makefile
1071         tests/regression/ust/baddr-statedump/Makefile
1072         tests/regression/ust/ust-dl/Makefile
1073         tests/regression/ust/java-jul/Makefile
1074         tests/regression/ust/java-log4j/Makefile
1075         tests/regression/ust/python-logging/Makefile
1076         tests/regression/ust/getcpu-override/Makefile
1077         tests/regression/ust/clock-override/Makefile
1078         tests/regression/ust/type-declarations/Makefile
1079         tests/regression/ust/rotation-destroy-flush/Makefile
1080         tests/regression/ust/blocking/Makefile
1081         tests/stress/Makefile
1082         tests/unit/Makefile
1083         tests/unit/ini_config/Makefile
1084         tests/perf/Makefile
1085         tests/utils/Makefile
1086         tests/utils/tap/Makefile
1087         tests/utils/testapp/Makefile
1088         tests/utils/testapp/gen-ust-events/Makefile
1089         tests/utils/testapp/gen-ust-nevents/Makefile
1090         tests/utils/testapp/gen-ust-nevents-str/Makefile
1091         tests/utils/testapp/gen-ust-tracef/Makefile
1092 ])
1093
1094 # Inject variable into python test script.
1095 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1096 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1097 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1098
1099 AC_OUTPUT
1100
1101 #
1102 # Mini-report on what will be built.
1103 #
1104
1105 PPRINT_INIT
1106 PPRINT_SET_INDENT(1)
1107 PPRINT_SET_TS(38)
1108
1109 AS_ECHO
1110 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1111 AS_ECHO
1112
1113 AS_IF([test -n "$report_fold"], [
1114         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1115 ], [
1116         AS_ECHO("$version_description")
1117 ])
1118
1119 AS_ECHO
1120 PPRINT_SUBTITLE([Features])
1121
1122 # Target architecture we're building for.
1123 target_arch=$host_cpu
1124 [
1125 for f in $CFLAGS; do
1126         if test $f = "-m32"; then
1127                         target_arch="32-bit"
1128         elif test $f = "-m64"; then
1129                         target_arch="64-bit"
1130         fi
1131 done
1132 ]
1133 PPRINT_PROP_STRING([Target architecture], $target_arch)
1134
1135 # kmod enabled/disabled
1136 test "x$with_kmod" != "xno" && value=1 || value=0
1137 PPRINT_PROP_BOOL([libkmod support], $value)
1138
1139 # LTTng-UST enabled/disabled
1140 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1141 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1142
1143 AS_ECHO
1144 PPRINT_SUBTITLE([Binaries])
1145
1146 # List binaries to be built
1147 test x$enable_bin_lttng != xno && value=1 || value=0
1148 PPRINT_PROP_BOOL([lttng], $value)
1149
1150 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1151 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1152
1153 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1154 PPRINT_PROP_BOOL([lttng-crash], $value)
1155
1156 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1157 PPRINT_PROP_BOOL([lttng-relayd], $value)
1158
1159 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1160 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1161
1162 # Extras
1163 test x$enable_extras != xno && value=1 || value=0
1164 AS_ECHO
1165 PPRINT_SET_INDENT(0)
1166 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1167 PPRINT_SET_INDENT(1)
1168
1169 AS_ECHO
1170 PPRINT_SUBTITLE([Tests])
1171
1172 # Print clear message that tests won't be built
1173 AS_IF([test "x$build_tests" = "xno"],[
1174         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1175 ])
1176
1177 # LTTng UST Java agent JUL tests enabled/disabled
1178 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1179 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1180
1181 # LTTng UST Java agent Log4j tests enabled/disabled
1182 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1183 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1184
1185 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1186 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1187
1188 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1189 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1190
1191 #Python binding enabled/disabled
1192 test "x$enable_python_binding" = xyes && value=1 || value=0
1193 AS_ECHO
1194 PPRINT_SET_INDENT(0)
1195 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1196
1197 # man pages build enabled/disabled
1198 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1199
1200 AS_IF([test "x$man_pages_opt" != "xno"], [
1201         AS_IF([test "x$in_git_repo" = "xyes"], [
1202                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1203         ], [
1204                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1205                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1206                 ], [
1207                         PPRINT_PROP_STRING([build_man_pages_msg],
1208                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1209                                 $PPRINT_COLOR_SUBTITLE)
1210                 ])
1211         ])
1212 ], [
1213         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1214 ])
1215
1216 m4_popdef([build_man_pages_msg])
1217
1218 test "x$embedded_help" = xyes && value=1 || value=0
1219 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1220
1221 PPRINT_SET_INDENT(1)
1222
1223 report_bindir="`eval eval echo $bindir`"
1224 report_libdir="`eval eval echo $libdir`"
1225
1226 # Print the bindir and libdir this `make install' will install into.
1227 AS_ECHO
1228 PPRINT_SUBTITLE([Install directories])
1229 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1230 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1231
1232 AS_ECHO
1233 PPRINT_SUBTITLE([Search directories])
1234
1235 # If we build the sessiond, print the paths it will use
1236 AS_IF([test "$SESSIOND_BIN" = ""],[
1237         path="$report_bindir/lttng-sessiond"
1238 ],[
1239         path="$SESSIOND_BIN"
1240 ])
1241 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1242
1243 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1244         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1245 ],[
1246         path="$CONSUMERD32_BIN"
1247 ])
1248 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1249
1250 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1251         path="`eval eval echo $libdir`"
1252 ],[
1253         path="$CONSUMERD32_LIBDIR"
1254 ])
1255 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1256
1257 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1258         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1259 ],[
1260         path="$CONSUMERD64_BIN"
1261 ])
1262 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1263
1264 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1265         path="`eval eval echo $libdir`"
1266 ],[
1267         path="$CONSUMERD64_LIBDIR"
1268 ])
1269 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1270 PPRINT_SET_INDENT(0)
1271
1272 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1273         AS_ECHO
1274         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1275
1276 Note that the man pages are already built in this distribution tarball,
1277 therefore asciidoc and xmlto are only needed if you intend to modify
1278 their sources.
1279
1280 Also note that the installed man pages will contain the project's
1281 default command-line option and environment variable values.
1282
1283 Use --disable-man-pages to completely disable building and installing
1284 the man pages.])
1285 ])