src/lib/lttng-ctl/filter/filter-parser.y

   1 %{
   2 /*
   3  * filter-parser.y
   4  *
   5  * LTTng filter expression parser
   6  *
   7  * Copyright 2012 Mathieu Desnoyers <mathieu.desnoyers@efficios.com>
   8  *
   9  * SPDX-License-Identifier: LGPL-2.1-only
  10  *
  11  * Grammar inspired from http://www.quut.com/c/ANSI-C-grammar-y.html
  12  */
  13
  14 #include <stdio.h>
  15 #include <unistd.h>
  16 #include <string.h>
  17 #include <stdlib.h>
  18 #include <assert.h>
  19 #include <errno.h>
  20 #include <inttypes.h>
  21 #include "filter-ast.h"
  22 #include "filter-parser.h"
  23
  24 #include <common/macros.h>
  25
  26 #define WIDTH_u64_SCANF_IS_A_BROKEN_API "20"
  27 #define WIDTH_o64_SCANF_IS_A_BROKEN_API "22"
  28 #define WIDTH_x64_SCANF_IS_A_BROKEN_API "17"
  29 #define WIDTH_lg_SCANF_IS_A_BROKEN_API  "4096"  /* Hugely optimistic approximation */
  30
  31 LTTNG_HIDDEN
  32 int yydebug;
  33 LTTNG_HIDDEN
  34 int filter_parser_debug = 0;
  35
  36 LTTNG_HIDDEN
  37 int yyparse(struct filter_parser_ctx *parser_ctx, yyscan_t scanner);
  38 LTTNG_HIDDEN
  39 int yylex(union YYSTYPE *yyval, yyscan_t scanner);
  40 LTTNG_HIDDEN
  41 int yylex_init_extra(struct filter_parser_ctx *parser_ctx, yyscan_t * ptr_yy_globals);
  42 LTTNG_HIDDEN
  43 int yylex_destroy(yyscan_t yyparser_ctx);
  44 LTTNG_HIDDEN
  45 void yyrestart(FILE * in_str, yyscan_t parser_ctx);
  46
  47 struct gc_string {
  48         struct cds_list_head gc;
  49         size_t alloclen;
  50         char s[];
  51 };
  52
  53 static const char *node_type_to_str[] = {
  54         [ NODE_UNKNOWN ] = "NODE_UNKNOWN",
  55         [ NODE_ROOT ] = "NODE_ROOT",
  56         [ NODE_EXPRESSION ] = "NODE_EXPRESSION",
  57         [ NODE_OP ] = "NODE_OP",
  58         [ NODE_UNARY_OP ] = "NODE_UNARY_OP",
  59 };
  60
  61 LTTNG_HIDDEN
  62 const char *node_type(struct filter_node *node)
  63 {
  64         if (node->type < NR_NODE_TYPES)
  65                 return node_type_to_str[node->type];
  66         else
  67                 return NULL;
  68 }
  69
  70 static struct gc_string *gc_string_alloc(struct filter_parser_ctx *parser_ctx,
  71                                          size_t len)
  72 {
  73         struct gc_string *gstr;
  74         size_t alloclen;
  75
  76         /* TODO: could be faster with find first bit or glib Gstring */
  77         /* sizeof long to account for malloc header (int or long ?) */
  78         for (alloclen = 8; alloclen < sizeof(long) + sizeof(*gstr) + len;
  79              alloclen *= 2);
  80
  81         gstr = zmalloc(alloclen);
  82         if (!gstr) {
  83                 goto end;
  84         }
  85         cds_list_add(&gstr->gc, &parser_ctx->allocated_strings);
  86         gstr->alloclen = alloclen;
  87 end:
  88         return gstr;
  89 }
  90
  91 /*
  92  * note: never use gc_string_append on a string that has external references.
  93  * gsrc will be garbage collected immediately, and gstr might be.
  94  * Should only be used to append characters to a string literal or constant.
  95  */
  96 static
  97 struct gc_string *gc_string_append(struct filter_parser_ctx *parser_ctx,
  98                                    struct gc_string *gstr,
  99                                    struct gc_string *gsrc)
 100 {
 101         size_t newlen = strlen(gsrc->s) + strlen(gstr->s) + 1;
 102         size_t alloclen;
 103
 104         /* TODO: could be faster with find first bit or glib Gstring */
 105         /* sizeof long to account for malloc header (int or long ?) */
 106         for (alloclen = 8; alloclen < sizeof(long) + sizeof(*gstr) + newlen;
 107              alloclen *= 2);
 108
 109         if (alloclen > gstr->alloclen) {
 110                 struct gc_string *newgstr;
 111
 112                 newgstr = gc_string_alloc(parser_ctx, newlen);
 113                 strcpy(newgstr->s, gstr->s);
 114                 strcat(newgstr->s, gsrc->s);
 115                 cds_list_del(&gstr->gc);
 116                 free(gstr);
 117                 gstr = newgstr;
 118         } else {
 119                 strcat(gstr->s, gsrc->s);
 120         }
 121         cds_list_del(&gsrc->gc);
 122         free(gsrc);
 123         return gstr;
 124 }
 125
 126 LTTNG_HIDDEN
 127 void setstring(struct filter_parser_ctx *parser_ctx, YYSTYPE *lvalp, const char *src)
 128 {
 129         lvalp->gs = gc_string_alloc(parser_ctx, strlen(src) + 1);
 130         strcpy(lvalp->gs->s, src);
 131 }
 132
 133 static struct filter_node *make_node(struct filter_parser_ctx *scanner,
 134                                   enum node_type type)
 135 {
 136         struct filter_ast *ast = filter_parser_get_ast(scanner);
 137         struct filter_node *node;
 138
 139         node = zmalloc(sizeof(*node));
 140         if (!node)
 141                 return NULL;
 142         memset(node, 0, sizeof(*node));
 143         node->type = type;
 144         cds_list_add(&node->gc, &ast->allocated_nodes);
 145
 146         switch (type) {
 147         case NODE_ROOT:
 148                 fprintf(stderr, "[error] %s: trying to create root node\n", __func__);
 149                 break;
 150
 151         case NODE_EXPRESSION:
 152                 break;
 153         case NODE_OP:
 154                 break;
 155         case NODE_UNARY_OP:
 156                 break;
 157
 158         case NODE_UNKNOWN:
 159         default:
 160                 fprintf(stderr, "[error] %s: unknown node type %d\n", __func__,
 161                         (int) type);
 162                 break;
 163         }
 164
 165         return node;
 166 }
 167
 168 static struct filter_node *make_op_node(struct filter_parser_ctx *scanner,
 169                         enum op_type type,
 170                         struct filter_node *lchild,
 171                         struct filter_node *rchild)
 172 {
 173         struct filter_ast *ast = filter_parser_get_ast(scanner);
 174         struct filter_node *node;
 175
 176         node = zmalloc(sizeof(*node));
 177         if (!node)
 178                 return NULL;
 179         memset(node, 0, sizeof(*node));
 180         node->type = NODE_OP;
 181         cds_list_add(&node->gc, &ast->allocated_nodes);
 182         node->u.op.type = type;
 183         node->u.op.lchild = lchild;
 184         node->u.op.rchild = rchild;
 185         return node;
 186 }
 187
 188 static
 189 void yyerror(struct filter_parser_ctx *parser_ctx, yyscan_t scanner, const char *str)
 190 {
 191         fprintf(stderr, "error %s\n", str);
 192 }
 193
 194 #define parse_error(parser_ctx, str)                            \
 195 do {                                                            \
 196         yyerror(parser_ctx, parser_ctx->scanner, YY_("parse error: " str "\n"));        \
 197         YYERROR;                                                \
 198 } while (0)
 199
 200 static void free_strings(struct cds_list_head *list)
 201 {
 202         struct gc_string *gstr, *tmp;
 203
 204         cds_list_for_each_entry_safe(gstr, tmp, list, gc)
 205                 free(gstr);
 206 }
 207
 208 static struct filter_ast *filter_ast_alloc(void)
 209 {
 210         struct filter_ast *ast;
 211
 212         ast = zmalloc(sizeof(*ast));
 213         if (!ast)
 214                 return NULL;
 215         memset(ast, 0, sizeof(*ast));
 216         CDS_INIT_LIST_HEAD(&ast->allocated_nodes);
 217         ast->root.type = NODE_ROOT;
 218         return ast;
 219 }
 220
 221 static void filter_ast_free(struct filter_ast *ast)
 222 {
 223         struct filter_node *node, *tmp;
 224
 225         cds_list_for_each_entry_safe(node, tmp, &ast->allocated_nodes, gc)
 226                 free(node);
 227         free(ast);
 228 }
 229
 230 LTTNG_HIDDEN
 231 int filter_parser_ctx_append_ast(struct filter_parser_ctx *parser_ctx)
 232 {
 233         return yyparse(parser_ctx, parser_ctx->scanner);
 234 }
 235
 236 LTTNG_HIDDEN
 237 struct filter_parser_ctx *filter_parser_ctx_alloc(FILE *input)
 238 {
 239         struct filter_parser_ctx *parser_ctx;
 240         int ret;
 241
 242         yydebug = filter_parser_debug;
 243
 244         parser_ctx = zmalloc(sizeof(*parser_ctx));
 245         if (!parser_ctx)
 246                 return NULL;
 247         memset(parser_ctx, 0, sizeof(*parser_ctx));
 248
 249         ret = yylex_init_extra(parser_ctx, &parser_ctx->scanner);
 250         if (ret) {
 251                 fprintf(stderr, "yylex_init error\n");
 252                 goto cleanup_parser_ctx;
 253         }
 254         /* Start processing new stream */
 255         yyrestart(input, parser_ctx->scanner);
 256
 257         parser_ctx->ast = filter_ast_alloc();
 258         if (!parser_ctx->ast)
 259                 goto cleanup_lexer;
 260         CDS_INIT_LIST_HEAD(&parser_ctx->allocated_strings);
 261
 262         if (yydebug)
 263                 fprintf(stdout, "parser_ctx input is a%s.\n",
 264                         isatty(fileno(input)) ? "n interactive tty" :
 265                                                 " noninteractive file");
 266
 267         return parser_ctx;
 268
 269 cleanup_lexer:
 270         ret = yylex_destroy(parser_ctx->scanner);
 271         if (!ret)
 272                 fprintf(stderr, "yylex_destroy error\n");
 273 cleanup_parser_ctx:
 274         free(parser_ctx);
 275         return NULL;
 276 }
 277
 278 LTTNG_HIDDEN
 279 void filter_parser_ctx_free(struct filter_parser_ctx *parser_ctx)
 280 {
 281         int ret;
 282
 283         ret = yylex_destroy(parser_ctx->scanner);
 284         if (ret)
 285                 fprintf(stderr, "yylex_destroy error\n");
 286
 287         filter_ast_free(parser_ctx->ast);
 288         free_strings(&parser_ctx->allocated_strings);
 289         filter_ir_free(parser_ctx);
 290         free(parser_ctx->bytecode);
 291         free(parser_ctx->bytecode_reloc);
 292
 293         free(parser_ctx);
 294 }
 295
 296 %}
 297
 298 %code provides
 299 {
 300 #include "common/macros.h"
 301
 302 LTTNG_HIDDEN
 303 void setstring(struct filter_parser_ctx *parser_ctx, YYSTYPE *lvalp, const char *src);
 304 }
 305
 306 %define api.pure
 307         /* %locations */
 308 %parse-param {struct filter_parser_ctx *parser_ctx}
 309 %parse-param {yyscan_t scanner}
 310 %lex-param {yyscan_t scanner}
 311 %start translation_unit
 312 %token CHARACTER_CONSTANT_START SQUOTE STRING_LITERAL_START DQUOTE
 313 %token ESCSEQ CHAR_STRING_TOKEN
 314 %token DECIMAL_CONSTANT OCTAL_CONSTANT HEXADECIMAL_CONSTANT FLOAT_CONSTANT
 315 %token LSBRAC RSBRAC LPAREN RPAREN LBRAC RBRAC RARROW
 316 %token STAR PLUS MINUS
 317 %token MOD_OP DIV_OP RIGHT_OP LEFT_OP
 318 %token EQ_OP NE_OP LE_OP GE_OP LT_OP GT_OP AND_OP OR_OP NOT_OP
 319 %token ASSIGN COLON SEMICOLON DOTDOTDOT DOT EQUAL COMMA
 320 %token XOR_BIN AND_BIN OR_BIN NOT_BIN
 321
 322 %token <gs> IDENTIFIER GLOBAL_IDENTIFIER
 323 %token ERROR
 324 %union
 325 {
 326         long long ll;
 327         char c;
 328         struct gc_string *gs;
 329         struct filter_node *n;
 330 }
 331
 332 %type <gs> s_char s_char_sequence c_char c_char_sequence
 333
 334 %type <n> primary_expression
 335 %type <n> prefix_expression
 336 %type <n> prefix_expression_rec
 337 %type <n> postfix_expression
 338 %type <n> unary_expression
 339 %type <n> unary_operator
 340 %type <n> multiplicative_expression
 341 %type <n> additive_expression
 342 %type <n> shift_expression
 343 %type <n> relational_expression
 344 %type <n> equality_expression
 345 %type <n> and_expression
 346 %type <n> exclusive_or_expression
 347 %type <n> inclusive_or_expression
 348 %type <n> logical_and_expression
 349 %type <n> logical_or_expression
 350 %type <n> expression
 351 %type <n> identifiers
 352
 353 %%
 354
 355
 356 /* 1.5 Constants */
 357
 358 c_char_sequence:
 359                 c_char
 360                 {       $$ = $1;                                        }
 361         |       c_char_sequence c_char
 362                 {       $$ = gc_string_append(parser_ctx, $1, $2);              }
 363         ;
 364
 365 c_char:
 366                 CHAR_STRING_TOKEN
 367                 {       $$ = yylval.gs;                                 }
 368         |       ESCSEQ
 369                 {
 370                         parse_error(parser_ctx, "escape sequences not supported yet");
 371                 }
 372         ;
 373
 374 /* 1.6 String literals */
 375
 376 s_char_sequence:
 377                 s_char
 378                 {       $$ = $1;                                        }
 379         |       s_char_sequence s_char
 380                 {       $$ = gc_string_append(parser_ctx, $1, $2);              }
 381         ;
 382
 383 s_char:
 384                 CHAR_STRING_TOKEN
 385                 {       $$ = yylval.gs;                                 }
 386         |       ESCSEQ
 387                 {
 388                         parse_error(parser_ctx, "escape sequences not supported yet");
 389                 }
 390         ;
 391
 392 primary_expression:
 393                 DECIMAL_CONSTANT
 394                 {
 395                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 396                         $$->u.expression.type = AST_EXP_CONSTANT;
 397                         if (sscanf(yylval.gs->s, "%" WIDTH_u64_SCANF_IS_A_BROKEN_API SCNu64,
 398                                         &$$->u.expression.u.constant) != 1) {
 399                                 parse_error(parser_ctx, "cannot scanf decimal constant");
 400                         }
 401                 }
 402         |       OCTAL_CONSTANT
 403                 {
 404                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 405                         $$->u.expression.type = AST_EXP_CONSTANT;
 406                         if (!strcmp(yylval.gs->s, "0")) {
 407                                 $$->u.expression.u.constant = 0;
 408                         } else if (sscanf(yylval.gs->s, "0%" WIDTH_o64_SCANF_IS_A_BROKEN_API SCNo64,
 409                                         &$$->u.expression.u.constant) != 1) {
 410                                 parse_error(parser_ctx, "cannot scanf octal constant");
 411                         }
 412                 }
 413         |       HEXADECIMAL_CONSTANT
 414                 {
 415                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 416                         $$->u.expression.type = AST_EXP_CONSTANT;
 417                         if (sscanf(yylval.gs->s, "0x%" WIDTH_x64_SCANF_IS_A_BROKEN_API SCNx64,
 418                                         &$$->u.expression.u.constant) != 1) {
 419                                 parse_error(parser_ctx, "cannot scanf hexadecimal constant");
 420                         }
 421                 }
 422         |       FLOAT_CONSTANT
 423                 {
 424                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 425                         $$->u.expression.type = AST_EXP_FLOAT_CONSTANT;
 426                         if (sscanf(yylval.gs->s, "%" WIDTH_lg_SCANF_IS_A_BROKEN_API "lg",
 427                                         &$$->u.expression.u.float_constant) != 1) {
 428                                 parse_error(parser_ctx, "cannot scanf float constant");
 429                         }
 430                 }
 431         |       STRING_LITERAL_START DQUOTE
 432                 {
 433                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 434                         $$->u.expression.type = AST_EXP_STRING;
 435                         $$->u.expression.u.string = "";
 436                 }
 437         |       STRING_LITERAL_START s_char_sequence DQUOTE
 438                 {
 439                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 440                         $$->u.expression.type = AST_EXP_STRING;
 441                         $$->u.expression.u.string = $2->s;
 442                 }
 443         |       CHARACTER_CONSTANT_START c_char_sequence SQUOTE
 444                 {
 445                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 446                         $$->u.expression.type = AST_EXP_STRING;
 447                         $$->u.expression.u.string = $2->s;
 448                 }
 449         |       LPAREN expression RPAREN
 450                 {
 451                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 452                         $$->u.expression.type = AST_EXP_NESTED;
 453                         $$->u.expression.u.child = $2;
 454                 }
 455         ;
 456
 457 identifiers
 458         :       IDENTIFIER
 459                 {
 460                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 461                         $$->u.expression.type = AST_EXP_IDENTIFIER;
 462                         $$->u.expression.u.identifier = yylval.gs->s;
 463                 }
 464         |       GLOBAL_IDENTIFIER
 465                 {
 466                         $$ = make_node(parser_ctx, NODE_EXPRESSION);
 467                         $$->u.expression.type = AST_EXP_GLOBAL_IDENTIFIER;
 468                         $$->u.expression.u.identifier = yylval.gs->s;
 469                 }
 470         ;
 471
 472 prefix_expression_rec
 473         : LSBRAC unary_expression RSBRAC
 474                 {
 475                         $$ = $2;
 476                 }
 477         | LSBRAC unary_expression RSBRAC prefix_expression_rec
 478                 {
 479                         $$ = $2;
 480                         $$->u.expression.pre_op = AST_LINK_BRACKET;
 481                         $$->u.expression.prev = $4;
 482                 }
 483         ;
 484
 485 prefix_expression
 486         : identifiers
 487                 {
 488                         $$ = $1;
 489                 }
 490         | identifiers prefix_expression_rec
 491                 {
 492                         $$ = $1;
 493                         $$->u.expression.pre_op = AST_LINK_BRACKET;
 494                         $$->u.expression.next_bracket = $2;
 495                 }
 496         ;
 497
 498 postfix_expression
 499         : prefix_expression
 500                 {
 501                         $$ = $1;
 502                 }
 503         | postfix_expression DOT prefix_expression
 504                 {
 505                         $$ = $3;
 506                         $$->u.expression.post_op = AST_LINK_DOT;
 507                         $$->u.expression.prev = $1;
 508                 }
 509         | postfix_expression RARROW prefix_expression
 510                 {
 511                         $$ = $3;
 512                         $$->u.expression.post_op = AST_LINK_RARROW;
 513                         $$->u.expression.prev = $1;
 514                 }
 515         ;
 516
 517 unary_expression
 518         : postfix_expression
 519                 {       $$ = $1;                                        }
 520         | primary_expression
 521                 {       $$ = $1;                                        }
 522         | unary_operator unary_expression
 523                 {
 524                         $$ = $1;
 525                         $$->u.unary_op.child = $2;
 526                 }
 527         ;
 528
 529 unary_operator
 530         : PLUS
 531                 {
 532                         $$ = make_node(parser_ctx, NODE_UNARY_OP);
 533                         $$->u.unary_op.type = AST_UNARY_PLUS;
 534                 }
 535         | MINUS
 536                 {
 537                         $$ = make_node(parser_ctx, NODE_UNARY_OP);
 538                         $$->u.unary_op.type = AST_UNARY_MINUS;
 539                 }
 540         | NOT_OP
 541                 {
 542                         $$ = make_node(parser_ctx, NODE_UNARY_OP);
 543                         $$->u.unary_op.type = AST_UNARY_NOT;
 544                 }
 545         | NOT_BIN
 546                 {
 547                         $$ = make_node(parser_ctx, NODE_UNARY_OP);
 548                         $$->u.unary_op.type = AST_UNARY_BIT_NOT;
 549                 }
 550         ;
 551
 552 multiplicative_expression
 553         : unary_expression
 554                 {       $$ = $1;                                        }
 555         | multiplicative_expression STAR unary_expression
 556                 {
 557                         $$ = make_op_node(parser_ctx, AST_OP_MUL, $1, $3);
 558                 }
 559         | multiplicative_expression DIV_OP unary_expression
 560                 {
 561                         $$ = make_op_node(parser_ctx, AST_OP_DIV, $1, $3);
 562                 }
 563         | multiplicative_expression MOD_OP unary_expression
 564                 {
 565                         $$ = make_op_node(parser_ctx, AST_OP_MOD, $1, $3);
 566                 }
 567         ;
 568
 569 additive_expression
 570         : multiplicative_expression
 571                 {       $$ = $1;                                        }
 572         | additive_expression PLUS multiplicative_expression
 573                 {
 574                         $$ = make_op_node(parser_ctx, AST_OP_PLUS, $1, $3);
 575                 }
 576         | additive_expression MINUS multiplicative_expression
 577                 {
 578                         $$ = make_op_node(parser_ctx, AST_OP_MINUS, $1, $3);
 579                 }
 580         ;
 581
 582 shift_expression
 583         : additive_expression
 584                 {       $$ = $1;                                        }
 585         | shift_expression LEFT_OP additive_expression
 586                 {
 587                         $$ = make_op_node(parser_ctx, AST_OP_BIT_LSHIFT, $1, $3);
 588                 }
 589         | shift_expression RIGHT_OP additive_expression
 590                 {
 591                         $$ = make_op_node(parser_ctx, AST_OP_BIT_RSHIFT, $1, $3);
 592                 }
 593         ;
 594
 595 and_expression
 596         : shift_expression
 597                 {       $$ = $1;                                        }
 598         | and_expression AND_BIN shift_expression
 599                 {
 600                         $$ = make_op_node(parser_ctx, AST_OP_BIT_AND, $1, $3);
 601                 }
 602         ;
 603
 604 exclusive_or_expression
 605         : and_expression
 606                 {       $$ = $1;                                        }
 607         | exclusive_or_expression XOR_BIN and_expression
 608                 {
 609                         $$ = make_op_node(parser_ctx, AST_OP_BIT_XOR, $1, $3);
 610                 }
 611         ;
 612
 613 inclusive_or_expression
 614         : exclusive_or_expression
 615                 {       $$ = $1;                                        }
 616         | inclusive_or_expression OR_BIN exclusive_or_expression
 617                 {
 618                         $$ = make_op_node(parser_ctx, AST_OP_BIT_OR, $1, $3);
 619                 }
 620         ;
 621
 622 relational_expression
 623         : inclusive_or_expression
 624                 {       $$ = $1;                                        }
 625         | relational_expression LT_OP inclusive_or_expression
 626                 {
 627                         $$ = make_op_node(parser_ctx, AST_OP_LT, $1, $3);
 628                 }
 629         | relational_expression GT_OP inclusive_or_expression
 630                 {
 631                         $$ = make_op_node(parser_ctx, AST_OP_GT, $1, $3);
 632                 }
 633         | relational_expression LE_OP inclusive_or_expression
 634                 {
 635                         $$ = make_op_node(parser_ctx, AST_OP_LE, $1, $3);
 636                 }
 637         | relational_expression GE_OP inclusive_or_expression
 638                 {
 639                         $$ = make_op_node(parser_ctx, AST_OP_GE, $1, $3);
 640                 }
 641         ;
 642
 643 equality_expression
 644         : relational_expression
 645                 {       $$ = $1;                                        }
 646         | equality_expression EQ_OP relational_expression
 647                 {
 648                         $$ = make_op_node(parser_ctx, AST_OP_EQ, $1, $3);
 649                 }
 650         | equality_expression NE_OP relational_expression
 651                 {
 652                         $$ = make_op_node(parser_ctx, AST_OP_NE, $1, $3);
 653                 }
 654         ;
 655
 656 logical_and_expression
 657         : equality_expression
 658                 {       $$ = $1;                                        }
 659         | logical_and_expression AND_OP equality_expression
 660                 {
 661                         $$ = make_op_node(parser_ctx, AST_OP_AND, $1, $3);
 662                 }
 663         ;
 664
 665 logical_or_expression
 666         : logical_and_expression
 667                 {       $$ = $1;                                        }
 668         | logical_or_expression OR_OP logical_and_expression
 669                 {
 670                         $$ = make_op_node(parser_ctx, AST_OP_OR, $1, $3);
 671                 }
 672         ;
 673
 674 expression
 675         : logical_or_expression
 676                 {       $$ = $1;                                        }
 677         ;
 678
 679 translation_unit
 680         : expression
 681                 {
 682                         parser_ctx->ast->root.u.root.child = $1;
 683                 }
 684         ;