configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.3],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_MAKE_SET
  28 AC_PROG_SED
  29 AC_PATH_PROG([report_fold], [fold])
  30 LT_INIT
  31
  32 # Check for objcopy, required by the base address statedump and dynamic linker tests
  33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  34 AS_IF([test "x$OBJCOPY" = "xno"],
  35         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  36 )
  37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  38
  39 # check for pgrep
  40 AC_PATH_PROG([PGREP], [pgrep], [no])
  41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  42
  43 # check for bison
  44 AC_PROG_YACC
  45 BISON=$YACC
  46 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  47
  48 AS_IF([test "x$have_bison" != "xyes"], [
  49   AS_IF([test "x$in_git_repo" = "xyes"], [
  50     AC_MSG_FAILURE([
  51 Bison >= 2.4 is required when building from the Git repository. You can
  52 set the YACC variable to override automatic detection.
  53     ])
  54   ], [
  55     AC_MSG_WARN([
  56 Missing Bison >= 2.4. Note that the parser files are already built in
  57 this distribution tarball, so Bison is only needed if you intend to
  58 modify their sources. You can set the YACC variable to override automatic
  59 detection.
  60     ])
  61   ])
  62 ])
  63 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  64
  65 # check for flex
  66 AC_PROG_LEX
  67 FLEX=$LEX
  68 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  69
  70 AS_IF([test "x$have_flex" != "xyes"], [
  71   AS_IF([test "x$in_git_repo" = "xyes"], [
  72     AC_MSG_FAILURE([
  73 Flex >= 2.5.35 is required when building from the Git repository. You can
  74 set the LEX variable to override automatic detection.
  75     ])
  76   ], [
  77     AC_MSG_WARN([
  78 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  79 this distribution tarball, so Flex is only needed if you intend to
  80 modify their sources. You can set the LEX variable to override automatic
  81 detection.
  82     ])
  83   ])
  84 ])
  85 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  86
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_INT32_T
  91 AC_TYPE_INT64_T
  92 AC_TYPE_MODE_T
  93 AC_TYPE_OFF_T
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_SSIZE_T
  97 AC_TYPE_UID_T
  98 AC_TYPE_UINT16_T
  99 AC_TYPE_UINT32_T
 100 AC_TYPE_UINT64_T
 101 AC_TYPE_UINT8_T
 102
 103 AX_C___ATTRIBUTE__
 104 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 105         [:],
 106         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 107
 108 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 109
 110 AX_LIB_SOCKET_NSL
 111
 112 LT_NO_UNDEFINED=""
 113 AS_CASE([$host_os],
 114   [cygwin*],
 115     [
 116       LT_NO_UNDEFINED="-no-undefined"
 117     ],
 118   [cygwin*|darwin*|mingw*|solaris*],
 119     [
 120       # On platforms where we only support the relayd, disable the other binaries by default
 121       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 122       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 123       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 124       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 125       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 126       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 127     ]
 128 )
 129
 130 AC_SUBST(LT_NO_UNDEFINED)
 131
 132 # Compute minor/major/patchlevel version numbers
 133 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 134 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 135 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 136
 137 AC_SUBST([MAJOR_VERSION], [$major_version])
 138 AC_SUBST([MINOR_VERSION], [$minor_version])
 139 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 140 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 141 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 142 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 143
 144 version_name="KeKriek"
 145 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
 146 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 147
 148 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 149 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 150
 151 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 152 AC_ARG_ENABLE(libtool-linkdep-fixup,
 153         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 154                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 155         libtool_fixup=$enableval,
 156         libtool_fixup=yes)
 157
 158 AS_IF([test "x$libtool_fixup" = "xyes"],
 159             [
 160             libtool_m4="$srcdir/m4/libtool.m4"
 161             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 162             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 163             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 164             AS_IF([test $libtool_flag_pattern_count -ne 0],
 165             [
 166                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 167                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 168                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 169                   ],
 170                   [
 171                   AC_MSG_RESULT([none])
 172                   ])
 173             ])
 174
 175 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 176
 177 AC_CHECK_HEADERS([ \
 178         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 179         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 180         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 181         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 182         sys/mount.h sys/param.h sys/time.h
 183 ])
 184
 185 # Basic functions check
 186 AC_CHECK_FUNCS([ \
 187         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 188         gethostbyname gethostname getpagesize localtime_r memchr memset \
 189         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 190         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 191         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 192         sched_getcpu sysconf sync_file_range
 193 ])
 194
 195 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 196 # add -lrt to LIBS
 197 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 198
 199 # Checks for dl.
 200 AC_CHECK_LIB([dl], [dlopen], [
 201         have_libdl=yes
 202         libdl_name=dl
 203 ], [
 204         # libdl not found, check for dlopen in libc.
 205         AC_CHECK_LIB([c], [dlopen], [
 206                 have_libc_dl=yes
 207                 libdl_name=c
 208         ], [
 209                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 210         ])
 211 ])
 212
 213 # Check if libdl has dlmopen support.
 214 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 215 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 216         AC_DEFINE([HAVE_DLMOPEN], [1])
 217         HAVE_DLMOPEN=1
 218 ], [
 219         HAVE_DLMOPEN=0
 220 ])
 221 AC_SUBST(HAVE_DLMOPEN)
 222
 223 # Babeltrace viewer check
 224 AC_ARG_WITH([babeltrace-bin],
 225         AS_HELP_STRING([--with-babeltrace-bin],
 226         [Location of the babeltrace viewer executable (including the filename)]),
 227         [BABELTRACE_BIN="$withval"],
 228         [BABELTRACE_BIN=''])
 229 AC_SUBST([BABELTRACE_BIN])
 230
 231 # lttv-gui
 232 AC_ARG_WITH([lttv-gui-bin],
 233         AS_HELP_STRING([--with-lttv-gui-bin],
 234    [Location of the lttv GUI viewer executable (including the filename)]),
 235    [LTTV_GUI_BIN="$withval"],
 236    [LTTV_GUI_BIN=''])
 237 AC_SUBST([LTTV_GUI_BIN])
 238
 239 AC_ARG_WITH([consumerd32-bin],
 240         AS_HELP_STRING([--with-consumerd32-bin],
 241         [Location of the 32-bit consumerd executable (including the filename)]),
 242         [CONSUMERD32_BIN="$withval"],
 243         [CONSUMERD32_BIN=''])
 244 AC_SUBST([CONSUMERD32_BIN])
 245
 246 AC_ARG_WITH([consumerd64-bin],
 247         AS_HELP_STRING([--with-consumerd64-bin],
 248         [Location of the 64-bit consumerd executable (including the filename)]),
 249         [CONSUMERD64_BIN="$withval"],
 250         [CONSUMERD64_BIN=''])
 251 AC_SUBST([CONSUMERD64_BIN])
 252
 253 AC_ARG_WITH([consumerd32-libdir],
 254         AS_HELP_STRING([--with-consumerd32-libdir],
 255         [Directory containing the 32-bit consumerd libraries]),
 256         [CONSUMERD32_LIBDIR="$withval"],
 257         [CONSUMERD32_LIBDIR=''])
 258 AC_SUBST([CONSUMERD32_LIBDIR])
 259
 260 AC_ARG_WITH([consumerd64-libdir],
 261         AS_HELP_STRING([--with-consumerd64-libdir],
 262         [Directory containing the 64-bit consumerd libraries]),
 263         [CONSUMERD64_LIBDIR="$withval"],
 264         [CONSUMERD64_LIBDIR=''])
 265 AC_SUBST([CONSUMERD64_LIBDIR])
 266
 267 AC_ARG_WITH([sessiond-bin],
 268         AS_HELP_STRING([--with-sessiond-bin],
 269         [Location of the sessiond executable (including the filename)]),
 270         [SESSIOND_BIN="$withval"],
 271         [SESSIOND_BIN=''])
 272 AC_SUBST([SESSIOND_BIN])
 273
 274 AC_ARG_WITH([lttng-system-rundir],
 275         AS_HELP_STRING([--with-lttng-system-rundir],
 276         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 277         [LTTNG_SYSTEM_RUNDIR="$withval"],
 278         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 279 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 280
 281 AC_ARG_ENABLE([test-java-agent-jul],
 282         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 283         [test_java_agent_jul=$enableval],
 284         [test_java_agent_jul=no]
 285 )
 286
 287 AC_ARG_ENABLE([test-java-agent-log4j],
 288         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 289         [test_java_agent_log4j=$enableval],
 290         [test_java_agent_log4j=no]
 291 )
 292
 293 AC_ARG_ENABLE([test-java-agent-all],
 294         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 295         [test_java_agent_jul=$enableval
 296          test_java_agent_log4j=$enableval],
 297         [:]
 298 )
 299
 300 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 301 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 302 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 303 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 304 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 305 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 306 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 307 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 308
 309 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 310         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 311         $1="$2"
 312         AC_SUBST([$1])
 313 ])
 314
 315 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 316         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 317         $1="$2"
 318         AC_SUBST([$1])
 319 ])
 320
 321 # Default values
 322 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 323 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 324 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 325 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 326 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 327 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 328 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 329 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 330 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 331 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 332 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 333 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 334 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 335 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 336 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 337 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 338 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 339 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 340 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 341 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 342 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 343 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 344 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 345 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 346 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 347 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 348 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 349 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 350 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 351 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 352 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 353 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 354 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 355 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 356 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 357 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 358 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 359 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 360 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 361 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 362 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 363 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 364 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 365 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 366 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 367 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 368 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 369
 370 # Command short descriptions
 371 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 372 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 373 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 374 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 375 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 376 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 377 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 378 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 379 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 380 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 381 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 382 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 383 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 384 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 385 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 386 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 387 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 388 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 389 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 391 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 392
 393 if test "x$prefix" = "xNONE"; then
 394         prefix=$ac_default_prefix
 395 fi
 396 CONFDIR=`eval echo $sysconfdir`
 397 AC_SUBST(CONFDIR)
 398 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 399
 400 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 401
 402 # Check libpopt
 403 PKG_CHECK_MODULES([POPT], [popt],
 404   [
 405     dnl PKG_CHECK_MODULES defines POPT_LIBS
 406   ],
 407   [
 408     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 409     AC_MSG_WARN([Finding libpopt without pkg-config.])
 410     AC_CHECK_LIB([popt],
 411       [poptGetContext],
 412       [POPT_LIBS="-lpopt"],
 413       [
 414         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 415       ]
 416     )
 417   ]
 418 )
 419 AC_SUBST(POPT_LIBS)
 420
 421 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 422
 423 # First, check for uuid in system libs
 424 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 425 AC_CHECK_FUNCS([uuid_generate],
 426   [
 427     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 428     UUID_LIBS=""
 429   ],
 430   [
 431     # Then, check if the pkg-config module is available, otherwise explicitly check
 432     # for libuuid, or uuid support in the C-library.
 433     PKG_CHECK_MODULES([UUID], [uuid],
 434       [
 435         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 436         dnl PKG_CHECK_MODULES defines UUID_LIBS
 437       ],
 438       [
 439         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 440         AC_MSG_WARN([Finding libuuid without pkg-config.])
 441         AC_CHECK_LIB([uuid], [uuid_generate],
 442           [
 443             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 444             UUID_LIBS="-luuid"
 445           ],
 446           [
 447             # libuuid not found, check for uuid_create in libc.
 448             AC_CHECK_LIB([c], [uuid_create],
 449               [
 450                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 451                 UUID_LIBS="-lc"
 452               ],
 453               [
 454                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 455               ]
 456             )
 457           ]
 458         )
 459       ]
 460     )
 461   ]
 462 )
 463 AC_SUBST(UUID_LIBS)
 464
 465 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 466
 467 # URCU library version needed or newer
 468 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 469
 470 # Check liburcu needed function calls
 471 AC_CHECK_DECL([cds_list_add], [],
 472         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 473 AC_CHECK_DECL([cds_wfcq_init], [],
 474         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 475 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 476         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 477 AC_CHECK_DECL([futex_async], [],
 478         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 479 AC_CHECK_DECL([rcu_thread_offline], [],
 480         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 481 AC_CHECK_DECL([rcu_thread_online], [],
 482         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 483 AC_CHECK_DECL([caa_likely], [],
 484         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 485 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 486         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 487
 488 #Function added in urcu 0.7.0
 489 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 490         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 491 )
 492
 493 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 494 # it can be explicitly disabled with --without-kmod
 495 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 496 AC_ARG_WITH([kmod],
 497   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 498   [],
 499   [with_kmod=check]
 500 )
 501
 502 AS_IF([test "x$with_kmod" != "xno"],
 503   [
 504     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 505       [
 506         AC_DEFINE([HAVE_KMOD], [1])
 507         KMOD_LIBS="-lkmod"
 508       ],
 509       [
 510         if test "x$with_kmod" != xcheck; then
 511           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 512         else
 513           with_kmod=no
 514         fi
 515       ]
 516     )
 517   ]
 518 )
 519 AC_SUBST(KMOD_LIBS)
 520
 521 # Check for liblttng-ust-ctl, fail if it's not found,
 522 # it can be explicitly disabled with --without-lttng-ust
 523 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 524 AC_ARG_WITH([lttng-ust],
 525   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 526   [],
 527   [with_lttng_ust=yes]
 528 )
 529
 530 AS_IF([test "x$with_lttng_ust" = "xyes"],
 531   [
 532     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 533       [
 534         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 535       ],
 536       [
 537         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 538       ],
 539       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 540     )
 541   ]
 542 )
 543 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 544
 545
 546
 547 # check for dlopen
 548 AC_CHECK_LIB([dl], [dlopen],
 549   [DL_LIBS="-ldl"],
 550   [
 551     #libdl not found, check for dlopen in libc.
 552     AC_CHECK_LIB([c], [dlopen],
 553       [DL_LIBS="-lc"],
 554       [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
 555     )
 556   ]
 557 )
 558 AC_SUBST(DL_LIBS)
 559
 560 # Check for fmemopen
 561 AC_CHECK_LIB([c], [fmemopen],
 562 [
 563         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 564 ]
 565 )
 566
 567 # Check for open_memstream
 568 AC_CHECK_LIB([c], [open_memstream],
 569 [
 570         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 571 ]
 572 )
 573
 574 # check for libpfm
 575 AC_CHECK_LIB([pfm], [pfm_initialize],
 576              [
 577               have_libpfm=yes
 578               ])
 579 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 580
 581 AC_ARG_ENABLE([git-version],
 582               [AC_HELP_STRING([--disable-git-version],
 583                               [Do not use the git version for the build])],
 584               [have_git_version=$enableval], [have_git_version=yes]
 585 )
 586
 587 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 588         [test "x${have_git_version}" = "xyes"])
 589
 590 # For Python
 591 # SWIG version needed or newer:
 592 swig_version=2.0.0
 593
 594 AC_ARG_ENABLE([python-bindings],
 595               [AC_HELP_STRING([--enable-python-bindings],
 596                               [compile Python bindings])],
 597               [enable_python_binding=$enableval], [enable_python_binding=no])
 598
 599 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 600
 601 if test "x$enable_python_binding" = xyes; then
 602   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 603   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 604   AM_PATH_PYTHON([3.0])
 605
 606   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 607   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 608   AS_IF([test -z "$PYTHON_INCLUDE"], [
 609     AS_IF([test -z "$PYTHON_CONFIG"], [
 610       AC_PATH_PROGS([PYTHON_CONFIG],
 611                     [python$PYTHON_VERSION-config python-config],
 612                     [no],
 613                     [`dirname $PYTHON`])
 614       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 615     ])
 616     AC_MSG_CHECKING([python include flags])
 617     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 618     AC_MSG_RESULT([$PYTHON_INCLUDE])
 619   ])
 620
 621 else
 622     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 623 [if you want Python bindings.])
 624
 625 fi
 626
 627 # Epoll check. If not present, the build will fallback on poll() API
 628 AX_HAVE_EPOLL(
 629         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 630         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 631 )
 632 AX_CONFIG_FEATURE(
 633         [epoll], [This platform supports epoll(7)],
 634         [HAVE_EPOLL], [This platform supports epoll(7).],
 635         [enable_epoll="yes"], [enable_epoll="no"]
 636 )
 637 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 638
 639 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 640 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 641
 642 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 643         AX_JAVA_OPTIONS
 644         AX_PROG_JAVAC
 645         AX_PROG_JAVA
 646         AX_PROG_JAR
 647
 648         AX_CHECK_CLASSPATH
 649
 650         # Check for Java UST agent common class first
 651         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 652         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 653                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 654         fi
 655
 656         if test "x$test_java_agent_jul" = "xyes"; then
 657                 # Check for JUL agent class
 658                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 659                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 660                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 661                 fi
 662         fi
 663
 664         if test "x$test_java_agent_log4j" = "xyes"; then
 665                 # Check for Log4j agent class
 666                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 667                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 668                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 669                 fi
 670
 671                 # Check for Log4j class
 672                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 673                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 674                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 675                 fi
 676         fi
 677 fi
 678
 679 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 680 # is not distributed in tarballs
 681 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 682 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 683
 684 # enable building man pages (user's intention)
 685 AC_ARG_ENABLE(
 686         man-pages,
 687         AS_HELP_STRING(
 688                 [--disable-man-pages],
 689                 [Do not build and install man pages (already built in a distributed tarball)]
 690         ),
 691         [man_pages_opt=$enableval],
 692         [man_pages_opt=yes]
 693 )
 694
 695 # check for asciidoc and xmlto if we enabled building the man pages
 696 have_asciidoc_xmlto=no
 697 warn_prebuilt_man_pages=no
 698
 699 AS_IF([test "x$man_pages_opt" = "xyes"], [
 700         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 701         AC_PATH_PROG([XMLTO], [xmlto], [no])
 702
 703         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 704                 AS_IF([test "x$in_git_repo" = "xyes"], [
 705                         # this is an error because we're in the Git repo, which
 706                         # means the man pages are not already generated for us,
 707                         # thus asciidoc/xmlto are required because we were asked
 708                         # to build the man pages
 709                         AC_MSG_ERROR([
 710 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 711 --disable-man-pages to disable building the man pages, in which case
 712 they will not be installed.
 713                         ])
 714                 ], [
 715                         # only warn here: since we're in the tarball, the man
 716                         # pages should already be generated at this point, thus
 717                         # asciidoc/xmlto are not strictly required
 718                         warn_prebuilt_man_pages=yes
 719                 ])
 720         ], [
 721                 have_asciidoc_xmlto=yes
 722         ])
 723 ])
 724
 725 # export man page build condition: build the man pages if the user
 726 # asked for it, and if the tools are available
 727 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 728 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 729
 730 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 731
 732 # embedded --help message
 733 AC_ARG_ENABLE(
 734         [embedded-help],
 735         AS_HELP_STRING(
 736                 [--enable-embedded-help],
 737                 [Embed the --help messages in the executable files]
 738         ),
 739         [embedded_help=$enableval],
 740         [embedded_help=no]
 741 )
 742 AS_IF([test "x$embedded_help" = "xyes"], [
 743         AS_IF([test "x$man_pages_opt" = "xno"], [
 744                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 745         ])
 746         AC_PATH_PROG([man_prog_path], [man], [no])
 747         AS_IF([test "x$man_prog_path" = "xno"], [
 748                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 749         ])
 750         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 751         AC_SUBST([MANPROG], [$man_prog_path])
 752 ])
 753 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 754
 755 # Python agent test
 756 UST_PYTHON_AGENT="lttngust"
 757
 758 AC_ARG_ENABLE(test-python2-agent,
 759         AS_HELP_STRING([--enable-test-python2-agent],
 760                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 761         ),[:],[test_python2_agent_autodetect=yes]
 762 )
 763
 764 AC_ARG_ENABLE(test-python3-agent,
 765         AS_HELP_STRING([--enable-test-python3-agent],
 766                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 767         ),[:],[test_python3_agent_autodetect=yes]
 768 )
 769
 770 AC_ARG_ENABLE(test-python-agent-all,
 771         AS_HELP_STRING([--enable-test-python-agent-all],
 772                 [enable test for all python{2/3} agent.]
 773         ),
 774 )
 775
 776 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 777        unset test_python2_agent_autodetect
 778        unset test_python3_agent_autodetect
 779 ])
 780
 781 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 782        enable_test_python2_agent=yes
 783        enable_test_python3_agent=yes
 784 ])
 785
 786 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 787        enable_test_python2_agent=no
 788        enable_test_python3_agent=no
 789 ])
 790
 791
 792 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 793         AS_IF([test -z "$PYTHON2"], [
 794                         PYTHON2=python2
 795                 ], [
 796                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 797         ])
 798
 799         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 800         AS_IF([test -z "$PYTHON2_BIN"], [
 801                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 802                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 803                 ])
 804         ], [
 805                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 806                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 807                         PYTHON2_AGENT=$PYTHON2_BIN
 808                         AC_MSG_RESULT([yes])
 809                         RUN_PYTHON_AGENT_TEST=yes
 810                 ], [
 811                         AC_MSG_RESULT([no])
 812                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 813                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 814                         ])
 815                 ])
 816
 817         ])
 818
 819 ])
 820
 821 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 822         AS_IF([test -z "$PYTHON3"], [
 823                 PYTHON3=python3
 824         ], [
 825                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 826         ])
 827
 828         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 829         AS_IF([test -z "$PYTHON3_BIN"], [
 830                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 831                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 832                 ])
 833         ], [
 834                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 835                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 836                         PYTHON3_AGENT=$PYTHON3_BIN
 837                         AC_MSG_RESULT([yes])
 838                         RUN_PYTHON_AGENT_TEST=yes
 839                 ], [
 840                         AC_MSG_RESULT([no])
 841                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 842                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 843                         ])
 844                 ])
 845
 846         ])
 847 ])
 848 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 849 AC_SUBST([PYTHON2_AGENT])
 850 AC_SUBST([PYTHON3_AGENT])
 851
 852 # Arguments for binaries build exclusion
 853 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 854 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 855               [Disable the build of lttng-consumerd binaries]))
 856 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 857 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 858               [Disable the build of lttng-relayd binaries]))
 859 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 860               [Disable the build of lttng-sessiond binaries]))
 861 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 862               [Disable the build of the extra components]))
 863
 864
 865 # Always build libconfig since it a dependency of libcommon
 866 build_lib_config=yes
 867
 868 build_lib_compat=no
 869 build_lib_consumer=no
 870 build_lib_hashtable=no
 871 build_lib_health=no
 872 build_lib_index=no
 873 build_lib_kernel_consumer=no
 874 build_lib_kernel_ctl=no
 875 build_lib_lttng_ctl=no
 876 build_lib_relayd=no
 877 build_lib_sessiond_comm=no
 878 build_lib_testpoint=no
 879 build_lib_ust_consumer=no
 880
 881 # There is an overlap for enabled dependencies, but this makes everything
 882 # simpler. libcommon and libconfig are always compiled so they are not repeated
 883 # here.
 884
 885 # Enable binary dependencies.
 886 AS_IF([test x$enable_bin_lttng != xno],
 887       [
 888        build_lib_lttng_ctl=yes
 889       ]
 890 )
 891
 892 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 893       [
 894        build_lib_consumer=yes
 895        build_lib_sessiond_comm=yes
 896        build_lib_index=yes
 897        build_lib_health=yes
 898        build_lib_testpoint=yes
 899       ]
 900 )
 901
 902 AS_IF([test x$enable_bin_lttng_crash != xno],
 903       # Do nothing since libconfig and libcommon are built by default.
 904       []
 905 )
 906
 907 AS_IF([test x$enable_bin_lttng_relayd != xno],
 908       [
 909        build_lib_lttng_ctl=yes
 910        build_lib_sessiond_comm=yes
 911        build_lib_hashtable=yes
 912        build_lib_compat=yes
 913        build_lib_index=yes
 914        build_lib_health=yes
 915        build_lib_testpoint=yes
 916       ]
 917 )
 918 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 919       [
 920        build_lib_lttng_ctl=yes
 921        build_lib_sessiond_comm=yes
 922        build_lib_kernel_ctl=yes
 923        build_lib_hashtable=yes
 924        build_lib_compat=yes
 925        build_lib_relayd=yes
 926        build_lib_testpoint=yes
 927        build_lib_health=yes
 928        build_lib_health=yes
 929       ]
 930 )
 931
 932 # Libraries dependencies enabling
 933 AS_IF([test x$build_lib_lttng_ctl = xyes],
 934       [
 935        build_lib_sessiond_comm=yes
 936        build_lib_hashtable=yes
 937       ]
 938 )
 939
 940 AS_IF([test x$build_lib_consumer = xyes],
 941       [
 942        build_lib_sessiond_comm=yes
 943        build_lib_kernel_consumer=yes
 944        build_lib_hashtable=yes
 945        build_lib_compat=yes
 946        build_lib_relayd=yes
 947        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 948       ]
 949 )
 950
 951 AS_IF([test x$build_lib_kernel_consumer = xyes],
 952       [
 953        build_lib_kernel_ctl=yes
 954        build_lib_relayd=yes
 955       ]
 956 )
 957
 958 AS_IF([test x$build_lib_relayd = xyes],
 959       [
 960        build_lib_sessiond_comm=yes
 961       ]
 962 )
 963
 964
 965 # Export binaries build conditions.
 966 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 967 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 968 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 969 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 970 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 971
 972 # Export the tests and extras build conditions.
 973 AS_IF([\
 974 test "x$enable_bin_lttng" != "xno" && \
 975 test "x$enable_bin_lttng_consumerd" != "xno" && \
 976 test "x$enable_bin_lttng_crash" != "xno" && \
 977 test "x$enable_bin_lttng_relayd" != "xno" && \
 978 test "x$enable_bin_lttng_sessiond" != "xno"],
 979 [build_tests=yes],
 980 [build_tests=no]
 981 )
 982
 983 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 984 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 985
 986 # Export libraries build conditions.
 987 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 988 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 989 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 990 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 991 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 992 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 993 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 994 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 995 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 996 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 997 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 998 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 999 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1000
