configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.2],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_MAKE_SET
  28 AC_PROG_SED
  29 AC_PATH_PROG([report_fold], [fold])
  30 LT_INIT
  31
  32 # Check for objcopy, required by the base address statedump and dynamic linker tests
  33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  34 AS_IF([test "x$OBJCOPY" = "xno"],
  35         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  36 )
  37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  38
  39 # check for pgrep
  40 AC_PATH_PROG([PGREP], [pgrep], [no])
  41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  42
  43 # check for bison
  44 AC_PROG_YACC
  45 BISON=$YACC
  46 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  47
  48 AS_IF([test "x$have_bison" != "xyes"], [
  49   AS_IF([test "x$in_git_repo" = "xyes"], [
  50     AC_MSG_FAILURE([
  51 Bison >= 2.4 is required when building from the Git repository. You can
  52 set the YACC variable to override automatic detection.
  53     ])
  54   ], [
  55     AC_MSG_WARN([
  56 Missing Bison >= 2.4. Note that the parser files are already built in
  57 this distribution tarball, so Bison is only needed if you intend to
  58 modify their sources. You can set the YACC variable to override automatic
  59 detection.
  60     ])
  61   ])
  62 ])
  63 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  64
  65 # check for flex
  66 AC_PROG_LEX
  67 FLEX=$LEX
  68 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  69
  70 AS_IF([test "x$have_flex" != "xyes"], [
  71   AS_IF([test "x$in_git_repo" = "xyes"], [
  72     AC_MSG_FAILURE([
  73 Flex >= 2.5.35 is required when building from the Git repository. You can
  74 set the LEX variable to override automatic detection.
  75     ])
  76   ], [
  77     AC_MSG_WARN([
  78 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  79 this distribution tarball, so Flex is only needed if you intend to
  80 modify their sources. You can set the LEX variable to override automatic
  81 detection.
  82     ])
  83   ])
  84 ])
  85 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  86
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_INT32_T
  91 AC_TYPE_INT64_T
  92 AC_TYPE_MODE_T
  93 AC_TYPE_OFF_T
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_SSIZE_T
  97 AC_TYPE_UID_T
  98 AC_TYPE_UINT16_T
  99 AC_TYPE_UINT32_T
 100 AC_TYPE_UINT64_T
 101 AC_TYPE_UINT8_T
 102
 103 AX_C___ATTRIBUTE__
 104 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 105         [:],
 106         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 107
 108 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 109
 110 AX_LIB_SOCKET_NSL
 111
 112 LT_NO_UNDEFINED=""
 113 AS_CASE([$host_os],
 114   [cygwin*],
 115     [
 116       LT_NO_UNDEFINED="-no-undefined"
 117     ],
 118   [cygwin*|darwin*|mingw*|solaris*],
 119     [
 120       # On platforms where we only support the relayd, disable the other binaries by default
 121       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 122       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 123       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 124       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 125       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 126       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 127     ]
 128 )
 129
 130 AC_SUBST(LT_NO_UNDEFINED)
 131
 132 # Compute minor/major/patchlevel version numbers
 133 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 134 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 135 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 136
 137 AC_SUBST([MAJOR_VERSION], [$major_version])
 138 AC_SUBST([MINOR_VERSION], [$minor_version])
 139 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 140 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 141 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 142 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 143
 144 version_name="KeKriek"
 145 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
 146 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 147
 148 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 149 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 150
 151 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 152 AC_ARG_ENABLE(libtool-linkdep-fixup,
 153         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 154                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 155         libtool_fixup=$enableval,
 156         libtool_fixup=yes)
 157
 158 AS_IF([test "x$libtool_fixup" = "xyes"],
 159             [
 160             libtool_m4="$srcdir/m4/libtool.m4"
 161             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 162             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 163             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 164             AS_IF([test $libtool_flag_pattern_count -ne 0],
 165             [
 166                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 167                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 168                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 169                   ],
 170                   [
 171                   AC_MSG_RESULT([none])
 172                   ])
 173             ])
 174
 175 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 176
 177 AC_CHECK_HEADERS([ \
 178         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 179         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 180         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 181         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 182         sys/mount.h sys/param.h sys/time.h
 183 ])
 184
 185 # Basic functions check
 186 AC_CHECK_FUNCS([ \
 187         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 188         gethostbyname gethostname getpagesize localtime_r memchr memset \
 189         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 190         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 191         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 192         sched_getcpu sysconf sync_file_range
 193 ])
 194
 195 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 196 # add -lrt to LIBS
 197 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 198
 199 # Checks for dl.
 200 AC_CHECK_LIB([dl], [dlopen], [
 201         have_libdl=yes
 202         libdl_name=dl
 203 ], [
 204         # libdl not found, check for dlopen in libc.
 205         AC_CHECK_LIB([c], [dlopen], [
 206                 have_libc_dl=yes
 207                 libdl_name=c
 208         ], [
 209                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 210         ])
 211 ])
 212
 213 # Check if libdl has dlmopen support.
 214 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 215 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 216         AC_DEFINE([HAVE_DLMOPEN], [1])
 217         HAVE_DLMOPEN=1
 218 ], [
 219         HAVE_DLMOPEN=0
 220 ])
 221 AC_SUBST(HAVE_DLMOPEN)
 222
 223 # Babeltrace viewer check
 224 AC_ARG_WITH([babeltrace-bin],
 225         AS_HELP_STRING([--with-babeltrace-bin],
 226         [Location of the babeltrace viewer executable (including the filename)]),
 227         [BABELTRACE_BIN="$withval"],
 228         [BABELTRACE_BIN=''])
 229 AC_SUBST([BABELTRACE_BIN])
 230
 231 # lttv-gui
 232 AC_ARG_WITH([lttv-gui-bin],
 233         AS_HELP_STRING([--with-lttv-gui-bin],
 234    [Location of the lttv GUI viewer executable (including the filename)]),
 235    [LTTV_GUI_BIN="$withval"],
 236    [LTTV_GUI_BIN=''])
 237 AC_SUBST([LTTV_GUI_BIN])
 238
 239 AC_ARG_WITH([consumerd32-bin],
 240         AS_HELP_STRING([--with-consumerd32-bin],
 241         [Location of the 32-bit consumerd executable (including the filename)]),
 242         [CONSUMERD32_BIN="$withval"],
 243         [CONSUMERD32_BIN=''])
 244 AC_SUBST([CONSUMERD32_BIN])
 245
 246 AC_ARG_WITH([consumerd64-bin],
 247         AS_HELP_STRING([--with-consumerd64-bin],
 248         [Location of the 64-bit consumerd executable (including the filename)]),
 249         [CONSUMERD64_BIN="$withval"],
 250         [CONSUMERD64_BIN=''])
 251 AC_SUBST([CONSUMERD64_BIN])
 252
 253 AC_ARG_WITH([consumerd32-libdir],
 254         AS_HELP_STRING([--with-consumerd32-libdir],
 255         [Directory containing the 32-bit consumerd libraries]),
 256         [CONSUMERD32_LIBDIR="$withval"],
 257         [CONSUMERD32_LIBDIR=''])
 258 AC_SUBST([CONSUMERD32_LIBDIR])
 259
 260 AC_ARG_WITH([consumerd64-libdir],
 261         AS_HELP_STRING([--with-consumerd64-libdir],
 262         [Directory containing the 64-bit consumerd libraries]),
 263         [CONSUMERD64_LIBDIR="$withval"],
 264         [CONSUMERD64_LIBDIR=''])
 265 AC_SUBST([CONSUMERD64_LIBDIR])
 266
 267 AC_ARG_WITH([sessiond-bin],
 268         AS_HELP_STRING([--with-sessiond-bin],
 269         [Location of the sessiond executable (including the filename)]),
 270         [SESSIOND_BIN="$withval"],
 271         [SESSIOND_BIN=''])
 272 AC_SUBST([SESSIOND_BIN])
 273
 274 AC_ARG_WITH([lttng-system-rundir],
 275         AS_HELP_STRING([--with-lttng-system-rundir],
 276         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 277         [LTTNG_SYSTEM_RUNDIR="$withval"],
 278         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 279 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 280
 281 AC_ARG_ENABLE([test-java-agent-jul],
 282         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 283         [test_java_agent_jul=$enableval],
 284         [test_java_agent_jul=no]
 285 )
 286
 287 AC_ARG_ENABLE([test-java-agent-log4j],
 288         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 289         [test_java_agent_log4j=$enableval],
 290         [test_java_agent_log4j=no]
 291 )
 292
 293 AC_ARG_ENABLE([test-java-agent-all],
 294         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 295         [test_java_agent_jul=$enableval
 296          test_java_agent_log4j=$enableval],
 297         [:]
 298 )
 299
 300 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 301 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 302 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 303 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 304 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 305 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 306 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 307 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 308
 309 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 310         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 311         $1="$2"
 312         AC_SUBST([$1])
 313 ])
 314
 315 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 316         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 317         $1="$2"
 318         AC_SUBST([$1])
 319 ])
 320
 321 # Default values
 322 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 323 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 324 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 325 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 326 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 327 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 328 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 329 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 330 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 331 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 332 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 333 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 334 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 335 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 336 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 337 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 338 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 339 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 340 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 341 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 342 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 343 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 344 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 345 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 346 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 347 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 348 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 349 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 350 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 351 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 352 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 353 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 354 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 355 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 356 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 357 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 358 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 359 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 360 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 361 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 362 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 363 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 364 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 365 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 366 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 367 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 368
 369 # Command short descriptions
 370 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 371 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 372 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 373 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 374 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 375 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 376 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 377 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 378 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 379 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 380 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 381 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 382 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 383 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 384 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 385 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 386 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 387 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 388 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 389 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 391
 392 if test "x$prefix" = "xNONE"; then
 393         prefix=$ac_default_prefix
 394 fi
 395 CONFDIR=`eval echo $sysconfdir`
 396 AC_SUBST(CONFDIR)
 397 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 398
 399 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 400
 401 # Check libpopt
 402 PKG_CHECK_MODULES([POPT], [popt],
 403   [
 404     dnl PKG_CHECK_MODULES defines POPT_LIBS
 405   ],
 406   [
 407     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 408     AC_MSG_WARN([Finding libpopt without pkg-config.])
 409     AC_CHECK_LIB([popt],
 410       [poptGetContext],
 411       [POPT_LIBS="-lpopt"],
 412       [
 413         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 414       ]
 415     )
 416   ]
 417 )
 418 AC_SUBST(POPT_LIBS)
 419
 420 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 421
 422 # First, check for uuid in system libs
 423 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 424 AC_CHECK_FUNCS([uuid_generate],
 425   [
 426     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 427     UUID_LIBS=""
 428   ],
 429   [
 430     # Then, check if the pkg-config module is available, otherwise explicitly check
 431     # for libuuid, or uuid support in the C-library.
 432     PKG_CHECK_MODULES([UUID], [uuid],
 433       [
 434         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 435         dnl PKG_CHECK_MODULES defines UUID_LIBS
 436       ],
 437       [
 438         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 439         AC_MSG_WARN([Finding libuuid without pkg-config.])
 440         AC_CHECK_LIB([uuid], [uuid_generate],
 441           [
 442             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 443             UUID_LIBS="-luuid"
 444           ],
 445           [
 446             # libuuid not found, check for uuid_create in libc.
 447             AC_CHECK_LIB([c], [uuid_create],
 448               [
 449                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 450                 UUID_LIBS="-lc"
 451               ],
 452               [
 453                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 454               ]
 455             )
 456           ]
 457         )
 458       ]
 459     )
 460   ]
 461 )
 462 AC_SUBST(UUID_LIBS)
 463
 464 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 465
 466 # URCU library version needed or newer
 467 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 468
 469 # Check liburcu needed function calls
 470 AC_CHECK_DECL([cds_list_add], [],
 471         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 472 AC_CHECK_DECL([cds_wfcq_init], [],
 473         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 474 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 475         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 476 AC_CHECK_DECL([futex_async], [],
 477         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 478 AC_CHECK_DECL([rcu_thread_offline], [],
 479         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 480 AC_CHECK_DECL([rcu_thread_online], [],
 481         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 482 AC_CHECK_DECL([caa_likely], [],
 483         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 484 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 485         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 486
 487 #Function added in urcu 0.7.0
 488 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 489         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 490 )
 491
 492 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 493 # it can be explicitly disabled with --without-kmod
 494 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 495 AC_ARG_WITH([kmod],
 496   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 497   [],
 498   [with_kmod=check]
 499 )
 500
 501 AS_IF([test "x$with_kmod" != "xno"],
 502   [
 503     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 504       [
 505         AC_DEFINE([HAVE_KMOD], [1])
 506         KMOD_LIBS="-lkmod"
 507       ],
 508       [
 509         if test "x$with_kmod" != xcheck; then
 510           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 511         else
 512           with_kmod=no
 513         fi
 514       ]
 515     )
 516   ]
 517 )
 518 AC_SUBST(KMOD_LIBS)
 519
 520 # Check for liblttng-ust-ctl, fail if it's not found,
 521 # it can be explicitly disabled with --without-lttng-ust
 522 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 523 AC_ARG_WITH([lttng-ust],
 524   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 525   [],
 526   [with_lttng_ust=yes]
 527 )
 528
 529 AS_IF([test "x$with_lttng_ust" = "xyes"],
 530   [
 531     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 532       [
 533         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 534       ],
 535       [
 536         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 537       ],
 538       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 539     )
 540   ]
 541 )
 542 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 543
 544
 545
 546 # check for dlopen
 547 AC_CHECK_LIB([dl], [dlopen],
 548   [DL_LIBS="-ldl"],
 549   [
 550     #libdl not found, check for dlopen in libc.
 551     AC_CHECK_LIB([c], [dlopen],
 552       [DL_LIBS="-lc"],
 553       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 554     )
 555   ]
 556 )
 557 AC_SUBST(DL_LIBS)
 558
 559 # Check for fmemopen
 560 AC_CHECK_LIB([c], [fmemopen],
 561 [
 562         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 563 ]
 564 )
 565
 566 # Check for open_memstream
 567 AC_CHECK_LIB([c], [open_memstream],
 568 [
 569         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 570 ]
 571 )
 572
 573 # check for libpfm
 574 AC_CHECK_LIB([pfm], [pfm_initialize],
 575              [
 576               have_libpfm=yes
 577               ])
 578 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 579
 580 AC_ARG_ENABLE([git-version],
 581               [AC_HELP_STRING([--disable-git-version],
 582                               [Do not use the git version for the build])],
 583               [have_git_version=$enableval], [have_git_version=yes]
 584 )
 585
 586 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 587         [test "x${have_git_version}" = "xyes"])
 588
 589 # For Python
 590 # SWIG version needed or newer:
 591 swig_version=2.0.0
 592
 593 AC_ARG_ENABLE([python-bindings],
 594               [AC_HELP_STRING([--enable-python-bindings],
 595                               [compile Python bindings])],
 596               [enable_python_binding=$enableval], [enable_python_binding=no])
 597
 598 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 599
 600 if test "x$enable_python_binding" = xyes; then
 601   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 602   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 603   AM_PATH_PYTHON([3.0])
 604
 605   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 606   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 607   AS_IF([test -z "$PYTHON_INCLUDE"], [
 608     AS_IF([test -z "$PYTHON_CONFIG"], [
 609       AC_PATH_PROGS([PYTHON_CONFIG],
 610                     [python$PYTHON_VERSION-config python-config],
 611                     [no],
 612                     [`dirname $PYTHON`])
 613       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 614     ])
 615     AC_MSG_CHECKING([python include flags])
 616     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 617     AC_MSG_RESULT([$PYTHON_INCLUDE])
 618   ])
 619
 620 else
 621     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 622 [if you want Python bindings.])
 623
 624 fi
 625
 626 # Epoll check. If not present, the build will fallback on poll() API
 627 AX_HAVE_EPOLL(
 628         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 629         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 630 )
 631 AX_CONFIG_FEATURE(
 632         [epoll], [This platform supports epoll(7)],
 633         [HAVE_EPOLL], [This platform supports epoll(7).],
 634         [enable_epoll="yes"], [enable_epoll="no"]
 635 )
 636 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 637
 638 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 639 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 640
 641 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 642         AX_JAVA_OPTIONS
 643         AX_PROG_JAVAC
 644         AX_PROG_JAVA
 645         AX_PROG_JAR
 646
 647         AX_CHECK_CLASSPATH
 648
 649         # Check for Java UST agent common class first
 650         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 651         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 652                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 653         fi
 654
 655         if test "x$test_java_agent_jul" = "xyes"; then
 656                 # Check for JUL agent class
 657                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 658                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 659                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 660                 fi
 661         fi
 662
 663         if test "x$test_java_agent_log4j" = "xyes"; then
 664                 # Check for Log4j agent class
 665                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 666                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 667                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 668                 fi
 669
 670                 # Check for Log4j class
 671                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 672                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 673                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 674                 fi
 675         fi
 676 fi
 677
 678 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 679 # is not distributed in tarballs
 680 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 681 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 682
 683 # enable building man pages (user's intention)
 684 AC_ARG_ENABLE(
 685         man-pages,
 686         AS_HELP_STRING(
 687                 [--disable-man-pages],
 688                 [Do not build and install man pages (already built in a distributed tarball)]
 689         ),
 690         [man_pages_opt=$enableval],
 691         [man_pages_opt=yes]
 692 )
 693
 694 # check for asciidoc and xmlto if we enabled building the man pages
 695 have_asciidoc_xmlto=no
 696 warn_prebuilt_man_pages=no
 697
 698 AS_IF([test "x$man_pages_opt" = "xyes"], [
 699         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 700         AC_PATH_PROG([XMLTO], [xmlto], [no])
 701
 702         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 703                 AS_IF([test "x$in_git_repo" = "xyes"], [
 704                         # this is an error because we're in the Git repo, which
 705                         # means the man pages are not already generated for us,
 706                         # thus asciidoc/xmlto are required because we were asked
 707                         # to build the man pages
 708                         AC_MSG_ERROR([
 709 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 710 --disable-man-pages to disable building the man pages, in which case
 711 they will not be installed.
 712                         ])
 713                 ], [
 714                         # only warn here: since we're in the tarball, the man
 715                         # pages should already be generated at this point, thus
 716                         # asciidoc/xmlto are not strictly required
 717                         warn_prebuilt_man_pages=yes
 718                 ])
 719         ], [
 720                 have_asciidoc_xmlto=yes
 721         ])
 722 ])
 723
 724 # export man page build condition: build the man pages if the user
 725 # asked for it, and if the tools are available
 726 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 727 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 728
 729 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 730
 731 # embedded --help message
 732 AC_ARG_ENABLE(
 733         [embedded-help],
 734         AS_HELP_STRING(
 735                 [--enable-embedded-help],
 736                 [Embed the --help messages in the executable files]
 737         ),
 738         [embedded_help=$enableval],
 739         [embedded_help=no]
 740 )
 741 AS_IF([test "x$embedded_help" = "xyes"], [
 742         AS_IF([test "x$man_pages_opt" = "xno"], [
 743                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 744         ])
 745         AC_PATH_PROG([man_prog_path], [man], [no])
 746         AS_IF([test "x$man_prog_path" = "xno"], [
 747                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 748         ])
 749         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 750         AC_SUBST([MANPROG], [$man_prog_path])
 751 ])
 752 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 753
 754 # Python agent test
 755 UST_PYTHON_AGENT="lttngust"
 756
 757 AC_ARG_ENABLE(test-python2-agent,
 758         AS_HELP_STRING([--enable-test-python2-agent],
 759                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 760         ),[:],[test_python2_agent_autodetect=yes]
 761 )
 762
 763 AC_ARG_ENABLE(test-python3-agent,
 764         AS_HELP_STRING([--enable-test-python3-agent],
 765                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 766         ),[:],[test_python3_agent_autodetect=yes]
 767 )
 768
 769 AC_ARG_ENABLE(test-python-agent-all,
 770         AS_HELP_STRING([--enable-test-python-agent-all],
 771                 [enable test for all python{2/3} agent.]
 772         ),
 773 )
 774
 775 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 776        unset test_python2_agent_autodetect
 777        unset test_python3_agent_autodetect
 778 ])
 779
 780 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 781        enable_test_python2_agent=yes
 782        enable_test_python3_agent=yes
 783 ])
 784
 785 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 786        enable_test_python2_agent=no
 787        enable_test_python3_agent=no
 788 ])
 789
 790
 791 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 792         AS_IF([test -z "$PYTHON2"], [
 793                         PYTHON2=python2
 794                 ], [
 795                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 796         ])
 797
 798         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 799         AS_IF([test -z "$PYTHON2_BIN"], [
 800                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 801                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 802                 ])
 803         ], [
 804                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 805                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 806                         PYTHON2_AGENT=$PYTHON2_BIN
 807                         AC_MSG_RESULT([yes])
 808                         RUN_PYTHON_AGENT_TEST=yes
 809                 ], [
 810                         AC_MSG_RESULT([no])
 811                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 812                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 813                         ])
 814                 ])
 815
 816         ])
 817
 818 ])
 819
 820 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 821         AS_IF([test -z "$PYTHON3"], [
 822                 PYTHON3=python3
 823         ], [
 824                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 825         ])
 826
 827         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 828         AS_IF([test -z "$PYTHON3_BIN"], [
 829                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 830                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 831                 ])
 832         ], [
 833                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 834                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 835                         PYTHON3_AGENT=$PYTHON3_BIN
 836                         AC_MSG_RESULT([yes])
 837                         RUN_PYTHON_AGENT_TEST=yes
 838                 ], [
 839                         AC_MSG_RESULT([no])
 840                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 841                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 842                         ])
 843                 ])
 844
 845         ])
 846 ])
 847 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 848 AC_SUBST([PYTHON2_AGENT])
 849 AC_SUBST([PYTHON3_AGENT])
 850
 851 # Arguments for binaries build exclusion
 852 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 853 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 854               [Disable the build of lttng-consumerd binaries]))
 855 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 856 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 857               [Disable the build of lttng-relayd binaries]))
 858 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 859               [Disable the build of lttng-sessiond binaries]))
 860 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 861               [Disable the build of the extra components]))
 862
 863
 864 # Always build libconfig since it a dependency of libcommon
 865 build_lib_config=yes
 866
 867 build_lib_compat=no
 868 build_lib_consumer=no
 869 build_lib_hashtable=no
 870 build_lib_health=no
 871 build_lib_index=no
 872 build_lib_kernel_consumer=no
 873 build_lib_kernel_ctl=no
 874 build_lib_lttng_ctl=no
 875 build_lib_relayd=no
 876 build_lib_sessiond_comm=no
 877 build_lib_testpoint=no
 878 build_lib_ust_consumer=no
 879
 880 # There is an overlap for enabled dependencies, but this makes everything
 881 # simpler. libcommon and libconfig are always compiled so they are not repeated
 882 # here.
 883
 884 # Enable binary dependencies.
 885 AS_IF([test x$enable_bin_lttng != xno],
 886       [
 887        build_lib_lttng_ctl=yes
 888       ]
 889 )
 890
 891 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 892       [
 893        build_lib_consumer=yes
 894        build_lib_sessiond_comm=yes
 895        build_lib_index=yes
 896        build_lib_health=yes
 897        build_lib_testpoint=yes
 898       ]
 899 )
 900
 901 AS_IF([test x$enable_bin_lttng_crash != xno],
 902       # Do nothing since libconfig and libcommon are built by default.
 903       []
 904 )
 905
 906 AS_IF([test x$enable_bin_lttng_relayd != xno],
 907       [
 908        build_lib_lttng_ctl=yes
 909        build_lib_sessiond_comm=yes
 910        build_lib_hashtable=yes
 911        build_lib_compat=yes
 912        build_lib_index=yes
 913        build_lib_health=yes
 914        build_lib_testpoint=yes
 915       ]
 916 )
 917 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 918       [
 919        build_lib_lttng_ctl=yes
 920        build_lib_sessiond_comm=yes
 921        build_lib_kernel_ctl=yes
 922        build_lib_hashtable=yes
 923        build_lib_compat=yes
 924        build_lib_relayd=yes
 925        build_lib_testpoint=yes
 926        build_lib_health=yes
 927        build_lib_health=yes
 928       ]
 929 )
 930
 931 # Libraries dependencies enabling
 932 AS_IF([test x$build_lib_lttng_ctl = xyes],
 933       [
 934        build_lib_sessiond_comm=yes
 935        build_lib_hashtable=yes
 936       ]
 937 )
 938
 939 AS_IF([test x$build_lib_consumer = xyes],
 940       [
 941        build_lib_sessiond_comm=yes
 942        build_lib_kernel_consumer=yes
 943        build_lib_hashtable=yes
 944        build_lib_compat=yes
 945        build_lib_relayd=yes
 946        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 947       ]
 948 )
 949
 950 AS_IF([test x$build_lib_kernel_consumer = xyes],
 951       [
 952        build_lib_kernel_ctl=yes
 953        build_lib_relayd=yes
 954       ]
 955 )
 956
 957 AS_IF([test x$build_lib_relayd = xyes],
 958       [
 959        build_lib_sessiond_comm=yes
 960       ]
 961 )
 962
 963
 964 # Export binaries build conditions.
 965 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 966 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 967 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 968 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 969 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 970
 971 # Export the tests and extras build conditions.
 972 AS_IF([\
 973 test "x$enable_bin_lttng" != "xno" && \
 974 test "x$enable_bin_lttng_consumerd" != "xno" && \
 975 test "x$enable_bin_lttng_crash" != "xno" && \
 976 test "x$enable_bin_lttng_relayd" != "xno" && \
 977 test "x$enable_bin_lttng_sessiond" != "xno"],
 978 [build_tests=yes],
 979 [build_tests=no]
 980 )
 981
 982 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 983 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 984
 985 # Export libraries build conditions.
 986 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 987 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 988 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 989 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 990 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 991 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 992 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 993 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 994 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 995 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 996 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 997 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 998 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 999
