configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7
   8 # Project version information
   9 m4_define([ust_version_major], [2])
  10 m4_define([ust_version_minor], [13])
  11 m4_define([ust_version_patch], [5])
  12 m4_define([ust_version_dev_stage], [])
  13 m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
  14 m4_define([ust_version_name], [[Nordicité]])
  15 m4_define([ust_version_description], [[The product of a collaboration between Champ Libre and Boréale, this farmhouse IPA is brewed with Kveik yeast and Québec-grown barley, oats and juniper branches. The result is a remarkable fruity hazy golden IPA that offers a balanced touch of resinous and woodsy bitterness.]])
  16
  17 # Library version information of "liblttng-ust"
  18 # Following the numbering scheme proposed by libtool for the library version
  19 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  20 m4_define([ust_lib_version_current], [1])
  21 m4_define([ust_lib_version_revision], [0])
  22 m4_define([ust_lib_version_age], [0])
  23 m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)
  24
  25 # Library version information of "liblttng-ust-ctl"
  26 # Following the numbering scheme proposed by libtool for the library version
  27 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  28 m4_define([ust_ctl_lib_version_current], [5])
  29 m4_define([ust_ctl_lib_version_revision], [0])
  30 m4_define([ust_ctl_lib_version_age], [0])
  31 m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)
  32
  33
  34 ##                     ##
  35 ## Autoconf base setup ##
  36 ##                     ##
  37
  38 AC_PREREQ([2.69])
  39 AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])
  40
  41 AC_CONFIG_HEADERS([src/common/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
  42 AC_CONFIG_AUX_DIR([config])
  43 AC_CONFIG_MACRO_DIR([m4])
  44
  45 AC_CANONICAL_TARGET
  46 AC_CANONICAL_HOST
  47
  48
  49 ##                     ##
  50 ## Automake base setup ##
  51 ##                     ##
  52
  53 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  54 AM_MAINTAINER_MODE([enable])
  55
  56 # Enable silent rules by default
  57 AM_SILENT_RULES([yes])
  58
  59
  60 ##                               ##
  61 ## OS and Arch specific defaults ##
  62 ##                               ##
  63
  64 # Set os specific options
  65 AS_CASE([$host_os],
  66   [freebsd*], [AE_FEATURE_DISABLE([numa])]
  67 )
  68
  69 # Set architecture specific options
  70 AS_CASE([$host_cpu],
  71   [i[[3456]]86], [],
  72   [x86_64], [],
  73   [amd64], [],
  74   [powerpc], [],
  75   [ppc64], [],
  76   [ppc64le], [],
  77   [powerpc64], [],
  78   [powerpc64le], [],
  79   [s390], [],
  80   [s390x], [],
  81   [arm*], [AE_FEATURE_DISABLE([numa])],
  82   [aarch64*], [],
  83   [mips*], [],
  84   [tile*], [],
  85   [
  86     unsupported_arch="yes"
  87   ])
  88
  89
  90 ##                   ##
  91 ## C compiler checks ##
  92 ##                   ##
  93
  94 # Choose the C compiler
  95 AC_PROG_CC
  96 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  97 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  98
  99 # Make sure the C compiler supports C99
 100 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
 101
 102 # Enable available system extensions and LFS support
 103 AC_USE_SYSTEM_EXTENSIONS
 104 AC_SYS_LARGEFILE
 105
 106 # Make sure the C compiler supports __attribute__
 107 AX_C___ATTRIBUTE__
 108 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 109   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 110
 111 # Make sure we have pthread support
 112 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 113
 114 # Make sure the C compiler supports weak symbols
 115 AX_SYS_WEAK_ALIAS
 116 AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
 117   [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_INLINE
 121 AC_C_TYPEOF
 122 AC_TYPE_INT16_T
 123 AC_TYPE_INT32_T
 124 AC_TYPE_INT64_T
 125 AC_TYPE_INT8_T
 126 AC_TYPE_MODE_T
 127 AC_TYPE_OFF_T
 128 AC_TYPE_PID_T
 129 AC_TYPE_SIZE_T
 130 AC_TYPE_SSIZE_T
 131 AC_TYPE_UID_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_UINT64_T
 135 AC_TYPE_UINT8_T
 136 AC_CHECK_TYPES([ptrdiff_t])
 137
 138 # Detect warning flags supported by the C compiler and append them to
 139 # WARN_CFLAGS.
 140 m4_define([WARN_FLAGS_LIST], [ dnl
 141   -Wall dnl
 142   -Wextra dnl
 143   -Wmissing-prototypes dnl
 144   -Wmissing-declarations dnl
 145   -Wnull-dereference dnl
 146   -Wundef dnl
 147   -Wshadow dnl
 148   -Wjump-misses-init dnl
 149   -Wsuggest-attribute=format dnl
 150   -Wtautological-constant-out-of-range-compare dnl
 151   -Wnested-externs dnl
 152   -Wwrite-strings dnl
 153   -Wformat=2 dnl
 154   -Wstrict-aliasing dnl
 155   -Wmissing-noreturn dnl
 156   -Winit-self dnl
 157   -Wduplicated-cond dnl
 158   -Wduplicated-branches dnl
 159   -Wlogical-op dnl
 160   dnl These would require reworking the tracepoint macros
 161   dnl-Wredundant-decls dnl
 162   -Wno-sign-compare dnl
 163   -Wno-missing-field-initializers dnl
 164   -Wno-null-dereference dnl
 165   -Wno-gnu dnl Disable warnings for GNU extensions on Clang
 166 ])
 167
 168 # Pass -Werror as an extra flag during the test: this is needed to make the
 169 # -Wunknown-warning-option diagnostic fatal with clang.
 170 AC_LANG_PUSH([C])
 171 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
 172 AC_LANG_POP([C])
 173
 174 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 175 # written in such a way that it triggers warnings with the following warning
 176 # flags.  So they would always end up disabled if we put them there, because
 177 # the test program would not build.
 178 #
 179 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
 180 # Clang >= 3.3 (required by the project) and are only valid for C code.
 181 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 182
 183 # Disable 'strict aliasing' if the compiler supports it.
 184 AC_LANG_PUSH([C])
 185 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 186 AC_LANG_POP([C])
 187
 188
 189 ##                     ##
 190 ## C++ compiler checks ##
 191 ##                     ##
 192
 193 # Find an optional C++11 compiler without GNU extensions (-std=c++11)
 194 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 195
 196 AS_IF([test "$HAVE_CXX11" = "1"], [
 197   # Pass -Werror as an extra flag during the test: this is needed to make the
 198   # -Wunknown-warning-option diagnostic fatal with clang.
 199   AC_LANG_PUSH([C++])
 200   AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST -Wno-undef -Wno-duplicated-branches], [WARN_CXXFLAGS], [-Werror])
 201   AC_LANG_POP([C++])
 202 ])
 203
 204
 205 ##               ##
 206 ## Header checks ##
 207 ##               ##
 208
 209 AC_HEADER_STDBOOL
 210 AC_CHECK_HEADERS([ \
 211   arpa/inet.h \
 212   dlfcn.h \
 213   fcntl.h \
 214   float.h \
 215   limits.h \
 216   linux/perf_event.h \
 217   locale.h \
 218   stddef.h \
 219   sys/socket.h \
 220   sys/time.h \
 221   wchar.h \
 222 ])
 223
 224 # Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
 225 AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
 226   AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
 227 ])
 228
 229
 230 ##                 ##
 231 ## Programs checks ##
 232 ##                 ##
 233
 234 AM_PROG_AR
 235 AC_PROG_SED
 236 AC_PROG_GREP
 237 AC_PROG_LN_S
 238 AC_PROG_MKDIR_P
 239 AC_PROG_MAKE_SET
 240 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 241 AC_CHECK_PROGS([CMAKE], [cmake])
 242 AC_CHECK_PROGS([FOLD], [fold])
 243 AC_CHECK_PROGS([XMLTO], [xmlto])
 244
 245 AM_PATH_PYTHON([2.7], [], [PYTHON=""])
 246
 247 # Initialize and configure libtool
 248 LT_INIT([disable-static])
 249
 250
 251 ##                ##
 252 ## Library checks ##
 253 ##                ##
 254
 255 AC_FUNC_CHOWN
 256 AC_FUNC_FORK
 257 AC_FUNC_MMAP
 258 AC_FUNC_STRERROR_R
 259 AC_FUNC_STRNLEN
 260 AC_CHECK_FUNCS([ \
 261   atexit \
 262   clock_gettime \
 263   ftruncate \
 264   getpagesize \
 265   gettid \
 266   gettimeofday \
 267   localeconv \
 268   memchr \
 269   memmove \
 270   memset \
 271   mkdir \
 272   munmap \
 273   realpath \
 274   sched_getcpu \
 275   socket \
 276   strchr \
 277   strdup \
 278   strerror \
 279   strtol \
 280   strtoul \
 281   sysconf \
 282 ])
 283
 284 # AC_FUNC_MALLOC causes problems when cross-compiling.
 285 #AC_FUNC_MALLOC
 286 #AC_FUNC_REALLOC
 287
 288 # Check for pthread_setname_np and its signature
 289 LTTNG_PTHREAD_SETNAME_NP
 290 LTTNG_PTHREAD_GETNAME_NP
 291
 292 # Check dor dlopen() in -ldl or -lc
 293 AC_CHECK_LIB([dl], [dlopen], [
 294   libdl_name=dl
 295   DL_LIBS="-ldl"
 296 ], [
 297   # dlopen not found in libdl, check in libc
 298   AC_CHECK_LIB([c], [dlopen], [
 299     libdl_name=c
 300     DL_LIBS="-lc"
 301   ], [
 302     AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 303   ])
 304 ])
 305 AC_SUBST(DL_LIBS)
 306
 307 # Check if libdl has dlmopen()
 308 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 309   AC_DEFINE([HAVE_DLMOPEN], [1], [Define to 1 if dlmopen is available.])
 310 ])
 311
 312 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 313 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 314
 315
 316 ##                 ##
 317 ## User variables  ##
 318 ##                 ##
 319
 320 # Additional variables captured during ./configure
 321
 322 AC_ARG_VAR([CLASSPATH], [Java class path])
 323
 324
 325 ##                              ##
 326 ## Optionnal features selection ##
 327 ##                              ##
 328
 329 # numa integration
 330 # Enabled by default, except on some platforms
 331 AE_FEATURE_DEFAULT_ENABLE
 332 AE_FEATURE([numa],[disable NUMA support])
 333
 334 # Java JNI interface library
 335 # Disabled by default
 336 AE_FEATURE_DEFAULT_DISABLE
 337 AE_FEATURE([jni-interface], [build JNI interface between C and Java])
 338
 339 # Build the Java Logging API agent
 340 # Disabled by default
 341 AE_FEATURE_DEFAULT_DISABLE
 342 AE_FEATURE([java-agent-jul],[build the LTTng UST Java agent with JUL support])
 343
 344 # Build the Java Log4j 1.x agent
 345 # Disabled by default
 346 AE_FEATURE_DEFAULT_DISABLE
 347 AE_FEATURE([java-agent-log4j],[build the LTTng UST Java agent with Log4j 1.x support])
 348
 349 # Build the Java Log4j 2.x agent
 350 # Disabled by default
 351 AE_FEATURE_DEFAULT_DISABLE
 352 AE_FEATURE([java-agent-log4j2],[build the LTTng UST Java agent with Log4j 2.x support])
 353
 354 # Build both Java agents
 355 # Disabled by default
 356 AE_FEATURE_DEFAULT_DISABLE
 357 AE_FEATURE([java-agent-all],[build the LTTng UST Java agent with all supported backends])
 358
 359 # Build the Python agent
 360 # Disabled by default
 361 AE_FEATURE_DEFAULT_DISABLE
 362 AE_FEATURE([python-agent],[build the LTTng UST Python agent])
 363
 364 # Build the examples
 365 # Disabled by default
 366 AE_FEATURE_DEFAULT_ENABLE
 367 AE_FEATURE([examples],[Do not build and install examples])
 368
 369 # Man pages
 370 # Enabled by default
 371 AE_FEATURE_DEFAULT_ENABLE
 372 AE_FEATURE([man-pages],[Do not build and install man pages (already built in a distributed tarball)])
 373
 374 # Custom upgrade conflicting symbols
 375 # Disabled by default
 376 AE_FEATURE_DEFAULT_DISABLE
 377 AE_FEATURE([custom-upgrade-conflicting-symbols],[Emit and use original symbols for custom upgrade from 2.12 to 2.13])
 378
 379 # Systemtap sdt.h integration
 380 # Disabled by default
 381 AC_ARG_WITH([sdt],
 382   [AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])]
 383 )
 384
 385 # Override the default runtime directory
 386 AC_ARG_WITH([lttng-system-rundir], [
 387 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 388 ], [
 389   lttng_system_rundir="$withval"
 390 ], [
 391   lttng_system_rundir="/var/run/lttng"
 392 ])
 393
 394 # Add the java command line arguments like '--wit-java-prefix'
 395 AX_JAVA_OPTIONS
 396
 397
 398 ##                                          ##
 399 ## Check for conflicting features selection ##
 400 ##                                          ##
 401
 402 AE_IF_FEATURE_DISABLED([shared], [
 403   AC_MSG_ERROR(LTTng-UST requires shared libraries to be enabled)
 404 ])
 405
 406 AE_IF_FEATURE_ENABLED([java-agent-all], [
 407   AE_FEATURE_ENABLE([java-agent-jul])
 408   AE_FEATURE_ENABLE([java-agent-log4j])
 409   # This backport to a stable branch requires the explicit use of
 410   # '--enable-java-agent-log4j2' to avoid introducing a new dependency in
 411   # an existing configuration.
 412   dnl AE_FEATURE_ENABLE([java-agent-lkog4j2])
 413 ])
 414
 415
 416 ##                                          ##
 417 ## Check for optional features dependencies ##
 418 ##                                          ##
 419
 420 # The numa integration requires libnuma
 421 AE_IF_FEATURE_ENABLED([numa], [
 422   AC_CHECK_LIB([numa], [numa_available], [
 423     AC_DEFINE([HAVE_LIBNUMA], [1], [Define to 1 if libnuma is available.])
 424   ], [
 425     AC_MSG_ERROR([dnl
 426 libnuma is not available. Please either install it (e.g. libnuma-dev) or use
 427 [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure
 428 argument to disable NUMA support.
 429     ])
 430   ])
 431 ])
 432
 433 # The JNI interface and Java Agents require a working Java JDK
 434 AS_IF([AE_IS_FEATURE_ENABLED([jni-interface]) || AE_IS_FEATURE_ENABLED([java-agent-jul]) || \
 435     AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2])], [
 436   AX_PROG_JAVAC
 437   AX_PROG_JAVA
 438   AX_PROG_JAR
 439
 440   # Get the CPPFLAGS required to build jni libaries
 441   AX_JNI_INCLUDE_DIR
 442   for jni_include_dir in $JNI_INCLUDE_DIRS; do
 443     JNI_CPPFLAGS="$JNI_CPPFLAGS -I$jni_include_dir"
 444   done
 445
 446   # Check for javah and jni.h
 447   saved_CPPFLAGS="$CPPFLAGS"
 448   CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 449   AX_PROG_JAVAH
 450   CPPFLAGS="$saved_CPPFLAGS"
 451 ])
 452
 453 # The log4j 1.x agent requires the log4j jar in the classpath
 454 AE_IF_FEATURE_ENABLED([java-agent-log4j], [
 455   AX_CHECK_CLASS([org.apache.log4j.Logger])
 456   AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 457     AC_MSG_ERROR([dnl
 458 The UST Java agent support for log4j was requested but the Log4j classes were
 459 not found. Please specify the location of the Log4j jar via the Java CLASSPATH
 460 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j.jar"
 461
 462 Current CLASSPATH: "$CLASSPATH"
 463     ])
 464   ])
 465 ])
 466
 467 # The log4j 2.x agent requires the log4j core and api jars in the classpath
 468 AE_IF_FEATURE_ENABLED([java-agent-log4j2], [
 469   AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 470   AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 471   AS_IF([test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"], [
 472     AC_MSG_ERROR([dnl
 473 The UST Java agent support for log4j was requested but the Log4j classes were
 474 not found. Please specify the location of the Log4j API and core 2.x jars via the Java CLASSPATH
 475 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"
 476
 477 Current CLASSPATH: "$CLASSPATH"
 478     ])
 479   ])
 480 ])
 481
 482 # The python agent requires a python interpreter
 483 AE_IF_FEATURE_ENABLED([python-agent], [
 484   AS_IF([test "x$PYTHON" = "x"], [
 485     AC_MSG_ERROR([dnl
 486 Cannot find a suitable python interpreter. You can override it with the PYTHON
 487 environment variable.
 488     ])
 489   ])
 490 ])
 491
 492 # Check for asciidoc and xmlto if we enabled building the man pages.
 493 AE_IF_FEATURE_ENABLED([man-pages], [
 494   AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 495     AE_IF_IN_GIT_REPO([
 496       # This is an error because we're in the Git repo, which
 497       # means the man pages are not already generated for us,
 498       # thus asciidoc/xmlto are required because we were asked
 499       # to build the man pages.
 500       AC_MSG_ERROR([dnl
 501 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 502 --disable-man-pages to disable building the man pages, in which case
 503 they will not be installed.
 504       ])
 505     ], [
 506       # Only warn here: since we're in the tarball, the man
 507       # pages should already be generated at this point, thus
 508       # asciidoc/xmlto are not strictly required.
 509       warn_prebuilt_man_pages=yes
 510     ])
 511   ], [
 512     have_asciidoc_xmlto=yes
 513   ])
 514 ])
 515
 516 # Emit and use original symbols for custom upgrade from 2.12 to 2.13
 517 AE_IF_FEATURE_ENABLED([custom-upgrade-conflicting-symbols], [
 518   AC_DEFINE([LTTNG_UST_CUSTOM_UPGRADE_CONFLICTING_SYMBOLS], [1], [Emit and use original symbols for custom upgrade from 2.12 to 2.13])
 519 ])
 520
 521 AS_IF([test "x$with_sdt" = "xyes"], [
 522   AC_MSG_CHECKING([STAP_PROBEV()])
 523   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 524     #define SDT_USE_VARIADIC
 525     #include <sys/sdt.h>
 526     void fct(void)
 527     {
 528       STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 529     }
 530   ]])], [
 531     AC_MSG_RESULT([yes])
 532     AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1], [SystemTap integration via sdt.h])
 533   ], [
 534     AC_MSG_RESULT([no])
 535     AC_MSG_ERROR([dnl
 536 The sdt.h integration was requested but the STAP_PROBEV define cannot be used.
 537 Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify
 538 a non-standard path to sys/sdt.h
 539     ])
 540   ])
 541 ])
 542
 543
 544 ##                                                                    ##
 545 ## Set defines for optional features conditionnals in the source code ##
 546 ##                                                                    ##
 547
 548 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"], [LTTng system runtime directory])
 549
 550 # Defined in include/lttng/ust-version.h
 551 AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
 552 AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
 553 AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
 554 AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
 555 AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
 556 AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
 557
 558
 559 ##                                                                          ##
 560 ## Set automake variables for optional feature conditionnals in Makefile.am ##
 561 ##                                                                          ##
 562
 563 AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([examples]))
 564 AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])
 565 AM_CONDITIONAL([ENABLE_JAVA_AGENT], AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 566 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], AE_IS_FEATURE_ENABLED([java-agent-jul]))
 567 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], AE_IS_FEATURE_ENABLED([java-agent-log4j]))
 568 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J2], AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 569 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J_COMMON], AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 570 AM_CONDITIONAL([ENABLE_JNI_INTERFACE], AE_IS_FEATURE_ENABLED([jni-interface]))
 571 AM_CONDITIONAL([ENABLE_MAN_PAGES], AE_IS_FEATURE_ENABLED([man-pages]))
 572 AM_CONDITIONAL([ENABLE_NUMA], AE_IS_FEATURE_ENABLED([numa]))
 573 AM_CONDITIONAL([ENABLE_PYTHON_AGENT], AE_IS_FEATURE_ENABLED([python-agent]))
 574 AM_CONDITIONAL([ENABLE_UST_DL], [test "x$ac_cv_have_decl_RTLD_DI_LINKMAP" = "xyes"])
 575 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 576 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
 577 AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
 578 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 579 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])
 580 AM_CONDITIONAL([ENABLE_LTTNG_UST_CUSTOM_UPGRADE_CONFLICTING_SYMBOLS], AE_IS_FEATURE_ENABLED([custom-upgrade-conflicting-symbols]))
 581
 582 ##                                             ##
 583 ## Substitute variables for use in Makefile.am ##
 584 ##                                             ##
 585
 586 # Library versions for libtool
 587 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], ust_lib_version)
 588 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], ust_ctl_lib_version)
 589
 590 # Major soname for python-lttngust
 591 AC_SUBST([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current])
 592
 593 AM_CFLAGS="$OPT_CFLAGS $WARN_CFLAGS $URCU_CFLAGS $PTHREAD_CFLAGS"
 594 AC_SUBST(AM_CFLAGS)
 595
 596 AM_CXXFLAGS="$WARN_CXXFLAGS $URCU_CFLAGS $PTHREAD_CFLAGS"
 597 AC_SUBST(AM_CXXFLAGS)
 598
 599 # The order in which the include folders are searched is important.
 600 # The top_builddir should always be searched first in the event that a build
 601 # time generated file is included.
 602 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 603 AC_SUBST(AM_CPPFLAGS)
 604
 605 AC_SUBST(JNI_CPPFLAGS)
 606
 607
 608 ##                                     ##
 609 ## Output files generated by configure ##
 610 ##                                     ##
 611
 612 # List of files to be generated from '.in' templates by AC_OUTPUT
 613 AC_CONFIG_FILES([
 614   Makefile
 615   doc/examples/Makefile
 616   doc/Makefile
 617   doc/man/Makefile
 618   extras/Makefile
 619   include/Makefile
 620   src/common/Makefile
 621   src/lib/lttng-ust-common/Makefile
 622   src/lib/lttng-ust-ctl/Makefile
 623   src/lib/lttng-ust-cyg-profile/Makefile
 624   src/lib/lttng-ust-dl/Makefile
 625   src/lib/lttng-ust-fd/Makefile
 626   src/lib/lttng-ust-fork/Makefile
 627   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 628   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 629   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 630   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 631   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-log4j2/Makefile
 632   src/lib/lttng-ust-java-agent/java/Makefile
 633   src/lib/lttng-ust-java-agent/jni/common/Makefile
 634   src/lib/lttng-ust-java-agent/jni/jul/Makefile
 635   src/lib/lttng-ust-java-agent/jni/log4j/Makefile
 636   src/lib/lttng-ust-java-agent/jni/Makefile
 637   src/lib/lttng-ust-java-agent/Makefile
 638   src/lib/lttng-ust-java/Makefile
 639   src/lib/lttng-ust-libc-wrapper/Makefile
 640   src/lib/lttng-ust-pthread-wrapper/Makefile
 641   src/lib/lttng-ust-tracepoint/Makefile
 642   src/lib/lttng-ust/Makefile
 643   src/lib/lttng-ust-python-agent/Makefile
 644   src/lib/Makefile
 645   src/lib/lttng-ust-ctl.pc
 646   src/lib/lttng-ust.pc
 647   src/Makefile
 648   src/python-lttngust/lttngust/version.py
 649   src/python-lttngust/Makefile
 650   src/python-lttngust/setup.py
 651   tests/benchmark/Makefile
 652   tests/compile/api0/ctf-types/Makefile
 653   tests/compile/api0/hello.cxx/Makefile
 654   tests/compile/api0/hello/Makefile
 655   tests/compile/api0/hello-many/Makefile
 656   tests/compile/api0/Makefile
 657   tests/compile/api0/same_line_tracepoint/Makefile
 658   tests/compile/api1/ust-fields/Makefile
 659   tests/compile/api1/hello.cxx/Makefile
 660   tests/compile/api1/hello/Makefile
 661   tests/compile/api1/hello-many/Makefile
 662   tests/compile/api1/Makefile
 663   tests/compile/api1/same_line_tracepoint/Makefile
 664   tests/compile/api1/test-app-ctx/Makefile
 665   tests/compile/Makefile
 666   tests/Makefile
 667   tests/regression/abi0-conflict/Makefile
 668   tests/regression/Makefile
 669   tests/unit/gcc-weak-hidden/Makefile
 670   tests/unit/libcommon/Makefile
 671   tests/unit/libmsgpack/Makefile
 672   tests/unit/libringbuffer/Makefile
 673   tests/unit/Makefile
 674   tests/unit/pthread_name/Makefile
 675   tests/unit/snprintf/Makefile
 676   tests/unit/ust-elf/Makefile
 677   tests/unit/ust-error/Makefile
 678   tests/unit/ust-utils/Makefile
 679   tests/utils/Makefile
 680   tools/Makefile
 681 ])
 682
 683 AC_OUTPUT
 684
 685
 686 ##                                    ##
 687 ## Mini-report on what will be built. ##
 688 ##                                    ##
 689
 690 PPRINT_INIT
 691 PPRINT_SET_INDENT(1)
 692 PPRINT_SET_TS(38)
 693
 694 AS_ECHO
 695 AS_IF([test -n "ust_version_name"], [
 696   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
 697 ], [
 698   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
 699 ])
 700
 701 AS_ECHO
 702
 703 AS_IF([test -n "ust_version_description"], [
 704   AS_IF([test -n "$FOLD"], [
 705     AS_ECHO(["ust_version_description"]) | $FOLD -s
 706   ], [
 707     AS_ECHO(["ust_version_description"])
 708   ])
 709   AS_ECHO
 710 ])
 711
 712 PPRINT_SUBTITLE([System])
 713
 714 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 715
 716 AS_IF([test "x$unsupported_arch" = "xyes"],[
 717        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 718 ])
 719
 720 AS_ECHO
 721 PPRINT_SUBTITLE([Features])
 722 PPRINT_SET_INDENT(1)
 723
 724 test "x$with_sdt" = "xyes" && value=1 || value=0
 725 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 726
 727 AE_IS_FEATURE_ENABLED([java-agent-jul]) && value=1 || value=0
 728 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 729
 730 AE_IS_FEATURE_ENABLED([java-agent-log4j]) && value=1 || value=0
 731 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j 1.x support)], $value, [use --enable-java-agent-log4j])
 732
 733 AE_IS_FEATURE_ENABLED([java-agent-log4j2]) && value=1 || value=0
 734 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j 2.x support)], $value, [use --enable-java-agent-log4j2])
 735
 736 AE_IS_FEATURE_ENABLED([jni-interface]) && value=1 || value=0
 737 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 738
 739 AE_IS_FEATURE_ENABLED([python-agent]) && value=1 || value=0
 740 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 741
 742 test "x$ac_cv_header_linux_perf_event_h" = "xyes" && value=1 || value=0
 743 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 744
 745 AE_IS_FEATURE_ENABLED([numa]) && value=1 || value=0
 746 PPRINT_PROP_BOOL([NUMA], $value)
 747
 748 AS_ECHO
 749 PPRINT_SET_INDENT(0)
 750
 751 AE_IS_FEATURE_ENABLED([examples]) && value=1 || value=0
 752 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 753
 754 # man pages build enabled/disabled
 755 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 756
 757 AE_IF_FEATURE_ENABLED([man-pages], [
 758   AE_IF_IN_GIT_REPO([
 759     PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 760   ], [
 761     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 762       PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 763     ], [
 764       PPRINT_PROP_STRING([build_man_pages_msg],
 765         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 766         $PPRINT_COLOR_SUBTITLE)
 767     ])
 768   ])
 769 ], [
 770   PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 771 ])
 772
 773 m4_popdef([build_man_pages_msg])
 774
 775 PPRINT_SET_INDENT(1)
 776
 777 report_bindir="`eval eval echo $bindir`"
 778 report_libdir="`eval eval echo $libdir`"
 779
 780 # Print the bindir and libdir this `make install' will install into.
 781 AS_ECHO
 782 PPRINT_SUBTITLE([Install directories])
 783 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 784 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 785
 786 AS_ECHO
 787 PPRINT_SUBTITLE([System directories])
 788
 789 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 790
 791 PPRINT_SET_INDENT(0)
 792
 793 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 794   AS_ECHO
 795   PPRINT_WARN([dnl
 796 Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 797
 798 Note that the man pages are already built in this distribution tarball,
 799 therefore asciidoc and xmlto are only needed if you intend to modify
 800 their sources.
 801
 802 Use --disable-man-pages to completely disable building and installing
 803 the man pages.])
 804 ])
 805
 806 # vim: shiftwidth=2 softtabstop=2 expandtab