1001 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1002 AC_SUBST(AM_CFLAGS)
1003
1004 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1005 AC_SUBST(AM_CPPFLAGS)
1006
1007 lttngincludedir="${includedir}/lttng"
1008 AC_SUBST(lttngincludedir)
1009
1010 lttngactionincludedir="${includedir}/lttng/action"
1011 AC_SUBST(lttngactionincludedir)
1012
1013 lttngconditionincludedir="${includedir}/lttng/condition"
1014 AC_SUBST(lttngconditionincludedir)
1015
1016 lttngnotificationincludedir="${includedir}/lttng/notification"
1017 AC_SUBST(lttngnotificationincludedir)
1018
1019 lttngtriggerincludedir="${includedir}/lttng/trigger"
1020 AC_SUBST(lttngtriggerincludedir)
1021
1022 lttnglibexecdir="${libdir}/lttng/libexec"
1023 AC_SUBST(lttnglibexecdir)
1024
1025 AC_CONFIG_FILES([
1026         Makefile
1027         doc/Makefile
1028         doc/man/Makefile
1029         doc/man/asciidoc-attrs.conf
1030         include/Makefile
1031         extras/Makefile
1032         extras/bindings/Makefile
1033         extras/bindings/swig/Makefile
1034         extras/bindings/swig/python/Makefile
1035         extras/core-handler/Makefile
1036         src/Makefile
1037         src/common/Makefile
1038         src/common/kernel-ctl/Makefile
1039         src/common/kernel-consumer/Makefile
1040         src/common/consumer/Makefile
1041         src/common/ust-consumer/Makefile
1042         src/common/hashtable/Makefile
1043         src/common/sessiond-comm/Makefile
1044         src/common/compat/Makefile
1045         src/common/relayd/Makefile
1046         src/common/testpoint/Makefile
1047         src/common/index/Makefile
1048         src/common/health/Makefile
1049         src/common/config/Makefile
1050         src/common/string-utils/Makefile
1051         src/lib/Makefile
1052         src/lib/lttng-ctl/Makefile
1053         src/lib/lttng-ctl/filter/Makefile
1054         src/lib/lttng-ctl/lttng-ctl.pc
1055         src/bin/Makefile
1056         src/bin/lttng-consumerd/Makefile
1057         src/bin/lttng-sessiond/Makefile
1058         src/bin/lttng-relayd/Makefile
1059         src/bin/lttng/Makefile
1060         src/bin/lttng-crash/Makefile
1061         tests/Makefile
1062         tests/destructive/Makefile
1063         tests/regression/Makefile
1064         tests/regression/kernel/Makefile
1065         tests/regression/tools/Makefile
1066         tests/regression/tools/streaming/Makefile
1067         tests/regression/tools/filtering/Makefile
1068         tests/regression/tools/health/Makefile
1069         tests/regression/tools/tracefile-limits/Makefile
1070         tests/regression/tools/snapshots/Makefile
1071         tests/regression/tools/live/Makefile
1072         tests/regression/tools/exclusion/Makefile
1073         tests/regression/tools/save-load/Makefile
1074         tests/regression/tools/save-load/configuration/Makefile
1075         tests/regression/tools/mi/Makefile
1076         tests/regression/tools/wildcard/Makefile
1077         tests/regression/tools/crash/Makefile
1078         tests/regression/tools/regen-metadata/Makefile
1079         tests/regression/tools/regen-statedump/Makefile
1080         tests/regression/tools/notification/Makefile
1081         tests/regression/ust/Makefile
1082         tests/regression/ust/nprocesses/Makefile
1083         tests/regression/ust/high-throughput/Makefile
1084         tests/regression/ust/low-throughput/Makefile
1085         tests/regression/ust/before-after/Makefile
1086         tests/regression/ust/buffers-pid/Makefile
1087         tests/regression/ust/periodical-metadata-flush/Makefile
1088         tests/regression/ust/multi-session/Makefile
1089         tests/regression/ust/overlap/Makefile
1090         tests/regression/ust/overlap/demo/Makefile
1091         tests/regression/ust/linking/Makefile
1092         tests/regression/ust/daemon/Makefile
1093         tests/regression/ust/exit-fast/Makefile
1094         tests/regression/ust/fork/Makefile
1095         tests/regression/ust/libc-wrapper/Makefile
1096         tests/regression/ust/baddr-statedump/Makefile
1097         tests/regression/ust/ust-dl/Makefile
1098         tests/regression/ust/java-jul/Makefile
1099         tests/regression/ust/java-log4j/Makefile
1100         tests/regression/ust/python-logging/Makefile
1101         tests/regression/ust/getcpu-override/Makefile
1102         tests/regression/ust/clock-override/Makefile
1103         tests/regression/ust/type-declarations/Makefile
1104         tests/regression/ust/rotation-destroy-flush/Makefile
1105         tests/regression/ust/blocking/Makefile
1106         tests/stress/Makefile
1107         tests/unit/Makefile
1108         tests/unit/ini_config/Makefile
1109         tests/perf/Makefile
1110         tests/utils/Makefile
1111         tests/utils/tap/Makefile
1112         tests/utils/testapp/Makefile
1113         tests/utils/testapp/gen-ust-events/Makefile
1114         tests/utils/testapp/gen-ust-nevents/Makefile
1115         tests/utils/testapp/gen-ust-nevents-str/Makefile
1116         tests/utils/testapp/gen-ust-tracef/Makefile
1117 ])
1118
1119 # Inject variable into python test script.
1120 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1121 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1122 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1123 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1124
1125 AC_OUTPUT
1126
1127 #
1128 # Mini-report on what will be built.
1129 #
1130
1131 PPRINT_INIT
1132 PPRINT_SET_INDENT(1)
1133 PPRINT_SET_TS(38)
1134
1135 AS_ECHO
1136 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1137 AS_ECHO
1138
1139 AS_IF([test -n "$report_fold"], [
1140         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1141 ], [
1142         AS_ECHO("$version_description")
1143 ])
1144
1145 AS_ECHO
1146 PPRINT_SUBTITLE([Features])
1147
1148 # Target architecture we're building for.
1149 target_arch=$host_cpu
1150 [
1151 for f in $CFLAGS; do
1152         if test $f = "-m32"; then
1153                         target_arch="32-bit"
1154         elif test $f = "-m64"; then
1155                         target_arch="64-bit"
1156         fi
1157 done
1158 ]
1159 PPRINT_PROP_STRING([Target architecture], $target_arch)
1160
1161 # kmod enabled/disabled
1162 test "x$with_kmod" != "xno" && value=1 || value=0
1163 PPRINT_PROP_BOOL([libkmod support], $value)
1164
1165 # LTTng-UST enabled/disabled
1166 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1167 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1168
1169 AS_ECHO
1170 PPRINT_SUBTITLE([Binaries])
1171
1172 # List binaries to be built
1173 test x$enable_bin_lttng != xno && value=1 || value=0
1174 PPRINT_PROP_BOOL([lttng], $value)
1175
1176 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1177 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1178
1179 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1180 PPRINT_PROP_BOOL([lttng-crash], $value)
1181
1182 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1183 PPRINT_PROP_BOOL([lttng-relayd], $value)
1184
1185 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1186 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1187
1188 # Extras
1189 test x$enable_extras != xno && value=1 || value=0
1190 AS_ECHO
1191 PPRINT_SET_INDENT(0)
1192 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1193 PPRINT_SET_INDENT(1)
1194
1195 AS_ECHO
1196 PPRINT_SUBTITLE([Tests])
1197
1198 # Print clear message that tests won't be built
1199 AS_IF([test "x$build_tests" = "xno"],[
1200         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1201 ])
1202
1203 # LTTng UST Java agent JUL tests enabled/disabled
1204 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1205 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1206
1207 # LTTng UST Java agent Log4j tests enabled/disabled
1208 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1209 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1210
1211 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1212 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1213
1214 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1215 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1216
1217 #Python binding enabled/disabled
1218 test "x$enable_python_binding" = xyes && value=1 || value=0
1219 AS_ECHO
1220 PPRINT_SET_INDENT(0)
1221 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1222
1223 # man pages build enabled/disabled
1224 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1225
1226 AS_IF([test "x$man_pages_opt" != "xno"], [
1227         AS_IF([test "x$in_git_repo" = "xyes"], [
1228                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1229         ], [
1230                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1231                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1232                 ], [
1233                         PPRINT_PROP_STRING([build_man_pages_msg],
1234                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1235                                 $PPRINT_COLOR_SUBTITLE)
1236                 ])
1237         ])
1238 ], [
1239         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1240 ])
1241
1242 m4_popdef([build_man_pages_msg])
1243
1244 test "x$embedded_help" = xyes && value=1 || value=0
1245 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1246
1247 PPRINT_SET_INDENT(1)
1248
1249 report_bindir="`eval eval echo $bindir`"
1250 report_libdir="`eval eval echo $libdir`"
1251
1252 # Print the bindir and libdir this `make install' will install into.
1253 AS_ECHO
1254 PPRINT_SUBTITLE([Install directories])
1255 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1256 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1257
1258 AS_ECHO
1259 PPRINT_SUBTITLE([Search directories])
1260
1261 # If we build the sessiond, print the paths it will use
1262 AS_IF([test "$SESSIOND_BIN" = ""],[
1263         path="$report_bindir/lttng-sessiond"
1264 ],[
1265         path="$SESSIOND_BIN"
1266 ])
1267 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1268
1269 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1270         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1271 ],[
1272         path="$CONSUMERD32_BIN"
1273 ])
1274 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1275
1276 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1277         path="`eval eval echo $libdir`"
1278 ],[
1279         path="$CONSUMERD32_LIBDIR"
1280 ])
1281 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1282
1283 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1284         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1285 ],[
1286         path="$CONSUMERD64_BIN"
1287 ])
1288 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1289
1290 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1291         path="`eval eval echo $libdir`"
1292 ],[
1293         path="$CONSUMERD64_LIBDIR"
1294 ])
1295 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1296 PPRINT_SET_INDENT(0)
1297
1298 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1299         AS_ECHO
1300         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1301
1302 Note that the man pages are already built in this distribution tarball,
1303 therefore asciidoc and xmlto are only needed if you intend to modify
1304 their sources.
1305
1306 Also note that the installed man pages will contain the project's
1307 default command-line option and environment variable values.
1308
1309 Use --disable-man-pages to completely disable building and installing
1310 the man pages.])
1311 ])