1000 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1001 AC_SUBST(AM_CFLAGS)
1002
1003 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1004 AC_SUBST(AM_CPPFLAGS)
1005
1006 lttngincludedir="${includedir}/lttng"
1007 AC_SUBST(lttngincludedir)
1008
1009 lttngactionincludedir="${includedir}/lttng/action"
1010 AC_SUBST(lttngactionincludedir)
1011
1012 lttngconditionincludedir="${includedir}/lttng/condition"
1013 AC_SUBST(lttngconditionincludedir)
1014
1015 lttngnotificationincludedir="${includedir}/lttng/notification"
1016 AC_SUBST(lttngnotificationincludedir)
1017
1018 lttngtriggerincludedir="${includedir}/lttng/trigger"
1019 AC_SUBST(lttngtriggerincludedir)
1020
1021 lttnglibexecdir="${libdir}/lttng/libexec"
1022 AC_SUBST(lttnglibexecdir)
1023
1024 AC_CONFIG_FILES([
1025         Makefile
1026         doc/Makefile
1027         doc/man/Makefile
1028         doc/man/asciidoc-attrs.conf
1029         include/Makefile
1030         extras/Makefile
1031         extras/bindings/Makefile
1032         extras/bindings/swig/Makefile
1033         extras/bindings/swig/python/Makefile
1034         extras/core-handler/Makefile
1035         src/Makefile
1036         src/common/Makefile
1037         src/common/kernel-ctl/Makefile
1038         src/common/kernel-consumer/Makefile
1039         src/common/consumer/Makefile
1040         src/common/ust-consumer/Makefile
1041         src/common/hashtable/Makefile
1042         src/common/sessiond-comm/Makefile
1043         src/common/compat/Makefile
1044         src/common/relayd/Makefile
1045         src/common/testpoint/Makefile
1046         src/common/index/Makefile
1047         src/common/health/Makefile
1048         src/common/config/Makefile
1049         src/common/string-utils/Makefile
1050         src/lib/Makefile
1051         src/lib/lttng-ctl/Makefile
1052         src/lib/lttng-ctl/filter/Makefile
1053         src/lib/lttng-ctl/lttng-ctl.pc
1054         src/bin/Makefile
1055         src/bin/lttng-consumerd/Makefile
1056         src/bin/lttng-sessiond/Makefile
1057         src/bin/lttng-relayd/Makefile
1058         src/bin/lttng/Makefile
1059         src/bin/lttng-crash/Makefile
1060         tests/Makefile
1061         tests/destructive/Makefile
1062         tests/regression/Makefile
1063         tests/regression/kernel/Makefile
1064         tests/regression/tools/Makefile
1065         tests/regression/tools/streaming/Makefile
1066         tests/regression/tools/filtering/Makefile
1067         tests/regression/tools/health/Makefile
1068         tests/regression/tools/tracefile-limits/Makefile
1069         tests/regression/tools/snapshots/Makefile
1070         tests/regression/tools/live/Makefile
1071         tests/regression/tools/exclusion/Makefile
1072         tests/regression/tools/save-load/Makefile
1073         tests/regression/tools/save-load/configuration/Makefile
1074         tests/regression/tools/mi/Makefile
1075         tests/regression/tools/wildcard/Makefile
1076         tests/regression/tools/crash/Makefile
1077         tests/regression/tools/regen-metadata/Makefile
1078         tests/regression/tools/regen-statedump/Makefile
1079         tests/regression/tools/notification/Makefile
1080         tests/regression/ust/Makefile
1081         tests/regression/ust/nprocesses/Makefile
1082         tests/regression/ust/high-throughput/Makefile
1083         tests/regression/ust/low-throughput/Makefile
1084         tests/regression/ust/before-after/Makefile
1085         tests/regression/ust/buffers-pid/Makefile
1086         tests/regression/ust/periodical-metadata-flush/Makefile
1087         tests/regression/ust/multi-session/Makefile
1088         tests/regression/ust/overlap/Makefile
1089         tests/regression/ust/overlap/demo/Makefile
1090         tests/regression/ust/linking/Makefile
1091         tests/regression/ust/daemon/Makefile
1092         tests/regression/ust/exit-fast/Makefile
1093         tests/regression/ust/fork/Makefile
1094         tests/regression/ust/libc-wrapper/Makefile
1095         tests/regression/ust/baddr-statedump/Makefile
1096         tests/regression/ust/ust-dl/Makefile
1097         tests/regression/ust/java-jul/Makefile
1098         tests/regression/ust/java-log4j/Makefile
1099         tests/regression/ust/python-logging/Makefile
1100         tests/regression/ust/getcpu-override/Makefile
1101         tests/regression/ust/clock-override/Makefile
1102         tests/regression/ust/type-declarations/Makefile
1103         tests/regression/ust/rotation-destroy-flush/Makefile
1104         tests/regression/ust/blocking/Makefile
1105         tests/stress/Makefile
1106         tests/unit/Makefile
1107         tests/unit/ini_config/Makefile
1108         tests/perf/Makefile
1109         tests/utils/Makefile
1110         tests/utils/tap/Makefile
1111         tests/utils/testapp/Makefile
1112         tests/utils/testapp/gen-ust-events/Makefile
1113         tests/utils/testapp/gen-ust-nevents/Makefile
1114         tests/utils/testapp/gen-ust-nevents-str/Makefile
1115         tests/utils/testapp/gen-ust-tracef/Makefile
1116 ])
1117
1118 # Inject variable into python test script.
1119 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1120 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1121 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1122 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1123
1124 AC_OUTPUT
1125
1126 #
1127 # Mini-report on what will be built.
1128 #
1129
1130 PPRINT_INIT
1131 PPRINT_SET_INDENT(1)
1132 PPRINT_SET_TS(38)
1133
1134 AS_ECHO
1135 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1136 AS_ECHO
1137
1138 AS_IF([test -n "$report_fold"], [
1139         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1140 ], [
1141         AS_ECHO("$version_description")
1142 ])
1143
1144 AS_ECHO
1145 PPRINT_SUBTITLE([Features])
1146
1147 # Target architecture we're building for.
1148 target_arch=$host_cpu
1149 [
1150 for f in $CFLAGS; do
1151         if test $f = "-m32"; then
1152                         target_arch="32-bit"
1153         elif test $f = "-m64"; then
1154                         target_arch="64-bit"
1155         fi
1156 done
1157 ]
1158 PPRINT_PROP_STRING([Target architecture], $target_arch)
1159
1160 # kmod enabled/disabled
1161 test "x$with_kmod" != "xno" && value=1 || value=0
1162 PPRINT_PROP_BOOL([libkmod support], $value)
1163
1164 # LTTng-UST enabled/disabled
1165 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1166 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1167
1168 AS_ECHO
1169 PPRINT_SUBTITLE([Binaries])
1170
1171 # List binaries to be built
1172 test x$enable_bin_lttng != xno && value=1 || value=0
1173 PPRINT_PROP_BOOL([lttng], $value)
1174
1175 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1176 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1177
1178 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1179 PPRINT_PROP_BOOL([lttng-crash], $value)
1180
1181 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1182 PPRINT_PROP_BOOL([lttng-relayd], $value)
1183
1184 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1185 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1186
1187 # Extras
1188 test x$enable_extras != xno && value=1 || value=0
1189 AS_ECHO
1190 PPRINT_SET_INDENT(0)
1191 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1192 PPRINT_SET_INDENT(1)
1193
1194 AS_ECHO
1195 PPRINT_SUBTITLE([Tests])
1196
1197 # Print clear message that tests won't be built
1198 AS_IF([test "x$build_tests" = "xno"],[
1199         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1200 ])
1201
1202 # LTTng UST Java agent JUL tests enabled/disabled
1203 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1204 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1205
1206 # LTTng UST Java agent Log4j tests enabled/disabled
1207 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1208 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1209
1210 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1211 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1212
1213 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1214 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1215
1216 #Python binding enabled/disabled
1217 test "x$enable_python_binding" = xyes && value=1 || value=0
1218 AS_ECHO
1219 PPRINT_SET_INDENT(0)
1220 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1221
1222 # man pages build enabled/disabled
1223 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1224
1225 AS_IF([test "x$man_pages_opt" != "xno"], [
1226         AS_IF([test "x$in_git_repo" = "xyes"], [
1227                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1228         ], [
1229                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1230                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1231                 ], [
1232                         PPRINT_PROP_STRING([build_man_pages_msg],
1233                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1234                                 $PPRINT_COLOR_SUBTITLE)
1235                 ])
1236         ])
1237 ], [
1238         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1239 ])
1240
1241 m4_popdef([build_man_pages_msg])
1242
1243 test "x$embedded_help" = xyes && value=1 || value=0
1244 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1245
1246 PPRINT_SET_INDENT(1)
1247
1248 report_bindir="`eval eval echo $bindir`"
1249 report_libdir="`eval eval echo $libdir`"
1250
1251 # Print the bindir and libdir this `make install' will install into.
1252 AS_ECHO
1253 PPRINT_SUBTITLE([Install directories])
1254 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1255 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1256
1257 AS_ECHO
1258 PPRINT_SUBTITLE([Search directories])
1259
1260 # If we build the sessiond, print the paths it will use
1261 AS_IF([test "$SESSIOND_BIN" = ""],[
1262         path="$report_bindir/lttng-sessiond"
1263 ],[
1264         path="$SESSIOND_BIN"
1265 ])
1266 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1267
1268 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1269         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1270 ],[
1271         path="$CONSUMERD32_BIN"
1272 ])
1273 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1274
1275 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1276         path="`eval eval echo $libdir`"
1277 ],[
1278         path="$CONSUMERD32_LIBDIR"
1279 ])
1280 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1281
1282 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1283         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1284 ],[
1285         path="$CONSUMERD64_BIN"
1286 ])
1287 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1288
1289 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1290         path="`eval eval echo $libdir`"
1291 ],[
1292         path="$CONSUMERD64_LIBDIR"
1293 ])
1294 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1295 PPRINT_SET_INDENT(0)
1296
1297 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1298         AS_ECHO
1299         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1300
1301 Note that the man pages are already built in this distribution tarball,
1302 therefore asciidoc and xmlto are only needed if you intend to modify
1303 their sources.
1304
1305 Also note that the installed man pages will contain the project's
1306 default command-line option and environment variable values.
1307
1308 Use --disable-man-pages to completely disable building and installing
1309 the man pages.])
1310 ])