m4/ax_check_compile_flag.m4

   1 # SPDX-License-Identifier: FSFAP
   2 # ===========================================================================
   3 #  https://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
   4 # ===========================================================================
   5 #
   6 # SYNOPSIS
   7 #
   8 #   AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
   9 #
  10 # DESCRIPTION
  11 #
  12 #   Check whether the given FLAG works with the current language's compiler
  13 #   or gives an error.  (Warnings, however, are ignored)
  14 #
  15 #   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
  16 #   success/failure.
  17 #
  18 #   If EXTRA-FLAGS is defined, it is added to the current language's default
  19 #   flags (e.g. CFLAGS) when the check is done.  The check is thus made with
  20 #   the flags: "CFLAGS EXTRA-FLAGS FLAG".  This can for example be used to
  21 #   force the compiler to issue an error when a bad flag is given.
  22 #
  23 #   INPUT gives an alternative input source to AC_COMPILE_IFELSE.
  24 #
  25 #   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
  26 #   macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
  27 #
  28 # LICENSE
  29 #
  30 #   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
  31 #   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
  32 #
  33 #   Copying and distribution of this file, with or without modification, are
  34 #   permitted in any medium without royalty provided the copyright notice
  35 #   and this notice are preserved.  This file is offered as-is, without any
  36 #   warranty.
  37
  38 #serial 6
  39
  40 AC_DEFUN([AX_CHECK_COMPILE_FLAG],
  41 [AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
  42 AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
  43 AC_CACHE_CHECK([whether _AC_LANG compiler accepts $1], CACHEVAR, [
  44   ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  45   _AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
  46   AC_COMPILE_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
  47     [AS_VAR_SET(CACHEVAR,[yes])],
  48     [AS_VAR_SET(CACHEVAR,[no])])
  49   _AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
  50 AS_VAR_IF(CACHEVAR,yes,
  51   [m4_default([$2], :)],
  52   [m4_default([$3], :)])
  53 AS_VAR_POPDEF([CACHEVAR])dnl
  54 ])dnl AX_CHECK_COMPILE_FLAGS